configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl !!! WHEN ADDING NEW CONFIGURE TESTS, PLEASE ADD CODE TO MAIN.C !!!
   4 dnl !!! TO DUMP THEIR RESULTS WHEN MUTT -V IS CALLED            !!!
   5
   6 AC_PREREQ([2.50])
   7 AC_INIT([mutt.h])
   8 AM_CONFIG_HEADER(config.h)
   9
  10 mutt_cv_version=`cat "$srcdir/VERSION.in"`
  11
  12 AM_INIT_AUTOMAKE(muttng, $mutt_cv_version)
  13 AC_SUBST([CONFIGURE_DEPENDENCIES], ['$(top_srcdir)/VERSION.in'])
  14
  15 AC_GNU_SOURCE
  16
  17 ifdef([AC_LIBOBJ], , [define([AC_LIBOBJ], [LIB[]OBJS="$LIBOBJS $1.o"])])
  18
  19 ALL_LINGUAS="de ru it es uk fr pl nl cs id sk ko el zh_TW zh_CN pt_BR eo gl sv da lt tr ja hu et ca bg"
  20
  21 AC_CANONICAL_HOST
  22
  23 AC_MSG_CHECKING([for prefix])
  24 if test x$prefix = xNONE; then
  25         mutt_cv_prefix=$ac_default_prefix
  26 else
  27         mutt_cv_prefix=$prefix
  28 fi
  29 AC_MSG_RESULT($mutt_cv_prefix)
  30
  31 AC_PROG_CC
  32 AC_ISC_POSIX
  33 AM_C_PROTOTYPES
  34 if test "x$U" != "x"; then
  35   AC_MSG_ERROR(Compiler not ANSI compliant)
  36 fi
  37 AC_PROG_CPP
  38 AC_PROG_MAKE_SET
  39 AC_PROG_INSTALL
  40 AC_PROG_RANLIB
  41 AC_CHECK_TOOL(AR, ar, ar)
  42
  43 AC_C_INLINE
  44 AC_C_CONST
  45
  46 AC_SYS_LARGEFILE
  47 AC_FUNC_FSEEKO
  48 AC_CHECK_SIZEOF(off_t)
  49
  50 AC_PATH_PROG(DBX, dbx, no)
  51 AC_PATH_PROG(GDB, gdb, no)
  52 AC_PATH_PROG(SDB, sdb, no)
  53
  54 if test $GDB != no ; then
  55         DEBUGGER=$GDB
  56 elif test $DBX != no ; then
  57         DEBUGGER=$DBX
  58 elif test $SDB != no ; then
  59         DEBUGGER=$SDB
  60 else
  61         DEBUGGER=no
  62 fi
  63
  64 AC_SUBST([DEBUGGER])
  65
  66 AH_TEMPLATE([sig_atomic_t],
  67             [/* Define to `int' if <signal.h> doesn't define.])
  68 AH_TEMPLATE([HAVE_START_COLOR],
  69             [Define if you have start_color, as a function or macro.])
  70 AH_TEMPLATE([HAVE_TYPEAHEAD],
  71             [Define if you have typeahead, as a function or macro.])
  72 AH_TEMPLATE([HAVE_BKGDSET],
  73             [Define if you have bkgdset, as a function or macro.])
  74 AH_TEMPLATE([HAVE_CURS_SET],
  75             [Define if you have curs_set, as a function or macro.])
  76 AH_TEMPLATE([HAVE_META],
  77             [Define if you have meta, as a function or macro.])
  78 AH_TEMPLATE([HAVE_USE_DEFAULT_COLORS],
  79             [Define if you have use_default_colors, as a function or macro.])
  80 AH_TEMPLATE([HAVE_RESIZETERM],
  81             [Define if you have resizeterm, as a function or macro.])
  82 AH_TEMPLATE([SIG_ATOMIC_VOLATILE_T],
  83             [Some systems declare sig_atomic_t as volatile, some others -- no.
  84              This define will have value `sig_atomic_t' or
  85              `volatile sig_atomic_t' accordingly.])
  86 AH_TEMPLATE([ICONV_NONTRANS],
  87             [Define as 1 if iconv() only converts exactly and we should treat
  88              all return values other than (size_t)(-1) as equivalent.])
  89
  90 MUTT_C99_INTTYPES
  91
  92 ac_aux_path_sendmail=/usr/sbin:/usr/lib
  93 AC_PATH_PROG(SENDMAIL, sendmail, /usr/sbin/sendmail, $PATH:$ac_aux_path_sendmail)
  94 AC_DEFINE_UNQUOTED(SENDMAIL,"$ac_cv_path_SENDMAIL",[ Where to find sendmail on your system. ])
  95
  96 OPS='$(srcdir)/OPS'
  97
  98         AC_ARG_ENABLE(gpgme, AC_HELP_STRING([--enable-gpgme], [Enable GPGME support]),
  99         [       if test x$enableval = xyes; then
 100                         have_gpgme=yes
 101                 fi
 102         ])
 103         AC_ARG_WITH(gpgme-prefix, AC_HELP_STRING([--with-gpgme-prefix=PFX], [prefix where GPGME is installed (optional)]),
 104         gpgme_config_prefix="$withval", gpgme_config_prefix="")
 105
 106         if test x$have_gpgme = xyes; then
 107                 if test x$gpgme_config_prefix != x; then
 108                         GPGME_CONFIG="$gpgme_config_prefix/bin/gpgme-config"
 109                 else
 110                         AC_PATH_PROG(GPGME_CONFIG, gpgme-config, no)
 111                 fi
 112                 if test "x$GPGME_CONFIG" = "xno"; then
 113                         AC_MSG_ERROR([GPGME not found])
 114                 else
 115                         LIBGPGME_CFLAGS=`$GPGME_CONFIG --cflags`
 116                         LIBGPGME_LIBS=`$GPGME_CONFIG --libs`
 117       MUTTLIBS="$MUTTLIBS $LIBGPGME_LIBS"
 118                         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS crypt-gpgme.o crypt-mod-pgp-gpgme.o crypt-mod-smime-gpgme.o"
 119                         AC_DEFINE(CRYPT_BACKEND_GPGME, 1,
 120                                   [Defined, if GPGME support is enabled])
 121                 fi
 122         fi
 123         AC_SUBST(LIBGPGME_CFLAGS)
 124         AC_SUBST(LIBGPGME_LIBS)
 125
 126         AC_ARG_ENABLE(pgp, AC_HELP_STRING([--disable-pgp], [Disable PGP support]),
 127         [       if test x$enableval = xno ; then
 128                         have_pgp=no
 129                 fi
 130         ])
 131
 132         if test x$have_pgp != xno ; then
 133                 AC_DEFINE(CRYPT_BACKEND_CLASSIC_PGP,1,
 134                     [ Define if you want classic PGP support. ])
 135                 PGPAUX_TARGET="pgpringng\$(EXEEXT) pgpewrapng\$(EXEEXT)"
 136                 MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS pgp.o pgpinvoke.o pgpkey.o pgplib.o gnupgparse.o pgpmicalg.o pgppacket.o crypt-mod-pgp-classic.o"
 137         fi
 138
 139         AC_ARG_ENABLE(smime, AC_HELP_STRING([--disable-smime], [Disable SMIME support]),
 140         [       if test x$enableval = xno ; then
 141                         have_smime=no
 142                 fi
 143         ])
 144
 145         if test x$have_smime != xno ; then
 146                 AC_DEFINE(CRYPT_BACKEND_CLASSIC_SMIME,1,
 147                   [ Define if you want clasic S/MIME support. ])
 148                 MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS smime.o crypt-mod-smime-classic.o"
 149                 SMIMEAUX_TARGET="smime_keysng"
 150         fi
 151
 152         AC_ARG_WITH(mixmaster, AC_HELP_STRING([--with-mixmaster[=PATH]], [Include Mixmaster support]),
 153                 [if test -x "$withval" ; then
 154                         MIXMASTER="$withval"
 155                  else
 156                         MIXMASTER="mixmaster"
 157                  fi
 158                  OPS="$OPS \$(srcdir)/OPS.MIX"
 159                  MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS remailer.o"
 160                  AC_DEFINE_UNQUOTED(MIXMASTER,"$MIXMASTER",
 161                          [ Where to find mixmaster on your system. ])
 162                 ])
 163
 164 # We now require all OPS
 165 OPS="$OPS \$(srcdir)/OPS.PGP \$(srcdir)/OPS.SMIME \$(srcdir)/OPS.CRYPT "
 166 AC_SUBST([OPS])
 167
 168
 169 AC_SUBST(PGPAUX_TARGET)
 170 AC_SUBST(SMIMEAUX_TARGET)
 171
 172 AC_PATH_PROG(ISPELL, ispell, no)
 173 if test $ISPELL != no; then
 174         AC_DEFINE_UNQUOTED(ISPELL,"$ISPELL",[ Where to find ispell on your system. ])
 175 fi
 176
 177 AC_ARG_WITH(slang, AC_HELP_STRING([--with-slang[=DIR]], [Use S-Lang instead of ncurses]),
 178         [AC_CACHE_CHECK([if this is a BSD system], mutt_cv_bsdish,
 179                 [AC_TRY_RUN([#include <sys/param.h>
 180
 181 main ()
 182 {
 183 #ifdef BSD
 184         exit (0);
 185 #else
 186         exit (1);
 187 #endif
 188 }],
 189                         mutt_cv_bsdish=yes,
 190                         mutt_cv_bsdish=no,
 191                         mutt_cv_bsdish=no)])
 192
 193         AC_MSG_CHECKING(for S-Lang)
 194         if test $withval = yes; then
 195                 if test -d $srcdir/../slang; then
 196                         mutt_cv_slang=$srcdir/../slang/src
 197                         CFLAGS="$CFLAGS -I${mutt_cv_slang}"
 198                         LDFLAGS="$LDFLAGS -L${mutt_cv_slang}/objs"
 199                 else
 200                         if test -d $mutt_cv_prefix/include/slang; then
 201                                 CFLAGS="$CFLAGS -I$mutt_cv_prefix/include/slang"
 202                         elif test -d /usr/include/slang; then
 203                                 CFLAGS="$CFLAGS -I/usr/include/slang"
 204                         fi
 205                         mutt_cv_slang=yes
 206                 fi
 207         else
 208                 dnl ---Check to see if $withval is a source directory
 209                 if test -f $withval/src/slang.h; then
 210                         mutt_cv_slang=$withval/src
 211                         CFLAGS="$CFLAGS -I${mutt_cv_slang}"
 212                         LDFLAGS="$LDFLAGS -L${mutt_cv_slang}/objs"
 213                 else
 214                         dnl ---Must be installed somewhere
 215                         mutt_cv_slang=$withval
 216                         if test -d $withval/include/slang; then
 217                                 CFLAGS="$CFLAGS -I${withval}/include/slang"
 218                         elif test -d $withval/include; then
 219                                 CFLAGS="$CFLAGS -I${withval}/include"
 220                         fi
 221                         LDFLAGS="$LDFLAGS -L${withval}/lib"
 222                 fi
 223         fi
 224         AC_MSG_RESULT($mutt_cv_slang)
 225         if test $mutt_cv_bsdish = yes; then
 226                 AC_CHECK_LIB(termlib, main)
 227         fi
 228         AC_DEFINE(USE_SLANG_CURSES,1,
 229                 [ Define if you compile with SLang instead of curses/ncurses. ])
 230         AC_DEFINE(HAVE_COLOR,1,[ Define if your curses library supports color. ])
 231         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS resize.o"
 232
 233         dnl --- now that we've found it, check the link
 234
 235         AC_CHECK_LIB(slang, SLtt_get_terminfo,
 236                 [MUTTLIBS="$MUTTLIBS -lslang -lm"],
 237                 [AC_MSG_ERROR(unable to compile.  check config.log)], -lm)
 238
 239         ],
 240
 241         [mutt_cv_curses=/usr
 242         AC_ARG_WITH(curses, AC_HELP_STRING([--with-curses=DIR], [Where ncurses is installed]),
 243                 [if test $withval != yes; then
 244                         mutt_cv_curses=$withval
 245                 fi
 246                 if test x$mutt_cv_curses != x/usr; then
 247                         LDFLAGS="-L${mutt_cv_curses}/lib $LDFLAGS"
 248                         CPPFLAGS="$CPPFLAGS -I${mutt_cv_curses}/include"
 249                 fi])
 250
 251         AC_CHECK_FUNC(initscr,,[
 252         cf_ncurses="ncurses"
 253         for lib in ncursesw ncurses
 254         do
 255                 AC_CHECK_LIB($lib, waddnwstr, [cf_ncurses="$lib"; break])
 256         done
 257         AC_CHECK_LIB($cf_ncurses, initscr,
 258                 [MUTTLIBS="$MUTTLIBS -l$cf_ncurses"
 259                 if test x$mutt_cv_curses = x/usr -a -d /usr/include/ncurses; then
 260                         CPPFLAGS="$CPPFLAGS -I/usr/include/ncurses"
 261                 fi
 262
 263                 if test "$cf_ncurses" = ncursesw; then
 264                         AC_CHECK_HEADERS(ncurses/ncurses.h,[cf_cv_ncurses_header="ncurses/ncurses.h"])
 265                         AC_CHECK_HEADERS(ncursesw/ncurses.h,[cf_cv_ncurses_header="ncursesw/ncurses.h"])
 266                 else
 267                         AC_CHECK_HEADERS(ncurses.h,[cf_cv_ncurses_header="ncurses.h"])
 268                 fi],
 269
 270                 [CF_CURSES_LIBS])
 271                 ])
 272
 273         old_LIBS="$LIBS"
 274         LIBS="$LIBS $MUTTLIBS"
 275         CF_CHECK_FUNCDECLS([#include <${cf_cv_ncurses_header-curses.h}>],
 276                            [start_color typeahead bkgdset curs_set meta use_default_colors resizeterm])
 277         if test "$ac_cv_func_decl_start_color" = yes; then
 278                 AC_DEFINE(HAVE_COLOR,1,[ Define if your curses library supports color. ])
 279         fi
 280         if test "$ac_cv_func_decl_resizeterm" = yes; then
 281                 MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS resize.o"
 282         fi
 283         LIBS="$old_LIBS"
 284         ])
 285
 286 AC_HEADER_STDC
 287
 288 AC_CHECK_HEADERS(stdarg.h sys/ioctl.h ioctl.h sysexits.h)
 289 AC_CHECK_HEADERS(sys/time.h sys/resource.h)
 290 AC_CHECK_HEADERS(unix.h)
 291
 292 AC_CHECK_FUNCS(setrlimit getsid isctype)
 293
 294 AC_TYPE_SIGNAL
 295
 296 AC_MSG_CHECKING(for sig_atomic_t in signal.h)
 297 AC_EGREP_HEADER(sig_atomic_t,signal.h,
 298   [
 299     ac_cv_type_sig_atomic_t=yes;
 300     AC_EGREP_HEADER(volatile.*sig_atomic_t,
 301                     signal.h,
 302                     [
 303                         is_sig_atomic_t_volatile=yes;
 304                         AC_MSG_RESULT([yes, volatile])
 305                     ],
 306                     [
 307                         is_sig_atomic_t_volatile=no;
 308                         AC_MSG_RESULT([yes, non volatile])
 309                     ])
 310   ],
 311   [
 312     AC_MSG_RESULT(no)
 313     AC_CHECK_TYPE(sig_atomic_t, int)
 314     is_sig_atomic_t_volatile=no
 315   ])
 316 if test $is_sig_atomic_t_volatile = 'yes'
 317 then
 318     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, sig_atomic_t)
 319 else
 320     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, [volatile sig_atomic_t])
 321 fi
 322
 323 AC_DECL_SYS_SIGLIST
 324
 325 AC_TYPE_PID_T
 326 dnl AC_CHECK_TYPE(ssize_t, int)
 327
 328 AC_CHECK_FUNCS(fgetpos memmove setegid srand48 strerror)
 329 AC_REPLACE_FUNCS(strcasecmp setenv)
 330 AC_CHECK_FUNCS(snprintf vsnprintf)
 331
 332 AC_CHECK_FUNC(getopt)
 333 if test $ac_cv_func_getopt = yes; then
 334         AC_CHECK_HEADERS(getopt.h)
 335 fi
 336
 337 dnl SCO uses chsize() instead of ftruncate()
 338 AC_CHECK_FUNCS(ftruncate, , [AC_CHECK_LIB(x, chsize)])
 339
 340 dnl SCO has strftime() in libintl
 341 AC_CHECK_FUNCS(strftime, , [AC_CHECK_LIB(intl, strftime)])
 342
 343 dnl AIX may not have fchdir()
 344 AC_CHECK_FUNCS(fchdir, , [mutt_cv_fchdir=no])
 345
 346 AC_ARG_WITH(regex, AC_HELP_STRING([--with-regex], [Use the GNU regex library]),
 347         [mutt_cv_regex=yes],
 348         [AC_CHECK_FUNCS(regcomp, mutt_cv_regex=no, mutt_cv_regex=yes)])
 349
 350 if test $mutt_cv_regex = no ; then
 351 AC_CACHE_CHECK([whether your system's regexp library is completely broken],
 352         [mutt_cv_regex_broken],
 353         AC_TRY_RUN([
 354 #include <unistd.h>
 355 #include <regex.h>
 356 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
 357         mutt_cv_regex_broken=no, mutt_cv_regex_broken=yes, mutt_cv_regex_broken=yes))
 358         if test $mutt_cv_regex_broken = yes ; then
 359                 echo "Using the included GNU regex instead." >&AC_FD_MSG
 360                 mutt_cv_regex=yes
 361         fi
 362 fi
 363
 364 if test $mutt_cv_regex = yes; then
 365         AC_DEFINE(USE_GNU_REGEX,1,[ Define if you want to use the included regex.c. ])
 366         AC_LIBOBJ(regex)
 367 fi
 368
 369
 370 AC_ARG_WITH(homespool,
 371   AC_HELP_STRING([--with-homespool[=FILE]], [File in user's directory where new mail is spooled]), with_homespool=${withval})
 372 if test x$with_homespool != x; then
 373         if test $with_homespool = yes; then
 374                 with_homespool=mailbox
 375         fi
 376         AC_DEFINE_UNQUOTED(MAILPATH,"$with_homespool",[ Where new mail is spooled. ])
 377         AC_DEFINE(HOMESPOOL,1,
 378           [Is mail spooled to the user's home directory?  If defined,
 379            MAILPATH should be set to the filename of the spool mailbox
 380            relative the the home directory.
 381            use: configure --with-homespool=FILE])
 382         AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 383         mutt_cv_setgid=no
 384 else
 385         AC_ARG_WITH(mailpath, AC_HELP_STRING([--with-mailpath=DIR], [Directory where spool mailboxes are located]),
 386                 [mutt_cv_mailpath=$withval],
 387                 [ AC_CACHE_CHECK(where new mail is stored, mutt_cv_mailpath,
 388                         [mutt_cv_mailpath=no
 389                         if test -d /var/mail; then
 390                                 mutt_cv_mailpath=/var/mail
 391                         elif test -d /var/spool/mail; then
 392                                 mutt_cv_mailpath=/var/spool/mail
 393                         elif test -d /usr/spool/mail; then
 394                                 mutt_cv_mailpath=/usr/spool/mail
 395                         elif test -d /usr/mail; then
 396                                 mutt_cv_mailpath=/usr/mail
 397                         fi])
 398                 ])
 399         if test "$mutt_cv_mailpath" = no; then
 400                 AC_MSG_ERROR("Could not determine where new mail is stored.")
 401         fi
 402         AC_DEFINE_UNQUOTED(MAILPATH,"$mutt_cv_mailpath",[ Where new mail is spooled. ])
 403
 404         AC_CACHE_CHECK(if $mutt_cv_mailpath is world writable, mutt_cv_worldwrite, [AC_TRY_RUN([#include <sys/types.h>
 405 #include <sys/stat.h>
 406
 407 int main (int argc, char **argv)
 408 {
 409         struct stat s;
 410
 411         stat ("$mutt_cv_mailpath", &s);
 412         if (s.st_mode & S_IWOTH) exit (0);
 413         exit (1);
 414 }], mutt_cv_worldwrite=yes, mutt_cv_worldwrite=no, mutt_cv_worldwrite=no)])
 415
 416         mutt_cv_setgid=no
 417         if test $mutt_cv_worldwrite = yes; then
 418                 AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 419         else
 420
 421                 AC_CACHE_CHECK(if $mutt_cv_mailpath is group writable, mutt_cv_groupwrite, [AC_TRY_RUN([#include <sys/types.h>
 422 #include <sys/stat.h>
 423
 424 int main (int argc, char **argv)
 425 {
 426         struct stat s;
 427
 428         stat ("$mutt_cv_mailpath", &s);
 429         if (s.st_mode & S_IWGRP) exit (0);
 430         exit (1);
 431 }], mutt_cv_groupwrite=yes, mutt_cv_groupwrite=no, mutt_cv_groupwrite=no)])
 432
 433                 if test $mutt_cv_groupwrite = yes; then
 434                         AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 435                         AC_DEFINE(USE_SETGID,1,[ Define if mutt should run setgid "mail". ])
 436                         mutt_cv_setgid=yes
 437                 fi
 438         fi
 439 fi
 440
 441 AC_MSG_CHECKING(where to put the documentation)
 442 AC_ARG_WITH(docdir, AC_HELP_STRING([--with-docdir=PATH], [Specify where to put the documentation]),
 443         [mutt_cv_docdir=$withval],
 444         [mutt_cv_docdir="${prefix}/doc/muttng"])
 445 AC_MSG_RESULT($mutt_cv_docdir)
 446
 447 docdir=$mutt_cv_docdir
 448 AC_SUBST(docdir)
 449
 450 if test x$mutt_cv_setgid = xyes; then
 451         DOTLOCK_GROUP='mail'
 452         DOTLOCK_PERMISSION=2755
 453 else
 454         DOTLOCK_GROUP=''
 455         DOTLOCK_PERMISSION=755
 456 fi
 457 AC_SUBST(DOTLOCK_GROUP)
 458 AC_SUBST(DOTLOCK_PERMISSION)
 459
 460 AC_ARG_WITH(domain, AC_HELP_STRING([--with-domain=DOMAIN], [Specify your DNS domain name]),
 461         [if test $withval != yes; then
 462          if test $withval != no; then
 463            AC_DEFINE_UNQUOTED(DOMAIN,"$withval",[ Define your domain name. ])
 464          fi
 465         fi])
 466
 467 need_socket="no"
 468
 469 dnl -- socket dependencies --
 470
 471 AC_ARG_ENABLE(pop,  AC_HELP_STRING([--enable-pop], [Enable POP3 support]),
 472 [       if test x$enableval = xyes ; then
 473                 AC_DEFINE(USE_POP,1,[ Define if you want support for the POP3 protocol. ])
 474                 LIBPOP="-Lpop -lpop"
 475                 LIBPOPDEPS="\$(top_srcdir)/pop/pop.h pop/libpop.a"
 476                 need_socket="yes"
 477                 need_pop="yes"
 478                 need_md5="yes"
 479         fi
 480 ])
 481 AM_CONDITIONAL(BUILD_POP, test x$need_pop = xyes)
 482
 483 AC_ARG_ENABLE(imap, AC_HELP_STRING([--enable-imap], [Enable IMAP support]),
 484 [       if test x$enableval = xyes ; then
 485                 AC_DEFINE(USE_IMAP,1,[ Define if you want support for the IMAP protocol. ])
 486                 LIBIMAP="-Limap -limap"
 487                 LIBIMAPDEPS="\$(top_srcdir)/imap/imap.h imap/libimap.a"
 488                 need_imap="yes"
 489                 need_socket="yes"
 490                 need_md5="yes"
 491         fi
 492 ])
 493 AM_CONDITIONAL(BUILD_IMAP, test x$need_imap = xyes)
 494
 495 AC_ARG_ENABLE(nntp, [  --enable-nntp              Enable NNTP support],
 496 [       if test x$enableval = xyes ; then
 497                 AC_DEFINE(USE_NNTP,1,[ Compiling with newsreading support with NNTP ])
 498                 LIBNNTP="-Lnntp -lnntp"
 499                 LIBNNTPDEPS="\$(top_srcdir)/nntp/nntp.h nntp/libnntp.a"
 500                 need_nntp="yes"
 501                 need_socket="yes"
 502         fi
 503 ])
 504 AM_CONDITIONAL(BUILD_NNTP, test x$need_nntp = xyes)
 505
 506 dnl -- end socket dependencies --
 507
 508 if test "$need_socket" = "yes"
 509 then
 510         AC_MSG_CHECKING([for socklen_t])
 511         AC_EGREP_HEADER(socklen_t, sys/socket.h, AC_MSG_RESULT([yes]),
 512                 AC_MSG_RESULT([no])
 513                 AC_DEFINE(socklen_t,int,
 514                         [ Define to 'int' if <sys/socket.h> doesn't have it. ]))
 515         AC_CHECK_FUNC(gethostent, , AC_CHECK_LIB(nsl, gethostent))
 516         AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt))
 517         AC_CHECK_FUNCS(getaddrinfo)
 518         AC_DEFINE(USE_SOCKET,1,
 519                 [ Include code for socket support. Set automatically if you enable POP3 or IMAP ])
 520         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS account.o mutt_socket.o mutt_tunnel.o"
 521 fi
 522
 523 dnl -- imap dependencies --
 524
 525 AC_ARG_WITH(gss, AC_HELP_STRING([--with-gss[=PFX]], [Compile in GSSAPI authentication for IMAP]),
 526     gss_prefix="$withval", gss_prefix="no")
 527 if test "$gss_prefix" != "no"
 528 then
 529   if test "$need_imap" = "yes"
 530   then
 531     MUTT_AM_PATH_GSSAPI(gss_prefix)
 532     AC_MSG_CHECKING(GSSAPI implementation)
 533     AC_MSG_RESULT($GSSAPI_IMPL)
 534     if test "$GSSAPI_IMPL" = "none"
 535     then
 536       AC_CACHE_SAVE
 537       AC_MSG_RESULT([GSSAPI libraries not found])
 538     fi
 539     if test "$GSSAPI_IMPL" = "Heimdal"
 540     then
 541       AC_DEFINE(HAVE_HEIMDAL,1,[ Define if your GSSAPI implementation is Heimdal ])
 542     fi
 543     CPPFLAGS="$CPPFLAGS $GSSAPI_CFLAGS"
 544     MUTTLIBS="$MUTTLIBS $GSSAPI_LIBS"
 545     AC_DEFINE(USE_GSS,1,[ Define if you have GSSAPI libraries available ])
 546     need_gss="yes"
 547   else
 548     AC_MSG_WARN([GSS was requested but IMAP is not enabled])
 549   fi
 550 fi
 551 AM_CONDITIONAL(USE_GSS, test x$need_gss = xyes)
 552
 553 dnl -- end imap dependencies --
 554
 555 AC_ARG_WITH(ssl, AC_HELP_STRING([--with-ssl[=PFX]], [Compile in SSL support for POP/IMAP]),
 556 [       if test "$with_ssl" != "no"
 557         then
 558           if test "$need_socket" != "yes"; then
 559            AC_MSG_ERROR([SSL support is only useful with POP or IMAP support])
 560           fi
 561
 562           if test "$with_ssl" != "yes"
 563           then
 564            LDFLAGS="$LDFLAGS -L$withval/lib"
 565            CPPFLAGS="$CPPFLAGS -I$withval/include"
 566           fi
 567           saved_LIBS="$LIBS"
 568
 569           AC_CHECK_LIB(crypto, X509_new,, AC_MSG_ERROR([Unable to find SSL library]))
 570           AC_CHECK_LIB(ssl, SSL_new,, AC_MSG_ERROR([Unable to find SSL library]), -lcrypto)
 571
 572           AC_CHECK_FUNCS(RAND_status RAND_egd)
 573
 574           AC_DEFINE(USE_SSL,1,[ Define if you want support for SSL. ])
 575           LIBS="$saved_LIBS"
 576           MUTTLIBS="$MUTTLIBS -lssl -lcrypto"
 577           MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_ssl.o"
 578           need_ssl=yes
 579
 580         fi
 581 ])
 582
 583 AC_ARG_WITH([gnutls], AC_HELP_STRING([--with-gnutls[=PFX]], [Enable SSL support using gnutls]),
 584     [gnutls_prefix="$withval"], [gnutls_prefix="no"])
 585 if test "$gnutls_prefix" != "no"
 586 then
 587   if test "$need_socket" != "yes"
 588   then
 589     AC_MSG_ERROR([SSL support is only useful with POP or IMAP support])
 590   fi
 591   if test x"$need_ssl" = x"yes"
 592   then
 593     AC_MSG_ERROR([Only either OpenSSL or GNUTLS may be used])
 594   fi
 595   MUTT_AM_PATH_GNUTLS([$gnutls_prefix],
 596     [dnl GNUTLS found
 597     CPPFLAGS="$CPPFLAGS $LIBGNUTLS_CFLAGS"
 598     MUTTLIBS="$MUTTLIBS $LIBGNUTLS_LIBS"
 599     AC_DEFINE(USE_GNUTLS, 1, [Define if you want support for SSL via the gnutls library.])
 600
 601     MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_ssl_gnutls.o"
 602     need_ssl=yes],
 603     [dnl GNUTLS not found
 604       AC_MSG_ERROR([could not find libgnutls])
 605     ])
 606 fi
 607
 608 AM_CONDITIONAL(USE_SSL, test x$need_ssl = xyes)
 609
 610 AC_ARG_WITH(sasl2, AC_HELP_STRING([--with-sasl2[=PFX]], [Use Cyrus SASL library version 2 for POP/IMAP authentication]),
 611         [
 612         if test "$with_sasl2" != "no" -a "$need_imap" != "yes" -a "$need_pop" != "yes"
 613         then
 614           AC_MSG_ERROR([SASL2 support is only useful with POP or IMAP support])
 615         fi
 616
 617         if test "$with_sasl2" != "no"
 618         then
 619           if test "$with_sasl2" != "yes"
 620           then
 621             CPPFLAGS="$CPPFLAGS -I$with_sasl2/include"
 622             LDFLAGS="$LDFLAGS -L$with_sasl2/lib"
 623           fi
 624
 625           saved_LIBS="$LIBS"
 626
 627           AC_CHECK_LIB(sasl2, sasl_client_init,,
 628             AC_MSG_ERROR([could not find libsasl2]),)
 629
 630           MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_sasl.o"
 631           MUTTLIBS="$MUTTLIBS -lsasl2"
 632           LIBS="$saved_LIBS"
 633           AC_DEFINE(USE_SASL,1,
 634                   [ Define if want to use version 2 of the Cyrus SASL library. ])
 635           need_sasl=yes
 636         fi
 637         ])
 638 AM_CONDITIONAL(USE_SASL, test x$need_sasl = xyes)
 639
 640 AC_ARG_WITH(idn, AC_HELP_STRING([--with-idn=[PFX]], [Use GNU libidn for domain names]),
 641                  [
 642                   if test "$with_idn" != "no" ; then
 643                         if test "$with_idn" != "yes" ; then
 644                            CPPFLAGS="$CPPFLAGS -I$with_idn/include"
 645                            LDFLAGS="$LDFLAGS -L$with_idn/lib"
 646                         fi
 647                   fi
 648                  ]
 649 )
 650
 651 if test "x$with_idn" != "xno"; then
 652    AC_CHECK_LIB(idn, stringprep_check_version)
 653    AC_CHECK_FUNCS(idna_to_unicode_utf8_from_utf8 idna_to_unicode_8z8z)
 654    AC_CHECK_FUNCS(idna_to_ascii_from_utf8 idna_to_ascii_8z)
 655    AC_CHECK_FUNCS(idna_to_ascii_lz idna_to_ascii_from_locale)
 656 fi
 657
 658 dnl -- end socket --
 659
 660 AC_ARG_ENABLE(debug, AC_HELP_STRING([--enable-debug], [Enable debugging support]),
 661         [ if test x$enableval = xyes ; then
 662                 AC_DEFINE(DEBUG,1,[ Define to enable debugging info. ])
 663           fi
 664          ])
 665
 666 AC_ARG_ENABLE(flock, AC_HELP_STRING([--enable-flock], [Use flock() to lock files]),
 667         [if test $enableval = yes; then
 668                 AC_DEFINE(USE_FLOCK,1, [ Define to use flock() to lock mailboxes. ])
 669         fi])
 670
 671 mutt_cv_fcntl=yes
 672 AC_ARG_ENABLE(fcntl, AC_HELP_STRING([--disable-fcntl], [Do NOT use fcntl() to lock files]),
 673         [if test $enableval = no; then mutt_cv_fcntl=no; fi])
 674
 675 if test $mutt_cv_fcntl = yes; then
 676         AC_DEFINE(USE_FCNTL,1, [ Define to use fcntl() to lock folders. ])
 677 fi
 678
 679 AC_MSG_CHECKING(whether struct dirent defines d_ino)
 680 ac_cv_dirent_d_ino=no
 681 AC_TRY_LINK([#include <dirent.h>],[struct dirent dp; (void)dp.d_ino],[ac_cv_dirent_d_ino=yes])
 682 if test x$ac_cv_dirent_d_ino = xyes ; then
 683   AC_DEFINE(HAVE_DIRENT_D_INO,1,
 684             [Define to 1 if your system has the dirent::d_ino member])
 685 fi
 686 AC_MSG_RESULT($ac_cv_dirent_d_ino)
 687
 688 dnl This may look cumbersome -- please keep it that way, so we can
 689 dnl quickly change the default to "yes" again.
 690 mutt_cv_inodesort=no
 691 AC_ARG_ENABLE(inodesort,  AC_HELP_STRING([--enable-inodesort], [Read files in maildir folders sorted by inode.]),
 692        [if test x$enableval = xyes -a x$ac_cv_dirent_d_ino = xyes ; then mutt_cv_inodesort=yes; fi])
 693
 694 if test $mutt_cv_inodesort = yes; then
 695         AC_DEFINE(USE_INODESORT, 1, [ Define to sort files in a maildir by inode number. ])
 696 fi
 697
 698 mutt_cv_warnings=yes
 699 AC_ARG_ENABLE(warnings, AC_HELP_STRING([--disable-warnings], [Turn off compiler warnings (not recommended)]),
 700 [if test $enableval = no; then
 701         mutt_cv_warnings=no
 702 fi])
 703
 704 if test x$GCC = xyes -a $mutt_cv_warnings = yes; then
 705         CFLAGS="-Wall -pedantic $CFLAGS"
 706 fi
 707
 708 AC_ARG_ENABLE(nfs-fix, AC_HELP_STRING([--enable-nfs-fix], [Work around an NFS with broken attributes caching]),
 709         [if test x$enableval = xyes; then
 710                 AC_DEFINE(NFS_ATTRIBUTE_HACK,1,
 711                   [Define if you have problems with mutt not detecting
 712                    new/old mailboxes over NFS.  Some NFS implementations
 713                    incorrectly cache the attributes of small files.])
 714         fi])
 715
 716 AC_ARG_ENABLE(buffy-size, AC_HELP_STRING([--enable-buffy-size], [Use file size attribute instead of access time]),
 717         [if test x$enableval = xyes; then
 718                 AC_DEFINE(BUFFY_SIZE,1,[ Define to enable the "buffy_size" feature. ])
 719         fi])
 720
 721 AC_ARG_ENABLE(mailtool, AC_HELP_STRING([--enable-mailtool], [Enable Sun mailtool attachments support ]),
 722         [if test x$enableval = xyes; then
 723                 AC_DEFINE(SUN_ATTACHMENT,1,[ Define to enable Sun mailtool attachments support. ])
 724         fi])
 725
 726 AC_ARG_ENABLE(compressed, [  --enable-compressed        Enable compressed folders support ],
 727         [if test x$enableval = xyes; then
 728                 AC_DEFINE(USE_COMPRESSED,1,[ The compressed mailboxes support ])
 729         fi])
 730
 731 AC_ARG_ENABLE(locales-fix, AC_HELP_STRING([--enable-locales-fix], [The result of isprint() is unreliable ]),
 732         [if test x$enableval = xyes; then
 733                 AC_DEFINE(LOCALES_HACK,1,[ Define if the result of isprint() is unreliable. ])
 734         fi])
 735
 736 AC_ARG_WITH(exec-shell, AC_HELP_STRING([--with-exec-shell=SHELL], [Specify alternate shell (ONLY if /bin/sh is broken)]),
 737         [if test $withval != yes; then
 738                 AC_DEFINE_UNQUOTED(EXECSHELL, "$withval",
 739                  [program to use for shell commands])
 740          else
 741                 AC_DEFINE_UNQUOTED(EXECSHELL, "/bin/sh")
 742         fi],
 743         [AC_DEFINE_UNQUOTED(EXECSHELL, "/bin/sh")])
 744
 745 dnl -- start cache --
 746 AC_ARG_ENABLE(hcache, AC_HELP_STRING([--enable-hcache], [Enable header caching]),
 747 [if test x$enableval = xyes; then
 748     AC_DEFINE(USE_HCACHE, 1, [Enable header caching])
 749
 750     OLDCPPFLAGS="$CPPFLAGS"
 751     OLDLIBS="$LIBS"
 752
 753     need_md5="yes"
 754
 755     ac_prefer_qdbm=yes
 756     AC_ARG_WITH(qdbm, AC_HELP_STRING([--without-qdbm], [Don't use qdbm even if it is available]),
 757         ac_prefer_qdbm=$withval)
 758     if test x$ac_prefer_qdbm != xno; then
 759         ac_cv_vlopen=no
 760         QDBM_DIRS="$mutt_cv_prefix /usr/local /usr"
 761         AC_MSG_CHECKING([for vlopen])
 762         for d in $QDBM_DIRS; do
 763           if test x$ac_cv_vlopen = xno && test -d "$d/include" && test -d "$d/lib"; then
 764             QDBM_INC="-I$d/include"
 765             QDBM_LIB="-L$d/lib"
 766             CPPFLAGS="$OLDCPPFLAGS $QDBM_INC"
 767             LIBS="$OLDLIBS $QDBM_LIB -lqdbm"
 768             AC_TRY_LINK([#include <villa.h>],[vlopen(0,0,0);],[ac_cv_vlopen=yes])
 769           fi
 770         done
 771         if test x$ac_cv_vlopen = xyes; then
 772           AC_MSG_RESULT(yes)
 773         else
 774           AC_MSG_RESULT(no)
 775         fi
 776     fi
 777
 778     ac_prefer_gdbm=yes
 779     AC_ARG_WITH(gdbm, AC_HELP_STRING([--without-gdbm], [Don't use gdbm even if it is available]),
 780         ac_prefer_gdbm=$withval)
 781     if test x$ac_prefer_gdbm != xno -a x$ac_cv_vlopen != xyes; then
 782         ac_cv_gdbmopen=no
 783         GDBM_DIRS="$mutt_cv_prefix /usr/local /usr"
 784         AC_MSG_CHECKING([for gdbm_open])
 785         for d in $GDBM_DIRS; do
 786           if test x$ac_cv_gdbmopen = xno && test -d "$d/include" && test -d "$d/lib"; then
 787             GDBM_INC="-I$d/include"
 788             GDBM_LIB="-L$d/lib"
 789             CPPFLAGS="$OLDCPPFLAGS $GDBM_INC"
 790             LIBS="$OLDLIBS $GDBM_LIB -lgdbm"
 791             AC_TRY_LINK([#include <gdbm.h>],[gdbm_open(0,0,0,0,0);],[ac_cv_gdbmopen=yes])
 792           fi
 793         done
 794         if test x$ac_cv_gdbmopen = xyes; then
 795           AC_MSG_RESULT(yes)
 796         else
 797           AC_MSG_RESULT(no)
 798         fi
 799     fi
 800
 801     ac_bdb_prefix=yes
 802     AC_ARG_WITH(bdb, AC_HELP_STRING([--with-bdb[=DIR]], [Use BerkeleyDB4 if gdbm is not available ]),
 803         ac_bdb_prefix=$withval)
 804     if test x$ac_bdb_prefix != xno -a x$ac_cv_gdbmopen != xyes -a x$ac_cv_vlopen != xyes; then
 805         test x$ac_bdb_prefix = xyes && ac_bdb_prefix="$mutt_cv_prefix /opt/csw/bdb4 /opt /usr/local /usr"
 806         for d in $ac_bdb_prefix; do
 807             bdbpfx="$bdbpfx $d"
 808             for v in BerkeleyDB.4.3 BerkeleyDB.4.2 BerkeleyDB.4.1; do
 809                 bdbpfx="$bdbpfx $d/$v"
 810             done
 811         done
 812         BDB_VERSIONS="db-4 db4 db-4.3 db4.3 db43 db-4.2 db4.2 db42 db-4.1 db4.1 db41 db ''"
 813         AC_MSG_CHECKING([for BerkeleyDB > 4.0])
 814         for d in $bdbpfx; do
 815             BDB_INCLUDE_DIR=""
 816             BDB_LIB_DIR=""
 817             for v in / $BDB_VERSIONS; do
 818                 if test -r "$d/include/$v/db.h"; then
 819                     BDB_INCLUDE_DIR="$d/include/$v"
 820                     if test -d "$d/lib/$v"; then
 821                         BDB_LIB_DIR="$d/lib/$v"
 822                         for l in `echo $BDB_VERSIONS`; do
 823                             CPPFLAGS="-I$BDB_INCLUDE_DIR $OLDCPPFLAGS"
 824                             LIBS="$OLDLIBS -L$BDB_LIB_DIR -l$l"
 825                             AC_TRY_LINK([
 826                                 #include <stdlib.h>
 827                                 #include <db.h>
 828                             ],[
 829                                 DB *db = NULL;
 830                                 db->open(db,NULL,NULL,NULL,0,0,0);
 831                             ],[
 832                                 ac_cv_dbcreate=yes
 833                                 BDB_LIB="$l"
 834                                 break
 835                             ])
 836                         done
 837                         test x$ac_cv_dbcreate = xyes && break
 838                     fi
 839                 fi
 840             done
 841             test x$BDB_LIB != x && break
 842         done
 843         if test x$ac_cv_dbcreate = xyes; then
 844             AC_MSG_RESULT(yes)
 845         else
 846             AC_MSG_RESULT(no)
 847         fi
 848     fi
 849
 850     if test x$ac_cv_vlopen = xyes; then
 851         CPPFLAGS="$OLDCPPFLAGS $QDBM_INC"
 852         LIBS="$OLDLIBS $QDBM_LIB -lqdbm"
 853         AC_DEFINE(HAVE_QDBM, 1, [QDBM Support])
 854     elif test x$ac_cv_gdbmopen = xyes; then
 855         CPPFLAGS="$OLDCPPFLAGS $GDBM_INC"
 856         LIBS="$OLDLIBS $GDBM_LIB -lgdbm";
 857         AC_DEFINE(HAVE_GDBM, 1, [GDBM Support])
 858     elif test x$ac_cv_dbcreate = xyes; then
 859         CPPFLAGS="-I$BDB_INCLUDE_DIR $OLDCPPFLAGS"
 860         LIBS="$OLDLIBS -L$BDB_LIB_DIR -l$BDB_LIB"
 861         AC_DEFINE(HAVE_DB4, 1, [Sleepycat DB4 Support])
 862     else
 863         AC_MSG_ERROR([You need one of: QDBM, GDBM or Sleepycat DB4 for --enable-hcache])
 864     fi
 865 fi])
 866 dnl -- end cache --
 867
 868 AC_SUBST(MUTTLIBS)
 869 AC_SUBST(MUTT_LIB_OBJECTS)
 870 AC_SUBST(LIBIMAP)
 871 AC_SUBST(LIBIMAPDEPS)
 872 AC_SUBST(LIBPOP)
 873 AC_SUBST(LIBPOPDEPS)
 874 AC_SUBST(LIBNNTP)
 875 AC_SUBST(LIBNNTPDEPS)
 876
 877 dnl -- iconv/gettext --
 878
 879 AC_ARG_ENABLE(iconv, AC_HELP_STRING([--disable-iconv], [Disable iconv support]),
 880         [if test x$enableval = xno ; then
 881                 am_cv_func_iconv=no
 882         fi
 883 ])
 884
 885 AM_GNU_GETTEXT
 886
 887 if test "$am_cv_func_iconv" != "yes"
 888 then
 889   AC_MSG_WARN([Configuring without iconv support. See INSTALL for details])
 890 else
 891
 892 AC_CHECK_HEADERS(iconv.h,
 893         [AC_MSG_CHECKING(whether iconv.h defines iconv_t)
 894          AC_EGREP_HEADER([typedef.*iconv_t],iconv.h,
 895                 [AC_MSG_RESULT(yes)
 896                  AC_DEFINE(HAVE_ICONV_T_DEF, 1,
 897                         [Define if <iconv.h> defines iconv_t.])],
 898                  AC_MSG_RESULT(no))])
 899
 900 dnl (1) Some implementations of iconv won't convert from UTF-8 to UTF-8.
 901 dnl (2) In glibc-2.1.2 and earlier there is a bug that messes up ob and
 902 dnl     obl when args 2 and 3 are 0 (fixed in glibc-2.1.3).
 903 AC_CACHE_CHECK([whether this iconv is good enough], mutt_cv_iconv_good,
 904         mutt_save_LIBS="$LIBS"
 905         LIBS="$LIBS $LIBICONV"
 906         AC_TRY_RUN([
 907 #include <iconv.h>
 908 int main()
 909 {
 910   iconv_t cd;
 911 changequote(, )dnl
 912   char buf[4];
 913 changequote([, ])dnl
 914   char *ob;
 915   size_t obl;
 916   ob = buf, obl = sizeof(buf);
 917   return ((cd = iconv_open("UTF-8", "UTF-8")) != (iconv_t)(-1) &&
 918           (iconv(cd, 0, 0, &ob, &obl) ||
 919            !(ob == buf && obl == sizeof(buf)) ||
 920            iconv_close(cd)));
 921 }
 922                 ],
 923                 mutt_cv_iconv_good=yes,
 924                 mutt_cv_iconv_good=no,
 925                 mutt_cv_iconv_good=yes)
 926         LIBS="$mutt_save_LIBS")
 927 if test "$mutt_cv_iconv_good" = no; then
 928   AC_MSG_ERROR(Try using libiconv instead)
 929 fi
 930
 931 dnl This is to detect implementations such as the one in glibc-2.1,
 932 dnl which always convert exactly but return the number of characters
 933 dnl converted instead of the number converted inexactly.
 934 AC_CACHE_CHECK([whether iconv is non-transcribing], mutt_cv_iconv_nontrans,
 935         mutt_save_LIBS="$LIBS"
 936         LIBS="$LIBS $LIBICONV"
 937         AC_TRY_RUN([
 938 #include <iconv.h>
 939 #include <string.h>
 940 int main()
 941 {
 942   iconv_t cd;
 943   const char *ib;
 944   char *ob;
 945   size_t ibl, obl;
 946   const char *s = "\304\211";
 947 changequote(, )dnl
 948   char t[3];
 949 changequote([, ])dnl
 950   ib = s, ibl = 2, ob = t, obl = 3;
 951   return ((cd = iconv_open("UTF-8", "UTF-8")) == (iconv_t)(-1) ||
 952           iconv(cd, &ib, &ibl, &ob, &obl));
 953 }
 954                 ],
 955                 mutt_cv_iconv_nontrans=no,
 956                 mutt_cv_iconv_nontrans=yes,
 957                 mutt_cv_iconv_nontrans=no)
 958         LIBS="$mutt_save_LIBS")
 959 if test "$mutt_cv_iconv_nontrans" = yes; then
 960   AC_DEFINE(ICONV_NONTRANS, 1)
 961 else
 962   AC_DEFINE(ICONV_NONTRANS, 0)
 963 fi
 964
 965 CPPFLAGS="$CPPFLAGS -I\$(top_srcdir)/intl"
 966
 967 if test "$BUILD_INCLUDED_LIBINTL" = "yes"; then
 968   AC_DEFINE(HAVE_BIND_TEXTDOMAIN_CODESET,1,
 969           [ Define if your gettext has bind_textdomain_codeset. ])
 970 else
 971   AC_CHECK_FUNCS(bind_textdomain_codeset)
 972 fi
 973
 974 fi # libiconv
 975
 976 dnl -- locales --
 977
 978 AC_CHECK_HEADERS(wchar.h)
 979
 980 AC_CACHE_CHECK([for wchar_t], mutt_cv_wchar_t,
 981         AC_TRY_COMPILE([
 982 #include <stddef.h>
 983 #include <stdlib.h>
 984 #ifdef HAVE_WCHAR_H
 985 #include <wchar.h>
 986 #endif
 987                 ],
 988                 [ wchar_t wc; return 0; ],
 989                 mutt_cv_wchar_t=yes,
 990                 mutt_cv_wchar_t=no))
 991
 992 if test "$mutt_cv_wchar_t" = no; then
 993         AC_DEFINE(wchar_t,int,[ Define to 'int' if system headers don't define. ])
 994 fi
 995
 996 AC_CACHE_CHECK([for wint_t], mutt_cv_wint_t,
 997         AC_TRY_COMPILE([
 998 #include <stddef.h>
 999 #include <stdlib.h>
1000 #ifdef HAVE_WCHAR_H
1001 #include <wchar.h>
1002 #endif
1003                 ],
1004                 [ wint_t wc; return 0; ],
1005                 mutt_cv_wint_t=yes,
1006                 mutt_cv_wint_t=no))
1007
1008 if test "$mutt_cv_wint_t" = no; then
1009         AC_DEFINE(wint_t,int,[ Define to 'int' if system headers don't define. ])
1010 fi
1011
1012 AC_CHECK_HEADERS(wctype.h)
1013 AC_CHECK_FUNCS(iswalnum iswalpha  iswcntrl iswdigit)
1014 AC_CHECK_FUNCS(iswgraph iswlower iswprint iswpunct iswspace iswupper)
1015 AC_CHECK_FUNCS(iswxdigit towupper towlower)
1016
1017 AC_CACHE_CHECK([for mbstate_t], mutt_cv_mbstate_t,
1018         AC_TRY_COMPILE([
1019 #include <stddef.h>
1020 #include <stdlib.h>
1021 #ifdef HAVE_WCHAR_H
1022 #include <wchar.h>
1023 #endif
1024                 ],
1025                 [ mbstate_t s; return 0; ],
1026                 mutt_cv_mbstate_t=yes,
1027                 mutt_cv_mbstate_t=no))
1028
1029 if test "$mutt_cv_mbstate_t" = no; then
1030         AC_DEFINE(mbstate_t,int,[ Define to 'int' if system headers don't define. ])
1031 fi
1032
1033 wc_funcs=maybe
1034 AC_ARG_WITH(wc-funcs, AC_HELP_STRING([--without-wc-funcs], [Do not use the system's wchar_t functions]),
1035         wc_funcs=$withval)
1036
1037 if test "$wc_funcs" != yes -a "$wc_funcs" != no; then
1038         AC_CACHE_CHECK([for wchar_t functions], mutt_cv_wc_funcs,
1039                 mutt_cv_wc_funcs=no
1040                 AC_TRY_LINK([
1041 #define _XOPEN_SOURCE 1
1042 #include <stddef.h>
1043 #include <stdlib.h>
1044 #ifdef HAVE_WCTYPE_H
1045 #include <wctype.h>
1046 #endif
1047 #ifdef HAVE_WCHAR_H
1048 #include <wchar.h>
1049 #endif],
1050                         [mbrtowc(0, 0, 0, 0); wctomb(0, 0); wcwidth(0);
1051         iswprint(0); iswspace(0); towlower(0); towupper(0); iswalnum(0)],
1052                         mutt_cv_wc_funcs=yes))
1053         wc_funcs=$mutt_cv_wc_funcs
1054 fi
1055
1056 if test $wc_funcs = yes; then
1057         AC_DEFINE(HAVE_WC_FUNCS,1,[ Define if you are using the system's wchar_t functions. ])
1058 fi
1059
1060 AC_CACHE_CHECK([for nl_langinfo and CODESET], mutt_cv_langinfo_codeset,
1061   [AC_TRY_LINK([#include <langinfo.h>],
1062     [char* cs = nl_langinfo(CODESET);],
1063     mutt_cv_langinfo_codeset=yes,
1064     mutt_cv_langinfo_codeset=no)])
1065 if test $mutt_cv_langinfo_codeset = yes; then
1066   AC_DEFINE(HAVE_LANGINFO_CODESET,1,[ Define if you have <langinfo.h> and nl_langinfo(CODESET). ])
1067 fi
1068
1069 AC_CACHE_CHECK([for nl_langinfo and YESEXPR], mutt_cv_langinfo_yesexpr,
1070   [AC_TRY_LINK([#include <langinfo.h>],
1071     [char* cs = nl_langinfo(YESEXPR);],
1072     mutt_cv_langinfo_yesexpr=yes,
1073     mutt_cv_langinfo_yesexpr=no)])
1074 if test $mutt_cv_langinfo_yesexpr = yes; then
1075   AC_DEFINE(HAVE_LANGINFO_YESEXPR,1,[ Define if you have <langinfo.h> and nl_langinfo(YESEXPR). ])
1076 fi
1077
1078 dnl -- libesmtp --
1079 MUTT_AM_LIBESMTP
1080 if test x$use_libesmtp = xyes; then
1081     CFLAGS="$CFLAGS $mutt_libesmtp_cflags"
1082     MUTTLIBS="$MUTTLIBS $mutt_libesmtp_libs"
1083     MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_libesmtp.o"
1084
1085     AC_DEFINE(USE_LIBESMTP,
1086               1,
1087               [Define to enable the use of libesmtp])
1088 fi
1089 dnl -- end libesmtp --
1090
1091 dnl -- sgml tools --
1092
1093 dnl Documentation tools
1094 have_openjade="no"
1095 AC_PATH_PROG([OSPCAT], [ospcat], [none])
1096 if test "$OSPCAT" != "none"
1097 then
1098   AC_MSG_CHECKING([for openjade docbook stylesheets])
1099   dslosfile=`ospcat --public-id="-//Norman Walsh//DOCUMENT DocBook Print Stylesheet//EN"`
1100   DSLROOT=`echo $dslosfile | sed -n -e "s/.*SOIBASE='\(@<:@^'@:>@*\)\/catalog'.*/\1/p"`
1101   # ospcat may spit out an absolute path without an SOIBASE
1102   if test -z "$DSLROOT"
1103   then
1104     DSLROOT=`echo $dslosfile | sed -e 's|<OSFILE>\(.*\)/print/docbook.dsl|\1|'`
1105   fi
1106   if test -f $DSLROOT/print/docbook.dsl
1107   then
1108     AC_MSG_RESULT([in $DSLROOT])
1109     have_openjade="yes"
1110   else
1111     AC_MSG_RESULT([not found: PDF documentation will not be built.])
1112   fi
1113 fi
1114 AC_SUBST(DSLROOT)
1115
1116 AC_MSG_CHECKING([for lynx])
1117 AC_PATH_PROG([HTML2TXT_CMD], [lynx], [none])
1118 if test x"$HTML2TXT_CMD" = x"none"
1119 then
1120   AC_MSG_CHECKING([for w3m])
1121   AC_PATH_PROG([HTML2TXT_CMD], [w3m], [none])
1122 fi
1123 if test x"$HTML2TXT_CMD" = x"none"
1124 then
1125   AC_MSG_CHECKING([for elinks])
1126   AC_PATH_PROG([HTML2TXT_CMD], [elinks], [none])
1127 fi
1128 case "$HTML2TXT_CMD" in
1129   *elinks*)
1130     HTML2TXT_CMD="$HTML2TXT_CMD -dump -no-numbering -no-references \$^ > \$@"
1131     ;;
1132   *lynx*)
1133     HTML2TXT_CMD="$HTML2TXT_CMD -dump -nolist -with_backspaces \$^ > \$@"
1134     ;;
1135   *w3m*)
1136     HTML2TXT_CMD="$HTML2TXT_CMD -dump \$^ > \$@"
1137     ;;
1138   *)
1139     HTML2TXT_CMD="true"
1140     ;;
1141 esac
1142 AC_SUBST(HTML2TXT_CMD)
1143
1144 AC_MSG_CHECKING([for tidy])
1145 AC_PATH_PROG([HTMLCLEAN_CMD], [tidy], [none])
1146
1147 if test x"$HTMLCLEAN_CMD" != x"none"
1148 then
1149   HTMLCLEAN_CMD="$HTMLCLEAN_CMD -q -i -m -asxml -utf8 "
1150 else
1151   HTMLCLEAN_CMD="echo "
1152 fi
1153 AC_SUBST(HTMLCLEAN_CMD)
1154
1155 AC_OUTPUT(Makefile intl/Makefile m4/Makefile
1156         po/Makefile.in doc/Makefile contrib/Makefile
1157         muttbug.sh
1158         lib-lib/Makefile
1159         lib-mime/Makefile
1160         lib-hash/Makefile
1161         lib/Makefile
1162         imap/Makefile
1163         pop/Makefile
1164         nntp/Makefile
1165         Muttngrc.head
1166         doc/instdoc.sh)