configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl !!! WHEN ADDING NEW CONFIGURE TESTS, PLEASE ADD CODE TO MAIN.C !!!
   4 dnl !!! TO DUMP THEIR RESULTS WHEN MUTT -V IS CALLED            !!!
   5
   6 AC_PREREQ([2.50])
   7 AC_INIT([mutt.h])
   8 AM_CONFIG_HEADER(config.h)
   9 AM_INIT_AUTOMAKE(madmutt, `cat "$srcdir/VERSION.in"`)
  10
  11 AC_SUBST([CONFIGURE_DEPENDENCIES], ['$(top_srcdir)/VERSION.in'])
  12
  13 AC_GNU_SOURCE
  14
  15 ALL_LINGUAS="de ru it es uk fr pl nl cs id sk ko el zh_TW zh_CN pt_BR eo gl sv da lt tr ja hu et ca bg"
  16
  17 AC_CANONICAL_HOST
  18
  19 AC_MSG_CHECKING([for prefix])
  20 if test x$prefix = xNONE; then
  21     mutt_cv_prefix=$ac_default_prefix
  22 else
  23     mutt_cv_prefix=$prefix
  24 fi
  25 AC_MSG_RESULT($mutt_cv_prefix)
  26
  27 AC_PROG_CPP
  28 AC_PROG_CC_C99
  29
  30 AM_C_PROTOTYPES
  31 AC_C_INLINE
  32 AC_C_CONST
  33 if test "x$U" != "x"; then
  34     AC_MSG_ERROR(Compiler not ANSI compliant)
  35 fi
  36 AC_ISC_POSIX
  37 AC_HEADER_STDC
  38
  39 AC_PROG_MAKE_SET
  40 AC_PROG_INSTALL
  41 AC_PROG_RANLIB
  42 AC_PROG_GPERF
  43 PKG_PROG_PKG_CONFIG
  44 AC_CHECK_TOOL(AR, ar, ar)
  45
  46 AC_SYS_LARGEFILE
  47 AC_FUNC_FSEEKO
  48 AC_CHECK_SIZEOF(off_t)
  49
  50 AH_TEMPLATE([sig_atomic_t],
  51             [Define to 'int' if <signal.h> doesn't define.])
  52 AH_TEMPLATE([HAVE_START_COLOR],
  53             [Define if you have start_color, as a function or macro.])
  54 AH_TEMPLATE([HAVE_TYPEAHEAD],
  55             [Define if you have typeahead, as a function or macro.])
  56 AH_TEMPLATE([HAVE_BKGDSET],
  57             [Define if you have bkgdset, as a function or macro.])
  58 AH_TEMPLATE([HAVE_CURS_SET],
  59             [Define if you have curs_set, as a function or macro.])
  60 AH_TEMPLATE([HAVE_META],
  61             [Define if you have meta, as a function or macro.])
  62 AH_TEMPLATE([HAVE_USE_DEFAULT_COLORS],
  63             [Define if you have use_default_colors, as a function or macro.])
  64 AH_TEMPLATE([HAVE_RESIZETERM],
  65             [Define if you have resizeterm, as a function or macro.])
  66 AH_TEMPLATE([SIG_ATOMIC_VOLATILE_T],
  67             [Some systems declare sig_atomic_t as volatile, some others -- no.
  68              This define will have value `sig_atomic_t' or
  69              `volatile sig_atomic_t' accordingly.])
  70 AH_TEMPLATE([ICONV_NONTRANS],
  71             [Define as 1 if iconv() only converts exactly and we should treat
  72              all return values other than (size_t)(-1) as equivalent.])
  73
  74 MUTT_C99_INTTYPES
  75
  76 dnl ---------------- sendmail ----------------
  77
  78 ac_aux_path_sendmail=/usr/sbin:/usr/lib
  79 AC_PATH_PROG(SENDMAIL, sendmail, /usr/sbin/sendmail, $PATH:$ac_aux_path_sendmail)
  80 AC_DEFINE_UNQUOTED(SENDMAIL,"$ac_cv_path_SENDMAIL",[ Where to find sendmail on your system. ])
  81
  82 OPS='$(srcdir)/OPS'
  83
  84 dnl ---------------- gpgme ----------------
  85
  86 AC_ARG_ENABLE(gpgme, AC_HELP_STRING([--enable-gpgme], [Enable GPGME support]),[
  87     if test x$enableval = xyes; then
  88         AM_PATH_GPGME(,,[AC_MSG_ERROR(GPGME not found)])
  89         MUTTLIBS="$MUTTLIBS $GPGME_LIBS"
  90         AC_DEFINE(CRYPT_BACKEND_GPGME, 1, [Defined, if GPGME support is enabled])
  91         AM_CONDITIONAL(BUILD_GPGME, true)
  92     else
  93         AM_CONDITIONAL(BUILD_GPGME, false)
  94     fi
  95 ])
  96
  97 dnl ---------------- mixmaster ----------------
  98
  99 AC_ARG_WITH(mixmaster, AC_HELP_STRING([--with-mixmaster[=PATH]], [Include Mixmaster support]), [
 100     MIXMASTER=${withval:-"mixmaster"}
 101     OPS="$OPS \$(srcdir)/OPS.MIX"
 102     MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS remailer.o"
 103     AC_DEFINE_UNQUOTED(MIXMASTER,"$MIXMASTER",[Where to find mixmaster on your system.])
 104 ])
 105
 106 # We now require all OPS
 107 OPS="$OPS \$(srcdir)/OPS.PGP \$(srcdir)/OPS.SMIME \$(srcdir)/OPS.CRYPT "
 108 AC_SUBST([OPS])
 109
 110 AC_PATH_PROG(ISPELL, ispell, no)
 111 if test $ISPELL != no; then
 112     AC_DEFINE_UNQUOTED(ISPELL,"$ISPELL",[Where to find ispell on your system.])
 113 fi
 114
 115 AC_ARG_WITH(slang, AC_HELP_STRING([--with-slang[=DIR]], [Use S-Lang instead of ncurses]),
 116     [AC_CACHE_CHECK([if this is a BSD system], mutt_cv_bsdish,
 117         [AC_TRY_RUN([#include <sys/param.h>
 118
 119 main ()
 120 {
 121 #ifdef BSD
 122         exit (0);
 123 #else
 124         exit (1);
 125 #endif
 126 }],
 127         mutt_cv_bsdish=yes,
 128         mutt_cv_bsdish=no,
 129         mutt_cv_bsdish=no)])
 130
 131         AC_MSG_CHECKING(for S-Lang)
 132         if test $withval = yes; then
 133             if test -d $srcdir/../slang; then
 134                 mutt_cv_slang=$srcdir/../slang/src
 135                 CFLAGS="$CFLAGS -I${mutt_cv_slang}"
 136                 LDFLAGS="$LDFLAGS -L${mutt_cv_slang}/objs"
 137             else
 138                 if test -d $mutt_cv_prefix/include/slang; then
 139                     CFLAGS="$CFLAGS -I$mutt_cv_prefix/include/slang"
 140                 elif test -d /usr/include/slang; then
 141                     CFLAGS="$CFLAGS -I/usr/include/slang"
 142                 fi
 143                 mutt_cv_slang=yes
 144             fi
 145         else
 146             dnl ---Check to see if $withval is a source directory
 147             if test -f $withval/src/slang.h; then
 148                 mutt_cv_slang=$withval/src
 149                 CFLAGS="$CFLAGS -I${mutt_cv_slang}"
 150                 LDFLAGS="$LDFLAGS -L${mutt_cv_slang}/objs"
 151             else
 152                 dnl ---Must be installed somewhere
 153                 mutt_cv_slang=$withval
 154                 if test -d $withval/include/slang; then
 155                         CFLAGS="$CFLAGS -I${withval}/include/slang"
 156                 elif test -d $withval/include; then
 157                         CFLAGS="$CFLAGS -I${withval}/include"
 158                 fi
 159                 LDFLAGS="$LDFLAGS -L${withval}/lib"
 160             fi
 161         fi
 162         AC_MSG_RESULT($mutt_cv_slang)
 163         if test $mutt_cv_bsdish = yes; then
 164             AC_CHECK_LIB(termlib, main)
 165         fi
 166         AC_DEFINE(USE_SLANG_CURSES,1, [ Define if you compile with SLang instead of curses/ncurses. ])
 167         AC_DEFINE(HAVE_COLOR,1,[ Define if your curses library supports color. ])
 168
 169         dnl --- now that we've found it, check the link
 170
 171         AC_CHECK_LIB(slang, SLtt_get_terminfo,
 172             [MUTTLIBS="$MUTTLIBS -lslang -lm"],
 173             [AC_MSG_ERROR(unable to compile.  check config.log)], -lm)
 174     ],
 175     [   mutt_cv_curses=/usr
 176         AC_ARG_WITH(curses, AC_HELP_STRING([--with-curses=DIR], [Where ncurses is installed]), [
 177             if test $withval != yes; then
 178                 mutt_cv_curses=$withval
 179             fi
 180             if test x$mutt_cv_curses != x/usr; then
 181                 LDFLAGS="-L${mutt_cv_curses}/lib $LDFLAGS"
 182                 CPPFLAGS="$CPPFLAGS -I${mutt_cv_curses}/include"
 183             fi
 184         ])
 185
 186         AC_CHECK_FUNC(initscr,,[
 187         cf_ncurses="ncurses"
 188         for lib in ncursesw ncurses; do
 189             AC_CHECK_LIB($lib, waddnwstr, [cf_ncurses="$lib"; break])
 190         done
 191         AC_CHECK_LIB($cf_ncurses, initscr,
 192             [   MUTTLIBS="$MUTTLIBS -l$cf_ncurses"
 193                 if test x$mutt_cv_curses = x/usr -a -d /usr/include/ncurses; then
 194                     CPPFLAGS="$CPPFLAGS -I/usr/include/ncurses"
 195                 fi
 196
 197                 if test "$cf_ncurses" = ncursesw; then
 198                     AC_CHECK_HEADERS(ncurses/ncurses.h,[cf_cv_ncurses_header="ncurses/ncurses.h"])
 199                     AC_CHECK_HEADERS(ncursesw/ncurses.h,[cf_cv_ncurses_header="ncursesw/ncurses.h"])
 200                 else
 201                     AC_CHECK_HEADERS(ncurses.h,[cf_cv_ncurses_header="ncurses.h"])
 202                 fi
 203             ],
 204             [CF_CURSES_LIBS])
 205         ])
 206
 207         old_LIBS="$LIBS"
 208         LIBS="$LIBS $MUTTLIBS"
 209         CF_CHECK_FUNCDECLS([#include <${cf_cv_ncurses_header-curses.h}>],
 210                            [start_color typeahead bkgdset curs_set meta use_default_colors resizeterm])
 211         if test "$ac_cv_func_decl_start_color" = yes; then
 212             AC_DEFINE(HAVE_COLOR,1,[ Define if your curses library supports color. ])
 213         fi
 214         LIBS="$old_LIBS"
 215     ])
 216
 217 AC_CHECK_HEADERS(stdarg.h sys/ioctl.h ioctl.h sysexits.h)
 218 AC_CHECK_HEADERS(sys/time.h sys/resource.h)
 219 AC_CHECK_HEADERS(unix.h)
 220
 221 AC_CHECK_FUNCS(setrlimit getsid isctype)
 222
 223 AC_TYPE_SIGNAL
 224
 225 AC_MSG_CHECKING(for sig_atomic_t in signal.h)
 226 AC_EGREP_HEADER(sig_atomic_t,signal.h,
 227     [   ac_cv_type_sig_atomic_t=yes;
 228         AC_EGREP_HEADER(volatile.*sig_atomic_t,
 229                         signal.h,
 230                         [is_sig_atomic_t_volatile=yes; AC_MSG_RESULT([yes, volatile])],
 231                         [is_sig_atomic_t_volatile=no;  AC_MSG_RESULT([yes, non volatile])])
 232     ],
 233     [   AC_MSG_RESULT(no)
 234         AC_CHECK_TYPE(sig_atomic_t, int)
 235         is_sig_atomic_t_volatile=no
 236     ])
 237 if test $is_sig_atomic_t_volatile = 'yes'
 238 then
 239     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, sig_atomic_t)
 240 else
 241     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, [volatile sig_atomic_t])
 242 fi
 243
 244 AC_DECL_SYS_SIGLIST
 245 AC_TYPE_PID_T
 246
 247 AC_CHECK_FUNC(getopt)
 248 if test $ac_cv_func_getopt = yes; then
 249     AC_CHECK_HEADERS(getopt.h)
 250 fi
 251
 252 AC_CHECK_FUNC(regcomp)
 253 if test $ac_cv_func_regcomp = yes; then
 254    AC_CHECK_HEADERS(regex.h)
 255 fi
 256
 257 AC_ARG_WITH(homespool,
 258             AC_HELP_STRING([--with-homespool[=FILE]],
 259                            [File in user's directory where new mail is spooled]),
 260                            with_homespool=${withval})
 261 if test x$with_homespool != x; then
 262     if test $with_homespool = yes; then
 263             with_homespool=mailbox
 264     fi
 265     AC_DEFINE_UNQUOTED(MAILPATH,"$with_homespool",[ Where new mail is spooled. ])
 266     AC_DEFINE(HOMESPOOL,1,
 267     [   Is mail spooled to the user's home directory?  If defined,
 268         MAILPATH should be set to the filename of the spool mailbox
 269         relative the the home directory.
 270         use: configure --with-homespool=FILE
 271     ])
 272     AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 273     mutt_cv_setgid=no
 274 else
 275     AC_ARG_WITH(mailpath, AC_HELP_STRING([--with-mailpath=DIR], [Directory where spool mailboxes are located]),
 276         [mutt_cv_mailpath=$withval],
 277         [ AC_CACHE_CHECK(where new mail is stored, mutt_cv_mailpath,
 278             [mutt_cv_mailpath=no
 279             if test -d /var/mail; then
 280                 mutt_cv_mailpath=/var/mail
 281             elif test -d /var/spool/mail; then
 282                 mutt_cv_mailpath=/var/spool/mail
 283             elif test -d /usr/spool/mail; then
 284                 mutt_cv_mailpath=/usr/spool/mail
 285             elif test -d /usr/mail; then
 286                 mutt_cv_mailpath=/usr/mail
 287             fi])
 288         ])
 289     if test "$mutt_cv_mailpath" = no; then
 290         AC_MSG_ERROR("Could not determine where new mail is stored.")
 291     fi
 292     AC_DEFINE_UNQUOTED(MAILPATH,"$mutt_cv_mailpath",[ Where new mail is spooled. ])
 293
 294     AC_CACHE_CHECK(if $mutt_cv_mailpath is world writable, mutt_cv_worldwrite, [AC_TRY_RUN([#include <sys/types.h>
 295 #include <sys/stat.h>
 296
 297 int main (int argc, char **argv)
 298 {
 299         struct stat s;
 300
 301         stat ("$mutt_cv_mailpath", &s);
 302         if (s.st_mode & S_IWOTH) exit (0);
 303         exit (1);
 304 }], mutt_cv_worldwrite=yes, mutt_cv_worldwrite=no, mutt_cv_worldwrite=no)])
 305
 306         mutt_cv_setgid=no
 307         if test $mutt_cv_worldwrite = yes; then
 308                 AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 309         else
 310                 AC_CACHE_CHECK(if $mutt_cv_mailpath is group writable, mutt_cv_groupwrite, [AC_TRY_RUN([#include <sys/types.h>
 311 #include <sys/stat.h>
 312
 313 int main (int argc, char **argv)
 314 {
 315         struct stat s;
 316
 317         stat ("$mutt_cv_mailpath", &s);
 318         if (s.st_mode & S_IWGRP) exit (0);
 319         exit (1);
 320 }], mutt_cv_groupwrite=yes, mutt_cv_groupwrite=no, mutt_cv_groupwrite=no)])
 321
 322         if test $mutt_cv_groupwrite = yes; then
 323             AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 324             AC_DEFINE(USE_SETGID,1,[ Define if mutt should run setgid "mail". ])
 325             mutt_cv_setgid=yes
 326         fi
 327     fi
 328 fi
 329
 330 AC_MSG_CHECKING(where to put the documentation)
 331 AC_ARG_WITH(docdir, AC_HELP_STRING([--with-docdir=PATH], [Specify where to put the documentation]),
 332         [mutt_cv_docdir=$withval],
 333         [mutt_cv_docdir="${prefix}/doc/madmutt"])
 334 AC_MSG_RESULT($mutt_cv_docdir)
 335
 336 docdir=$mutt_cv_docdir
 337 AC_SUBST(docdir)
 338
 339 if test x$mutt_cv_setgid = xyes; then
 340     DOTLOCK_GROUP='mail'
 341     DOTLOCK_PERMISSION=2755
 342 else
 343     DOTLOCK_GROUP=''
 344     DOTLOCK_PERMISSION=755
 345 fi
 346 AC_SUBST(DOTLOCK_GROUP)
 347 AC_SUBST(DOTLOCK_PERMISSION)
 348
 349 dnl -- socket dependencies --
 350
 351 AC_ARG_ENABLE(nntp, AC_HELP_STRING([--enable-nntp],[Enable NNTP support]),[
 352     if test x$enableval = xyes ; then
 353         AC_DEFINE(USE_NNTP,1,[ Compiling with newsreading support with NNTP ])
 354         LIBNNTP="-Lnntp -lnntp"
 355         LIBNNTPDEPS="\$(top_srcdir)/nntp/nntp.h nntp/libnntp.a"
 356         need_nntp="yes"
 357     fi
 358 ])
 359 AM_CONDITIONAL(BUILD_NNTP, test x$need_nntp = xyes)
 360
 361 dnl -- end socket dependencies --
 362
 363 AC_MSG_CHECKING([for socklen_t])
 364 AC_EGREP_HEADER(socklen_t, sys/socket.h, AC_MSG_RESULT([yes]),
 365         AC_MSG_RESULT([no])
 366         AC_DEFINE(socklen_t,int, [ Define to 'int' if <sys/socket.h> doesn't have it. ]))
 367 AC_CHECK_FUNC(gethostent, , AC_CHECK_LIB(nsl, gethostent))
 368 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt))
 369 AC_CHECK_FUNCS(getaddrinfo)
 370
 371 dnl -- imap dependencies --
 372
 373 AC_ARG_WITH(gss, AC_HELP_STRING([--with-gss[=PFX]], [Compile in GSSAPI authentication for IMAP]),
 374     gss_prefix="$withval", gss_prefix="no")
 375 if test "$gss_prefix" != "no"
 376 then
 377     MUTT_AM_PATH_GSSAPI(gss_prefix)
 378     AC_MSG_CHECKING(GSSAPI implementation)
 379     AC_MSG_RESULT($GSSAPI_IMPL)
 380     if test "$GSSAPI_IMPL" = "none"
 381     then
 382       AC_CACHE_SAVE
 383       AC_MSG_RESULT([GSSAPI libraries not found])
 384     fi
 385     if test "$GSSAPI_IMPL" = "Heimdal"
 386     then
 387       AC_DEFINE(HAVE_HEIMDAL,1,[ Define if your GSSAPI implementation is Heimdal ])
 388     fi
 389     CPPFLAGS="$CPPFLAGS $GSSAPI_CFLAGS"
 390     MUTTLIBS="$MUTTLIBS $GSSAPI_LIBS"
 391     AC_DEFINE(USE_GSS,1,[ Define if you have GSSAPI libraries available ])
 392     need_gss="yes"
 393 fi
 394 AM_CONDITIONAL(USE_GSS, test x$need_gss = xyes)
 395
 396 dnl -- end imap dependencies --
 397
 398 AC_ARG_WITH(ssl, AC_HELP_STRING([--with-ssl[=PFX]], [Compile in SSL support for POP/IMAP]),
 399 [   if test "$with_ssl" != "no"; then
 400         if test "$with_ssl" != "yes"; then
 401             LDFLAGS="$LDFLAGS -L$withval/lib"
 402             CPPFLAGS="$CPPFLAGS -I$withval/include"
 403         fi
 404         saved_LIBS="$LIBS"
 405
 406         AC_CHECK_LIB(crypto, X509_new,, AC_MSG_ERROR([Unable to find SSL library]))
 407         AC_CHECK_LIB(ssl, SSL_new,, AC_MSG_ERROR([Unable to find SSL library]), -lcrypto)
 408
 409         AC_CHECK_FUNCS(RAND_status RAND_egd)
 410
 411         AC_DEFINE(USE_SSL,1,[ Define if you want support for SSL. ])
 412         LIBS="$saved_LIBS"
 413         MUTTLIBS="$MUTTLIBS -lssl -lcrypto"
 414         need_ssl=yes
 415     fi
 416 ])
 417
 418 AC_ARG_WITH([gnutls], AC_HELP_STRING([--with-gnutls], [Enable SSL support using gnutls]),
 419             [gnutls_prefix="$withval"], [gnutls_prefix="no"])
 420 if test "$gnutls_prefix" != "no"; then
 421     if test x"$need_ssl" = x"yes"; then
 422         AC_MSG_ERROR([Only either OpenSSL or GNUTLS may be used])
 423     fi
 424     AM_PATH_LIBGNUTLS(,[
 425         CPPFLAGS="$CPPFLAGS $LIBGNUTLS_CFLAGS"
 426         MUTTLIBS="$MUTTLIBS $LIBGNUTLS_LIBS"
 427         AC_DEFINE(USE_GNUTLS, 1, [Define if you want support for SSL via the gnutls library.])
 428         need_ssl=yes],
 429         [AC_MSG_ERROR([could not find libgnutls])
 430     ])
 431 fi
 432 AM_CONDITIONAL(USE_SSL, test x$need_ssl = xyes)
 433 AC_SUBST(MUTT_SSL_OBJECTS)
 434
 435 AC_ARG_WITH(sasl2, AC_HELP_STRING([--with-sasl2[=PFX]],
 436             [Use Cyrus SASL library version 2 for POP/IMAP authentication]),[
 437     if test "$with_sasl2" != "no"; then
 438         if test "$with_sasl2" != "yes"; then
 439             CPPFLAGS="$CPPFLAGS -I$with_sasl2/include"
 440             LDFLAGS="$LDFLAGS -L$with_sasl2/lib"
 441         fi
 442
 443         saved_LIBS="$LIBS"
 444
 445         AC_CHECK_LIB(sasl2, sasl_client_init,,AC_MSG_ERROR([could not find libsasl2]))
 446
 447         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_sasl.o"
 448         MUTTLIBS="$MUTTLIBS -lsasl2"
 449         LIBS="$saved_LIBS"
 450         AC_DEFINE(USE_SASL,1,
 451                   [Define if want to use version 2 of the Cyrus SASL library.])
 452         need_sasl=yes
 453     fi
 454 ])
 455 AM_CONDITIONAL(USE_SASL, test x$need_sasl = xyes)
 456
 457 AC_ARG_WITH(idn, AC_HELP_STRING([--with-idn=[PFX]], [Use GNU libidn for domain names]),[
 458     if test x$with_idn != xno ; then
 459         PKG_CHECK_MODULES(IDN,libidn,[
 460             if $PKG_CONFIG --atleast-version=0.6; then
 461                 AC_MSG_ERROR([libidn is too old, want 0.6 at least])
 462             fi
 463             CPPFLAGS="$CPPFLAGS $IDN_CFLAGS"
 464             LDFLAGS="$LDFLAGS $IDN_LIBS"
 465         ],[AC_MSG_ERROR([could not find libidn])])
 466     fi
 467 ])
 468
 469 dnl -- end socket --
 470
 471 AC_ARG_ENABLE(flock, AC_HELP_STRING([--enable-flock], [Use flock() to lock files]),
 472         [if test $enableval = yes; then
 473                 AC_DEFINE(USE_FLOCK,1, [ Define to use flock() to lock mailboxes. ])
 474         fi])
 475
 476 mutt_cv_fcntl=yes
 477 AC_ARG_ENABLE(fcntl, AC_HELP_STRING([--disable-fcntl], [Do NOT use fcntl() to lock files]),
 478         [if test $enableval = no; then mutt_cv_fcntl=no; fi])
 479
 480 if test $mutt_cv_fcntl = yes; then
 481         AC_DEFINE(USE_FCNTL,1, [ Define to use fcntl() to lock folders. ])
 482 fi
 483
 484 AC_MSG_CHECKING(whether struct dirent defines d_ino)
 485 ac_cv_dirent_d_ino=no
 486 AC_TRY_LINK([#include <dirent.h>],[struct dirent dp; (void)dp.d_ino],[ac_cv_dirent_d_ino=yes])
 487 if test x$ac_cv_dirent_d_ino = xyes ; then
 488   AC_DEFINE(HAVE_DIRENT_D_INO,1,
 489             [Define to 1 if your system has the dirent::d_ino member])
 490 fi
 491 AC_MSG_RESULT($ac_cv_dirent_d_ino)
 492
 493 AC_ARG_ENABLE(buffy-size, AC_HELP_STRING([--enable-buffy-size], [Use file size attribute instead of access time]),
 494         [if test x$enableval = xyes; then
 495                 AC_DEFINE(BUFFY_SIZE,1,[ Define to enable the "buffy_size" feature. ])
 496         fi])
 497
 498 dnl -- start cache --
 499 AC_ARG_ENABLE(hcache, AC_HELP_STRING([--enable-hcache], [Enable header caching]),
 500 [if test x$enableval = xyes; then
 501     AC_DEFINE(USE_HCACHE, 1, [Enable header caching])
 502
 503     OLDCPPFLAGS="$CPPFLAGS"
 504     OLDLIBS="$LIBS"
 505
 506     need_md5="yes"
 507
 508     ac_prefer_qdbm=yes
 509     AC_ARG_WITH(qdbm, AC_HELP_STRING([--without-qdbm], [Don't use qdbm even if it is available]),
 510         ac_prefer_qdbm=$withval)
 511     if test x$ac_prefer_qdbm != xno; then
 512         PKG_CHECK_MODULES(QDBM,qdbm,[ac_qdbm_here=yes],[ac_qdbm_here=no])
 513     fi
 514
 515     ac_prefer_gdbm=yes
 516     AC_ARG_WITH(gdbm, AC_HELP_STRING([--without-gdbm], [Don't use gdbm even if it is available]),
 517         ac_prefer_gdbm=$withval)
 518     if test x$ac_prefer_gdbm != xno -a x$ac_qdbm_here != xyes; then
 519         ac_cv_gdbmopen=no
 520         GDBM_DIRS="$mutt_cv_prefix /usr/local /usr"
 521         AC_MSG_CHECKING([for gdbm_open])
 522         for d in $GDBM_DIRS; do
 523           if test x$ac_cv_gdbmopen = xno && test -d "$d/include" && test -d "$d/lib"; then
 524             GDBM_INC="-I$d/include"
 525             GDBM_LIB="-L$d/lib"
 526             CPPFLAGS="$OLDCPPFLAGS $GDBM_INC"
 527             LIBS="$OLDLIBS $GDBM_LIB -lgdbm"
 528             AC_TRY_LINK([#include <gdbm.h>],[gdbm_open(0,0,0,0,0);],[ac_cv_gdbmopen=yes])
 529           fi
 530         done
 531         if test x$ac_cv_gdbmopen = xyes; then
 532           AC_MSG_RESULT(yes)
 533         else
 534           AC_MSG_RESULT(no)
 535         fi
 536     fi
 537
 538     ac_bdb_prefix=yes
 539     AC_ARG_WITH(bdb, AC_HELP_STRING([--with-bdb[=DIR]], [Use BerkeleyDB4 if gdbm is not available ]),
 540         ac_bdb_prefix=$withval)
 541     if test x$ac_bdb_prefix != xno -a x$ac_cv_gdbmopen != xyes -a x$ac_qdbm_here != xyes; then
 542         test x$ac_bdb_prefix = xyes && ac_bdb_prefix="$mutt_cv_prefix /opt/csw/bdb4 /opt /usr/local /usr"
 543         for d in $ac_bdb_prefix; do
 544             bdbpfx="$bdbpfx $d"
 545             for v in BerkeleyDB.4.3 BerkeleyDB.4.2 BerkeleyDB.4.1; do
 546                 bdbpfx="$bdbpfx $d/$v"
 547             done
 548         done
 549         BDB_VERSIONS="db-4 db4 db-4.3 db4.3 db43 db-4.2 db4.2 db42 db-4.1 db4.1 db41 db ''"
 550         AC_MSG_CHECKING([for BerkeleyDB > 4.0])
 551         for d in $bdbpfx; do
 552             BDB_INCLUDE_DIR=""
 553             BDB_LIB_DIR=""
 554             for v in / $BDB_VERSIONS; do
 555                 if test -r "$d/include/$v/db.h"; then
 556                     BDB_INCLUDE_DIR="$d/include/$v"
 557                     if test -d "$d/lib/$v"; then
 558                         BDB_LIB_DIR="$d/lib/$v"
 559                         for l in `echo $BDB_VERSIONS`; do
 560                             CPPFLAGS="-I$BDB_INCLUDE_DIR $OLDCPPFLAGS"
 561                             LIBS="$OLDLIBS -L$BDB_LIB_DIR -l$l"
 562                             AC_TRY_LINK([
 563                                 #include <stdlib.h>
 564                                 #include <db.h>
 565                             ],[
 566                                 DB *db = NULL;
 567                                 db->open(db,NULL,NULL,NULL,0,0,0);
 568                             ],[
 569                                 ac_cv_dbcreate=yes
 570                                 BDB_LIB="$l"
 571                                 break
 572                             ])
 573                         done
 574                         test x$ac_cv_dbcreate = xyes && break
 575                     fi
 576                 fi
 577             done
 578             test x$BDB_LIB != x && break
 579         done
 580         if test x$ac_cv_dbcreate = xyes; then
 581             AC_MSG_RESULT(yes)
 582         else
 583             AC_MSG_RESULT(no)
 584         fi
 585     fi
 586
 587     if test x$ac_qdbm_here = xyes; then
 588         CPPFLAGS="$OLDCPPFLAGS $QDBM_CFLAGS"
 589         LIBS="$OLDLIBS $QDBM_LIBS"
 590         AC_DEFINE(HAVE_QDBM, 1, [QDBM Support])
 591     elif test x$ac_cv_gdbmopen = xyes; then
 592         CPPFLAGS="$OLDCPPFLAGS $GDBM_INC"
 593         LIBS="$OLDLIBS $GDBM_LIB -lgdbm";
 594         AC_DEFINE(HAVE_GDBM, 1, [GDBM Support])
 595     elif test x$ac_cv_dbcreate = xyes; then
 596         CPPFLAGS="-I$BDB_INCLUDE_DIR $OLDCPPFLAGS"
 597         LIBS="$OLDLIBS -L$BDB_LIB_DIR -l$BDB_LIB"
 598         AC_DEFINE(HAVE_DB4, 1, [Sleepycat DB4 Support])
 599     else
 600         AC_MSG_ERROR([You need one of: QDBM, GDBM or Sleepycat DB4 for --enable-hcache])
 601     fi
 602 fi])
 603 dnl -- end cache --
 604
 605 AC_SUBST(MUTTLIBS)
 606 AC_SUBST(MUTT_LIB_OBJECTS)
 607 AC_SUBST(LIBNNTP)
 608 AC_SUBST(LIBNNTPDEPS)
 609
 610 dnl -- iconv/gettext --
 611
 612 AC_ARG_ENABLE(iconv, AC_HELP_STRING([--disable-iconv], [Disable iconv support]),
 613         [if test x$enableval = xno ; then
 614                 am_cv_func_iconv=no
 615         fi
 616 ])
 617
 618 AM_GNU_GETTEXT
 619
 620 if test "$am_cv_func_iconv" != "yes"
 621 then
 622   AC_MSG_WARN([Configuring without iconv support. See INSTALL for details])
 623 else
 624
 625 AC_CHECK_HEADERS(iconv.h,
 626         [AC_MSG_CHECKING(whether iconv.h defines iconv_t)
 627          AC_EGREP_HEADER([typedef.*iconv_t],iconv.h,
 628                 [AC_MSG_RESULT(yes)
 629                  AC_DEFINE(HAVE_ICONV_T_DEF, 1,
 630                         [Define if <iconv.h> defines iconv_t.])],
 631                  AC_MSG_RESULT(no))])
 632
 633 dnl (1) Some implementations of iconv won't convert from UTF-8 to UTF-8.
 634 dnl (2) In glibc-2.1.2 and earlier there is a bug that messes up ob and
 635 dnl     obl when args 2 and 3 are 0 (fixed in glibc-2.1.3).
 636 AC_CACHE_CHECK([whether this iconv is good enough], mutt_cv_iconv_good,
 637         mutt_save_LIBS="$LIBS"
 638         LIBS="$LIBS $LIBICONV"
 639         AC_TRY_RUN([
 640 #include <iconv.h>
 641 int main()
 642 {
 643   iconv_t cd;
 644 changequote(, )dnl
 645   char buf[4];
 646 changequote([, ])dnl
 647   char *ob;
 648   size_t obl;
 649   ob = buf, obl = sizeof(buf);
 650   return ((cd = iconv_open("UTF-8", "UTF-8")) != (iconv_t)(-1) &&
 651           (iconv(cd, 0, 0, &ob, &obl) ||
 652            !(ob == buf && obl == sizeof(buf)) ||
 653            iconv_close(cd)));
 654 }
 655                 ],
 656                 mutt_cv_iconv_good=yes,
 657                 mutt_cv_iconv_good=no,
 658                 mutt_cv_iconv_good=yes)
 659         LIBS="$mutt_save_LIBS")
 660 if test "$mutt_cv_iconv_good" = no; then
 661   AC_MSG_ERROR(Try using libiconv instead)
 662 fi
 663
 664 dnl This is to detect implementations such as the one in glibc-2.1,
 665 dnl which always convert exactly but return the number of characters
 666 dnl converted instead of the number converted inexactly.
 667 AC_CACHE_CHECK([whether iconv is non-transcribing], mutt_cv_iconv_nontrans,
 668         mutt_save_LIBS="$LIBS"
 669         LIBS="$LIBS $LIBICONV"
 670         AC_TRY_RUN([
 671 #include <iconv.h>
 672 #include <string.h>
 673 int main()
 674 {
 675   iconv_t cd;
 676   const char *ib;
 677   char *ob;
 678   size_t ibl, obl;
 679   const char *s = "\304\211";
 680 changequote(, )dnl
 681   char t[3];
 682 changequote([, ])dnl
 683   ib = s, ibl = 2, ob = t, obl = 3;
 684   return ((cd = iconv_open("UTF-8", "UTF-8")) == (iconv_t)(-1) ||
 685           iconv(cd, &ib, &ibl, &ob, &obl));
 686 }
 687                 ],
 688                 mutt_cv_iconv_nontrans=no,
 689                 mutt_cv_iconv_nontrans=yes,
 690                 mutt_cv_iconv_nontrans=no)
 691         LIBS="$mutt_save_LIBS")
 692 if test "$mutt_cv_iconv_nontrans" = yes; then
 693     AC_DEFINE(ICONV_NONTRANS, 1)
 694 else
 695     AC_DEFINE(ICONV_NONTRANS, 0)
 696 fi
 697
 698 CPPFLAGS="$CPPFLAGS -I\$(top_srcdir)/intl"
 699
 700 if test "$BUILD_INCLUDED_LIBINTL" = "yes"; then
 701     AC_DEFINE(HAVE_BIND_TEXTDOMAIN_CODESET,1,
 702               [ Define if your gettext has bind_textdomain_codeset. ])
 703 else
 704     AC_CHECK_FUNCS(bind_textdomain_codeset)
 705 fi
 706
 707 fi # libiconv
 708
 709 dnl -- locales --
 710
 711 AC_CHECK_HEADERS(wchar.h)
 712 AC_CHECK_HEADERS(wctype.h)
 713 AC_CHECK_FUNCS(iswalnum iswalpha  iswcntrl iswdigit)
 714 AC_CHECK_FUNCS(iswgraph iswlower iswprint iswpunct iswspace iswupper)
 715 AC_CHECK_FUNCS(iswxdigit towupper towlower)
 716 AC_TYPE_MBSTATE_T
 717
 718 AC_CACHE_CHECK([for nl_langinfo and CODESET], mutt_cv_langinfo_codeset,
 719   [AC_TRY_LINK([#include <langinfo.h>],
 720     [char* cs = nl_langinfo(CODESET);],
 721     mutt_cv_langinfo_codeset=yes,
 722     mutt_cv_langinfo_codeset=no)])
 723 if test $mutt_cv_langinfo_codeset = yes; then
 724   AC_DEFINE(HAVE_LANGINFO_CODESET,1,[ Define if you have <langinfo.h> and nl_langinfo(CODESET). ])
 725 fi
 726
 727 AC_CACHE_CHECK([for nl_langinfo and YESEXPR], mutt_cv_langinfo_yesexpr,
 728   [AC_TRY_LINK([#include <langinfo.h>],
 729     [char* cs = nl_langinfo(YESEXPR);],
 730     mutt_cv_langinfo_yesexpr=yes,
 731     mutt_cv_langinfo_yesexpr=no)])
 732 if test $mutt_cv_langinfo_yesexpr = yes; then
 733   AC_DEFINE(HAVE_LANGINFO_YESEXPR,1,[ Define if you have <langinfo.h> and nl_langinfo(YESEXPR). ])
 734 fi
 735
 736 dnl -- libesmtp --
 737 MUTT_AM_LIBESMTP
 738 if test x$use_libesmtp = xyes; then
 739     CFLAGS="$CFLAGS $mutt_libesmtp_cflags"
 740     MUTTLIBS="$MUTTLIBS $mutt_libesmtp_libs"
 741     MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_libesmtp.o"
 742
 743     AC_DEFINE(USE_LIBESMTP,
 744               1,
 745               [Define to enable the use of libesmtp])
 746 fi
 747 dnl -- end libesmtp --
 748
 749 dnl -- sgml tools --
 750
 751 dnl Documentation tools
 752 have_openjade="no"
 753 AC_PATH_PROG([OSPCAT], [ospcat], [none])
 754 if test "$OSPCAT" != "none"
 755 then
 756   AC_MSG_CHECKING([for openjade docbook stylesheets])
 757   dslosfile=`ospcat --public-id="-//Norman Walsh//DOCUMENT DocBook Print Stylesheet//EN"`
 758   DSLROOT=`echo $dslosfile | sed -n -e "s/.*SOIBASE='\(@<:@^'@:>@*\)\/catalog'.*/\1/p"`
 759   # ospcat may spit out an absolute path without an SOIBASE
 760   if test -z "$DSLROOT"
 761   then
 762     DSLROOT=`echo $dslosfile | sed -e 's|<OSFILE>\(.*\)/print/docbook.dsl|\1|'`
 763   fi
 764   if test -f $DSLROOT/print/docbook.dsl
 765   then
 766     AC_MSG_RESULT([in $DSLROOT])
 767     have_openjade="yes"
 768   else
 769     AC_MSG_RESULT([not found: PDF documentation will not be built.])
 770   fi
 771 fi
 772 AC_SUBST(DSLROOT)
 773
 774 AC_MSG_CHECKING([for lynx])
 775 AC_PATH_PROG([HTML2TXT_CMD], [lynx], [none])
 776 if test x"$HTML2TXT_CMD" = x"none"
 777 then
 778   AC_MSG_CHECKING([for w3m])
 779   AC_PATH_PROG([HTML2TXT_CMD], [w3m], [none])
 780 fi
 781 if test x"$HTML2TXT_CMD" = x"none"
 782 then
 783   AC_MSG_CHECKING([for elinks])
 784   AC_PATH_PROG([HTML2TXT_CMD], [elinks], [none])
 785 fi
 786 case "$HTML2TXT_CMD" in
 787   *elinks*)
 788     HTML2TXT_CMD="$HTML2TXT_CMD -dump -no-numbering -no-references \$^ > \$@"
 789     ;;
 790   *lynx*)
 791     HTML2TXT_CMD="$HTML2TXT_CMD -dump -nolist -with_backspaces \$^ > \$@"
 792     ;;
 793   *w3m*)
 794     HTML2TXT_CMD="$HTML2TXT_CMD -dump \$^ > \$@"
 795     ;;
 796   *)
 797     HTML2TXT_CMD="true"
 798     ;;
 799 esac
 800 AC_SUBST(HTML2TXT_CMD)
 801
 802 AC_MSG_CHECKING([for tidy])
 803 AC_PATH_PROG([HTMLCLEAN_CMD], [tidy], [none])
 804
 805 if test x"$HTMLCLEAN_CMD" != x"none"
 806 then
 807   HTMLCLEAN_CMD="$HTMLCLEAN_CMD -q -i -m -asxml -utf8 "
 808 else
 809   HTMLCLEAN_CMD="echo "
 810 fi
 811 AC_SUBST(HTMLCLEAN_CMD)
 812
 813 AC_OUTPUT(Makefile intl/Makefile m4/Makefile
 814         po/Makefile.in doc/Makefile contrib/Makefile
 815         lib-lib/Makefile
 816         lib-mime/Makefile
 817         lib-crypt/Makefile
 818         lib-hash/Makefile
 819         lib-sys/Makefile
 820         lib-ui/Makefile
 821         lib/Makefile
 822         imap/Makefile
 823         pop/Makefile
 824         nntp/Makefile
 825         Madmuttrc.head
 826         doc/instdoc.sh)