configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl !!! WHEN ADDING NEW CONFIGURE TESTS, PLEASE ADD CODE TO MAIN.C !!!
   4 dnl !!! TO DUMP THEIR RESULTS WHEN MUTT -V IS CALLED            !!!
   5
   6 AC_PREREQ([2.50])
   7 AC_INIT([mutt.h])
   8 AM_CONFIG_HEADER(config.h)
   9
  10 mutt_cv_version=`cat "$srcdir/VERSION.in"`
  11
  12 AM_INIT_AUTOMAKE(muttng, $mutt_cv_version)
  13 AC_SUBST([CONFIGURE_DEPENDENCIES], ['$(top_srcdir)/VERSION.in'])
  14
  15 AC_GNU_SOURCE
  16
  17 ALL_LINGUAS="de ru it es uk fr pl nl cs id sk ko el zh_TW zh_CN pt_BR eo gl sv da lt tr ja hu et ca bg"
  18
  19 AC_CANONICAL_HOST
  20
  21 AC_MSG_CHECKING([for prefix])
  22 if test x$prefix = xNONE; then
  23     mutt_cv_prefix=$ac_default_prefix
  24 else
  25     mutt_cv_prefix=$prefix
  26 fi
  27 AC_MSG_RESULT($mutt_cv_prefix)
  28
  29 AC_PROG_CC
  30 AC_ISC_POSIX
  31 AM_C_PROTOTYPES
  32 if test "x$U" != "x"; then
  33     AC_MSG_ERROR(Compiler not ANSI compliant)
  34 fi
  35 AC_PROG_CPP
  36 AC_PROG_MAKE_SET
  37 AC_PROG_INSTALL
  38 AC_PROG_RANLIB
  39 AC_CHECK_TOOL(AR, ar, ar)
  40
  41 AC_C_INLINE
  42 AC_C_CONST
  43
  44 AC_SYS_LARGEFILE
  45 AC_FUNC_FSEEKO
  46 AC_CHECK_SIZEOF(off_t)
  47
  48 AC_PATH_PROG(DBX, dbx, no)
  49 AC_PATH_PROG(GDB, gdb, no)
  50 AC_PATH_PROG(SDB, sdb, no)
  51
  52 if test $GDB != no ; then
  53     DEBUGGER=$GDB
  54 elif test $DBX != no ; then
  55     DEBUGGER=$DBX
  56 elif test $SDB != no ; then
  57     DEBUGGER=$SDB
  58 else
  59     DEBUGGER=no
  60 fi
  61
  62 AC_SUBST([DEBUGGER])
  63
  64 AH_TEMPLATE([sig_atomic_t],
  65             [Define to 'int' if <signal.h> doesn't define.])
  66 AH_TEMPLATE([HAVE_START_COLOR],
  67             [Define if you have start_color, as a function or macro.])
  68 AH_TEMPLATE([HAVE_TYPEAHEAD],
  69             [Define if you have typeahead, as a function or macro.])
  70 AH_TEMPLATE([HAVE_BKGDSET],
  71             [Define if you have bkgdset, as a function or macro.])
  72 AH_TEMPLATE([HAVE_CURS_SET],
  73             [Define if you have curs_set, as a function or macro.])
  74 AH_TEMPLATE([HAVE_META],
  75             [Define if you have meta, as a function or macro.])
  76 AH_TEMPLATE([HAVE_USE_DEFAULT_COLORS],
  77             [Define if you have use_default_colors, as a function or macro.])
  78 AH_TEMPLATE([HAVE_RESIZETERM],
  79             [Define if you have resizeterm, as a function or macro.])
  80 AH_TEMPLATE([SIG_ATOMIC_VOLATILE_T],
  81             [Some systems declare sig_atomic_t as volatile, some others -- no.
  82              This define will have value `sig_atomic_t' or
  83              `volatile sig_atomic_t' accordingly.])
  84 AH_TEMPLATE([ICONV_NONTRANS],
  85             [Define as 1 if iconv() only converts exactly and we should treat
  86              all return values other than (size_t)(-1) as equivalent.])
  87
  88 MUTT_C99_INTTYPES
  89
  90 dnl ---------------- sendmail ----------------
  91
  92 ac_aux_path_sendmail=/usr/sbin:/usr/lib
  93 AC_PATH_PROG(SENDMAIL, sendmail, /usr/sbin/sendmail, $PATH:$ac_aux_path_sendmail)
  94 AC_DEFINE_UNQUOTED(SENDMAIL,"$ac_cv_path_SENDMAIL",[ Where to find sendmail on your system. ])
  95
  96
  97 OPS='$(srcdir)/OPS'
  98
  99 dnl ---------------- gpgme ----------------
 100
 101     AC_ARG_ENABLE(gpgme, AC_HELP_STRING([--enable-gpgme], [Enable GPGME support]),
 102     [   if test x$enableval = xyes; then
 103             have_gpgme=yes
 104         fi
 105     ])
 106     AC_ARG_WITH(gpgme-prefix, AC_HELP_STRING([--with-gpgme-prefix=PFX], [prefix where GPGME is installed (optional)]),
 107     gpgme_config_prefix="$withval", gpgme_config_prefix="")
 108
 109     if test x$have_gpgme = xyes; then
 110         if test x$gpgme_config_prefix != x; then
 111             GPGME_CONFIG="$gpgme_config_prefix/bin/gpgme-config"
 112         else
 113             AC_PATH_PROG(GPGME_CONFIG, gpgme-config, no)
 114         fi
 115         if test "x$GPGME_CONFIG" = "xno"; then
 116             AC_MSG_ERROR([GPGME not found])
 117         else
 118             LIBGPGME_CFLAGS=`$GPGME_CONFIG --cflags`
 119             LIBGPGME_LIBS=`$GPGME_CONFIG --libs`
 120             MUTTLIBS="$MUTTLIBS $LIBGPGME_LIBS"
 121             MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS crypt-gpgme.o crypt-mod-pgp-gpgme.o crypt-mod-smime-gpgme.o"
 122             AC_DEFINE(CRYPT_BACKEND_GPGME, 1, [Defined, if GPGME support is enabled])
 123         fi
 124     fi
 125     AC_SUBST(LIBGPGME_CFLAGS)
 126     AC_SUBST(LIBGPGME_LIBS)
 127
 128 dnl ---------------- mixmaster ----------------
 129
 130     AC_ARG_WITH(mixmaster, AC_HELP_STRING([--with-mixmaster[=PATH]], [Include Mixmaster support]),
 131     [   if test -x "$withval" ; then
 132             MIXMASTER="$withval"
 133         else
 134             MIXMASTER="mixmaster"
 135         fi
 136         OPS="$OPS \$(srcdir)/OPS.MIX"
 137         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS remailer.o"
 138         AC_DEFINE_UNQUOTED(MIXMASTER,"$MIXMASTER", [ Where to find mixmaster on your system. ])
 139     ])
 140
 141 # We now require all OPS
 142 OPS="$OPS \$(srcdir)/OPS.PGP \$(srcdir)/OPS.SMIME \$(srcdir)/OPS.CRYPT "
 143 AC_SUBST([OPS])
 144
 145 AC_PATH_PROG(ISPELL, ispell, no)
 146 if test $ISPELL != no; then
 147     AC_DEFINE_UNQUOTED(ISPELL,"$ISPELL",[ Where to find ispell on your system. ])
 148 fi
 149
 150 AC_ARG_WITH(slang, AC_HELP_STRING([--with-slang[=DIR]], [Use S-Lang instead of ncurses]),
 151     [AC_CACHE_CHECK([if this is a BSD system], mutt_cv_bsdish,
 152         [AC_TRY_RUN([#include <sys/param.h>
 153
 154 main ()
 155 {
 156 #ifdef BSD
 157         exit (0);
 158 #else
 159         exit (1);
 160 #endif
 161 }],
 162         mutt_cv_bsdish=yes,
 163         mutt_cv_bsdish=no,
 164         mutt_cv_bsdish=no)])
 165
 166         AC_MSG_CHECKING(for S-Lang)
 167         if test $withval = yes; then
 168             if test -d $srcdir/../slang; then
 169                 mutt_cv_slang=$srcdir/../slang/src
 170                 CFLAGS="$CFLAGS -I${mutt_cv_slang}"
 171                 LDFLAGS="$LDFLAGS -L${mutt_cv_slang}/objs"
 172             else
 173                 if test -d $mutt_cv_prefix/include/slang; then
 174                     CFLAGS="$CFLAGS -I$mutt_cv_prefix/include/slang"
 175                 elif test -d /usr/include/slang; then
 176                     CFLAGS="$CFLAGS -I/usr/include/slang"
 177                 fi
 178                 mutt_cv_slang=yes
 179             fi
 180         else
 181             dnl ---Check to see if $withval is a source directory
 182             if test -f $withval/src/slang.h; then
 183                 mutt_cv_slang=$withval/src
 184                 CFLAGS="$CFLAGS -I${mutt_cv_slang}"
 185                 LDFLAGS="$LDFLAGS -L${mutt_cv_slang}/objs"
 186             else
 187                 dnl ---Must be installed somewhere
 188                 mutt_cv_slang=$withval
 189                 if test -d $withval/include/slang; then
 190                         CFLAGS="$CFLAGS -I${withval}/include/slang"
 191                 elif test -d $withval/include; then
 192                         CFLAGS="$CFLAGS -I${withval}/include"
 193                 fi
 194                 LDFLAGS="$LDFLAGS -L${withval}/lib"
 195             fi
 196         fi
 197         AC_MSG_RESULT($mutt_cv_slang)
 198         if test $mutt_cv_bsdish = yes; then
 199             AC_CHECK_LIB(termlib, main)
 200         fi
 201         AC_DEFINE(USE_SLANG_CURSES,1, [ Define if you compile with SLang instead of curses/ncurses. ])
 202         AC_DEFINE(HAVE_COLOR,1,[ Define if your curses library supports color. ])
 203         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS resize.o"
 204
 205         dnl --- now that we've found it, check the link
 206
 207         AC_CHECK_LIB(slang, SLtt_get_terminfo,
 208             [MUTTLIBS="$MUTTLIBS -lslang -lm"],
 209             [AC_MSG_ERROR(unable to compile.  check config.log)], -lm)
 210         ],
 211
 212         [   mutt_cv_curses=/usr
 213             AC_ARG_WITH(curses, AC_HELP_STRING([--with-curses=DIR], [Where ncurses is installed]),
 214             [   if test $withval != yes; then
 215                     mutt_cv_curses=$withval
 216                 fi
 217                 if test x$mutt_cv_curses != x/usr; then
 218                     LDFLAGS="-L${mutt_cv_curses}/lib $LDFLAGS"
 219                     CPPFLAGS="$CPPFLAGS -I${mutt_cv_curses}/include"
 220                 fi
 221             ])
 222
 223             AC_CHECK_FUNC(initscr,,[
 224             cf_ncurses="ncurses"
 225             for lib in ncursesw ncurses; do
 226                 AC_CHECK_LIB($lib, waddnwstr, [cf_ncurses="$lib"; break])
 227             done
 228             AC_CHECK_LIB($cf_ncurses, initscr,
 229                 [   MUTTLIBS="$MUTTLIBS -l$cf_ncurses"
 230                     if test x$mutt_cv_curses = x/usr -a -d /usr/include/ncurses; then
 231                         CPPFLAGS="$CPPFLAGS -I/usr/include/ncurses"
 232                     fi
 233
 234                     if test "$cf_ncurses" = ncursesw; then
 235                         AC_CHECK_HEADERS(ncurses/ncurses.h,[cf_cv_ncurses_header="ncurses/ncurses.h"])
 236                         AC_CHECK_HEADERS(ncursesw/ncurses.h,[cf_cv_ncurses_header="ncursesw/ncurses.h"])
 237                     else
 238                         AC_CHECK_HEADERS(ncurses.h,[cf_cv_ncurses_header="ncurses.h"])
 239                     fi
 240                 ],
 241                 [CF_CURSES_LIBS])
 242             ])
 243
 244             old_LIBS="$LIBS"
 245             LIBS="$LIBS $MUTTLIBS"
 246             CF_CHECK_FUNCDECLS([#include <${cf_cv_ncurses_header-curses.h}>],
 247                                [start_color typeahead bkgdset curs_set meta use_default_colors resizeterm])
 248             if test "$ac_cv_func_decl_start_color" = yes; then
 249                 AC_DEFINE(HAVE_COLOR,1,[ Define if your curses library supports color. ])
 250             fi
 251             if test "$ac_cv_func_decl_resizeterm" = yes; then
 252                 MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS resize.o"
 253             fi
 254             LIBS="$old_LIBS"
 255         ])
 256
 257 AC_HEADER_STDC
 258
 259 AC_CHECK_HEADERS(stdarg.h sys/ioctl.h ioctl.h sysexits.h)
 260 AC_CHECK_HEADERS(sys/time.h sys/resource.h)
 261 AC_CHECK_HEADERS(unix.h)
 262
 263 AC_CHECK_FUNCS(setrlimit getsid isctype)
 264
 265 AC_TYPE_SIGNAL
 266
 267 AC_MSG_CHECKING(for sig_atomic_t in signal.h)
 268 AC_EGREP_HEADER(sig_atomic_t,signal.h,
 269     [   ac_cv_type_sig_atomic_t=yes;
 270         AC_EGREP_HEADER(volatile.*sig_atomic_t,
 271                         signal.h,
 272                         [is_sig_atomic_t_volatile=yes; AC_MSG_RESULT([yes, volatile])],
 273                         [is_sig_atomic_t_volatile=no;  AC_MSG_RESULT([yes, non volatile])])
 274     ],
 275     [   AC_MSG_RESULT(no)
 276         AC_CHECK_TYPE(sig_atomic_t, int)
 277         is_sig_atomic_t_volatile=no
 278     ])
 279 if test $is_sig_atomic_t_volatile = 'yes'
 280 then
 281     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, sig_atomic_t)
 282 else
 283     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, [volatile sig_atomic_t])
 284 fi
 285
 286 AC_DECL_SYS_SIGLIST
 287
 288 AC_TYPE_PID_T
 289
 290 AC_CHECK_FUNCS(fgetpos memmove setegid srand48 strerror)
 291 AC_REPLACE_FUNCS(strcasecmp setenv)
 292 AC_CHECK_FUNCS(snprintf vsnprintf)
 293
 294 AC_CHECK_FUNC(getopt)
 295 if test $ac_cv_func_getopt = yes; then
 296     AC_CHECK_HEADERS(getopt.h)
 297 fi
 298
 299 AC_ARG_WITH(regex, AC_HELP_STRING([--with-regex], [Use the GNU regex library]),
 300         [mutt_cv_regex=yes],
 301         [AC_CHECK_FUNCS(regcomp, mutt_cv_regex=no, mutt_cv_regex=yes)])
 302
 303 if test $mutt_cv_regex = no ; then
 304     AC_CACHE_CHECK([whether your system's regexp library is completely broken],
 305         [mutt_cv_regex_broken],
 306         AC_TRY_RUN([
 307 #include <unistd.h>
 308 #include <regex.h>
 309 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
 310         mutt_cv_regex_broken=no, mutt_cv_regex_broken=yes, mutt_cv_regex_broken=yes))
 311     if test $mutt_cv_regex_broken = yes ; then
 312         echo "Using the included GNU regex instead." >&AC_FD_MSG
 313         mutt_cv_regex=yes
 314     fi
 315 fi
 316
 317 if test $mutt_cv_regex = yes; then
 318     AC_DEFINE(USE_GNU_REGEX,1,[ Define if you want to use the included regex.c. ])
 319     LIBOBJS="$LIBOBJS regex.o"
 320 fi
 321
 322
 323 AC_ARG_WITH(homespool,
 324             AC_HELP_STRING([--with-homespool[=FILE]],
 325                            [File in user's directory where new mail is spooled]),
 326                            with_homespool=${withval})
 327 if test x$with_homespool != x; then
 328     if test $with_homespool = yes; then
 329             with_homespool=mailbox
 330     fi
 331     AC_DEFINE_UNQUOTED(MAILPATH,"$with_homespool",[ Where new mail is spooled. ])
 332     AC_DEFINE(HOMESPOOL,1,
 333     [   Is mail spooled to the user's home directory?  If defined,
 334         MAILPATH should be set to the filename of the spool mailbox
 335         relative the the home directory.
 336         use: configure --with-homespool=FILE
 337     ])
 338     AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 339     mutt_cv_setgid=no
 340 else
 341     AC_ARG_WITH(mailpath, AC_HELP_STRING([--with-mailpath=DIR], [Directory where spool mailboxes are located]),
 342         [mutt_cv_mailpath=$withval],
 343         [ AC_CACHE_CHECK(where new mail is stored, mutt_cv_mailpath,
 344             [mutt_cv_mailpath=no
 345             if test -d /var/mail; then
 346                 mutt_cv_mailpath=/var/mail
 347             elif test -d /var/spool/mail; then
 348                 mutt_cv_mailpath=/var/spool/mail
 349             elif test -d /usr/spool/mail; then
 350                 mutt_cv_mailpath=/usr/spool/mail
 351             elif test -d /usr/mail; then
 352                 mutt_cv_mailpath=/usr/mail
 353             fi])
 354         ])
 355     if test "$mutt_cv_mailpath" = no; then
 356         AC_MSG_ERROR("Could not determine where new mail is stored.")
 357     fi
 358     AC_DEFINE_UNQUOTED(MAILPATH,"$mutt_cv_mailpath",[ Where new mail is spooled. ])
 359
 360     AC_CACHE_CHECK(if $mutt_cv_mailpath is world writable, mutt_cv_worldwrite, [AC_TRY_RUN([#include <sys/types.h>
 361 #include <sys/stat.h>
 362
 363 int main (int argc, char **argv)
 364 {
 365         struct stat s;
 366
 367         stat ("$mutt_cv_mailpath", &s);
 368         if (s.st_mode & S_IWOTH) exit (0);
 369         exit (1);
 370 }], mutt_cv_worldwrite=yes, mutt_cv_worldwrite=no, mutt_cv_worldwrite=no)])
 371
 372         mutt_cv_setgid=no
 373         if test $mutt_cv_worldwrite = yes; then
 374                 AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 375         else
 376
 377                 AC_CACHE_CHECK(if $mutt_cv_mailpath is group writable, mutt_cv_groupwrite, [AC_TRY_RUN([#include <sys/types.h>
 378 #include <sys/stat.h>
 379
 380 int main (int argc, char **argv)
 381 {
 382         struct stat s;
 383
 384         stat ("$mutt_cv_mailpath", &s);
 385         if (s.st_mode & S_IWGRP) exit (0);
 386         exit (1);
 387 }], mutt_cv_groupwrite=yes, mutt_cv_groupwrite=no, mutt_cv_groupwrite=no)])
 388
 389         if test $mutt_cv_groupwrite = yes; then
 390             AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 391             AC_DEFINE(USE_SETGID,1,[ Define if mutt should run setgid "mail". ])
 392             mutt_cv_setgid=yes
 393         fi
 394     fi
 395 fi
 396
 397 AC_MSG_CHECKING(where to put the documentation)
 398 AC_ARG_WITH(docdir, AC_HELP_STRING([--with-docdir=PATH], [Specify where to put the documentation]),
 399         [mutt_cv_docdir=$withval],
 400         [mutt_cv_docdir="${prefix}/doc/muttng"])
 401 AC_MSG_RESULT($mutt_cv_docdir)
 402
 403 docdir=$mutt_cv_docdir
 404 AC_SUBST(docdir)
 405
 406 if test x$mutt_cv_setgid = xyes; then
 407     DOTLOCK_GROUP='mail'
 408     DOTLOCK_PERMISSION=2755
 409 else
 410     DOTLOCK_GROUP=''
 411     DOTLOCK_PERMISSION=755
 412 fi
 413 AC_SUBST(DOTLOCK_GROUP)
 414 AC_SUBST(DOTLOCK_PERMISSION)
 415
 416 dnl -- socket dependencies --
 417
 418 AC_ARG_ENABLE(pop,  AC_HELP_STRING([--enable-pop], [Enable POP3 support]),
 419 [   if test x$enableval = xyes ; then
 420         AC_DEFINE(USE_POP,1,[ Define if you want support for the POP3 protocol. ])
 421         LIBPOP="-Lpop -lpop"
 422         LIBPOPDEPS="\$(top_srcdir)/pop/pop.h pop/libpop.a"
 423         need_pop="yes"
 424         need_md5="yes"
 425     fi
 426 ])
 427 AM_CONDITIONAL(BUILD_POP, test x$need_pop = xyes)
 428
 429 AC_ARG_ENABLE(imap, AC_HELP_STRING([--enable-imap], [Enable IMAP support]),
 430 [   if test x$enableval = xyes ; then
 431         AC_DEFINE(USE_IMAP,1,[ Define if you want support for the IMAP protocol. ])
 432         LIBIMAP="-Limap -limap"
 433         LIBIMAPDEPS="\$(top_srcdir)/imap/imap.h imap/libimap.a"
 434         need_imap="yes"
 435         need_md5="yes"
 436     fi
 437 ])
 438 AM_CONDITIONAL(BUILD_IMAP, test x$need_imap = xyes)
 439
 440 AC_ARG_ENABLE(nntp, [  --enable-nntp              Enable NNTP support],
 441 [   if test x$enableval = xyes ; then
 442         AC_DEFINE(USE_NNTP,1,[ Compiling with newsreading support with NNTP ])
 443         LIBNNTP="-Lnntp -lnntp"
 444         LIBNNTPDEPS="\$(top_srcdir)/nntp/nntp.h nntp/libnntp.a"
 445         need_nntp="yes"
 446     fi
 447 ])
 448 AM_CONDITIONAL(BUILD_NNTP, test x$need_nntp = xyes)
 449
 450 dnl -- end socket dependencies --
 451
 452 AC_MSG_CHECKING([for socklen_t])
 453 AC_EGREP_HEADER(socklen_t, sys/socket.h, AC_MSG_RESULT([yes]),
 454         AC_MSG_RESULT([no])
 455         AC_DEFINE(socklen_t,int, [ Define to 'int' if <sys/socket.h> doesn't have it. ]))
 456 AC_CHECK_FUNC(gethostent, , AC_CHECK_LIB(nsl, gethostent))
 457 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt))
 458 AC_CHECK_FUNCS(getaddrinfo)
 459
 460 dnl -- imap dependencies --
 461
 462 AC_ARG_WITH(gss, AC_HELP_STRING([--with-gss[=PFX]], [Compile in GSSAPI authentication for IMAP]),
 463     gss_prefix="$withval", gss_prefix="no")
 464 if test "$gss_prefix" != "no"
 465 then
 466   if test "$need_imap" = "yes"
 467   then
 468     MUTT_AM_PATH_GSSAPI(gss_prefix)
 469     AC_MSG_CHECKING(GSSAPI implementation)
 470     AC_MSG_RESULT($GSSAPI_IMPL)
 471     if test "$GSSAPI_IMPL" = "none"
 472     then
 473       AC_CACHE_SAVE
 474       AC_MSG_RESULT([GSSAPI libraries not found])
 475     fi
 476     if test "$GSSAPI_IMPL" = "Heimdal"
 477     then
 478       AC_DEFINE(HAVE_HEIMDAL,1,[ Define if your GSSAPI implementation is Heimdal ])
 479     fi
 480     CPPFLAGS="$CPPFLAGS $GSSAPI_CFLAGS"
 481     MUTTLIBS="$MUTTLIBS $GSSAPI_LIBS"
 482     AC_DEFINE(USE_GSS,1,[ Define if you have GSSAPI libraries available ])
 483     need_gss="yes"
 484   else
 485     AC_MSG_WARN([GSS was requested but IMAP is not enabled])
 486   fi
 487 fi
 488 AM_CONDITIONAL(USE_GSS, test x$need_gss = xyes)
 489
 490 dnl -- end imap dependencies --
 491
 492 AC_ARG_WITH(ssl, AC_HELP_STRING([--with-ssl[=PFX]], [Compile in SSL support for POP/IMAP]),
 493 [       if test "$with_ssl" != "no"
 494         then
 495           if test "$with_ssl" != "yes"
 496           then
 497            LDFLAGS="$LDFLAGS -L$withval/lib"
 498            CPPFLAGS="$CPPFLAGS -I$withval/include"
 499           fi
 500           saved_LIBS="$LIBS"
 501
 502           AC_CHECK_LIB(crypto, X509_new,, AC_MSG_ERROR([Unable to find SSL library]))
 503           AC_CHECK_LIB(ssl, SSL_new,, AC_MSG_ERROR([Unable to find SSL library]), -lcrypto)
 504
 505           AC_CHECK_FUNCS(RAND_status RAND_egd)
 506
 507           AC_DEFINE(USE_SSL,1,[ Define if you want support for SSL. ])
 508           LIBS="$saved_LIBS"
 509           MUTTLIBS="$MUTTLIBS -lssl -lcrypto"
 510           MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_ssl.o"
 511           need_ssl=yes
 512
 513         fi
 514 ])
 515
 516 AC_ARG_WITH([gnutls], AC_HELP_STRING([--with-gnutls[=PFX]], [Enable SSL support using gnutls]),
 517     [gnutls_prefix="$withval"], [gnutls_prefix="no"])
 518 if test "$gnutls_prefix" != "no"
 519 then
 520   if test x"$need_ssl" = x"yes"
 521   then
 522     AC_MSG_ERROR([Only either OpenSSL or GNUTLS may be used])
 523   fi
 524   MUTT_AM_PATH_GNUTLS([$gnutls_prefix],
 525     [dnl GNUTLS found
 526     CPPFLAGS="$CPPFLAGS $LIBGNUTLS_CFLAGS"
 527     MUTTLIBS="$MUTTLIBS $LIBGNUTLS_LIBS"
 528     AC_DEFINE(USE_GNUTLS, 1, [Define if you want support for SSL via the gnutls library.])
 529
 530     MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_ssl_gnutls.o"
 531     need_ssl=yes],
 532     [dnl GNUTLS not found
 533       AC_MSG_ERROR([could not find libgnutls])
 534     ])
 535 fi
 536
 537 AM_CONDITIONAL(USE_SSL, test x$need_ssl = xyes)
 538
 539 AC_ARG_WITH(sasl2, AC_HELP_STRING([--with-sasl2[=PFX]], [Use Cyrus SASL library version 2 for POP/IMAP authentication]),
 540         [
 541         if test "$with_sasl2" != "no" -a "$need_imap" != "yes" -a "$need_pop" != "yes"
 542         then
 543           AC_MSG_ERROR([SASL2 support is only useful with POP or IMAP support])
 544         fi
 545
 546         if test "$with_sasl2" != "no"
 547         then
 548           if test "$with_sasl2" != "yes"
 549           then
 550             CPPFLAGS="$CPPFLAGS -I$with_sasl2/include"
 551             LDFLAGS="$LDFLAGS -L$with_sasl2/lib"
 552           fi
 553
 554           saved_LIBS="$LIBS"
 555
 556           AC_CHECK_LIB(sasl2, sasl_client_init,,
 557             AC_MSG_ERROR([could not find libsasl2]),)
 558
 559           MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_sasl.o"
 560           MUTTLIBS="$MUTTLIBS -lsasl2"
 561           LIBS="$saved_LIBS"
 562           AC_DEFINE(USE_SASL,1,
 563                   [ Define if want to use version 2 of the Cyrus SASL library. ])
 564           need_sasl=yes
 565         fi
 566         ])
 567 AM_CONDITIONAL(USE_SASL, test x$need_sasl = xyes)
 568
 569 AC_ARG_WITH(idn, AC_HELP_STRING([--with-idn=[PFX]], [Use GNU libidn for domain names]),
 570                  [
 571                   if test "$with_idn" != "no" ; then
 572                         if test "$with_idn" != "yes" ; then
 573                            CPPFLAGS="$CPPFLAGS -I$with_idn/include"
 574                            LDFLAGS="$LDFLAGS -L$with_idn/lib"
 575                         fi
 576                   fi
 577                  ]
 578 )
 579
 580 if test "x$with_idn" != "xno"; then
 581     AC_CHECK_LIB(idn, stringprep_check_version)
 582     AC_CHECK_FUNCS(idna_to_unicode_utf8_from_utf8 idna_to_unicode_8z8z)
 583     AC_CHECK_FUNCS(idna_to_ascii_from_utf8 idna_to_ascii_8z)
 584     AC_CHECK_FUNCS(idna_to_ascii_lz idna_to_ascii_from_locale)
 585 fi
 586
 587 dnl -- end socket --
 588
 589 AC_ARG_ENABLE(debug, AC_HELP_STRING([--enable-debug], [Enable debugging support]),
 590     [ if test x$enableval = xyes ; then
 591             AC_DEFINE(DEBUG,1,[ Define to enable debugging info. ])
 592       fi
 593      ])
 594
 595 AC_ARG_ENABLE(flock, AC_HELP_STRING([--enable-flock], [Use flock() to lock files]),
 596         [if test $enableval = yes; then
 597                 AC_DEFINE(USE_FLOCK,1, [ Define to use flock() to lock mailboxes. ])
 598         fi])
 599
 600 mutt_cv_fcntl=yes
 601 AC_ARG_ENABLE(fcntl, AC_HELP_STRING([--disable-fcntl], [Do NOT use fcntl() to lock files]),
 602         [if test $enableval = no; then mutt_cv_fcntl=no; fi])
 603
 604 if test $mutt_cv_fcntl = yes; then
 605         AC_DEFINE(USE_FCNTL,1, [ Define to use fcntl() to lock folders. ])
 606 fi
 607
 608 AC_MSG_CHECKING(whether struct dirent defines d_ino)
 609 ac_cv_dirent_d_ino=no
 610 AC_TRY_LINK([#include <dirent.h>],[struct dirent dp; (void)dp.d_ino],[ac_cv_dirent_d_ino=yes])
 611 if test x$ac_cv_dirent_d_ino = xyes ; then
 612   AC_DEFINE(HAVE_DIRENT_D_INO,1,
 613             [Define to 1 if your system has the dirent::d_ino member])
 614 fi
 615 AC_MSG_RESULT($ac_cv_dirent_d_ino)
 616
 617 AC_ARG_ENABLE(buffy-size, AC_HELP_STRING([--enable-buffy-size], [Use file size attribute instead of access time]),
 618         [if test x$enableval = xyes; then
 619                 AC_DEFINE(BUFFY_SIZE,1,[ Define to enable the "buffy_size" feature. ])
 620         fi])
 621
 622 dnl -- start cache --
 623 AC_ARG_ENABLE(hcache, AC_HELP_STRING([--enable-hcache], [Enable header caching]),
 624 [if test x$enableval = xyes; then
 625     AC_DEFINE(USE_HCACHE, 1, [Enable header caching])
 626
 627     OLDCPPFLAGS="$CPPFLAGS"
 628     OLDLIBS="$LIBS"
 629
 630     need_md5="yes"
 631
 632     ac_prefer_qdbm=yes
 633     AC_ARG_WITH(qdbm, AC_HELP_STRING([--without-qdbm], [Don't use qdbm even if it is available]),
 634         ac_prefer_qdbm=$withval)
 635     if test x$ac_prefer_qdbm != xno; then
 636         ac_cv_vlopen=no
 637         QDBM_DIRS="$mutt_cv_prefix /usr/local /usr"
 638         AC_MSG_CHECKING([for vlopen])
 639         for d in $QDBM_DIRS; do
 640           if test x$ac_cv_vlopen = xno && test -d "$d/include" && test -d "$d/lib"; then
 641             QDBM_INC="-I$d/include"
 642             QDBM_LIB="-L$d/lib"
 643             CPPFLAGS="$OLDCPPFLAGS $QDBM_INC"
 644             LIBS="$OLDLIBS $QDBM_LIB -lqdbm"
 645             AC_TRY_LINK([#include <villa.h>],[vlopen(0,0,0);],[ac_cv_vlopen=yes])
 646           fi
 647         done
 648         if test x$ac_cv_vlopen = xyes; then
 649           AC_MSG_RESULT(yes)
 650         else
 651           AC_MSG_RESULT(no)
 652         fi
 653     fi
 654
 655     ac_prefer_gdbm=yes
 656     AC_ARG_WITH(gdbm, AC_HELP_STRING([--without-gdbm], [Don't use gdbm even if it is available]),
 657         ac_prefer_gdbm=$withval)
 658     if test x$ac_prefer_gdbm != xno -a x$ac_cv_vlopen != xyes; then
 659         ac_cv_gdbmopen=no
 660         GDBM_DIRS="$mutt_cv_prefix /usr/local /usr"
 661         AC_MSG_CHECKING([for gdbm_open])
 662         for d in $GDBM_DIRS; do
 663           if test x$ac_cv_gdbmopen = xno && test -d "$d/include" && test -d "$d/lib"; then
 664             GDBM_INC="-I$d/include"
 665             GDBM_LIB="-L$d/lib"
 666             CPPFLAGS="$OLDCPPFLAGS $GDBM_INC"
 667             LIBS="$OLDLIBS $GDBM_LIB -lgdbm"
 668             AC_TRY_LINK([#include <gdbm.h>],[gdbm_open(0,0,0,0,0);],[ac_cv_gdbmopen=yes])
 669           fi
 670         done
 671         if test x$ac_cv_gdbmopen = xyes; then
 672           AC_MSG_RESULT(yes)
 673         else
 674           AC_MSG_RESULT(no)
 675         fi
 676     fi
 677
 678     ac_bdb_prefix=yes
 679     AC_ARG_WITH(bdb, AC_HELP_STRING([--with-bdb[=DIR]], [Use BerkeleyDB4 if gdbm is not available ]),
 680         ac_bdb_prefix=$withval)
 681     if test x$ac_bdb_prefix != xno -a x$ac_cv_gdbmopen != xyes -a x$ac_cv_vlopen != xyes; then
 682         test x$ac_bdb_prefix = xyes && ac_bdb_prefix="$mutt_cv_prefix /opt/csw/bdb4 /opt /usr/local /usr"
 683         for d in $ac_bdb_prefix; do
 684             bdbpfx="$bdbpfx $d"
 685             for v in BerkeleyDB.4.3 BerkeleyDB.4.2 BerkeleyDB.4.1; do
 686                 bdbpfx="$bdbpfx $d/$v"
 687             done
 688         done
 689         BDB_VERSIONS="db-4 db4 db-4.3 db4.3 db43 db-4.2 db4.2 db42 db-4.1 db4.1 db41 db ''"
 690         AC_MSG_CHECKING([for BerkeleyDB > 4.0])
 691         for d in $bdbpfx; do
 692             BDB_INCLUDE_DIR=""
 693             BDB_LIB_DIR=""
 694             for v in / $BDB_VERSIONS; do
 695                 if test -r "$d/include/$v/db.h"; then
 696                     BDB_INCLUDE_DIR="$d/include/$v"
 697                     if test -d "$d/lib/$v"; then
 698                         BDB_LIB_DIR="$d/lib/$v"
 699                         for l in `echo $BDB_VERSIONS`; do
 700                             CPPFLAGS="-I$BDB_INCLUDE_DIR $OLDCPPFLAGS"
 701                             LIBS="$OLDLIBS -L$BDB_LIB_DIR -l$l"
 702                             AC_TRY_LINK([
 703                                 #include <stdlib.h>
 704                                 #include <db.h>
 705                             ],[
 706                                 DB *db = NULL;
 707                                 db->open(db,NULL,NULL,NULL,0,0,0);
 708                             ],[
 709                                 ac_cv_dbcreate=yes
 710                                 BDB_LIB="$l"
 711                                 break
 712                             ])
 713                         done
 714                         test x$ac_cv_dbcreate = xyes && break
 715                     fi
 716                 fi
 717             done
 718             test x$BDB_LIB != x && break
 719         done
 720         if test x$ac_cv_dbcreate = xyes; then
 721             AC_MSG_RESULT(yes)
 722         else
 723             AC_MSG_RESULT(no)
 724         fi
 725     fi
 726
 727     if test x$ac_cv_vlopen = xyes; then
 728         CPPFLAGS="$OLDCPPFLAGS $QDBM_INC"
 729         LIBS="$OLDLIBS $QDBM_LIB -lqdbm"
 730         AC_DEFINE(HAVE_QDBM, 1, [QDBM Support])
 731     elif test x$ac_cv_gdbmopen = xyes; then
 732         CPPFLAGS="$OLDCPPFLAGS $GDBM_INC"
 733         LIBS="$OLDLIBS $GDBM_LIB -lgdbm";
 734         AC_DEFINE(HAVE_GDBM, 1, [GDBM Support])
 735     elif test x$ac_cv_dbcreate = xyes; then
 736         CPPFLAGS="-I$BDB_INCLUDE_DIR $OLDCPPFLAGS"
 737         LIBS="$OLDLIBS -L$BDB_LIB_DIR -l$BDB_LIB"
 738         AC_DEFINE(HAVE_DB4, 1, [Sleepycat DB4 Support])
 739     else
 740         AC_MSG_ERROR([You need one of: QDBM, GDBM or Sleepycat DB4 for --enable-hcache])
 741     fi
 742 fi])
 743 dnl -- end cache --
 744
 745 AC_SUBST(MUTTLIBS)
 746 AC_SUBST(MUTT_LIB_OBJECTS)
 747 AC_SUBST(LIBIMAP)
 748 AC_SUBST(LIBIMAPDEPS)
 749 AC_SUBST(LIBPOP)
 750 AC_SUBST(LIBPOPDEPS)
 751 AC_SUBST(LIBNNTP)
 752 AC_SUBST(LIBNNTPDEPS)
 753
 754 dnl -- iconv/gettext --
 755
 756 AC_ARG_ENABLE(iconv, AC_HELP_STRING([--disable-iconv], [Disable iconv support]),
 757         [if test x$enableval = xno ; then
 758                 am_cv_func_iconv=no
 759         fi
 760 ])
 761
 762 AM_GNU_GETTEXT
 763
 764 if test "$am_cv_func_iconv" != "yes"
 765 then
 766   AC_MSG_WARN([Configuring without iconv support. See INSTALL for details])
 767 else
 768
 769 AC_CHECK_HEADERS(iconv.h,
 770         [AC_MSG_CHECKING(whether iconv.h defines iconv_t)
 771          AC_EGREP_HEADER([typedef.*iconv_t],iconv.h,
 772                 [AC_MSG_RESULT(yes)
 773                  AC_DEFINE(HAVE_ICONV_T_DEF, 1,
 774                         [Define if <iconv.h> defines iconv_t.])],
 775                  AC_MSG_RESULT(no))])
 776
 777 dnl (1) Some implementations of iconv won't convert from UTF-8 to UTF-8.
 778 dnl (2) In glibc-2.1.2 and earlier there is a bug that messes up ob and
 779 dnl     obl when args 2 and 3 are 0 (fixed in glibc-2.1.3).
 780 AC_CACHE_CHECK([whether this iconv is good enough], mutt_cv_iconv_good,
 781         mutt_save_LIBS="$LIBS"
 782         LIBS="$LIBS $LIBICONV"
 783         AC_TRY_RUN([
 784 #include <iconv.h>
 785 int main()
 786 {
 787   iconv_t cd;
 788 changequote(, )dnl
 789   char buf[4];
 790 changequote([, ])dnl
 791   char *ob;
 792   size_t obl;
 793   ob = buf, obl = sizeof(buf);
 794   return ((cd = iconv_open("UTF-8", "UTF-8")) != (iconv_t)(-1) &&
 795           (iconv(cd, 0, 0, &ob, &obl) ||
 796            !(ob == buf && obl == sizeof(buf)) ||
 797            iconv_close(cd)));
 798 }
 799                 ],
 800                 mutt_cv_iconv_good=yes,
 801                 mutt_cv_iconv_good=no,
 802                 mutt_cv_iconv_good=yes)
 803         LIBS="$mutt_save_LIBS")
 804 if test "$mutt_cv_iconv_good" = no; then
 805   AC_MSG_ERROR(Try using libiconv instead)
 806 fi
 807
 808 dnl This is to detect implementations such as the one in glibc-2.1,
 809 dnl which always convert exactly but return the number of characters
 810 dnl converted instead of the number converted inexactly.
 811 AC_CACHE_CHECK([whether iconv is non-transcribing], mutt_cv_iconv_nontrans,
 812         mutt_save_LIBS="$LIBS"
 813         LIBS="$LIBS $LIBICONV"
 814         AC_TRY_RUN([
 815 #include <iconv.h>
 816 #include <string.h>
 817 int main()
 818 {
 819   iconv_t cd;
 820   const char *ib;
 821   char *ob;
 822   size_t ibl, obl;
 823   const char *s = "\304\211";
 824 changequote(, )dnl
 825   char t[3];
 826 changequote([, ])dnl
 827   ib = s, ibl = 2, ob = t, obl = 3;
 828   return ((cd = iconv_open("UTF-8", "UTF-8")) == (iconv_t)(-1) ||
 829           iconv(cd, &ib, &ibl, &ob, &obl));
 830 }
 831                 ],
 832                 mutt_cv_iconv_nontrans=no,
 833                 mutt_cv_iconv_nontrans=yes,
 834                 mutt_cv_iconv_nontrans=no)
 835         LIBS="$mutt_save_LIBS")
 836 if test "$mutt_cv_iconv_nontrans" = yes; then
 837   AC_DEFINE(ICONV_NONTRANS, 1)
 838 else
 839   AC_DEFINE(ICONV_NONTRANS, 0)
 840 fi
 841
 842 CPPFLAGS="$CPPFLAGS -I\$(top_srcdir)/intl"
 843
 844 if test "$BUILD_INCLUDED_LIBINTL" = "yes"; then
 845   AC_DEFINE(HAVE_BIND_TEXTDOMAIN_CODESET,1,
 846           [ Define if your gettext has bind_textdomain_codeset. ])
 847 else
 848   AC_CHECK_FUNCS(bind_textdomain_codeset)
 849 fi
 850
 851 fi # libiconv
 852
 853 dnl -- locales --
 854
 855 AC_CHECK_HEADERS(wchar.h)
 856
 857 AC_CACHE_CHECK([for wchar_t], mutt_cv_wchar_t,
 858         AC_TRY_COMPILE([
 859 #include <stddef.h>
 860 #include <stdlib.h>
 861 #ifdef HAVE_WCHAR_H
 862 #include <wchar.h>
 863 #endif
 864                 ],
 865                 [ wchar_t wc; return 0; ],
 866                 mutt_cv_wchar_t=yes,
 867                 mutt_cv_wchar_t=no))
 868
 869 if test "$mutt_cv_wchar_t" = no; then
 870         AC_DEFINE(wchar_t,int,[ Define to 'int' if system headers don't define. ])
 871 fi
 872
 873 AC_CACHE_CHECK([for wint_t], mutt_cv_wint_t,
 874         AC_TRY_COMPILE([
 875 #include <stddef.h>
 876 #include <stdlib.h>
 877 #ifdef HAVE_WCHAR_H
 878 #include <wchar.h>
 879 #endif
 880                 ],
 881                 [ wint_t wc; return 0; ],
 882                 mutt_cv_wint_t=yes,
 883                 mutt_cv_wint_t=no))
 884
 885 if test "$mutt_cv_wint_t" = no; then
 886         AC_DEFINE(wint_t,int,[ Define to 'int' if system headers don't define. ])
 887 fi
 888
 889 AC_CHECK_HEADERS(wctype.h)
 890 AC_CHECK_FUNCS(iswalnum iswalpha  iswcntrl iswdigit)
 891 AC_CHECK_FUNCS(iswgraph iswlower iswprint iswpunct iswspace iswupper)
 892 AC_CHECK_FUNCS(iswxdigit towupper towlower)
 893
 894 AC_CACHE_CHECK([for mbstate_t], mutt_cv_mbstate_t,
 895         AC_TRY_COMPILE([
 896 #include <stddef.h>
 897 #include <stdlib.h>
 898 #ifdef HAVE_WCHAR_H
 899 #include <wchar.h>
 900 #endif
 901                 ],
 902                 [ mbstate_t s; return 0; ],
 903                 mutt_cv_mbstate_t=yes,
 904                 mutt_cv_mbstate_t=no))
 905
 906 if test "$mutt_cv_mbstate_t" = no; then
 907         AC_DEFINE(mbstate_t,int,[ Define to 'int' if system headers don't define. ])
 908 fi
 909
 910 wc_funcs=maybe
 911 AC_ARG_WITH(wc-funcs, AC_HELP_STRING([--without-wc-funcs], [Do not use the system's wchar_t functions]),
 912         wc_funcs=$withval)
 913
 914 if test "$wc_funcs" != yes -a "$wc_funcs" != no; then
 915         AC_CACHE_CHECK([for wchar_t functions], mutt_cv_wc_funcs,
 916                 mutt_cv_wc_funcs=no
 917                 AC_TRY_LINK([
 918 #define _XOPEN_SOURCE 1
 919 #include <stddef.h>
 920 #include <stdlib.h>
 921 #ifdef HAVE_WCTYPE_H
 922 #include <wctype.h>
 923 #endif
 924 #ifdef HAVE_WCHAR_H
 925 #include <wchar.h>
 926 #endif],
 927                         [mbrtowc(0, 0, 0, 0); wctomb(0, 0); wcwidth(0);
 928         iswprint(0); iswspace(0); towlower(0); towupper(0); iswalnum(0)],
 929                         mutt_cv_wc_funcs=yes))
 930         wc_funcs=$mutt_cv_wc_funcs
 931 fi
 932
 933 if test $wc_funcs = yes; then
 934         AC_DEFINE(HAVE_WC_FUNCS,1,[ Define if you are using the system's wchar_t functions. ])
 935 fi
 936
 937 AC_CACHE_CHECK([for nl_langinfo and CODESET], mutt_cv_langinfo_codeset,
 938   [AC_TRY_LINK([#include <langinfo.h>],
 939     [char* cs = nl_langinfo(CODESET);],
 940     mutt_cv_langinfo_codeset=yes,
 941     mutt_cv_langinfo_codeset=no)])
 942 if test $mutt_cv_langinfo_codeset = yes; then
 943   AC_DEFINE(HAVE_LANGINFO_CODESET,1,[ Define if you have <langinfo.h> and nl_langinfo(CODESET). ])
 944 fi
 945
 946 AC_CACHE_CHECK([for nl_langinfo and YESEXPR], mutt_cv_langinfo_yesexpr,
 947   [AC_TRY_LINK([#include <langinfo.h>],
 948     [char* cs = nl_langinfo(YESEXPR);],
 949     mutt_cv_langinfo_yesexpr=yes,
 950     mutt_cv_langinfo_yesexpr=no)])
 951 if test $mutt_cv_langinfo_yesexpr = yes; then
 952   AC_DEFINE(HAVE_LANGINFO_YESEXPR,1,[ Define if you have <langinfo.h> and nl_langinfo(YESEXPR). ])
 953 fi
 954
 955 dnl -- libesmtp --
 956 MUTT_AM_LIBESMTP
 957 if test x$use_libesmtp = xyes; then
 958     CFLAGS="$CFLAGS $mutt_libesmtp_cflags"
 959     MUTTLIBS="$MUTTLIBS $mutt_libesmtp_libs"
 960     MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_libesmtp.o"
 961
 962     AC_DEFINE(USE_LIBESMTP,
 963               1,
 964               [Define to enable the use of libesmtp])
 965 fi
 966 dnl -- end libesmtp --
 967
 968 dnl -- sgml tools --
 969
 970 dnl Documentation tools
 971 have_openjade="no"
 972 AC_PATH_PROG([OSPCAT], [ospcat], [none])
 973 if test "$OSPCAT" != "none"
 974 then
 975   AC_MSG_CHECKING([for openjade docbook stylesheets])
 976   dslosfile=`ospcat --public-id="-//Norman Walsh//DOCUMENT DocBook Print Stylesheet//EN"`
 977   DSLROOT=`echo $dslosfile | sed -n -e "s/.*SOIBASE='\(@<:@^'@:>@*\)\/catalog'.*/\1/p"`
 978   # ospcat may spit out an absolute path without an SOIBASE
 979   if test -z "$DSLROOT"
 980   then
 981     DSLROOT=`echo $dslosfile | sed -e 's|<OSFILE>\(.*\)/print/docbook.dsl|\1|'`
 982   fi
 983   if test -f $DSLROOT/print/docbook.dsl
 984   then
 985     AC_MSG_RESULT([in $DSLROOT])
 986     have_openjade="yes"
 987   else
 988     AC_MSG_RESULT([not found: PDF documentation will not be built.])
 989   fi
 990 fi
 991 AC_SUBST(DSLROOT)
 992
 993 AC_MSG_CHECKING([for lynx])
 994 AC_PATH_PROG([HTML2TXT_CMD], [lynx], [none])
 995 if test x"$HTML2TXT_CMD" = x"none"
 996 then
 997   AC_MSG_CHECKING([for w3m])
 998   AC_PATH_PROG([HTML2TXT_CMD], [w3m], [none])
 999 fi
1000 if test x"$HTML2TXT_CMD" = x"none"
1001 then
1002   AC_MSG_CHECKING([for elinks])
1003   AC_PATH_PROG([HTML2TXT_CMD], [elinks], [none])
1004 fi
1005 case "$HTML2TXT_CMD" in
1006   *elinks*)
1007     HTML2TXT_CMD="$HTML2TXT_CMD -dump -no-numbering -no-references \$^ > \$@"
1008     ;;
1009   *lynx*)
1010     HTML2TXT_CMD="$HTML2TXT_CMD -dump -nolist -with_backspaces \$^ > \$@"
1011     ;;
1012   *w3m*)
1013     HTML2TXT_CMD="$HTML2TXT_CMD -dump \$^ > \$@"
1014     ;;
1015   *)
1016     HTML2TXT_CMD="true"
1017     ;;
1018 esac
1019 AC_SUBST(HTML2TXT_CMD)
1020
1021 AC_MSG_CHECKING([for tidy])
1022 AC_PATH_PROG([HTMLCLEAN_CMD], [tidy], [none])
1023
1024 if test x"$HTMLCLEAN_CMD" != x"none"
1025 then
1026   HTMLCLEAN_CMD="$HTMLCLEAN_CMD -q -i -m -asxml -utf8 "
1027 else
1028   HTMLCLEAN_CMD="echo "
1029 fi
1030 AC_SUBST(HTMLCLEAN_CMD)
1031
1032 AC_OUTPUT(Makefile intl/Makefile m4/Makefile
1033         po/Makefile.in doc/Makefile contrib/Makefile
1034         muttbug.sh
1035         lib-lib/Makefile
1036         lib-mime/Makefile
1037         lib-hash/Makefile
1038         lib/Makefile
1039         imap/Makefile
1040         pop/Makefile
1041         nntp/Makefile
1042         Muttngrc.head
1043         doc/instdoc.sh)