configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl !!! WHEN ADDING NEW CONFIGURE TESTS, PLEASE ADD CODE TO MAIN.C !!!
   4 dnl !!! TO DUMP THEIR RESULTS WHEN MUTT -V IS CALLED            !!!
   5
   6 AC_PREREQ([2.50])
   7 AC_INIT([mutt.h])
   8 AM_CONFIG_HEADER(config.h)
   9
  10 mutt_cv_version=`cat "$srcdir/VERSION.in"`
  11
  12 AM_INIT_AUTOMAKE(madmutt, $mutt_cv_version)
  13 AC_SUBST([CONFIGURE_DEPENDENCIES], ['$(top_srcdir)/VERSION.in'])
  14
  15 AC_GNU_SOURCE
  16
  17 ALL_LINGUAS="de ru it es uk fr pl nl cs id sk ko el zh_TW zh_CN pt_BR eo gl sv da lt tr ja hu et ca bg"
  18
  19 AC_CANONICAL_HOST
  20
  21 AC_MSG_CHECKING([for prefix])
  22 if test x$prefix = xNONE; then
  23     mutt_cv_prefix=$ac_default_prefix
  24 else
  25     mutt_cv_prefix=$prefix
  26 fi
  27 AC_MSG_RESULT($mutt_cv_prefix)
  28
  29 AC_PROG_CC
  30 AC_ISC_POSIX
  31 AM_C_PROTOTYPES
  32 if test "x$U" != "x"; then
  33     AC_MSG_ERROR(Compiler not ANSI compliant)
  34 fi
  35 AC_PROG_CPP
  36 AC_PROG_MAKE_SET
  37 AC_PROG_INSTALL
  38 AC_PROG_RANLIB
  39 AC_PROG_GPERF
  40 AC_CHECK_TOOL(AR, ar, ar)
  41
  42 AC_C_INLINE
  43 AC_C_CONST
  44
  45 AC_SYS_LARGEFILE
  46 AC_FUNC_FSEEKO
  47 AC_CHECK_SIZEOF(off_t)
  48
  49 AC_PATH_PROG(DBX, dbx, no)
  50 AC_PATH_PROG(GDB, gdb, no)
  51 AC_PATH_PROG(SDB, sdb, no)
  52
  53 if test $GDB != no ; then
  54     DEBUGGER=$GDB
  55 elif test $DBX != no ; then
  56     DEBUGGER=$DBX
  57 elif test $SDB != no ; then
  58     DEBUGGER=$SDB
  59 else
  60     DEBUGGER=no
  61 fi
  62
  63 AC_SUBST([DEBUGGER])
  64
  65 AH_TEMPLATE([sig_atomic_t],
  66             [Define to 'int' if <signal.h> doesn't define.])
  67 AH_TEMPLATE([HAVE_START_COLOR],
  68             [Define if you have start_color, as a function or macro.])
  69 AH_TEMPLATE([HAVE_TYPEAHEAD],
  70             [Define if you have typeahead, as a function or macro.])
  71 AH_TEMPLATE([HAVE_BKGDSET],
  72             [Define if you have bkgdset, as a function or macro.])
  73 AH_TEMPLATE([HAVE_CURS_SET],
  74             [Define if you have curs_set, as a function or macro.])
  75 AH_TEMPLATE([HAVE_META],
  76             [Define if you have meta, as a function or macro.])
  77 AH_TEMPLATE([HAVE_USE_DEFAULT_COLORS],
  78             [Define if you have use_default_colors, as a function or macro.])
  79 AH_TEMPLATE([HAVE_RESIZETERM],
  80             [Define if you have resizeterm, as a function or macro.])
  81 AH_TEMPLATE([SIG_ATOMIC_VOLATILE_T],
  82             [Some systems declare sig_atomic_t as volatile, some others -- no.
  83              This define will have value `sig_atomic_t' or
  84              `volatile sig_atomic_t' accordingly.])
  85 AH_TEMPLATE([ICONV_NONTRANS],
  86             [Define as 1 if iconv() only converts exactly and we should treat
  87              all return values other than (size_t)(-1) as equivalent.])
  88
  89 MUTT_C99_INTTYPES
  90
  91 dnl ---------------- sendmail ----------------
  92
  93 ac_aux_path_sendmail=/usr/sbin:/usr/lib
  94 AC_PATH_PROG(SENDMAIL, sendmail, /usr/sbin/sendmail, $PATH:$ac_aux_path_sendmail)
  95 AC_DEFINE_UNQUOTED(SENDMAIL,"$ac_cv_path_SENDMAIL",[ Where to find sendmail on your system. ])
  96
  97
  98 OPS='$(srcdir)/OPS'
  99
 100 dnl ---------------- gpgme ----------------
 101
 102     AC_ARG_ENABLE(gpgme, AC_HELP_STRING([--enable-gpgme], [Enable GPGME support]),
 103     [   if test x$enableval = xyes; then
 104             have_gpgme=yes
 105         fi
 106     ])
 107     AC_ARG_WITH(gpgme-prefix, AC_HELP_STRING([--with-gpgme-prefix=PFX], [prefix where GPGME is installed (optional)]),
 108     gpgme_config_prefix="$withval", gpgme_config_prefix="")
 109
 110     if test x$have_gpgme = xyes; then
 111         if test x$gpgme_config_prefix != x; then
 112             GPGME_CONFIG="$gpgme_config_prefix/bin/gpgme-config"
 113         else
 114             AC_PATH_PROG(GPGME_CONFIG, gpgme-config, no)
 115         fi
 116         if test "x$GPGME_CONFIG" = "xno"; then
 117             AC_MSG_ERROR([GPGME not found])
 118         else
 119             LIBGPGME_CFLAGS=`$GPGME_CONFIG --cflags`
 120             LIBGPGME_LIBS=`$GPGME_CONFIG --libs`
 121             MUTTLIBS="$MUTTLIBS $LIBGPGME_LIBS"
 122             MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS crypt-gpgme.o crypt-mod-pgp-gpgme.o crypt-mod-smime-gpgme.o"
 123             AC_DEFINE(CRYPT_BACKEND_GPGME, 1, [Defined, if GPGME support is enabled])
 124         fi
 125     fi
 126     AC_SUBST(LIBGPGME_CFLAGS)
 127     AC_SUBST(LIBGPGME_LIBS)
 128
 129 dnl ---------------- mixmaster ----------------
 130
 131     AC_ARG_WITH(mixmaster, AC_HELP_STRING([--with-mixmaster[=PATH]], [Include Mixmaster support]),
 132     [   if test -x "$withval" ; then
 133             MIXMASTER="$withval"
 134         else
 135             MIXMASTER="mixmaster"
 136         fi
 137         OPS="$OPS \$(srcdir)/OPS.MIX"
 138         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS remailer.o"
 139         AC_DEFINE_UNQUOTED(MIXMASTER,"$MIXMASTER", [ Where to find mixmaster on your system. ])
 140     ])
 141
 142 # We now require all OPS
 143 OPS="$OPS \$(srcdir)/OPS.PGP \$(srcdir)/OPS.SMIME \$(srcdir)/OPS.CRYPT "
 144 AC_SUBST([OPS])
 145
 146 AC_PATH_PROG(ISPELL, ispell, no)
 147 if test $ISPELL != no; then
 148     AC_DEFINE_UNQUOTED(ISPELL,"$ISPELL",[ Where to find ispell on your system. ])
 149 fi
 150
 151 AC_ARG_WITH(slang, AC_HELP_STRING([--with-slang[=DIR]], [Use S-Lang instead of ncurses]),
 152     [AC_CACHE_CHECK([if this is a BSD system], mutt_cv_bsdish,
 153         [AC_TRY_RUN([#include <sys/param.h>
 154
 155 main ()
 156 {
 157 #ifdef BSD
 158         exit (0);
 159 #else
 160         exit (1);
 161 #endif
 162 }],
 163         mutt_cv_bsdish=yes,
 164         mutt_cv_bsdish=no,
 165         mutt_cv_bsdish=no)])
 166
 167         AC_MSG_CHECKING(for S-Lang)
 168         if test $withval = yes; then
 169             if test -d $srcdir/../slang; then
 170                 mutt_cv_slang=$srcdir/../slang/src
 171                 CFLAGS="$CFLAGS -I${mutt_cv_slang}"
 172                 LDFLAGS="$LDFLAGS -L${mutt_cv_slang}/objs"
 173             else
 174                 if test -d $mutt_cv_prefix/include/slang; then
 175                     CFLAGS="$CFLAGS -I$mutt_cv_prefix/include/slang"
 176                 elif test -d /usr/include/slang; then
 177                     CFLAGS="$CFLAGS -I/usr/include/slang"
 178                 fi
 179                 mutt_cv_slang=yes
 180             fi
 181         else
 182             dnl ---Check to see if $withval is a source directory
 183             if test -f $withval/src/slang.h; then
 184                 mutt_cv_slang=$withval/src
 185                 CFLAGS="$CFLAGS -I${mutt_cv_slang}"
 186                 LDFLAGS="$LDFLAGS -L${mutt_cv_slang}/objs"
 187             else
 188                 dnl ---Must be installed somewhere
 189                 mutt_cv_slang=$withval
 190                 if test -d $withval/include/slang; then
 191                         CFLAGS="$CFLAGS -I${withval}/include/slang"
 192                 elif test -d $withval/include; then
 193                         CFLAGS="$CFLAGS -I${withval}/include"
 194                 fi
 195                 LDFLAGS="$LDFLAGS -L${withval}/lib"
 196             fi
 197         fi
 198         AC_MSG_RESULT($mutt_cv_slang)
 199         if test $mutt_cv_bsdish = yes; then
 200             AC_CHECK_LIB(termlib, main)
 201         fi
 202         AC_DEFINE(USE_SLANG_CURSES,1, [ Define if you compile with SLang instead of curses/ncurses. ])
 203         AC_DEFINE(HAVE_COLOR,1,[ Define if your curses library supports color. ])
 204         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS resize.o"
 205
 206         dnl --- now that we've found it, check the link
 207
 208         AC_CHECK_LIB(slang, SLtt_get_terminfo,
 209             [MUTTLIBS="$MUTTLIBS -lslang -lm"],
 210             [AC_MSG_ERROR(unable to compile.  check config.log)], -lm)
 211         ],
 212
 213         [   mutt_cv_curses=/usr
 214             AC_ARG_WITH(curses, AC_HELP_STRING([--with-curses=DIR], [Where ncurses is installed]),
 215             [   if test $withval != yes; then
 216                     mutt_cv_curses=$withval
 217                 fi
 218                 if test x$mutt_cv_curses != x/usr; then
 219                     LDFLAGS="-L${mutt_cv_curses}/lib $LDFLAGS"
 220                     CPPFLAGS="$CPPFLAGS -I${mutt_cv_curses}/include"
 221                 fi
 222             ])
 223
 224             AC_CHECK_FUNC(initscr,,[
 225             cf_ncurses="ncurses"
 226             for lib in ncursesw ncurses; do
 227                 AC_CHECK_LIB($lib, waddnwstr, [cf_ncurses="$lib"; break])
 228             done
 229             AC_CHECK_LIB($cf_ncurses, initscr,
 230                 [   MUTTLIBS="$MUTTLIBS -l$cf_ncurses"
 231                     if test x$mutt_cv_curses = x/usr -a -d /usr/include/ncurses; then
 232                         CPPFLAGS="$CPPFLAGS -I/usr/include/ncurses"
 233                     fi
 234
 235                     if test "$cf_ncurses" = ncursesw; then
 236                         AC_CHECK_HEADERS(ncurses/ncurses.h,[cf_cv_ncurses_header="ncurses/ncurses.h"])
 237                         AC_CHECK_HEADERS(ncursesw/ncurses.h,[cf_cv_ncurses_header="ncursesw/ncurses.h"])
 238                     else
 239                         AC_CHECK_HEADERS(ncurses.h,[cf_cv_ncurses_header="ncurses.h"])
 240                     fi
 241                 ],
 242                 [CF_CURSES_LIBS])
 243             ])
 244
 245             old_LIBS="$LIBS"
 246             LIBS="$LIBS $MUTTLIBS"
 247             CF_CHECK_FUNCDECLS([#include <${cf_cv_ncurses_header-curses.h}>],
 248                                [start_color typeahead bkgdset curs_set meta use_default_colors resizeterm])
 249             if test "$ac_cv_func_decl_start_color" = yes; then
 250                 AC_DEFINE(HAVE_COLOR,1,[ Define if your curses library supports color. ])
 251             fi
 252             if test "$ac_cv_func_decl_resizeterm" = yes; then
 253                 MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS resize.o"
 254             fi
 255             LIBS="$old_LIBS"
 256         ])
 257
 258 AC_HEADER_STDC
 259
 260 AC_CHECK_HEADERS(stdarg.h sys/ioctl.h ioctl.h sysexits.h)
 261 AC_CHECK_HEADERS(sys/time.h sys/resource.h)
 262 AC_CHECK_HEADERS(unix.h)
 263
 264 AC_CHECK_FUNCS(setrlimit getsid isctype)
 265
 266 AC_TYPE_SIGNAL
 267
 268 AC_MSG_CHECKING(for sig_atomic_t in signal.h)
 269 AC_EGREP_HEADER(sig_atomic_t,signal.h,
 270     [   ac_cv_type_sig_atomic_t=yes;
 271         AC_EGREP_HEADER(volatile.*sig_atomic_t,
 272                         signal.h,
 273                         [is_sig_atomic_t_volatile=yes; AC_MSG_RESULT([yes, volatile])],
 274                         [is_sig_atomic_t_volatile=no;  AC_MSG_RESULT([yes, non volatile])])
 275     ],
 276     [   AC_MSG_RESULT(no)
 277         AC_CHECK_TYPE(sig_atomic_t, int)
 278         is_sig_atomic_t_volatile=no
 279     ])
 280 if test $is_sig_atomic_t_volatile = 'yes'
 281 then
 282     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, sig_atomic_t)
 283 else
 284     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, [volatile sig_atomic_t])
 285 fi
 286
 287 AC_DECL_SYS_SIGLIST
 288
 289 AC_TYPE_PID_T
 290
 291 AC_CHECK_FUNCS(fgetpos memmove setegid srand48 strerror)
 292 AC_REPLACE_FUNCS(strcasecmp setenv)
 293 AC_CHECK_FUNCS(snprintf vsnprintf)
 294
 295 AC_CHECK_FUNC(getopt)
 296 if test $ac_cv_func_getopt = yes; then
 297     AC_CHECK_HEADERS(getopt.h)
 298 fi
 299
 300 AC_ARG_WITH(regex, AC_HELP_STRING([--with-regex], [Use the GNU regex library]),
 301         [mutt_cv_regex=yes],
 302         [AC_CHECK_FUNCS(regcomp, mutt_cv_regex=no, mutt_cv_regex=yes)])
 303
 304 if test $mutt_cv_regex = no ; then
 305     AC_CACHE_CHECK([whether your system's regexp library is completely broken],
 306         [mutt_cv_regex_broken],
 307         AC_TRY_RUN([
 308 #include <unistd.h>
 309 #include <regex.h>
 310 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
 311         mutt_cv_regex_broken=no, mutt_cv_regex_broken=yes, mutt_cv_regex_broken=yes))
 312     if test $mutt_cv_regex_broken = yes ; then
 313         echo "Using the included GNU regex instead." >&AC_FD_MSG
 314         mutt_cv_regex=yes
 315     fi
 316 fi
 317
 318 if test $mutt_cv_regex = yes; then
 319     AC_DEFINE(USE_GNU_REGEX,1,[ Define if you want to use the included regex.c. ])
 320     LIBOBJS="$LIBOBJS regex.o"
 321 fi
 322
 323
 324 AC_ARG_WITH(homespool,
 325             AC_HELP_STRING([--with-homespool[=FILE]],
 326                            [File in user's directory where new mail is spooled]),
 327                            with_homespool=${withval})
 328 if test x$with_homespool != x; then
 329     if test $with_homespool = yes; then
 330             with_homespool=mailbox
 331     fi
 332     AC_DEFINE_UNQUOTED(MAILPATH,"$with_homespool",[ Where new mail is spooled. ])
 333     AC_DEFINE(HOMESPOOL,1,
 334     [   Is mail spooled to the user's home directory?  If defined,
 335         MAILPATH should be set to the filename of the spool mailbox
 336         relative the the home directory.
 337         use: configure --with-homespool=FILE
 338     ])
 339     AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 340     mutt_cv_setgid=no
 341 else
 342     AC_ARG_WITH(mailpath, AC_HELP_STRING([--with-mailpath=DIR], [Directory where spool mailboxes are located]),
 343         [mutt_cv_mailpath=$withval],
 344         [ AC_CACHE_CHECK(where new mail is stored, mutt_cv_mailpath,
 345             [mutt_cv_mailpath=no
 346             if test -d /var/mail; then
 347                 mutt_cv_mailpath=/var/mail
 348             elif test -d /var/spool/mail; then
 349                 mutt_cv_mailpath=/var/spool/mail
 350             elif test -d /usr/spool/mail; then
 351                 mutt_cv_mailpath=/usr/spool/mail
 352             elif test -d /usr/mail; then
 353                 mutt_cv_mailpath=/usr/mail
 354             fi])
 355         ])
 356     if test "$mutt_cv_mailpath" = no; then
 357         AC_MSG_ERROR("Could not determine where new mail is stored.")
 358     fi
 359     AC_DEFINE_UNQUOTED(MAILPATH,"$mutt_cv_mailpath",[ Where new mail is spooled. ])
 360
 361     AC_CACHE_CHECK(if $mutt_cv_mailpath is world writable, mutt_cv_worldwrite, [AC_TRY_RUN([#include <sys/types.h>
 362 #include <sys/stat.h>
 363
 364 int main (int argc, char **argv)
 365 {
 366         struct stat s;
 367
 368         stat ("$mutt_cv_mailpath", &s);
 369         if (s.st_mode & S_IWOTH) exit (0);
 370         exit (1);
 371 }], mutt_cv_worldwrite=yes, mutt_cv_worldwrite=no, mutt_cv_worldwrite=no)])
 372
 373         mutt_cv_setgid=no
 374         if test $mutt_cv_worldwrite = yes; then
 375                 AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 376         else
 377
 378                 AC_CACHE_CHECK(if $mutt_cv_mailpath is group writable, mutt_cv_groupwrite, [AC_TRY_RUN([#include <sys/types.h>
 379 #include <sys/stat.h>
 380
 381 int main (int argc, char **argv)
 382 {
 383         struct stat s;
 384
 385         stat ("$mutt_cv_mailpath", &s);
 386         if (s.st_mode & S_IWGRP) exit (0);
 387         exit (1);
 388 }], mutt_cv_groupwrite=yes, mutt_cv_groupwrite=no, mutt_cv_groupwrite=no)])
 389
 390         if test $mutt_cv_groupwrite = yes; then
 391             AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 392             AC_DEFINE(USE_SETGID,1,[ Define if mutt should run setgid "mail". ])
 393             mutt_cv_setgid=yes
 394         fi
 395     fi
 396 fi
 397
 398 AC_MSG_CHECKING(where to put the documentation)
 399 AC_ARG_WITH(docdir, AC_HELP_STRING([--with-docdir=PATH], [Specify where to put the documentation]),
 400         [mutt_cv_docdir=$withval],
 401         [mutt_cv_docdir="${prefix}/doc/muttng"])
 402 AC_MSG_RESULT($mutt_cv_docdir)
 403
 404 docdir=$mutt_cv_docdir
 405 AC_SUBST(docdir)
 406
 407 if test x$mutt_cv_setgid = xyes; then
 408     DOTLOCK_GROUP='mail'
 409     DOTLOCK_PERMISSION=2755
 410 else
 411     DOTLOCK_GROUP=''
 412     DOTLOCK_PERMISSION=755
 413 fi
 414 AC_SUBST(DOTLOCK_GROUP)
 415 AC_SUBST(DOTLOCK_PERMISSION)
 416
 417 dnl -- socket dependencies --
 418
 419 AC_ARG_ENABLE(nntp, [  --enable-nntp              Enable NNTP support],
 420 [   if test x$enableval = xyes ; then
 421         AC_DEFINE(USE_NNTP,1,[ Compiling with newsreading support with NNTP ])
 422         LIBNNTP="-Lnntp -lnntp"
 423         LIBNNTPDEPS="\$(top_srcdir)/nntp/nntp.h nntp/libnntp.a"
 424         need_nntp="yes"
 425     fi
 426 ])
 427 AM_CONDITIONAL(BUILD_NNTP, test x$need_nntp = xyes)
 428
 429 dnl -- end socket dependencies --
 430
 431 AC_MSG_CHECKING([for socklen_t])
 432 AC_EGREP_HEADER(socklen_t, sys/socket.h, AC_MSG_RESULT([yes]),
 433         AC_MSG_RESULT([no])
 434         AC_DEFINE(socklen_t,int, [ Define to 'int' if <sys/socket.h> doesn't have it. ]))
 435 AC_CHECK_FUNC(gethostent, , AC_CHECK_LIB(nsl, gethostent))
 436 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt))
 437 AC_CHECK_FUNCS(getaddrinfo)
 438
 439 dnl -- imap dependencies --
 440
 441 AC_ARG_WITH(gss, AC_HELP_STRING([--with-gss[=PFX]], [Compile in GSSAPI authentication for IMAP]),
 442     gss_prefix="$withval", gss_prefix="no")
 443 if test "$gss_prefix" != "no"
 444 then
 445     MUTT_AM_PATH_GSSAPI(gss_prefix)
 446     AC_MSG_CHECKING(GSSAPI implementation)
 447     AC_MSG_RESULT($GSSAPI_IMPL)
 448     if test "$GSSAPI_IMPL" = "none"
 449     then
 450       AC_CACHE_SAVE
 451       AC_MSG_RESULT([GSSAPI libraries not found])
 452     fi
 453     if test "$GSSAPI_IMPL" = "Heimdal"
 454     then
 455       AC_DEFINE(HAVE_HEIMDAL,1,[ Define if your GSSAPI implementation is Heimdal ])
 456     fi
 457     CPPFLAGS="$CPPFLAGS $GSSAPI_CFLAGS"
 458     MUTTLIBS="$MUTTLIBS $GSSAPI_LIBS"
 459     AC_DEFINE(USE_GSS,1,[ Define if you have GSSAPI libraries available ])
 460     need_gss="yes"
 461 fi
 462 AM_CONDITIONAL(USE_GSS, test x$need_gss = xyes)
 463
 464 dnl -- end imap dependencies --
 465
 466 AC_ARG_WITH(ssl, AC_HELP_STRING([--with-ssl[=PFX]], [Compile in SSL support for POP/IMAP]),
 467 [       if test "$with_ssl" != "no"
 468         then
 469           if test "$with_ssl" != "yes"
 470           then
 471            LDFLAGS="$LDFLAGS -L$withval/lib"
 472            CPPFLAGS="$CPPFLAGS -I$withval/include"
 473           fi
 474           saved_LIBS="$LIBS"
 475
 476           AC_CHECK_LIB(crypto, X509_new,, AC_MSG_ERROR([Unable to find SSL library]))
 477           AC_CHECK_LIB(ssl, SSL_new,, AC_MSG_ERROR([Unable to find SSL library]), -lcrypto)
 478
 479           AC_CHECK_FUNCS(RAND_status RAND_egd)
 480
 481           AC_DEFINE(USE_SSL,1,[ Define if you want support for SSL. ])
 482           LIBS="$saved_LIBS"
 483           MUTTLIBS="$MUTTLIBS -lssl -lcrypto"
 484           MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_ssl.o"
 485           need_ssl=yes
 486
 487         fi
 488 ])
 489
 490 AC_ARG_WITH([gnutls], AC_HELP_STRING([--with-gnutls[=PFX]], [Enable SSL support using gnutls]),
 491     [gnutls_prefix="$withval"], [gnutls_prefix="no"])
 492 if test "$gnutls_prefix" != "no"
 493 then
 494   if test x"$need_ssl" = x"yes"
 495   then
 496     AC_MSG_ERROR([Only either OpenSSL or GNUTLS may be used])
 497   fi
 498   MUTT_AM_PATH_GNUTLS([$gnutls_prefix],
 499     [dnl GNUTLS found
 500     CPPFLAGS="$CPPFLAGS $LIBGNUTLS_CFLAGS"
 501     MUTTLIBS="$MUTTLIBS $LIBGNUTLS_LIBS"
 502     AC_DEFINE(USE_GNUTLS, 1, [Define if you want support for SSL via the gnutls library.])
 503
 504     MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_ssl_gnutls.o"
 505     need_ssl=yes],
 506     [dnl GNUTLS not found
 507       AC_MSG_ERROR([could not find libgnutls])
 508     ])
 509 fi
 510
 511 AM_CONDITIONAL(USE_SSL, test x$need_ssl = xyes)
 512
 513 AC_ARG_WITH(sasl2, AC_HELP_STRING([--with-sasl2[=PFX]],
 514             [Use Cyrus SASL library version 2 for POP/IMAP authentication]),
 515         [
 516         if test "$with_sasl2" != "no"
 517         then
 518           if test "$with_sasl2" != "yes"
 519           then
 520             CPPFLAGS="$CPPFLAGS -I$with_sasl2/include"
 521             LDFLAGS="$LDFLAGS -L$with_sasl2/lib"
 522           fi
 523
 524           saved_LIBS="$LIBS"
 525
 526           AC_CHECK_LIB(sasl2, sasl_client_init,,
 527             AC_MSG_ERROR([could not find libsasl2]),)
 528
 529           MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_sasl.o"
 530           MUTTLIBS="$MUTTLIBS -lsasl2"
 531           LIBS="$saved_LIBS"
 532           AC_DEFINE(USE_SASL,1,
 533                   [ Define if want to use version 2 of the Cyrus SASL library. ])
 534           need_sasl=yes
 535         fi
 536         ])
 537 AM_CONDITIONAL(USE_SASL, test x$need_sasl = xyes)
 538
 539 AC_ARG_WITH(idn, AC_HELP_STRING([--with-idn=[PFX]], [Use GNU libidn for domain names]),
 540                  [
 541                   if test "$with_idn" != "no" ; then
 542                         if test "$with_idn" != "yes" ; then
 543                            CPPFLAGS="$CPPFLAGS -I$with_idn/include"
 544                            LDFLAGS="$LDFLAGS -L$with_idn/lib"
 545                         fi
 546                   fi
 547                  ]
 548 )
 549
 550 if test "x$with_idn" != "xno"; then
 551     AC_CHECK_LIB(idn, stringprep_check_version)
 552     AC_CHECK_FUNCS(idna_to_unicode_utf8_from_utf8 idna_to_unicode_8z8z)
 553     AC_CHECK_FUNCS(idna_to_ascii_from_utf8 idna_to_ascii_8z)
 554     AC_CHECK_FUNCS(idna_to_ascii_lz idna_to_ascii_from_locale)
 555 fi
 556
 557 dnl -- end socket --
 558
 559 AC_ARG_ENABLE(debug, AC_HELP_STRING([--enable-debug], [Enable debugging support]),
 560     [ if test x$enableval = xyes ; then
 561             AC_DEFINE(DEBUG,1,[ Define to enable debugging info. ])
 562       fi
 563      ])
 564
 565 AC_ARG_ENABLE(flock, AC_HELP_STRING([--enable-flock], [Use flock() to lock files]),
 566         [if test $enableval = yes; then
 567                 AC_DEFINE(USE_FLOCK,1, [ Define to use flock() to lock mailboxes. ])
 568         fi])
 569
 570 mutt_cv_fcntl=yes
 571 AC_ARG_ENABLE(fcntl, AC_HELP_STRING([--disable-fcntl], [Do NOT use fcntl() to lock files]),
 572         [if test $enableval = no; then mutt_cv_fcntl=no; fi])
 573
 574 if test $mutt_cv_fcntl = yes; then
 575         AC_DEFINE(USE_FCNTL,1, [ Define to use fcntl() to lock folders. ])
 576 fi
 577
 578 AC_MSG_CHECKING(whether struct dirent defines d_ino)
 579 ac_cv_dirent_d_ino=no
 580 AC_TRY_LINK([#include <dirent.h>],[struct dirent dp; (void)dp.d_ino],[ac_cv_dirent_d_ino=yes])
 581 if test x$ac_cv_dirent_d_ino = xyes ; then
 582   AC_DEFINE(HAVE_DIRENT_D_INO,1,
 583             [Define to 1 if your system has the dirent::d_ino member])
 584 fi
 585 AC_MSG_RESULT($ac_cv_dirent_d_ino)
 586
 587 AC_ARG_ENABLE(buffy-size, AC_HELP_STRING([--enable-buffy-size], [Use file size attribute instead of access time]),
 588         [if test x$enableval = xyes; then
 589                 AC_DEFINE(BUFFY_SIZE,1,[ Define to enable the "buffy_size" feature. ])
 590         fi])
 591
 592 dnl -- start cache --
 593 AC_ARG_ENABLE(hcache, AC_HELP_STRING([--enable-hcache], [Enable header caching]),
 594 [if test x$enableval = xyes; then
 595     AC_DEFINE(USE_HCACHE, 1, [Enable header caching])
 596
 597     OLDCPPFLAGS="$CPPFLAGS"
 598     OLDLIBS="$LIBS"
 599
 600     need_md5="yes"
 601
 602     ac_prefer_qdbm=yes
 603     AC_ARG_WITH(qdbm, AC_HELP_STRING([--without-qdbm], [Don't use qdbm even if it is available]),
 604         ac_prefer_qdbm=$withval)
 605     if test x$ac_prefer_qdbm != xno; then
 606         ac_cv_vlopen=no
 607         QDBM_DIRS="$mutt_cv_prefix /usr/local /usr"
 608         AC_MSG_CHECKING([for vlopen])
 609         for d in $QDBM_DIRS; do
 610           if test x$ac_cv_vlopen = xno && test -d "$d/include" && test -d "$d/lib"; then
 611             QDBM_INC="-I$d/include"
 612             QDBM_LIB="-L$d/lib"
 613             CPPFLAGS="$OLDCPPFLAGS $QDBM_INC"
 614             LIBS="$OLDLIBS $QDBM_LIB -lqdbm"
 615             AC_TRY_LINK([#include <villa.h>],[vlopen(0,0,0);],[ac_cv_vlopen=yes])
 616           fi
 617         done
 618         if test x$ac_cv_vlopen = xyes; then
 619           AC_MSG_RESULT(yes)
 620         else
 621           AC_MSG_RESULT(no)
 622         fi
 623     fi
 624
 625     ac_prefer_gdbm=yes
 626     AC_ARG_WITH(gdbm, AC_HELP_STRING([--without-gdbm], [Don't use gdbm even if it is available]),
 627         ac_prefer_gdbm=$withval)
 628     if test x$ac_prefer_gdbm != xno -a x$ac_cv_vlopen != xyes; then
 629         ac_cv_gdbmopen=no
 630         GDBM_DIRS="$mutt_cv_prefix /usr/local /usr"
 631         AC_MSG_CHECKING([for gdbm_open])
 632         for d in $GDBM_DIRS; do
 633           if test x$ac_cv_gdbmopen = xno && test -d "$d/include" && test -d "$d/lib"; then
 634             GDBM_INC="-I$d/include"
 635             GDBM_LIB="-L$d/lib"
 636             CPPFLAGS="$OLDCPPFLAGS $GDBM_INC"
 637             LIBS="$OLDLIBS $GDBM_LIB -lgdbm"
 638             AC_TRY_LINK([#include <gdbm.h>],[gdbm_open(0,0,0,0,0);],[ac_cv_gdbmopen=yes])
 639           fi
 640         done
 641         if test x$ac_cv_gdbmopen = xyes; then
 642           AC_MSG_RESULT(yes)
 643         else
 644           AC_MSG_RESULT(no)
 645         fi
 646     fi
 647
 648     ac_bdb_prefix=yes
 649     AC_ARG_WITH(bdb, AC_HELP_STRING([--with-bdb[=DIR]], [Use BerkeleyDB4 if gdbm is not available ]),
 650         ac_bdb_prefix=$withval)
 651     if test x$ac_bdb_prefix != xno -a x$ac_cv_gdbmopen != xyes -a x$ac_cv_vlopen != xyes; then
 652         test x$ac_bdb_prefix = xyes && ac_bdb_prefix="$mutt_cv_prefix /opt/csw/bdb4 /opt /usr/local /usr"
 653         for d in $ac_bdb_prefix; do
 654             bdbpfx="$bdbpfx $d"
 655             for v in BerkeleyDB.4.3 BerkeleyDB.4.2 BerkeleyDB.4.1; do
 656                 bdbpfx="$bdbpfx $d/$v"
 657             done
 658         done
 659         BDB_VERSIONS="db-4 db4 db-4.3 db4.3 db43 db-4.2 db4.2 db42 db-4.1 db4.1 db41 db ''"
 660         AC_MSG_CHECKING([for BerkeleyDB > 4.0])
 661         for d in $bdbpfx; do
 662             BDB_INCLUDE_DIR=""
 663             BDB_LIB_DIR=""
 664             for v in / $BDB_VERSIONS; do
 665                 if test -r "$d/include/$v/db.h"; then
 666                     BDB_INCLUDE_DIR="$d/include/$v"
 667                     if test -d "$d/lib/$v"; then
 668                         BDB_LIB_DIR="$d/lib/$v"
 669                         for l in `echo $BDB_VERSIONS`; do
 670                             CPPFLAGS="-I$BDB_INCLUDE_DIR $OLDCPPFLAGS"
 671                             LIBS="$OLDLIBS -L$BDB_LIB_DIR -l$l"
 672                             AC_TRY_LINK([
 673                                 #include <stdlib.h>
 674                                 #include <db.h>
 675                             ],[
 676                                 DB *db = NULL;
 677                                 db->open(db,NULL,NULL,NULL,0,0,0);
 678                             ],[
 679                                 ac_cv_dbcreate=yes
 680                                 BDB_LIB="$l"
 681                                 break
 682                             ])
 683                         done
 684                         test x$ac_cv_dbcreate = xyes && break
 685                     fi
 686                 fi
 687             done
 688             test x$BDB_LIB != x && break
 689         done
 690         if test x$ac_cv_dbcreate = xyes; then
 691             AC_MSG_RESULT(yes)
 692         else
 693             AC_MSG_RESULT(no)
 694         fi
 695     fi
 696
 697     if test x$ac_cv_vlopen = xyes; then
 698         CPPFLAGS="$OLDCPPFLAGS $QDBM_INC"
 699         LIBS="$OLDLIBS $QDBM_LIB -lqdbm"
 700         AC_DEFINE(HAVE_QDBM, 1, [QDBM Support])
 701     elif test x$ac_cv_gdbmopen = xyes; then
 702         CPPFLAGS="$OLDCPPFLAGS $GDBM_INC"
 703         LIBS="$OLDLIBS $GDBM_LIB -lgdbm";
 704         AC_DEFINE(HAVE_GDBM, 1, [GDBM Support])
 705     elif test x$ac_cv_dbcreate = xyes; then
 706         CPPFLAGS="-I$BDB_INCLUDE_DIR $OLDCPPFLAGS"
 707         LIBS="$OLDLIBS -L$BDB_LIB_DIR -l$BDB_LIB"
 708         AC_DEFINE(HAVE_DB4, 1, [Sleepycat DB4 Support])
 709     else
 710         AC_MSG_ERROR([You need one of: QDBM, GDBM or Sleepycat DB4 for --enable-hcache])
 711     fi
 712 fi])
 713 dnl -- end cache --
 714
 715 AC_SUBST(MUTTLIBS)
 716 AC_SUBST(MUTT_LIB_OBJECTS)
 717 AC_SUBST(LIBNNTP)
 718 AC_SUBST(LIBNNTPDEPS)
 719
 720 dnl -- iconv/gettext --
 721
 722 AC_ARG_ENABLE(iconv, AC_HELP_STRING([--disable-iconv], [Disable iconv support]),
 723         [if test x$enableval = xno ; then
 724                 am_cv_func_iconv=no
 725         fi
 726 ])
 727
 728 AM_GNU_GETTEXT
 729
 730 if test "$am_cv_func_iconv" != "yes"
 731 then
 732   AC_MSG_WARN([Configuring without iconv support. See INSTALL for details])
 733 else
 734
 735 AC_CHECK_HEADERS(iconv.h,
 736         [AC_MSG_CHECKING(whether iconv.h defines iconv_t)
 737          AC_EGREP_HEADER([typedef.*iconv_t],iconv.h,
 738                 [AC_MSG_RESULT(yes)
 739                  AC_DEFINE(HAVE_ICONV_T_DEF, 1,
 740                         [Define if <iconv.h> defines iconv_t.])],
 741                  AC_MSG_RESULT(no))])
 742
 743 dnl (1) Some implementations of iconv won't convert from UTF-8 to UTF-8.
 744 dnl (2) In glibc-2.1.2 and earlier there is a bug that messes up ob and
 745 dnl     obl when args 2 and 3 are 0 (fixed in glibc-2.1.3).
 746 AC_CACHE_CHECK([whether this iconv is good enough], mutt_cv_iconv_good,
 747         mutt_save_LIBS="$LIBS"
 748         LIBS="$LIBS $LIBICONV"
 749         AC_TRY_RUN([
 750 #include <iconv.h>
 751 int main()
 752 {
 753   iconv_t cd;
 754 changequote(, )dnl
 755   char buf[4];
 756 changequote([, ])dnl
 757   char *ob;
 758   size_t obl;
 759   ob = buf, obl = sizeof(buf);
 760   return ((cd = iconv_open("UTF-8", "UTF-8")) != (iconv_t)(-1) &&
 761           (iconv(cd, 0, 0, &ob, &obl) ||
 762            !(ob == buf && obl == sizeof(buf)) ||
 763            iconv_close(cd)));
 764 }
 765                 ],
 766                 mutt_cv_iconv_good=yes,
 767                 mutt_cv_iconv_good=no,
 768                 mutt_cv_iconv_good=yes)
 769         LIBS="$mutt_save_LIBS")
 770 if test "$mutt_cv_iconv_good" = no; then
 771   AC_MSG_ERROR(Try using libiconv instead)
 772 fi
 773
 774 dnl This is to detect implementations such as the one in glibc-2.1,
 775 dnl which always convert exactly but return the number of characters
 776 dnl converted instead of the number converted inexactly.
 777 AC_CACHE_CHECK([whether iconv is non-transcribing], mutt_cv_iconv_nontrans,
 778         mutt_save_LIBS="$LIBS"
 779         LIBS="$LIBS $LIBICONV"
 780         AC_TRY_RUN([
 781 #include <iconv.h>
 782 #include <string.h>
 783 int main()
 784 {
 785   iconv_t cd;
 786   const char *ib;
 787   char *ob;
 788   size_t ibl, obl;
 789   const char *s = "\304\211";
 790 changequote(, )dnl
 791   char t[3];
 792 changequote([, ])dnl
 793   ib = s, ibl = 2, ob = t, obl = 3;
 794   return ((cd = iconv_open("UTF-8", "UTF-8")) == (iconv_t)(-1) ||
 795           iconv(cd, &ib, &ibl, &ob, &obl));
 796 }
 797                 ],
 798                 mutt_cv_iconv_nontrans=no,
 799                 mutt_cv_iconv_nontrans=yes,
 800                 mutt_cv_iconv_nontrans=no)
 801         LIBS="$mutt_save_LIBS")
 802 if test "$mutt_cv_iconv_nontrans" = yes; then
 803   AC_DEFINE(ICONV_NONTRANS, 1)
 804 else
 805   AC_DEFINE(ICONV_NONTRANS, 0)
 806 fi
 807
 808 CPPFLAGS="$CPPFLAGS -I\$(top_srcdir)/intl"
 809
 810 if test "$BUILD_INCLUDED_LIBINTL" = "yes"; then
 811   AC_DEFINE(HAVE_BIND_TEXTDOMAIN_CODESET,1,
 812           [ Define if your gettext has bind_textdomain_codeset. ])
 813 else
 814   AC_CHECK_FUNCS(bind_textdomain_codeset)
 815 fi
 816
 817 fi # libiconv
 818
 819 dnl -- locales --
 820
 821 AC_CHECK_HEADERS(wchar.h)
 822
 823 AC_CACHE_CHECK([for wchar_t], mutt_cv_wchar_t,
 824         AC_TRY_COMPILE([
 825 #include <stddef.h>
 826 #include <stdlib.h>
 827 #ifdef HAVE_WCHAR_H
 828 #include <wchar.h>
 829 #endif
 830                 ],
 831                 [ wchar_t wc; return 0; ],
 832                 mutt_cv_wchar_t=yes,
 833                 mutt_cv_wchar_t=no))
 834
 835 if test "$mutt_cv_wchar_t" = no; then
 836         AC_DEFINE(wchar_t,int,[ Define to 'int' if system headers don't define. ])
 837 fi
 838
 839 AC_CACHE_CHECK([for wint_t], mutt_cv_wint_t,
 840         AC_TRY_COMPILE([
 841 #include <stddef.h>
 842 #include <stdlib.h>
 843 #ifdef HAVE_WCHAR_H
 844 #include <wchar.h>
 845 #endif
 846                 ],
 847                 [ wint_t wc; return 0; ],
 848                 mutt_cv_wint_t=yes,
 849                 mutt_cv_wint_t=no))
 850
 851 if test "$mutt_cv_wint_t" = no; then
 852         AC_DEFINE(wint_t,int,[ Define to 'int' if system headers don't define. ])
 853 fi
 854
 855 AC_CHECK_HEADERS(wctype.h)
 856 AC_CHECK_FUNCS(iswalnum iswalpha  iswcntrl iswdigit)
 857 AC_CHECK_FUNCS(iswgraph iswlower iswprint iswpunct iswspace iswupper)
 858 AC_CHECK_FUNCS(iswxdigit towupper towlower)
 859
 860 AC_CACHE_CHECK([for mbstate_t], mutt_cv_mbstate_t,
 861         AC_TRY_COMPILE([
 862 #include <stddef.h>
 863 #include <stdlib.h>
 864 #ifdef HAVE_WCHAR_H
 865 #include <wchar.h>
 866 #endif
 867                 ],
 868                 [ mbstate_t s; return 0; ],
 869                 mutt_cv_mbstate_t=yes,
 870                 mutt_cv_mbstate_t=no))
 871
 872 if test "$mutt_cv_mbstate_t" = no; then
 873         AC_DEFINE(mbstate_t,int,[ Define to 'int' if system headers don't define. ])
 874 fi
 875
 876 wc_funcs=maybe
 877 AC_ARG_WITH(wc-funcs, AC_HELP_STRING([--without-wc-funcs], [Do not use the system's wchar_t functions]),
 878         wc_funcs=$withval)
 879
 880 if test "$wc_funcs" != yes -a "$wc_funcs" != no; then
 881         AC_CACHE_CHECK([for wchar_t functions], mutt_cv_wc_funcs,
 882                 mutt_cv_wc_funcs=no
 883                 AC_TRY_LINK([
 884 #define _XOPEN_SOURCE 1
 885 #include <stddef.h>
 886 #include <stdlib.h>
 887 #ifdef HAVE_WCTYPE_H
 888 #include <wctype.h>
 889 #endif
 890 #ifdef HAVE_WCHAR_H
 891 #include <wchar.h>
 892 #endif],
 893                         [mbrtowc(0, 0, 0, 0); wctomb(0, 0); wcwidth(0);
 894         iswprint(0); iswspace(0); towlower(0); towupper(0); iswalnum(0)],
 895                         mutt_cv_wc_funcs=yes))
 896         wc_funcs=$mutt_cv_wc_funcs
 897 fi
 898
 899 if test $wc_funcs = yes; then
 900         AC_DEFINE(HAVE_WC_FUNCS,1,[ Define if you are using the system's wchar_t functions. ])
 901 fi
 902
 903 AC_CACHE_CHECK([for nl_langinfo and CODESET], mutt_cv_langinfo_codeset,
 904   [AC_TRY_LINK([#include <langinfo.h>],
 905     [char* cs = nl_langinfo(CODESET);],
 906     mutt_cv_langinfo_codeset=yes,
 907     mutt_cv_langinfo_codeset=no)])
 908 if test $mutt_cv_langinfo_codeset = yes; then
 909   AC_DEFINE(HAVE_LANGINFO_CODESET,1,[ Define if you have <langinfo.h> and nl_langinfo(CODESET). ])
 910 fi
 911
 912 AC_CACHE_CHECK([for nl_langinfo and YESEXPR], mutt_cv_langinfo_yesexpr,
 913   [AC_TRY_LINK([#include <langinfo.h>],
 914     [char* cs = nl_langinfo(YESEXPR);],
 915     mutt_cv_langinfo_yesexpr=yes,
 916     mutt_cv_langinfo_yesexpr=no)])
 917 if test $mutt_cv_langinfo_yesexpr = yes; then
 918   AC_DEFINE(HAVE_LANGINFO_YESEXPR,1,[ Define if you have <langinfo.h> and nl_langinfo(YESEXPR). ])
 919 fi
 920
 921 dnl -- libesmtp --
 922 MUTT_AM_LIBESMTP
 923 if test x$use_libesmtp = xyes; then
 924     CFLAGS="$CFLAGS $mutt_libesmtp_cflags"
 925     MUTTLIBS="$MUTTLIBS $mutt_libesmtp_libs"
 926     MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_libesmtp.o"
 927
 928     AC_DEFINE(USE_LIBESMTP,
 929               1,
 930               [Define to enable the use of libesmtp])
 931 fi
 932 dnl -- end libesmtp --
 933
 934 dnl -- sgml tools --
 935
 936 dnl Documentation tools
 937 have_openjade="no"
 938 AC_PATH_PROG([OSPCAT], [ospcat], [none])
 939 if test "$OSPCAT" != "none"
 940 then
 941   AC_MSG_CHECKING([for openjade docbook stylesheets])
 942   dslosfile=`ospcat --public-id="-//Norman Walsh//DOCUMENT DocBook Print Stylesheet//EN"`
 943   DSLROOT=`echo $dslosfile | sed -n -e "s/.*SOIBASE='\(@<:@^'@:>@*\)\/catalog'.*/\1/p"`
 944   # ospcat may spit out an absolute path without an SOIBASE
 945   if test -z "$DSLROOT"
 946   then
 947     DSLROOT=`echo $dslosfile | sed -e 's|<OSFILE>\(.*\)/print/docbook.dsl|\1|'`
 948   fi
 949   if test -f $DSLROOT/print/docbook.dsl
 950   then
 951     AC_MSG_RESULT([in $DSLROOT])
 952     have_openjade="yes"
 953   else
 954     AC_MSG_RESULT([not found: PDF documentation will not be built.])
 955   fi
 956 fi
 957 AC_SUBST(DSLROOT)
 958
 959 AC_MSG_CHECKING([for lynx])
 960 AC_PATH_PROG([HTML2TXT_CMD], [lynx], [none])
 961 if test x"$HTML2TXT_CMD" = x"none"
 962 then
 963   AC_MSG_CHECKING([for w3m])
 964   AC_PATH_PROG([HTML2TXT_CMD], [w3m], [none])
 965 fi
 966 if test x"$HTML2TXT_CMD" = x"none"
 967 then
 968   AC_MSG_CHECKING([for elinks])
 969   AC_PATH_PROG([HTML2TXT_CMD], [elinks], [none])
 970 fi
 971 case "$HTML2TXT_CMD" in
 972   *elinks*)
 973     HTML2TXT_CMD="$HTML2TXT_CMD -dump -no-numbering -no-references \$^ > \$@"
 974     ;;
 975   *lynx*)
 976     HTML2TXT_CMD="$HTML2TXT_CMD -dump -nolist -with_backspaces \$^ > \$@"
 977     ;;
 978   *w3m*)
 979     HTML2TXT_CMD="$HTML2TXT_CMD -dump \$^ > \$@"
 980     ;;
 981   *)
 982     HTML2TXT_CMD="true"
 983     ;;
 984 esac
 985 AC_SUBST(HTML2TXT_CMD)
 986
 987 AC_MSG_CHECKING([for tidy])
 988 AC_PATH_PROG([HTMLCLEAN_CMD], [tidy], [none])
 989
 990 if test x"$HTMLCLEAN_CMD" != x"none"
 991 then
 992   HTMLCLEAN_CMD="$HTMLCLEAN_CMD -q -i -m -asxml -utf8 "
 993 else
 994   HTMLCLEAN_CMD="echo "
 995 fi
 996 AC_SUBST(HTMLCLEAN_CMD)
 997
 998 AC_OUTPUT(Makefile intl/Makefile m4/Makefile
 999         po/Makefile.in doc/Makefile contrib/Makefile
1000         muttbug.sh
1001         lib-lib/Makefile
1002         lib-mime/Makefile
1003         lib-crypt/Makefile
1004         lib-hash/Makefile
1005         lib/Makefile
1006         imap/Makefile
1007         pop/Makefile
1008         nntp/Makefile
1009         Madmuttrc.head
1010         doc/instdoc.sh)