configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl !!! WHEN ADDING NEW CONFIGURE TESTS, PLEASE ADD CODE TO MAIN.C !!!
   4 dnl !!! TO DUMP THEIR RESULTS WHEN MUTT -V IS CALLED            !!!
   5
   6 AC_PREREQ([2.50])
   7 AC_INIT([mutt.h])
   8 AM_CONFIG_HEADER(config.h)
   9 AM_INIT_AUTOMAKE(madmutt, `cat "$srcdir/VERSION.in"`)
  10
  11 AC_SUBST([CONFIGURE_DEPENDENCIES], ['$(top_srcdir)/VERSION.in'])
  12
  13 AC_GNU_SOURCE
  14
  15 ALL_LINGUAS="de ru it es uk fr pl nl cs id sk ko el zh_TW zh_CN pt_BR eo gl sv da lt tr ja hu et ca bg"
  16
  17 AC_CANONICAL_HOST
  18
  19 AC_PROG_CPP
  20 AC_PROG_CC_C99
  21 AC_ISC_POSIX
  22 AC_HEADER_STDC
  23
  24 PKG_PROG_PKG_CONFIG
  25 AC_PROG_MAKE_SET
  26 AC_PROG_INSTALL
  27 AC_PROG_RANLIB
  28 AC_PROG_GPERF
  29 AC_CHECK_TOOL(AR, ar, ar)
  30
  31 AC_SYS_LARGEFILE
  32 AC_FUNC_FSEEKO
  33 AC_CHECK_SIZEOF(off_t)
  34
  35 AH_TEMPLATE([sig_atomic_t],
  36             [Define to 'int' if <signal.h> doesn't define.])
  37 AH_TEMPLATE([HAVE_START_COLOR],
  38             [Define if you have start_color, as a function or macro.])
  39 AH_TEMPLATE([HAVE_TYPEAHEAD],
  40             [Define if you have typeahead, as a function or macro.])
  41 AH_TEMPLATE([HAVE_BKGDSET],
  42             [Define if you have bkgdset, as a function or macro.])
  43 AH_TEMPLATE([HAVE_CURS_SET],
  44             [Define if you have curs_set, as a function or macro.])
  45 AH_TEMPLATE([HAVE_META],
  46             [Define if you have meta, as a function or macro.])
  47 AH_TEMPLATE([HAVE_USE_DEFAULT_COLORS],
  48             [Define if you have use_default_colors, as a function or macro.])
  49 AH_TEMPLATE([HAVE_RESIZETERM],
  50             [Define if you have resizeterm, as a function or macro.])
  51 AH_TEMPLATE([SIG_ATOMIC_VOLATILE_T],
  52             [Some systems declare sig_atomic_t as volatile, some others -- no.
  53              This define will have value `sig_atomic_t' or
  54              `volatile sig_atomic_t' accordingly.])
  55 AH_TEMPLATE([ICONV_NONTRANS],
  56             [Define as 1 if iconv() only converts exactly and we should treat
  57              all return values other than (size_t)(-1) as equivalent.])
  58
  59 dnl ---------------- sendmail ----------------
  60
  61 ac_aux_path_sendmail=/usr/sbin:/usr/lib
  62 AC_PATH_PROG(SENDMAIL, sendmail, /usr/sbin/sendmail, $PATH:$ac_aux_path_sendmail)
  63 AC_DEFINE_UNQUOTED(SENDMAIL,"$ac_cv_path_SENDMAIL",[ Where to find sendmail on your system. ])
  64
  65 OPS="\$(srcdir)/OPS"
  66
  67 dnl ---------------- gpgme ----------------
  68
  69 AC_ARG_ENABLE(gpgme, AC_HELP_STRING([--enable-gpgme], [Enable GPGME support]),[
  70     if test x$enableval = xyes; then
  71         AM_PATH_GPGME(,,[AC_MSG_ERROR(GPGME not found)])
  72         MUTTLIBS="$MUTTLIBS $GPGME_LIBS"
  73         AC_DEFINE(CRYPT_BACKEND_GPGME, 1, [Defined, if GPGME support is enabled])
  74         AM_CONDITIONAL(BUILD_GPGME, true)
  75     else
  76         AM_CONDITIONAL(BUILD_GPGME, false)
  77     fi
  78 ])
  79
  80 dnl ---------------- mixmaster ----------------
  81
  82 AC_ARG_WITH(mixmaster, AC_HELP_STRING([--with-mixmaster[=PATH]], [Include Mixmaster support]), [
  83     MIXMASTER=${withval:-"mixmaster"}
  84     OPS="$OPS \$(srcdir)/OPS.MIX"
  85     MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS remailer.o"
  86     AC_DEFINE_UNQUOTED(MIXMASTER,"$MIXMASTER",[Where to find mixmaster on your system.])
  87 ])
  88
  89 AC_SUBST([OPS])
  90
  91 AC_PATH_PROG(ISPELL, ispell, no)
  92 if test $ISPELL != no; then
  93     AC_DEFINE_UNQUOTED(ISPELL,"$ISPELL",[Where to find ispell on your system.])
  94 fi
  95
  96 AC_ARG_WITH(slang, AC_HELP_STRING([--with-slang[=DIR]], [Use S-Lang instead of ncurses]),
  97     [AC_CACHE_CHECK([if this is a BSD system], mutt_cv_bsdish,
  98         [AC_TRY_RUN([#include <sys/param.h>
  99
 100 main ()
 101 {
 102 #ifdef BSD
 103         exit (0);
 104 #else
 105         exit (1);
 106 #endif
 107 }],
 108         mutt_cv_bsdish=yes,
 109         mutt_cv_bsdish=no,
 110         mutt_cv_bsdish=no)])
 111
 112         AC_MSG_CHECKING(for S-Lang)
 113         if test $withval = yes; then
 114             if test -d $srcdir/../slang; then
 115                 mutt_cv_slang=$srcdir/../slang/src
 116                 CFLAGS="$CFLAGS -I${mutt_cv_slang}"
 117                 LDFLAGS="$LDFLAGS -L${mutt_cv_slang}/objs"
 118             else
 119                 if test -d ${prefix}/include/slang; then
 120                     CFLAGS="$CFLAGS -I${prefix}/include/slang"
 121                 elif test -d /usr/include/slang; then
 122                     CFLAGS="$CFLAGS -I/usr/include/slang"
 123                 fi
 124                 mutt_cv_slang=yes
 125             fi
 126         else
 127             dnl ---Check to see if $withval is a source directory
 128             if test -f $withval/src/slang.h; then
 129                 mutt_cv_slang=$withval/src
 130                 CFLAGS="$CFLAGS -I${mutt_cv_slang}"
 131                 LDFLAGS="$LDFLAGS -L${mutt_cv_slang}/objs"
 132             else
 133                 dnl ---Must be installed somewhere
 134                 mutt_cv_slang=$withval
 135                 if test -d $withval/include/slang; then
 136                         CFLAGS="$CFLAGS -I${withval}/include/slang"
 137                 elif test -d $withval/include; then
 138                         CFLAGS="$CFLAGS -I${withval}/include"
 139                 fi
 140                 LDFLAGS="$LDFLAGS -L${withval}/lib"
 141             fi
 142         fi
 143         AC_MSG_RESULT($mutt_cv_slang)
 144         if test $mutt_cv_bsdish = yes; then
 145             AC_CHECK_LIB(termlib, main)
 146         fi
 147         AC_DEFINE(USE_SLANG_CURSES,1, [ Define if you compile with SLang instead of curses/ncurses. ])
 148         AC_DEFINE(HAVE_COLOR,1,[ Define if your curses library supports color. ])
 149
 150         dnl --- now that we've found it, check the link
 151
 152         AC_CHECK_LIB(slang, SLtt_get_terminfo,
 153             [MUTTLIBS="$MUTTLIBS -lslang -lm"],
 154             [AC_MSG_ERROR(unable to compile.  check config.log)], -lm)
 155     ],
 156     [   mutt_cv_curses=/usr
 157         AC_ARG_WITH(curses, AC_HELP_STRING([--with-curses=DIR], [Where ncurses is installed]), [
 158             if test $withval != yes; then
 159                 mutt_cv_curses=$withval
 160             fi
 161             if test x$mutt_cv_curses != x/usr; then
 162                 LDFLAGS="-L${mutt_cv_curses}/lib $LDFLAGS"
 163                 CPPFLAGS="$CPPFLAGS -I${mutt_cv_curses}/include"
 164             fi
 165         ])
 166
 167         AC_CHECK_FUNC(initscr,,[
 168         cf_ncurses="ncurses"
 169         for lib in ncursesw ncurses; do
 170             AC_CHECK_LIB($lib, waddnwstr, [cf_ncurses="$lib"; break])
 171         done
 172         AC_CHECK_LIB($cf_ncurses, initscr,
 173             [   MUTTLIBS="$MUTTLIBS -l$cf_ncurses"
 174                 if test x$mutt_cv_curses = x/usr -a -d /usr/include/ncurses; then
 175                     CPPFLAGS="$CPPFLAGS -I/usr/include/ncurses"
 176                 fi
 177
 178                 if test "$cf_ncurses" = ncursesw; then
 179                     AC_CHECK_HEADERS(ncurses/ncurses.h,[cf_cv_ncurses_header="ncurses/ncurses.h"])
 180                     AC_CHECK_HEADERS(ncursesw/ncurses.h,[cf_cv_ncurses_header="ncursesw/ncurses.h"])
 181                 else
 182                     AC_CHECK_HEADERS(ncurses.h,[cf_cv_ncurses_header="ncurses.h"])
 183                 fi
 184             ],
 185             [CF_CURSES_LIBS])
 186         ])
 187
 188         old_LIBS="$LIBS"
 189         LIBS="$LIBS $MUTTLIBS"
 190         CF_CHECK_FUNCDECLS([#include <${cf_cv_ncurses_header-curses.h}>],
 191                            [start_color typeahead bkgdset curs_set meta use_default_colors resizeterm])
 192         if test "$ac_cv_func_decl_start_color" = yes; then
 193             AC_DEFINE(HAVE_COLOR,1,[ Define if your curses library supports color. ])
 194         fi
 195         LIBS="$old_LIBS"
 196     ])
 197
 198 AC_CHECK_HEADERS(stdarg.h sys/ioctl.h ioctl.h sysexits.h)
 199 AC_CHECK_HEADERS(sys/time.h sys/resource.h)
 200 AC_CHECK_HEADERS(unix.h)
 201
 202 AC_CHECK_FUNCS(setrlimit getsid isctype)
 203
 204 AC_TYPE_SIGNAL
 205
 206 AC_MSG_CHECKING(for sig_atomic_t in signal.h)
 207 AC_EGREP_HEADER(sig_atomic_t,signal.h,
 208     [   ac_cv_type_sig_atomic_t=yes;
 209         AC_EGREP_HEADER(volatile.*sig_atomic_t,
 210                         signal.h,
 211                         [is_sig_atomic_t_volatile=yes; AC_MSG_RESULT([yes, volatile])],
 212                         [is_sig_atomic_t_volatile=no;  AC_MSG_RESULT([yes, non volatile])])
 213     ],
 214     [   AC_MSG_RESULT(no)
 215         AC_CHECK_TYPE(sig_atomic_t, int)
 216         is_sig_atomic_t_volatile=no
 217     ])
 218 if test $is_sig_atomic_t_volatile = 'yes'
 219 then
 220     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, sig_atomic_t)
 221 else
 222     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, [volatile sig_atomic_t])
 223 fi
 224
 225 AC_DECL_SYS_SIGLIST
 226 AC_TYPE_PID_T
 227
 228 AC_CHECK_FUNC(getopt)
 229 if test $ac_cv_func_getopt = yes; then
 230     AC_CHECK_HEADERS(getopt.h)
 231 fi
 232
 233 AC_CHECK_FUNC(regcomp)
 234 if test $ac_cv_func_regcomp = yes; then
 235    AC_CHECK_HEADERS(regex.h)
 236 fi
 237
 238 AC_ARG_WITH(homespool,
 239             AC_HELP_STRING([--with-homespool[=FILE]],
 240                            [File in user's directory where new mail is spooled]),
 241                            with_homespool=${withval})
 242 if test x$with_homespool != x; then
 243     if test $with_homespool = yes; then
 244             with_homespool=mailbox
 245     fi
 246     AC_DEFINE_UNQUOTED(MAILPATH,"$with_homespool",[ Where new mail is spooled. ])
 247     AC_DEFINE(HOMESPOOL,1,
 248     [   Is mail spooled to the user's home directory?  If defined,
 249         MAILPATH should be set to the filename of the spool mailbox
 250         relative the the home directory.
 251         use: configure --with-homespool=FILE
 252     ])
 253     mutt_cv_setgid=no
 254 else
 255     AC_ARG_WITH(mailpath, AC_HELP_STRING([--with-mailpath=DIR], [Directory where spool mailboxes are located]),
 256         [mutt_cv_mailpath=$withval],
 257         [ AC_CACHE_CHECK(where new mail is stored, mutt_cv_mailpath,
 258             [mutt_cv_mailpath=no
 259             if test -d /var/mail; then
 260                 mutt_cv_mailpath=/var/mail
 261             elif test -d /var/spool/mail; then
 262                 mutt_cv_mailpath=/var/spool/mail
 263             elif test -d /usr/spool/mail; then
 264                 mutt_cv_mailpath=/usr/spool/mail
 265             elif test -d /usr/mail; then
 266                 mutt_cv_mailpath=/usr/mail
 267             fi])
 268         ])
 269     if test "$mutt_cv_mailpath" = no; then
 270         AC_MSG_ERROR("Could not determine where new mail is stored.")
 271     fi
 272     AC_DEFINE_UNQUOTED(MAILPATH,"$mutt_cv_mailpath",[ Where new mail is spooled. ])
 273
 274     AC_CACHE_CHECK(if $mutt_cv_mailpath is world writable, mutt_cv_worldwrite, [AC_TRY_RUN([#include <sys/types.h>
 275 #include <sys/stat.h>
 276
 277 int main (int argc, char **argv)
 278 {
 279         struct stat s;
 280
 281         stat ("$mutt_cv_mailpath", &s);
 282         if (s.st_mode & S_IWOTH) exit (0);
 283         exit (1);
 284 }], mutt_cv_worldwrite=yes, mutt_cv_worldwrite=no, mutt_cv_worldwrite=no)])
 285
 286         mutt_cv_setgid=no
 287         if test $mutt_cv_worldwrite != yes; then
 288                 AC_CACHE_CHECK(if $mutt_cv_mailpath is group writable, mutt_cv_groupwrite, [AC_TRY_RUN([#include <sys/types.h>
 289 #include <sys/stat.h>
 290
 291 int main (int argc, char **argv)
 292 {
 293         struct stat s;
 294
 295         stat ("$mutt_cv_mailpath", &s);
 296         if (s.st_mode & S_IWGRP) exit (0);
 297         exit (1);
 298 }], mutt_cv_groupwrite=yes, mutt_cv_groupwrite=no, mutt_cv_groupwrite=no)])
 299
 300         if test $mutt_cv_groupwrite = yes; then
 301             AC_DEFINE(USE_SETGID,1,[ Define if mutt should run setgid "mail". ])
 302             mutt_cv_setgid=yes
 303         fi
 304     fi
 305 fi
 306
 307 AC_MSG_CHECKING(where to put the documentation)
 308 AC_ARG_WITH(docdir, AC_HELP_STRING([--with-docdir=PATH], [Specify where to put the documentation]),
 309         [mutt_cv_docdir=$withval],
 310         [mutt_cv_docdir="${prefix}/doc/madmutt"])
 311 AC_MSG_RESULT($mutt_cv_docdir)
 312
 313 docdir=$mutt_cv_docdir
 314 AC_SUBST(docdir)
 315
 316 if test x$mutt_cv_setgid = xyes; then
 317     DOTLOCK_GROUP='mail'
 318     DOTLOCK_PERMISSION=2755
 319 else
 320     DOTLOCK_GROUP=''
 321     DOTLOCK_PERMISSION=755
 322 fi
 323 AC_SUBST(DOTLOCK_GROUP)
 324 AC_SUBST(DOTLOCK_PERMISSION)
 325
 326 dnl -- socket dependencies --
 327
 328 AC_ARG_ENABLE(nntp, AC_HELP_STRING([--enable-nntp],[Enable NNTP support]),[
 329     if test x$enableval = xyes ; then
 330         AC_DEFINE(USE_NNTP,1,[ Compiling with newsreading support with NNTP ])
 331         LIBNNTP="-Lnntp -lnntp"
 332         LIBNNTPDEPS="\$(top_srcdir)/nntp/nntp.h nntp/libnntp.a"
 333         need_nntp="yes"
 334     fi
 335 ])
 336 AM_CONDITIONAL(BUILD_NNTP, test x$need_nntp = xyes)
 337
 338 AC_MSG_CHECKING([for socklen_t])
 339 AC_EGREP_HEADER(socklen_t, sys/socket.h, AC_MSG_RESULT([yes]),
 340         AC_MSG_RESULT([no])
 341         AC_DEFINE(socklen_t,int, [ Define to 'int' if <sys/socket.h> doesn't have it. ]))
 342 AC_CHECK_FUNC(gethostent, , AC_CHECK_LIB(nsl, gethostent))
 343 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt))
 344 AC_CHECK_FUNCS(getaddrinfo)
 345
 346 dnl -- imap dependencies --
 347
 348 AC_ARG_WITH(gss, AC_HELP_STRING([--with-gss], [Compile in GSSAPI authentication for IMAP]),[
 349     if test x$with_gss != xno; then
 350         PKG_CHECK_MODULES(GSSAPI,libgssapi,[
 351             CPPFLAGS="$CPPFLAGS $GSSAPI_CFLAGS"
 352             MUTTLIBS="$MUTTLIBS $GSSAPI_LIBS"
 353             AC_DEFINE(USE_GSS,1,[ Define if you have GSSAPI libraries available ])
 354             AC_CHECK_HEADERS(xom.h)
 355         ],[
 356            AC_MSG_ERROR([could not find libgssapi])
 357         ])
 358     fi
 359 ])
 360
 361 AC_ARG_WITH(ssl, AC_HELP_STRING([--with-ssl[=PFX]], [Compile in SSL support for POP/IMAP]),
 362 [   if test "$with_ssl" != "no"; then
 363         if test "$with_ssl" != "yes"; then
 364             LDFLAGS="$LDFLAGS -L$withval/lib"
 365             CPPFLAGS="$CPPFLAGS -I$withval/include"
 366         fi
 367         saved_LIBS="$LIBS"
 368
 369         AC_CHECK_LIB(crypto, X509_new,, AC_MSG_ERROR([Unable to find SSL library]))
 370         AC_CHECK_LIB(ssl, SSL_new,, AC_MSG_ERROR([Unable to find SSL library]), -lcrypto)
 371
 372         AC_CHECK_FUNCS(RAND_status RAND_egd)
 373
 374         AC_DEFINE(USE_SSL,1,[ Define if you want support for SSL. ])
 375         LIBS="$saved_LIBS"
 376         MUTTLIBS="$MUTTLIBS -lssl -lcrypto"
 377         need_ssl=yes
 378     fi
 379 ])
 380
 381 AC_ARG_WITH([gnutls], AC_HELP_STRING([--with-gnutls], [Enable SSL support using gnutls]),
 382             [gnutls_prefix="$withval"], [gnutls_prefix="no"])
 383 if test "$gnutls_prefix" != "no"; then
 384     if test x"$need_ssl" = x"yes"; then
 385         AC_MSG_ERROR([Only either OpenSSL or GNUTLS may be used])
 386     fi
 387     AM_PATH_LIBGNUTLS(,[
 388         CPPFLAGS="$CPPFLAGS $LIBGNUTLS_CFLAGS"
 389         MUTTLIBS="$MUTTLIBS $LIBGNUTLS_LIBS"
 390         AC_DEFINE(USE_GNUTLS, 1, [Define if you want support for SSL via the gnutls library.])
 391         need_ssl=yes],
 392         [AC_MSG_ERROR([could not find libgnutls])
 393     ])
 394 fi
 395 AM_CONDITIONAL(USE_SSL, test x$need_ssl = xyes)
 396 AC_SUBST(MUTT_SSL_OBJECTS)
 397
 398 AC_ARG_WITH(sasl2, AC_HELP_STRING([--with-sasl2[=PFX]],
 399             [Use Cyrus SASL library version 2 for POP/IMAP authentication]),[
 400     if test "$with_sasl2" != "no"; then
 401         if test "$with_sasl2" != "yes"; then
 402             CPPFLAGS="$CPPFLAGS -I$with_sasl2/include"
 403             LDFLAGS="$LDFLAGS -L$with_sasl2/lib"
 404         fi
 405
 406         saved_LIBS="$LIBS"
 407
 408         AC_CHECK_LIB(sasl2, sasl_client_init,,AC_MSG_ERROR([could not find libsasl2]))
 409
 410         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_sasl.o"
 411         MUTTLIBS="$MUTTLIBS -lsasl2"
 412         LIBS="$saved_LIBS"
 413         AC_DEFINE(USE_SASL,1,
 414                   [Define if want to use version 2 of the Cyrus SASL library.])
 415         need_sasl=yes
 416     fi
 417 ])
 418 AM_CONDITIONAL(USE_SASL, test x$need_sasl = xyes)
 419
 420 AC_ARG_WITH(idn, AC_HELP_STRING([--with-idn], [Use GNU libidn for domain names]),[
 421     if test x$with_idn != xno ; then
 422         PKG_CHECK_MODULES(IDN,libidn,[
 423             if $PKG_CONFIG --atleast-version=0.6; then
 424                 AC_MSG_ERROR([libidn is too old, want 0.6 at least])
 425             fi
 426             CPPFLAGS="$CPPFLAGS $IDN_CFLAGS"
 427             LDFLAGS="$LDFLAGS $IDN_LIBS"
 428         ],[AC_MSG_ERROR([could not find libidn])])
 429     fi
 430 ])
 431
 432 dnl -- end socket --
 433
 434 AC_ARG_ENABLE(flock, AC_HELP_STRING([--enable-flock], [Use flock() to lock files]),
 435         [if test $enableval = yes; then
 436                 AC_DEFINE(USE_FLOCK,1, [ Define to use flock() to lock mailboxes. ])
 437         fi])
 438
 439 mutt_cv_fcntl=yes
 440 AC_ARG_ENABLE(fcntl, AC_HELP_STRING([--disable-fcntl], [Do NOT use fcntl() to lock files]),
 441         [if test $enableval = no; then mutt_cv_fcntl=no; fi])
 442
 443 if test $mutt_cv_fcntl = yes; then
 444         AC_DEFINE(USE_FCNTL,1, [ Define to use fcntl() to lock folders. ])
 445 fi
 446
 447 AC_MSG_CHECKING(whether struct dirent defines d_ino)
 448 ac_cv_dirent_d_ino=no
 449 AC_TRY_LINK([#include <dirent.h>],[struct dirent dp; (void)dp.d_ino],[ac_cv_dirent_d_ino=yes])
 450 if test x$ac_cv_dirent_d_ino = xyes ; then
 451   AC_DEFINE(HAVE_DIRENT_D_INO,1,
 452             [Define to 1 if your system has the dirent::d_ino member])
 453 fi
 454 AC_MSG_RESULT($ac_cv_dirent_d_ino)
 455
 456 dnl -- start cache --
 457 AC_ARG_ENABLE(hcache, AC_HELP_STRING([--enable-hcache], [Enable header caching]),
 458 [if test x$enableval = xyes; then
 459     AC_DEFINE(USE_HCACHE, 1, [Enable header caching])
 460
 461     OLDCPPFLAGS="$CPPFLAGS"
 462     OLDLIBS="$LIBS"
 463
 464     need_md5="yes"
 465
 466     ac_prefer_qdbm=yes
 467     AC_ARG_WITH(qdbm, AC_HELP_STRING([--without-qdbm], [Don't use qdbm even if it is available]),
 468         ac_prefer_qdbm=$withval)
 469     if test x$ac_prefer_qdbm != xno; then
 470         PKG_CHECK_MODULES(QDBM,qdbm,[ac_qdbm_here=yes],[ac_qdbm_here=no])
 471     fi
 472
 473     ac_prefer_gdbm=yes
 474     AC_ARG_WITH(gdbm, AC_HELP_STRING([--without-gdbm], [Don't use gdbm even if it is available]),
 475         ac_prefer_gdbm=$withval)
 476     if test x$ac_prefer_gdbm != xno -a x$ac_qdbm_here != xyes; then
 477         ac_cv_gdbmopen=no
 478         GDBM_DIRS="${prefix} /usr/local /usr"
 479         AC_MSG_CHECKING([for gdbm_open])
 480         for d in $GDBM_DIRS; do
 481           if test x$ac_cv_gdbmopen = xno && test -d "$d/include" && test -d "$d/lib"; then
 482             GDBM_INC="-I$d/include"
 483             GDBM_LIB="-L$d/lib"
 484             CPPFLAGS="$OLDCPPFLAGS $GDBM_INC"
 485             LIBS="$OLDLIBS $GDBM_LIB -lgdbm"
 486             AC_TRY_LINK([#include <gdbm.h>],[gdbm_open(0,0,0,0,0);],[ac_cv_gdbmopen=yes])
 487           fi
 488         done
 489         if test x$ac_cv_gdbmopen = xyes; then
 490           AC_MSG_RESULT(yes)
 491         else
 492           AC_MSG_RESULT(no)
 493         fi
 494     fi
 495
 496     ac_bdb_prefix=yes
 497     AC_ARG_WITH(bdb, AC_HELP_STRING([--with-bdb[=DIR]], [Use BerkeleyDB4 if gdbm is not available ]),
 498         ac_bdb_prefix=$withval)
 499     if test x$ac_bdb_prefix != xno -a x$ac_cv_gdbmopen != xyes -a x$ac_qdbm_here != xyes; then
 500         test x$ac_bdb_prefix = xyes && ac_bdb_prefix="${prefix} /opt/csw/bdb4 /opt /usr/local /usr"
 501         for d in $ac_bdb_prefix; do
 502             bdbpfx="$bdbpfx $d"
 503             for v in BerkeleyDB.4.3 BerkeleyDB.4.2 BerkeleyDB.4.1; do
 504                 bdbpfx="$bdbpfx $d/$v"
 505             done
 506         done
 507         BDB_VERSIONS="db-4 db4 db-4.3 db4.3 db43 db-4.2 db4.2 db42 db-4.1 db4.1 db41 db ''"
 508         AC_MSG_CHECKING([for BerkeleyDB > 4.0])
 509         for d in $bdbpfx; do
 510             BDB_INCLUDE_DIR=""
 511             BDB_LIB_DIR=""
 512             for v in / $BDB_VERSIONS; do
 513                 if test -r "$d/include/$v/db.h"; then
 514                     BDB_INCLUDE_DIR="$d/include/$v"
 515                     if test -d "$d/lib/$v"; then
 516                         BDB_LIB_DIR="$d/lib/$v"
 517                         for l in `echo $BDB_VERSIONS`; do
 518                             CPPFLAGS="-I$BDB_INCLUDE_DIR $OLDCPPFLAGS"
 519                             LIBS="$OLDLIBS -L$BDB_LIB_DIR -l$l"
 520                             AC_TRY_LINK([
 521                                 #include <stdlib.h>
 522                                 #include <db.h>
 523                             ],[
 524                                 DB *db = NULL;
 525                                 db->open(db,NULL,NULL,NULL,0,0,0);
 526                             ],[
 527                                 ac_cv_dbcreate=yes
 528                                 BDB_LIB="$l"
 529                                 break
 530                             ])
 531                         done
 532                         test x$ac_cv_dbcreate = xyes && break
 533                     fi
 534                 fi
 535             done
 536             test x$BDB_LIB != x && break
 537         done
 538         if test x$ac_cv_dbcreate = xyes; then
 539             AC_MSG_RESULT(yes)
 540         else
 541             AC_MSG_RESULT(no)
 542         fi
 543     fi
 544
 545     if test x$ac_qdbm_here = xyes; then
 546         CPPFLAGS="$OLDCPPFLAGS $QDBM_CFLAGS"
 547         LIBS="$OLDLIBS $QDBM_LIBS"
 548         AC_DEFINE(HAVE_QDBM, 1, [QDBM Support])
 549     elif test x$ac_cv_gdbmopen = xyes; then
 550         CPPFLAGS="$OLDCPPFLAGS $GDBM_INC"
 551         LIBS="$OLDLIBS $GDBM_LIB -lgdbm";
 552         AC_DEFINE(HAVE_GDBM, 1, [GDBM Support])
 553     elif test x$ac_cv_dbcreate = xyes; then
 554         CPPFLAGS="-I$BDB_INCLUDE_DIR $OLDCPPFLAGS"
 555         LIBS="$OLDLIBS -L$BDB_LIB_DIR -l$BDB_LIB"
 556         AC_DEFINE(HAVE_DB4, 1, [Sleepycat DB4 Support])
 557     else
 558         AC_MSG_ERROR([You need one of: QDBM, GDBM or Sleepycat DB4 for --enable-hcache])
 559     fi
 560 fi])
 561 dnl -- end cache --
 562
 563 AC_SUBST(MUTTLIBS)
 564 AC_SUBST(MUTT_LIB_OBJECTS)
 565 AC_SUBST(LIBNNTP)
 566 AC_SUBST(LIBNNTPDEPS)
 567
 568 dnl -- iconv/gettext --
 569
 570 AC_ARG_ENABLE(iconv, AC_HELP_STRING([--disable-iconv], [Disable iconv support]),
 571         [if test x$enableval = xno ; then
 572                 am_cv_func_iconv=no
 573         fi
 574 ])
 575
 576 AM_GNU_GETTEXT
 577
 578 if test "$am_cv_func_iconv" != "yes"; then
 579     AC_MSG_WARN([Configuring without iconv support. See INSTALL for details])
 580 else
 581
 582     AC_CHECK_HEADERS(iconv.h,
 583         [AC_MSG_CHECKING(whether iconv.h defines iconv_t)
 584          AC_EGREP_HEADER([typedef.*iconv_t],iconv.h,
 585                 [AC_MSG_RESULT(yes)
 586                  AC_DEFINE(HAVE_ICONV_T_DEF, 1,
 587                         [Define if <iconv.h> defines iconv_t.])],
 588                  AC_MSG_RESULT(no))])
 589
 590     dnl (1) Some implementations of iconv won't convert from UTF-8 to UTF-8.
 591     dnl (2) In glibc-2.1.2 and earlier there is a bug that messes up ob and
 592     dnl     obl when args 2 and 3 are 0 (fixed in glibc-2.1.3).
 593     AC_CACHE_CHECK([whether this iconv is good enough], mutt_cv_iconv_good,
 594                    mutt_save_LIBS="$LIBS"
 595                    LIBS="$LIBS $LIBICONV"
 596                    AC_TRY_RUN([
 597 #include <iconv.h>
 598 int main()
 599 {
 600   iconv_t cd;
 601 changequote(, )dnl
 602   char buf[4];
 603 changequote([, ])dnl
 604   char *ob;
 605   size_t obl;
 606   ob = buf, obl = sizeof(buf);
 607   return ((cd = iconv_open("UTF-8", "UTF-8")) != (iconv_t)(-1) &&
 608           (iconv(cd, 0, 0, &ob, &obl) ||
 609            !(ob == buf && obl == sizeof(buf)) ||
 610            iconv_close(cd)));
 611 }
 612                    ],
 613                    mutt_cv_iconv_good=yes,
 614                    mutt_cv_iconv_good=no,
 615                    mutt_cv_iconv_good=yes)
 616                    LIBS="$mutt_save_LIBS")
 617     if test "$mutt_cv_iconv_good" = no; then
 618         AC_MSG_ERROR(Try using libiconv instead)
 619     fi
 620
 621 fi # libiconv
 622
 623 dnl -- locales --
 624
 625 AC_CHECK_HEADERS(locale.h wchar.h wctype.h)
 626 AC_CHECK_FUNCS(iswalnum iswalpha  iswcntrl iswdigit)
 627 AC_CHECK_FUNCS(iswgraph iswlower iswprint iswpunct iswspace iswupper)
 628 AC_CHECK_FUNCS(iswxdigit towupper towlower)
 629 AC_TYPE_MBSTATE_T
 630
 631 AC_CACHE_CHECK([for nl_langinfo and CODESET], mutt_cv_langinfo_codeset,
 632                [AC_TRY_LINK([#include <langinfo.h>],
 633                             [char* cs = nl_langinfo(CODESET);],
 634                             mutt_cv_langinfo_codeset=yes,
 635                             mutt_cv_langinfo_codeset=no)])
 636 if test $mutt_cv_langinfo_codeset = yes; then
 637     AC_DEFINE(HAVE_LANGINFO_CODESET,1,
 638               [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
 639 fi
 640
 641 AC_CACHE_CHECK([for nl_langinfo and YESEXPR], mutt_cv_langinfo_yesexpr,
 642                [AC_TRY_LINK([#include <langinfo.h>],
 643                             [char* cs = nl_langinfo(YESEXPR);],
 644                             mutt_cv_langinfo_yesexpr=yes,
 645                             mutt_cv_langinfo_yesexpr=no)])
 646 if test $mutt_cv_langinfo_yesexpr = yes; then
 647     AC_DEFINE(HAVE_LANGINFO_YESEXPR,1,
 648               [Define if you have <langinfo.h> and nl_langinfo(YESEXPR).])
 649 fi
 650
 651 dnl -- libesmtp --
 652 MUTT_AM_LIBESMTP
 653 if test x$use_libesmtp = xyes; then
 654     CFLAGS="$CFLAGS $mutt_libesmtp_cflags"
 655     MUTTLIBS="$MUTTLIBS $mutt_libesmtp_libs"
 656     MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_libesmtp.o"
 657     AC_DEFINE(USE_LIBESMTP, 1, [Define to enable the use of libesmtp])
 658 fi
 659 dnl -- end libesmtp --
 660
 661 dnl -- sgml tools --
 662
 663 dnl Documentation tools
 664 have_openjade="no"
 665 AC_PATH_PROG([OSPCAT], [ospcat], [none])
 666 if test "x$OSPCAT" != "xnone"; then
 667     AC_MSG_CHECKING([for openjade docbook stylesheets])
 668     dslosfile=`ospcat --public-id="-//Norman Walsh//DOCUMENT DocBook Print Stylesheet//EN"`
 669     DSLROOT=`echo $dslosfile | sed -n -e "s/.*SOIBASE='\(@<:@^'@:>@*\)\/catalog'.*/\1/p"`
 670     # ospcat may spit out an absolute path without an SOIBASE
 671     if test -z "$DSLROOT"; then
 672         DSLROOT=`echo $dslosfile | sed -e 's|<OSFILE>\(.*\)/print/docbook.dsl|\1|'`
 673     fi
 674     if test -f $DSLROOT/print/docbook.dsl; then
 675         AC_MSG_RESULT([in $DSLROOT])
 676         have_openjade="yes"
 677     else
 678         AC_MSG_RESULT([not found: PDF documentation will not be built.])
 679     fi
 680 fi
 681 AC_SUBST(DSLROOT)
 682
 683 AC_MSG_CHECKING([for lynx])
 684 AC_PATH_PROG([HTML2TXT_CMD], [lynx], [none])
 685 if test x"$HTML2TXT_CMD" = x"none"; then
 686     AC_MSG_CHECKING([for w3m])
 687     AC_PATH_PROG([HTML2TXT_CMD], [w3m], [none])
 688 fi
 689 if test x"$HTML2TXT_CMD" = x"none"; then
 690     AC_MSG_CHECKING([for elinks])
 691     AC_PATH_PROG([HTML2TXT_CMD], [elinks], [none])
 692 fi
 693 case "$HTML2TXT_CMD" in
 694   *elinks*)
 695     HTML2TXT_CMD="$HTML2TXT_CMD -dump -no-numbering -no-references \$^ > \$@"
 696     ;;
 697   *lynx*)
 698     HTML2TXT_CMD="$HTML2TXT_CMD -dump -nolist -with_backspaces \$^ > \$@"
 699     ;;
 700   *w3m*)
 701     HTML2TXT_CMD="$HTML2TXT_CMD -dump \$^ > \$@"
 702     ;;
 703   *)
 704     HTML2TXT_CMD="true"
 705     ;;
 706 esac
 707 AC_SUBST(HTML2TXT_CMD)
 708
 709 AC_MSG_CHECKING([for tidy])
 710 AC_PATH_PROG([HTMLCLEAN_CMD], [tidy], [none])
 711
 712 if test x"$HTMLCLEAN_CMD" != x"none"; then
 713     HTMLCLEAN_CMD="$HTMLCLEAN_CMD -q -i -m -asxml -utf8 "
 714 else
 715     HTMLCLEAN_CMD="echo "
 716 fi
 717 AC_SUBST(HTMLCLEAN_CMD)
 718
 719 AC_OUTPUT(Makefile
 720           Madmuttrc.head
 721
 722           intl/Makefile
 723           m4/Makefile
 724           po/Makefile.in
 725           doc/Makefile doc/instdoc.sh
 726           contrib/Makefile
 727           lib-lib/Makefile
 728           lib-mime/Makefile
 729           lib-crypt/Makefile
 730           lib-hash/Makefile
 731           lib-mx/Makefile
 732           lib-sys/Makefile
 733           lib-ui/Makefile
 734           imap/Makefile
 735           pop/Makefile
 736           nntp/Makefile
 737 )