configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl !!! WHEN ADDING NEW CONFIGURE TESTS, PLEASE ADD CODE TO MAIN.C !!!
   4 dnl !!! TO DUMP THEIR RESULTS WHEN MUTT -V IS CALLED            !!!
   5
   6 AC_PREREQ([2.50])
   7 AC_INIT([mutt.h])
   8 AM_CONFIG_HEADER(config.h)
   9 AM_INIT_AUTOMAKE(madmutt, `cat "$srcdir/VERSION.in"`)
  10
  11 AC_SUBST([CONFIGURE_DEPENDENCIES], ['$(top_srcdir)/VERSION.in'])
  12
  13 AC_GNU_SOURCE
  14
  15 ALL_LINGUAS="de ru it es uk fr pl nl cs id sk ko el zh_TW zh_CN pt_BR eo gl sv da lt tr ja hu et ca bg"
  16
  17 AC_CANONICAL_HOST
  18
  19 AC_MSG_CHECKING([for prefix])
  20 if test x$prefix = xNONE; then
  21     mutt_cv_prefix=$ac_default_prefix
  22 else
  23     mutt_cv_prefix=$prefix
  24 fi
  25 AC_MSG_RESULT($mutt_cv_prefix)
  26
  27 AC_PROG_CPP
  28 AC_PROG_CC_C99
  29
  30 AM_C_PROTOTYPES
  31 AC_C_INLINE
  32 AC_C_CONST
  33 if test "x$U" != "x"; then
  34     AC_MSG_ERROR(Compiler not ANSI compliant)
  35 fi
  36 AC_ISC_POSIX
  37 AC_HEADER_STDC
  38
  39 AC_PROG_MAKE_SET
  40 AC_PROG_INSTALL
  41 AC_PROG_RANLIB
  42 AC_PROG_GPERF
  43 PKG_PROG_PKG_CONFIG
  44 AC_CHECK_TOOL(AR, ar, ar)
  45
  46 AC_SYS_LARGEFILE
  47 AC_FUNC_FSEEKO
  48 AC_CHECK_SIZEOF(off_t)
  49
  50 AH_TEMPLATE([sig_atomic_t],
  51             [Define to 'int' if <signal.h> doesn't define.])
  52 AH_TEMPLATE([HAVE_START_COLOR],
  53             [Define if you have start_color, as a function or macro.])
  54 AH_TEMPLATE([HAVE_TYPEAHEAD],
  55             [Define if you have typeahead, as a function or macro.])
  56 AH_TEMPLATE([HAVE_BKGDSET],
  57             [Define if you have bkgdset, as a function or macro.])
  58 AH_TEMPLATE([HAVE_CURS_SET],
  59             [Define if you have curs_set, as a function or macro.])
  60 AH_TEMPLATE([HAVE_META],
  61             [Define if you have meta, as a function or macro.])
  62 AH_TEMPLATE([HAVE_USE_DEFAULT_COLORS],
  63             [Define if you have use_default_colors, as a function or macro.])
  64 AH_TEMPLATE([HAVE_RESIZETERM],
  65             [Define if you have resizeterm, as a function or macro.])
  66 AH_TEMPLATE([SIG_ATOMIC_VOLATILE_T],
  67             [Some systems declare sig_atomic_t as volatile, some others -- no.
  68              This define will have value `sig_atomic_t' or
  69              `volatile sig_atomic_t' accordingly.])
  70 AH_TEMPLATE([ICONV_NONTRANS],
  71             [Define as 1 if iconv() only converts exactly and we should treat
  72              all return values other than (size_t)(-1) as equivalent.])
  73
  74 MUTT_C99_INTTYPES
  75
  76 dnl ---------------- sendmail ----------------
  77
  78 ac_aux_path_sendmail=/usr/sbin:/usr/lib
  79 AC_PATH_PROG(SENDMAIL, sendmail, /usr/sbin/sendmail, $PATH:$ac_aux_path_sendmail)
  80 AC_DEFINE_UNQUOTED(SENDMAIL,"$ac_cv_path_SENDMAIL",[ Where to find sendmail on your system. ])
  81
  82 OPS='$(srcdir)/OPS'
  83
  84 dnl ---------------- gpgme ----------------
  85
  86 AC_ARG_ENABLE(gpgme, AC_HELP_STRING([--enable-gpgme], [Enable GPGME support]),[
  87     if test x$enableval = xyes; then
  88         AM_PATH_GPGME(,,[AC_MSG_ERROR(GPGME not found)])
  89         MUTTLIBS="$MUTTLIBS $GPGME_LIBS"
  90         AC_DEFINE(CRYPT_BACKEND_GPGME, 1, [Defined, if GPGME support is enabled])
  91         AM_CONDITIONAL(BUILD_GPGME, true)
  92     else
  93         AM_CONDITIONAL(BUILD_GPGME, false)
  94     fi
  95 ])
  96
  97 dnl ---------------- mixmaster ----------------
  98
  99 AC_ARG_WITH(mixmaster, AC_HELP_STRING([--with-mixmaster[=PATH]], [Include Mixmaster support]), [
 100     MIXMASTER=${withval:-"mixmaster"}
 101     OPS="$OPS \$(srcdir)/OPS.MIX"
 102     MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS remailer.o"
 103     AC_DEFINE_UNQUOTED(MIXMASTER,"$MIXMASTER",[Where to find mixmaster on your system.])
 104 ])
 105
 106 # We now require all OPS
 107 OPS="$OPS \$(srcdir)/OPS.PGP \$(srcdir)/OPS.SMIME \$(srcdir)/OPS.CRYPT "
 108 AC_SUBST([OPS])
 109
 110 AC_PATH_PROG(ISPELL, ispell, no)
 111 if test $ISPELL != no; then
 112     AC_DEFINE_UNQUOTED(ISPELL,"$ISPELL",[Where to find ispell on your system.])
 113 fi
 114
 115 AC_ARG_WITH(slang, AC_HELP_STRING([--with-slang[=DIR]], [Use S-Lang instead of ncurses]),
 116     [AC_CACHE_CHECK([if this is a BSD system], mutt_cv_bsdish,
 117         [AC_TRY_RUN([#include <sys/param.h>
 118
 119 main ()
 120 {
 121 #ifdef BSD
 122         exit (0);
 123 #else
 124         exit (1);
 125 #endif
 126 }],
 127         mutt_cv_bsdish=yes,
 128         mutt_cv_bsdish=no,
 129         mutt_cv_bsdish=no)])
 130
 131         AC_MSG_CHECKING(for S-Lang)
 132         if test $withval = yes; then
 133             if test -d $srcdir/../slang; then
 134                 mutt_cv_slang=$srcdir/../slang/src
 135                 CFLAGS="$CFLAGS -I${mutt_cv_slang}"
 136                 LDFLAGS="$LDFLAGS -L${mutt_cv_slang}/objs"
 137             else
 138                 if test -d $mutt_cv_prefix/include/slang; then
 139                     CFLAGS="$CFLAGS -I$mutt_cv_prefix/include/slang"
 140                 elif test -d /usr/include/slang; then
 141                     CFLAGS="$CFLAGS -I/usr/include/slang"
 142                 fi
 143                 mutt_cv_slang=yes
 144             fi
 145         else
 146             dnl ---Check to see if $withval is a source directory
 147             if test -f $withval/src/slang.h; then
 148                 mutt_cv_slang=$withval/src
 149                 CFLAGS="$CFLAGS -I${mutt_cv_slang}"
 150                 LDFLAGS="$LDFLAGS -L${mutt_cv_slang}/objs"
 151             else
 152                 dnl ---Must be installed somewhere
 153                 mutt_cv_slang=$withval
 154                 if test -d $withval/include/slang; then
 155                         CFLAGS="$CFLAGS -I${withval}/include/slang"
 156                 elif test -d $withval/include; then
 157                         CFLAGS="$CFLAGS -I${withval}/include"
 158                 fi
 159                 LDFLAGS="$LDFLAGS -L${withval}/lib"
 160             fi
 161         fi
 162         AC_MSG_RESULT($mutt_cv_slang)
 163         if test $mutt_cv_bsdish = yes; then
 164             AC_CHECK_LIB(termlib, main)
 165         fi
 166         AC_DEFINE(USE_SLANG_CURSES,1, [ Define if you compile with SLang instead of curses/ncurses. ])
 167         AC_DEFINE(HAVE_COLOR,1,[ Define if your curses library supports color. ])
 168
 169         dnl --- now that we've found it, check the link
 170
 171         AC_CHECK_LIB(slang, SLtt_get_terminfo,
 172             [MUTTLIBS="$MUTTLIBS -lslang -lm"],
 173             [AC_MSG_ERROR(unable to compile.  check config.log)], -lm)
 174     ],
 175     [   mutt_cv_curses=/usr
 176         AC_ARG_WITH(curses, AC_HELP_STRING([--with-curses=DIR], [Where ncurses is installed]), [
 177             if test $withval != yes; then
 178                 mutt_cv_curses=$withval
 179             fi
 180             if test x$mutt_cv_curses != x/usr; then
 181                 LDFLAGS="-L${mutt_cv_curses}/lib $LDFLAGS"
 182                 CPPFLAGS="$CPPFLAGS -I${mutt_cv_curses}/include"
 183             fi
 184         ])
 185
 186         AC_CHECK_FUNC(initscr,,[
 187         cf_ncurses="ncurses"
 188         for lib in ncursesw ncurses; do
 189             AC_CHECK_LIB($lib, waddnwstr, [cf_ncurses="$lib"; break])
 190         done
 191         AC_CHECK_LIB($cf_ncurses, initscr,
 192             [   MUTTLIBS="$MUTTLIBS -l$cf_ncurses"
 193                 if test x$mutt_cv_curses = x/usr -a -d /usr/include/ncurses; then
 194                     CPPFLAGS="$CPPFLAGS -I/usr/include/ncurses"
 195                 fi
 196
 197                 if test "$cf_ncurses" = ncursesw; then
 198                     AC_CHECK_HEADERS(ncurses/ncurses.h,[cf_cv_ncurses_header="ncurses/ncurses.h"])
 199                     AC_CHECK_HEADERS(ncursesw/ncurses.h,[cf_cv_ncurses_header="ncursesw/ncurses.h"])
 200                 else
 201                     AC_CHECK_HEADERS(ncurses.h,[cf_cv_ncurses_header="ncurses.h"])
 202                 fi
 203             ],
 204             [CF_CURSES_LIBS])
 205         ])
 206
 207         old_LIBS="$LIBS"
 208         LIBS="$LIBS $MUTTLIBS"
 209         CF_CHECK_FUNCDECLS([#include <${cf_cv_ncurses_header-curses.h}>],
 210                            [start_color typeahead bkgdset curs_set meta use_default_colors resizeterm])
 211         if test "$ac_cv_func_decl_start_color" = yes; then
 212             AC_DEFINE(HAVE_COLOR,1,[ Define if your curses library supports color. ])
 213         fi
 214         LIBS="$old_LIBS"
 215     ])
 216
 217 AC_CHECK_HEADERS(stdarg.h sys/ioctl.h ioctl.h sysexits.h)
 218 AC_CHECK_HEADERS(sys/time.h sys/resource.h)
 219 AC_CHECK_HEADERS(unix.h)
 220
 221 AC_CHECK_FUNCS(setrlimit getsid isctype)
 222
 223 AC_TYPE_SIGNAL
 224
 225 AC_MSG_CHECKING(for sig_atomic_t in signal.h)
 226 AC_EGREP_HEADER(sig_atomic_t,signal.h,
 227     [   ac_cv_type_sig_atomic_t=yes;
 228         AC_EGREP_HEADER(volatile.*sig_atomic_t,
 229                         signal.h,
 230                         [is_sig_atomic_t_volatile=yes; AC_MSG_RESULT([yes, volatile])],
 231                         [is_sig_atomic_t_volatile=no;  AC_MSG_RESULT([yes, non volatile])])
 232     ],
 233     [   AC_MSG_RESULT(no)
 234         AC_CHECK_TYPE(sig_atomic_t, int)
 235         is_sig_atomic_t_volatile=no
 236     ])
 237 if test $is_sig_atomic_t_volatile = 'yes'
 238 then
 239     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, sig_atomic_t)
 240 else
 241     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, [volatile sig_atomic_t])
 242 fi
 243
 244 AC_DECL_SYS_SIGLIST
 245
 246 AC_TYPE_PID_T
 247
 248 AC_CHECK_FUNCS(fgetpos memmove setegid srand48 strerror)
 249 AC_REPLACE_FUNCS(strcasecmp setenv)
 250 AC_CHECK_FUNCS(snprintf vsnprintf)
 251
 252 AC_CHECK_FUNC(getopt)
 253 if test $ac_cv_func_getopt = yes; then
 254     AC_CHECK_HEADERS(getopt.h)
 255 fi
 256
 257 AC_CHECK_FUNC(regcomp)
 258 if test $ac_cv_func_regcomp = yes; then
 259    AC_CHECK_HEADERS(regex.h)
 260 fi
 261
 262 AC_ARG_WITH(homespool,
 263             AC_HELP_STRING([--with-homespool[=FILE]],
 264                            [File in user's directory where new mail is spooled]),
 265                            with_homespool=${withval})
 266 if test x$with_homespool != x; then
 267     if test $with_homespool = yes; then
 268             with_homespool=mailbox
 269     fi
 270     AC_DEFINE_UNQUOTED(MAILPATH,"$with_homespool",[ Where new mail is spooled. ])
 271     AC_DEFINE(HOMESPOOL,1,
 272     [   Is mail spooled to the user's home directory?  If defined,
 273         MAILPATH should be set to the filename of the spool mailbox
 274         relative the the home directory.
 275         use: configure --with-homespool=FILE
 276     ])
 277     AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 278     mutt_cv_setgid=no
 279 else
 280     AC_ARG_WITH(mailpath, AC_HELP_STRING([--with-mailpath=DIR], [Directory where spool mailboxes are located]),
 281         [mutt_cv_mailpath=$withval],
 282         [ AC_CACHE_CHECK(where new mail is stored, mutt_cv_mailpath,
 283             [mutt_cv_mailpath=no
 284             if test -d /var/mail; then
 285                 mutt_cv_mailpath=/var/mail
 286             elif test -d /var/spool/mail; then
 287                 mutt_cv_mailpath=/var/spool/mail
 288             elif test -d /usr/spool/mail; then
 289                 mutt_cv_mailpath=/usr/spool/mail
 290             elif test -d /usr/mail; then
 291                 mutt_cv_mailpath=/usr/mail
 292             fi])
 293         ])
 294     if test "$mutt_cv_mailpath" = no; then
 295         AC_MSG_ERROR("Could not determine where new mail is stored.")
 296     fi
 297     AC_DEFINE_UNQUOTED(MAILPATH,"$mutt_cv_mailpath",[ Where new mail is spooled. ])
 298
 299     AC_CACHE_CHECK(if $mutt_cv_mailpath is world writable, mutt_cv_worldwrite, [AC_TRY_RUN([#include <sys/types.h>
 300 #include <sys/stat.h>
 301
 302 int main (int argc, char **argv)
 303 {
 304         struct stat s;
 305
 306         stat ("$mutt_cv_mailpath", &s);
 307         if (s.st_mode & S_IWOTH) exit (0);
 308         exit (1);
 309 }], mutt_cv_worldwrite=yes, mutt_cv_worldwrite=no, mutt_cv_worldwrite=no)])
 310
 311         mutt_cv_setgid=no
 312         if test $mutt_cv_worldwrite = yes; then
 313                 AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 314         else
 315                 AC_CACHE_CHECK(if $mutt_cv_mailpath is group writable, mutt_cv_groupwrite, [AC_TRY_RUN([#include <sys/types.h>
 316 #include <sys/stat.h>
 317
 318 int main (int argc, char **argv)
 319 {
 320         struct stat s;
 321
 322         stat ("$mutt_cv_mailpath", &s);
 323         if (s.st_mode & S_IWGRP) exit (0);
 324         exit (1);
 325 }], mutt_cv_groupwrite=yes, mutt_cv_groupwrite=no, mutt_cv_groupwrite=no)])
 326
 327         if test $mutt_cv_groupwrite = yes; then
 328             AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 329             AC_DEFINE(USE_SETGID,1,[ Define if mutt should run setgid "mail". ])
 330             mutt_cv_setgid=yes
 331         fi
 332     fi
 333 fi
 334
 335 AC_MSG_CHECKING(where to put the documentation)
 336 AC_ARG_WITH(docdir, AC_HELP_STRING([--with-docdir=PATH], [Specify where to put the documentation]),
 337         [mutt_cv_docdir=$withval],
 338         [mutt_cv_docdir="${prefix}/doc/madmutt"])
 339 AC_MSG_RESULT($mutt_cv_docdir)
 340
 341 docdir=$mutt_cv_docdir
 342 AC_SUBST(docdir)
 343
 344 if test x$mutt_cv_setgid = xyes; then
 345     DOTLOCK_GROUP='mail'
 346     DOTLOCK_PERMISSION=2755
 347 else
 348     DOTLOCK_GROUP=''
 349     DOTLOCK_PERMISSION=755
 350 fi
 351 AC_SUBST(DOTLOCK_GROUP)
 352 AC_SUBST(DOTLOCK_PERMISSION)
 353
 354 dnl -- socket dependencies --
 355
 356 AC_ARG_ENABLE(nntp, AC_HELP_STRING([--enable-nntp],[Enable NNTP support]),[
 357     if test x$enableval = xyes ; then
 358         AC_DEFINE(USE_NNTP,1,[ Compiling with newsreading support with NNTP ])
 359         LIBNNTP="-Lnntp -lnntp"
 360         LIBNNTPDEPS="\$(top_srcdir)/nntp/nntp.h nntp/libnntp.a"
 361         need_nntp="yes"
 362     fi
 363 ])
 364 AM_CONDITIONAL(BUILD_NNTP, test x$need_nntp = xyes)
 365
 366 dnl -- end socket dependencies --
 367
 368 AC_MSG_CHECKING([for socklen_t])
 369 AC_EGREP_HEADER(socklen_t, sys/socket.h, AC_MSG_RESULT([yes]),
 370         AC_MSG_RESULT([no])
 371         AC_DEFINE(socklen_t,int, [ Define to 'int' if <sys/socket.h> doesn't have it. ]))
 372 AC_CHECK_FUNC(gethostent, , AC_CHECK_LIB(nsl, gethostent))
 373 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt))
 374 AC_CHECK_FUNCS(getaddrinfo)
 375
 376 dnl -- imap dependencies --
 377
 378 AC_ARG_WITH(gss, AC_HELP_STRING([--with-gss[=PFX]], [Compile in GSSAPI authentication for IMAP]),
 379     gss_prefix="$withval", gss_prefix="no")
 380 if test "$gss_prefix" != "no"
 381 then
 382     MUTT_AM_PATH_GSSAPI(gss_prefix)
 383     AC_MSG_CHECKING(GSSAPI implementation)
 384     AC_MSG_RESULT($GSSAPI_IMPL)
 385     if test "$GSSAPI_IMPL" = "none"
 386     then
 387       AC_CACHE_SAVE
 388       AC_MSG_RESULT([GSSAPI libraries not found])
 389     fi
 390     if test "$GSSAPI_IMPL" = "Heimdal"
 391     then
 392       AC_DEFINE(HAVE_HEIMDAL,1,[ Define if your GSSAPI implementation is Heimdal ])
 393     fi
 394     CPPFLAGS="$CPPFLAGS $GSSAPI_CFLAGS"
 395     MUTTLIBS="$MUTTLIBS $GSSAPI_LIBS"
 396     AC_DEFINE(USE_GSS,1,[ Define if you have GSSAPI libraries available ])
 397     need_gss="yes"
 398 fi
 399 AM_CONDITIONAL(USE_GSS, test x$need_gss = xyes)
 400
 401 dnl -- end imap dependencies --
 402
 403 AC_ARG_WITH(ssl, AC_HELP_STRING([--with-ssl[=PFX]], [Compile in SSL support for POP/IMAP]),
 404 [   if test "$with_ssl" != "no"; then
 405         if test "$with_ssl" != "yes"; then
 406             LDFLAGS="$LDFLAGS -L$withval/lib"
 407             CPPFLAGS="$CPPFLAGS -I$withval/include"
 408         fi
 409         saved_LIBS="$LIBS"
 410
 411         AC_CHECK_LIB(crypto, X509_new,, AC_MSG_ERROR([Unable to find SSL library]))
 412         AC_CHECK_LIB(ssl, SSL_new,, AC_MSG_ERROR([Unable to find SSL library]), -lcrypto)
 413
 414         AC_CHECK_FUNCS(RAND_status RAND_egd)
 415
 416         AC_DEFINE(USE_SSL,1,[ Define if you want support for SSL. ])
 417         LIBS="$saved_LIBS"
 418         MUTTLIBS="$MUTTLIBS -lssl -lcrypto"
 419         need_ssl=yes
 420     fi
 421 ])
 422
 423 AC_ARG_WITH([gnutls], AC_HELP_STRING([--with-gnutls], [Enable SSL support using gnutls]),
 424             [gnutls_prefix="$withval"], [gnutls_prefix="no"])
 425 if test "$gnutls_prefix" != "no"; then
 426     if test x"$need_ssl" = x"yes"; then
 427         AC_MSG_ERROR([Only either OpenSSL or GNUTLS may be used])
 428     fi
 429     AM_PATH_LIBGNUTLS(,[
 430         CPPFLAGS="$CPPFLAGS $LIBGNUTLS_CFLAGS"
 431         MUTTLIBS="$MUTTLIBS $LIBGNUTLS_LIBS"
 432         AC_DEFINE(USE_GNUTLS, 1, [Define if you want support for SSL via the gnutls library.])
 433         need_ssl=yes],
 434         [AC_MSG_ERROR([could not find libgnutls])
 435     ])
 436 fi
 437 AM_CONDITIONAL(USE_SSL, test x$need_ssl = xyes)
 438 AC_SUBST(MUTT_SSL_OBJECTS)
 439
 440 AC_ARG_WITH(sasl2, AC_HELP_STRING([--with-sasl2[=PFX]],
 441             [Use Cyrus SASL library version 2 for POP/IMAP authentication]),[
 442     if test "$with_sasl2" != "no"; then
 443         if test "$with_sasl2" != "yes"; then
 444             CPPFLAGS="$CPPFLAGS -I$with_sasl2/include"
 445             LDFLAGS="$LDFLAGS -L$with_sasl2/lib"
 446         fi
 447
 448         saved_LIBS="$LIBS"
 449
 450         AC_CHECK_LIB(sasl2, sasl_client_init,,AC_MSG_ERROR([could not find libsasl2]))
 451
 452         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_sasl.o"
 453         MUTTLIBS="$MUTTLIBS -lsasl2"
 454         LIBS="$saved_LIBS"
 455         AC_DEFINE(USE_SASL,1,
 456                   [Define if want to use version 2 of the Cyrus SASL library.])
 457         need_sasl=yes
 458     fi
 459 ])
 460 AM_CONDITIONAL(USE_SASL, test x$need_sasl = xyes)
 461
 462 AC_ARG_WITH(idn, AC_HELP_STRING([--with-idn=[PFX]], [Use GNU libidn for domain names]),[
 463     if test x$with_idn != xno ; then
 464         PKG_CHECK_MODULES(IDN,libidn,[
 465             if $PKG_CONFIG --atleast-version=0.6; then
 466                 AC_MSG_ERROR([libidn is too old, want 0.6 at least])
 467             fi
 468             CPPFLAGS="$CPPFLAGS $IDN_CFLAGS"
 469             LDFLAGS="$LDFLAGS $IDN_LIBS"
 470         ],[AC_MSG_ERROR([could not find libidn])])
 471     fi
 472 ])
 473
 474 dnl -- end socket --
 475
 476 AC_ARG_ENABLE(debug, AC_HELP_STRING([--enable-debug], [Enable debugging support]),
 477     [ if test x$enableval = xyes ; then
 478             AC_DEFINE(DEBUG,1,[ Define to enable debugging info. ])
 479       fi
 480      ])
 481
 482 AC_ARG_ENABLE(flock, AC_HELP_STRING([--enable-flock], [Use flock() to lock files]),
 483         [if test $enableval = yes; then
 484                 AC_DEFINE(USE_FLOCK,1, [ Define to use flock() to lock mailboxes. ])
 485         fi])
 486
 487 mutt_cv_fcntl=yes
 488 AC_ARG_ENABLE(fcntl, AC_HELP_STRING([--disable-fcntl], [Do NOT use fcntl() to lock files]),
 489         [if test $enableval = no; then mutt_cv_fcntl=no; fi])
 490
 491 if test $mutt_cv_fcntl = yes; then
 492         AC_DEFINE(USE_FCNTL,1, [ Define to use fcntl() to lock folders. ])
 493 fi
 494
 495 AC_MSG_CHECKING(whether struct dirent defines d_ino)
 496 ac_cv_dirent_d_ino=no
 497 AC_TRY_LINK([#include <dirent.h>],[struct dirent dp; (void)dp.d_ino],[ac_cv_dirent_d_ino=yes])
 498 if test x$ac_cv_dirent_d_ino = xyes ; then
 499   AC_DEFINE(HAVE_DIRENT_D_INO,1,
 500             [Define to 1 if your system has the dirent::d_ino member])
 501 fi
 502 AC_MSG_RESULT($ac_cv_dirent_d_ino)
 503
 504 AC_ARG_ENABLE(buffy-size, AC_HELP_STRING([--enable-buffy-size], [Use file size attribute instead of access time]),
 505         [if test x$enableval = xyes; then
 506                 AC_DEFINE(BUFFY_SIZE,1,[ Define to enable the "buffy_size" feature. ])
 507         fi])
 508
 509 dnl -- start cache --
 510 AC_ARG_ENABLE(hcache, AC_HELP_STRING([--enable-hcache], [Enable header caching]),
 511 [if test x$enableval = xyes; then
 512     AC_DEFINE(USE_HCACHE, 1, [Enable header caching])
 513
 514     OLDCPPFLAGS="$CPPFLAGS"
 515     OLDLIBS="$LIBS"
 516
 517     need_md5="yes"
 518
 519     ac_prefer_qdbm=yes
 520     AC_ARG_WITH(qdbm, AC_HELP_STRING([--without-qdbm], [Don't use qdbm even if it is available]),
 521         ac_prefer_qdbm=$withval)
 522     if test x$ac_prefer_qdbm != xno; then
 523         PKG_CHECK_MODULES(QDBM,qdbm,[ac_qdbm_here=yes],[ac_qdbm_here=no])
 524     fi
 525
 526     ac_prefer_gdbm=yes
 527     AC_ARG_WITH(gdbm, AC_HELP_STRING([--without-gdbm], [Don't use gdbm even if it is available]),
 528         ac_prefer_gdbm=$withval)
 529     if test x$ac_prefer_gdbm != xno -a x$ac_qdbm_here != xyes; then
 530         ac_cv_gdbmopen=no
 531         GDBM_DIRS="$mutt_cv_prefix /usr/local /usr"
 532         AC_MSG_CHECKING([for gdbm_open])
 533         for d in $GDBM_DIRS; do
 534           if test x$ac_cv_gdbmopen = xno && test -d "$d/include" && test -d "$d/lib"; then
 535             GDBM_INC="-I$d/include"
 536             GDBM_LIB="-L$d/lib"
 537             CPPFLAGS="$OLDCPPFLAGS $GDBM_INC"
 538             LIBS="$OLDLIBS $GDBM_LIB -lgdbm"
 539             AC_TRY_LINK([#include <gdbm.h>],[gdbm_open(0,0,0,0,0);],[ac_cv_gdbmopen=yes])
 540           fi
 541         done
 542         if test x$ac_cv_gdbmopen = xyes; then
 543           AC_MSG_RESULT(yes)
 544         else
 545           AC_MSG_RESULT(no)
 546         fi
 547     fi
 548
 549     ac_bdb_prefix=yes
 550     AC_ARG_WITH(bdb, AC_HELP_STRING([--with-bdb[=DIR]], [Use BerkeleyDB4 if gdbm is not available ]),
 551         ac_bdb_prefix=$withval)
 552     if test x$ac_bdb_prefix != xno -a x$ac_cv_gdbmopen != xyes -a x$ac_qdbm_here != xyes; then
 553         test x$ac_bdb_prefix = xyes && ac_bdb_prefix="$mutt_cv_prefix /opt/csw/bdb4 /opt /usr/local /usr"
 554         for d in $ac_bdb_prefix; do
 555             bdbpfx="$bdbpfx $d"
 556             for v in BerkeleyDB.4.3 BerkeleyDB.4.2 BerkeleyDB.4.1; do
 557                 bdbpfx="$bdbpfx $d/$v"
 558             done
 559         done
 560         BDB_VERSIONS="db-4 db4 db-4.3 db4.3 db43 db-4.2 db4.2 db42 db-4.1 db4.1 db41 db ''"
 561         AC_MSG_CHECKING([for BerkeleyDB > 4.0])
 562         for d in $bdbpfx; do
 563             BDB_INCLUDE_DIR=""
 564             BDB_LIB_DIR=""
 565             for v in / $BDB_VERSIONS; do
 566                 if test -r "$d/include/$v/db.h"; then
 567                     BDB_INCLUDE_DIR="$d/include/$v"
 568                     if test -d "$d/lib/$v"; then
 569                         BDB_LIB_DIR="$d/lib/$v"
 570                         for l in `echo $BDB_VERSIONS`; do
 571                             CPPFLAGS="-I$BDB_INCLUDE_DIR $OLDCPPFLAGS"
 572                             LIBS="$OLDLIBS -L$BDB_LIB_DIR -l$l"
 573                             AC_TRY_LINK([
 574                                 #include <stdlib.h>
 575                                 #include <db.h>
 576                             ],[
 577                                 DB *db = NULL;
 578                                 db->open(db,NULL,NULL,NULL,0,0,0);
 579                             ],[
 580                                 ac_cv_dbcreate=yes
 581                                 BDB_LIB="$l"
 582                                 break
 583                             ])
 584                         done
 585                         test x$ac_cv_dbcreate = xyes && break
 586                     fi
 587                 fi
 588             done
 589             test x$BDB_LIB != x && break
 590         done
 591         if test x$ac_cv_dbcreate = xyes; then
 592             AC_MSG_RESULT(yes)
 593         else
 594             AC_MSG_RESULT(no)
 595         fi
 596     fi
 597
 598     if test x$ac_qdbm_here = xyes; then
 599         CPPFLAGS="$OLDCPPFLAGS $QDBM_CFLAGS"
 600         LIBS="$OLDLIBS $QDBM_LIBS"
 601         AC_DEFINE(HAVE_QDBM, 1, [QDBM Support])
 602     elif test x$ac_cv_gdbmopen = xyes; then
 603         CPPFLAGS="$OLDCPPFLAGS $GDBM_INC"
 604         LIBS="$OLDLIBS $GDBM_LIB -lgdbm";
 605         AC_DEFINE(HAVE_GDBM, 1, [GDBM Support])
 606     elif test x$ac_cv_dbcreate = xyes; then
 607         CPPFLAGS="-I$BDB_INCLUDE_DIR $OLDCPPFLAGS"
 608         LIBS="$OLDLIBS -L$BDB_LIB_DIR -l$BDB_LIB"
 609         AC_DEFINE(HAVE_DB4, 1, [Sleepycat DB4 Support])
 610     else
 611         AC_MSG_ERROR([You need one of: QDBM, GDBM or Sleepycat DB4 for --enable-hcache])
 612     fi
 613 fi])
 614 dnl -- end cache --
 615
 616 AC_SUBST(MUTTLIBS)
 617 AC_SUBST(MUTT_LIB_OBJECTS)
 618 AC_SUBST(LIBNNTP)
 619 AC_SUBST(LIBNNTPDEPS)
 620
 621 dnl -- iconv/gettext --
 622
 623 AC_ARG_ENABLE(iconv, AC_HELP_STRING([--disable-iconv], [Disable iconv support]),
 624         [if test x$enableval = xno ; then
 625                 am_cv_func_iconv=no
 626         fi
 627 ])
 628
 629 AM_GNU_GETTEXT
 630
 631 if test "$am_cv_func_iconv" != "yes"
 632 then
 633   AC_MSG_WARN([Configuring without iconv support. See INSTALL for details])
 634 else
 635
 636 AC_CHECK_HEADERS(iconv.h,
 637         [AC_MSG_CHECKING(whether iconv.h defines iconv_t)
 638          AC_EGREP_HEADER([typedef.*iconv_t],iconv.h,
 639                 [AC_MSG_RESULT(yes)
 640                  AC_DEFINE(HAVE_ICONV_T_DEF, 1,
 641                         [Define if <iconv.h> defines iconv_t.])],
 642                  AC_MSG_RESULT(no))])
 643
 644 dnl (1) Some implementations of iconv won't convert from UTF-8 to UTF-8.
 645 dnl (2) In glibc-2.1.2 and earlier there is a bug that messes up ob and
 646 dnl     obl when args 2 and 3 are 0 (fixed in glibc-2.1.3).
 647 AC_CACHE_CHECK([whether this iconv is good enough], mutt_cv_iconv_good,
 648         mutt_save_LIBS="$LIBS"
 649         LIBS="$LIBS $LIBICONV"
 650         AC_TRY_RUN([
 651 #include <iconv.h>
 652 int main()
 653 {
 654   iconv_t cd;
 655 changequote(, )dnl
 656   char buf[4];
 657 changequote([, ])dnl
 658   char *ob;
 659   size_t obl;
 660   ob = buf, obl = sizeof(buf);
 661   return ((cd = iconv_open("UTF-8", "UTF-8")) != (iconv_t)(-1) &&
 662           (iconv(cd, 0, 0, &ob, &obl) ||
 663            !(ob == buf && obl == sizeof(buf)) ||
 664            iconv_close(cd)));
 665 }
 666                 ],
 667                 mutt_cv_iconv_good=yes,
 668                 mutt_cv_iconv_good=no,
 669                 mutt_cv_iconv_good=yes)
 670         LIBS="$mutt_save_LIBS")
 671 if test "$mutt_cv_iconv_good" = no; then
 672   AC_MSG_ERROR(Try using libiconv instead)
 673 fi
 674
 675 dnl This is to detect implementations such as the one in glibc-2.1,
 676 dnl which always convert exactly but return the number of characters
 677 dnl converted instead of the number converted inexactly.
 678 AC_CACHE_CHECK([whether iconv is non-transcribing], mutt_cv_iconv_nontrans,
 679         mutt_save_LIBS="$LIBS"
 680         LIBS="$LIBS $LIBICONV"
 681         AC_TRY_RUN([
 682 #include <iconv.h>
 683 #include <string.h>
 684 int main()
 685 {
 686   iconv_t cd;
 687   const char *ib;
 688   char *ob;
 689   size_t ibl, obl;
 690   const char *s = "\304\211";
 691 changequote(, )dnl
 692   char t[3];
 693 changequote([, ])dnl
 694   ib = s, ibl = 2, ob = t, obl = 3;
 695   return ((cd = iconv_open("UTF-8", "UTF-8")) == (iconv_t)(-1) ||
 696           iconv(cd, &ib, &ibl, &ob, &obl));
 697 }
 698                 ],
 699                 mutt_cv_iconv_nontrans=no,
 700                 mutt_cv_iconv_nontrans=yes,
 701                 mutt_cv_iconv_nontrans=no)
 702         LIBS="$mutt_save_LIBS")
 703 if test "$mutt_cv_iconv_nontrans" = yes; then
 704   AC_DEFINE(ICONV_NONTRANS, 1)
 705 else
 706   AC_DEFINE(ICONV_NONTRANS, 0)
 707 fi
 708
 709 CPPFLAGS="$CPPFLAGS -I\$(top_srcdir)/intl"
 710
 711 if test "$BUILD_INCLUDED_LIBINTL" = "yes"; then
 712   AC_DEFINE(HAVE_BIND_TEXTDOMAIN_CODESET,1,
 713           [ Define if your gettext has bind_textdomain_codeset. ])
 714 else
 715   AC_CHECK_FUNCS(bind_textdomain_codeset)
 716 fi
 717
 718 fi # libiconv
 719
 720 dnl -- locales --
 721
 722 AC_CHECK_HEADERS(wchar.h)
 723
 724 AC_CACHE_CHECK([for wchar_t], mutt_cv_wchar_t,
 725         AC_TRY_COMPILE([
 726 #include <stddef.h>
 727 #include <stdlib.h>
 728 #ifdef HAVE_WCHAR_H
 729 #include <wchar.h>
 730 #endif
 731                 ],
 732                 [ wchar_t wc; return 0; ],
 733                 mutt_cv_wchar_t=yes,
 734                 mutt_cv_wchar_t=no))
 735
 736 if test "$mutt_cv_wchar_t" = no; then
 737         AC_DEFINE(wchar_t,int,[ Define to 'int' if system headers don't define. ])
 738 fi
 739
 740 AC_CACHE_CHECK([for wint_t], mutt_cv_wint_t,
 741         AC_TRY_COMPILE([
 742 #include <stddef.h>
 743 #include <stdlib.h>
 744 #ifdef HAVE_WCHAR_H
 745 #include <wchar.h>
 746 #endif
 747                 ],
 748                 [ wint_t wc; return 0; ],
 749                 mutt_cv_wint_t=yes,
 750                 mutt_cv_wint_t=no))
 751
 752 if test "$mutt_cv_wint_t" = no; then
 753         AC_DEFINE(wint_t,int,[ Define to 'int' if system headers don't define. ])
 754 fi
 755
 756 AC_CHECK_HEADERS(wctype.h)
 757 AC_CHECK_FUNCS(iswalnum iswalpha  iswcntrl iswdigit)
 758 AC_CHECK_FUNCS(iswgraph iswlower iswprint iswpunct iswspace iswupper)
 759 AC_CHECK_FUNCS(iswxdigit towupper towlower)
 760
 761 AC_CACHE_CHECK([for mbstate_t], mutt_cv_mbstate_t,
 762         AC_TRY_COMPILE([
 763 #include <stddef.h>
 764 #include <stdlib.h>
 765 #ifdef HAVE_WCHAR_H
 766 #include <wchar.h>
 767 #endif
 768                 ],
 769                 [ mbstate_t s; return 0; ],
 770                 mutt_cv_mbstate_t=yes,
 771                 mutt_cv_mbstate_t=no))
 772
 773 if test "$mutt_cv_mbstate_t" = no; then
 774         AC_DEFINE(mbstate_t,int,[ Define to 'int' if system headers don't define. ])
 775 fi
 776
 777 wc_funcs=maybe
 778 AC_ARG_WITH(wc-funcs, AC_HELP_STRING([--without-wc-funcs], [Do not use the system's wchar_t functions]),
 779         wc_funcs=$withval)
 780
 781 if test "$wc_funcs" != yes -a "$wc_funcs" != no; then
 782         AC_CACHE_CHECK([for wchar_t functions], mutt_cv_wc_funcs,
 783                 mutt_cv_wc_funcs=no
 784                 AC_TRY_LINK([
 785 #define _XOPEN_SOURCE 1
 786 #include <stddef.h>
 787 #include <stdlib.h>
 788 #ifdef HAVE_WCTYPE_H
 789 #include <wctype.h>
 790 #endif
 791 #ifdef HAVE_WCHAR_H
 792 #include <wchar.h>
 793 #endif],
 794                         [mbrtowc(0, 0, 0, 0); wctomb(0, 0); wcwidth(0);
 795         iswprint(0); iswspace(0); towlower(0); towupper(0); iswalnum(0)],
 796                         mutt_cv_wc_funcs=yes))
 797         wc_funcs=$mutt_cv_wc_funcs
 798 fi
 799
 800 if test $wc_funcs = yes; then
 801         AC_DEFINE(HAVE_WC_FUNCS,1,[ Define if you are using the system's wchar_t functions. ])
 802 fi
 803
 804 AC_CACHE_CHECK([for nl_langinfo and CODESET], mutt_cv_langinfo_codeset,
 805   [AC_TRY_LINK([#include <langinfo.h>],
 806     [char* cs = nl_langinfo(CODESET);],
 807     mutt_cv_langinfo_codeset=yes,
 808     mutt_cv_langinfo_codeset=no)])
 809 if test $mutt_cv_langinfo_codeset = yes; then
 810   AC_DEFINE(HAVE_LANGINFO_CODESET,1,[ Define if you have <langinfo.h> and nl_langinfo(CODESET). ])
 811 fi
 812
 813 AC_CACHE_CHECK([for nl_langinfo and YESEXPR], mutt_cv_langinfo_yesexpr,
 814   [AC_TRY_LINK([#include <langinfo.h>],
 815     [char* cs = nl_langinfo(YESEXPR);],
 816     mutt_cv_langinfo_yesexpr=yes,
 817     mutt_cv_langinfo_yesexpr=no)])
 818 if test $mutt_cv_langinfo_yesexpr = yes; then
 819   AC_DEFINE(HAVE_LANGINFO_YESEXPR,1,[ Define if you have <langinfo.h> and nl_langinfo(YESEXPR). ])
 820 fi
 821
 822 dnl -- libesmtp --
 823 MUTT_AM_LIBESMTP
 824 if test x$use_libesmtp = xyes; then
 825     CFLAGS="$CFLAGS $mutt_libesmtp_cflags"
 826     MUTTLIBS="$MUTTLIBS $mutt_libesmtp_libs"
 827     MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_libesmtp.o"
 828
 829     AC_DEFINE(USE_LIBESMTP,
 830               1,
 831               [Define to enable the use of libesmtp])
 832 fi
 833 dnl -- end libesmtp --
 834
 835 dnl -- sgml tools --
 836
 837 dnl Documentation tools
 838 have_openjade="no"
 839 AC_PATH_PROG([OSPCAT], [ospcat], [none])
 840 if test "$OSPCAT" != "none"
 841 then
 842   AC_MSG_CHECKING([for openjade docbook stylesheets])
 843   dslosfile=`ospcat --public-id="-//Norman Walsh//DOCUMENT DocBook Print Stylesheet//EN"`
 844   DSLROOT=`echo $dslosfile | sed -n -e "s/.*SOIBASE='\(@<:@^'@:>@*\)\/catalog'.*/\1/p"`
 845   # ospcat may spit out an absolute path without an SOIBASE
 846   if test -z "$DSLROOT"
 847   then
 848     DSLROOT=`echo $dslosfile | sed -e 's|<OSFILE>\(.*\)/print/docbook.dsl|\1|'`
 849   fi
 850   if test -f $DSLROOT/print/docbook.dsl
 851   then
 852     AC_MSG_RESULT([in $DSLROOT])
 853     have_openjade="yes"
 854   else
 855     AC_MSG_RESULT([not found: PDF documentation will not be built.])
 856   fi
 857 fi
 858 AC_SUBST(DSLROOT)
 859
 860 AC_MSG_CHECKING([for lynx])
 861 AC_PATH_PROG([HTML2TXT_CMD], [lynx], [none])
 862 if test x"$HTML2TXT_CMD" = x"none"
 863 then
 864   AC_MSG_CHECKING([for w3m])
 865   AC_PATH_PROG([HTML2TXT_CMD], [w3m], [none])
 866 fi
 867 if test x"$HTML2TXT_CMD" = x"none"
 868 then
 869   AC_MSG_CHECKING([for elinks])
 870   AC_PATH_PROG([HTML2TXT_CMD], [elinks], [none])
 871 fi
 872 case "$HTML2TXT_CMD" in
 873   *elinks*)
 874     HTML2TXT_CMD="$HTML2TXT_CMD -dump -no-numbering -no-references \$^ > \$@"
 875     ;;
 876   *lynx*)
 877     HTML2TXT_CMD="$HTML2TXT_CMD -dump -nolist -with_backspaces \$^ > \$@"
 878     ;;
 879   *w3m*)
 880     HTML2TXT_CMD="$HTML2TXT_CMD -dump \$^ > \$@"
 881     ;;
 882   *)
 883     HTML2TXT_CMD="true"
 884     ;;
 885 esac
 886 AC_SUBST(HTML2TXT_CMD)
 887
 888 AC_MSG_CHECKING([for tidy])
 889 AC_PATH_PROG([HTMLCLEAN_CMD], [tidy], [none])
 890
 891 if test x"$HTMLCLEAN_CMD" != x"none"
 892 then
 893   HTMLCLEAN_CMD="$HTMLCLEAN_CMD -q -i -m -asxml -utf8 "
 894 else
 895   HTMLCLEAN_CMD="echo "
 896 fi
 897 AC_SUBST(HTMLCLEAN_CMD)
 898
 899 AC_OUTPUT(Makefile intl/Makefile m4/Makefile
 900         po/Makefile.in doc/Makefile contrib/Makefile
 901         lib-lib/Makefile
 902         lib-mime/Makefile
 903         lib-crypt/Makefile
 904         lib-hash/Makefile
 905         lib-sys/Makefile
 906         lib-ui/Makefile
 907         lib/Makefile
 908         imap/Makefile
 909         pop/Makefile
 910         nntp/Makefile
 911         Madmuttrc.head
 912         doc/instdoc.sh)