configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl !!! WHEN ADDING NEW CONFIGURE TESTS, PLEASE ADD CODE TO MAIN.C !!!
   4 dnl !!! TO DUMP THEIR RESULTS WHEN MUTT -V IS CALLED            !!!
   5
   6 AC_PREREQ([2.50])
   7 AC_INIT([mutt.h])
   8 AM_CONFIG_HEADER(config.h)
   9
  10 mutt_cv_version=`cat "$srcdir/VERSION.in"`
  11
  12 AM_INIT_AUTOMAKE(muttng, $mutt_cv_version)
  13 AC_SUBST([CONFIGURE_DEPENDENCIES], ['$(top_srcdir)/VERSION.in'])
  14
  15 AC_GNU_SOURCE
  16
  17 ifdef([AC_LIBOBJ], , [define([AC_LIBOBJ], [LIB[]OBJS="$LIBOBJS $1.o"])])
  18
  19 ALL_LINGUAS="de ru it es uk fr pl nl cs id sk ko el zh_TW zh_CN pt_BR eo gl sv da lt tr ja hu et ca bg"
  20
  21 AC_CANONICAL_HOST
  22
  23 AC_MSG_CHECKING([for prefix])
  24 if test x$prefix = xNONE; then
  25     mutt_cv_prefix=$ac_default_prefix
  26 else
  27     mutt_cv_prefix=$prefix
  28 fi
  29 AC_MSG_RESULT($mutt_cv_prefix)
  30
  31 AC_PROG_CC
  32 AC_ISC_POSIX
  33 AM_C_PROTOTYPES
  34 if test "x$U" != "x"; then
  35     AC_MSG_ERROR(Compiler not ANSI compliant)
  36 fi
  37 AC_PROG_CPP
  38 AC_PROG_MAKE_SET
  39 AC_PROG_INSTALL
  40 AC_PROG_RANLIB
  41 AC_CHECK_TOOL(AR, ar, ar)
  42
  43 AC_C_INLINE
  44 AC_C_CONST
  45
  46 AC_SYS_LARGEFILE
  47 AC_FUNC_FSEEKO
  48 AC_CHECK_SIZEOF(off_t)
  49
  50 AC_PATH_PROG(DBX, dbx, no)
  51 AC_PATH_PROG(GDB, gdb, no)
  52 AC_PATH_PROG(SDB, sdb, no)
  53
  54 if test $GDB != no ; then
  55     DEBUGGER=$GDB
  56 elif test $DBX != no ; then
  57     DEBUGGER=$DBX
  58 elif test $SDB != no ; then
  59     DEBUGGER=$SDB
  60 else
  61     DEBUGGER=no
  62 fi
  63
  64 AC_SUBST([DEBUGGER])
  65
  66 AH_TEMPLATE([sig_atomic_t],
  67             [Define to 'int' if <signal.h> doesn't define.])
  68 AH_TEMPLATE([HAVE_START_COLOR],
  69             [Define if you have start_color, as a function or macro.])
  70 AH_TEMPLATE([HAVE_TYPEAHEAD],
  71             [Define if you have typeahead, as a function or macro.])
  72 AH_TEMPLATE([HAVE_BKGDSET],
  73             [Define if you have bkgdset, as a function or macro.])
  74 AH_TEMPLATE([HAVE_CURS_SET],
  75             [Define if you have curs_set, as a function or macro.])
  76 AH_TEMPLATE([HAVE_META],
  77             [Define if you have meta, as a function or macro.])
  78 AH_TEMPLATE([HAVE_USE_DEFAULT_COLORS],
  79             [Define if you have use_default_colors, as a function or macro.])
  80 AH_TEMPLATE([HAVE_RESIZETERM],
  81             [Define if you have resizeterm, as a function or macro.])
  82 AH_TEMPLATE([SIG_ATOMIC_VOLATILE_T],
  83             [Some systems declare sig_atomic_t as volatile, some others -- no.
  84              This define will have value `sig_atomic_t' or
  85              `volatile sig_atomic_t' accordingly.])
  86 AH_TEMPLATE([ICONV_NONTRANS],
  87             [Define as 1 if iconv() only converts exactly and we should treat
  88              all return values other than (size_t)(-1) as equivalent.])
  89
  90 MUTT_C99_INTTYPES
  91
  92 dnl ---------------- sendmail ----------------
  93
  94 ac_aux_path_sendmail=/usr/sbin:/usr/lib
  95 AC_PATH_PROG(SENDMAIL, sendmail, /usr/sbin/sendmail, $PATH:$ac_aux_path_sendmail)
  96 AC_DEFINE_UNQUOTED(SENDMAIL,"$ac_cv_path_SENDMAIL",[ Where to find sendmail on your system. ])
  97
  98
  99 OPS='$(srcdir)/OPS'
 100
 101 dnl ---------------- gpgme ----------------
 102
 103     AC_ARG_ENABLE(gpgme, AC_HELP_STRING([--enable-gpgme], [Enable GPGME support]),
 104     [   if test x$enableval = xyes; then
 105             have_gpgme=yes
 106         fi
 107     ])
 108     AC_ARG_WITH(gpgme-prefix, AC_HELP_STRING([--with-gpgme-prefix=PFX], [prefix where GPGME is installed (optional)]),
 109     gpgme_config_prefix="$withval", gpgme_config_prefix="")
 110
 111     if test x$have_gpgme = xyes; then
 112         if test x$gpgme_config_prefix != x; then
 113             GPGME_CONFIG="$gpgme_config_prefix/bin/gpgme-config"
 114         else
 115             AC_PATH_PROG(GPGME_CONFIG, gpgme-config, no)
 116         fi
 117         if test "x$GPGME_CONFIG" = "xno"; then
 118             AC_MSG_ERROR([GPGME not found])
 119         else
 120             LIBGPGME_CFLAGS=`$GPGME_CONFIG --cflags`
 121             LIBGPGME_LIBS=`$GPGME_CONFIG --libs`
 122             MUTTLIBS="$MUTTLIBS $LIBGPGME_LIBS"
 123             MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS crypt-gpgme.o crypt-mod-pgp-gpgme.o crypt-mod-smime-gpgme.o"
 124             AC_DEFINE(CRYPT_BACKEND_GPGME, 1, [Defined, if GPGME support is enabled])
 125         fi
 126     fi
 127     AC_SUBST(LIBGPGME_CFLAGS)
 128     AC_SUBST(LIBGPGME_LIBS)
 129
 130
 131 dnl ---------------- pgp/smime ----------------
 132
 133     AC_ARG_ENABLE(smime, AC_HELP_STRING([--disable-smime], [Disable SMIME support]),
 134     [   if test x$enableval = xno ; then
 135             have_smime=no
 136         fi
 137     ])
 138
 139     if test x$have_smime != xno ; then
 140         AC_DEFINE(CRYPT_BACKEND_CLASSIC_SMIME,1, [ Define if you want clasic S/MIME support. ])
 141         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS smime.o crypt-mod-smime-classic.o"
 142         SMIMEAUX_TARGET="smime_keysng"
 143     fi
 144
 145
 146 dnl ---------------- mixmaster ----------------
 147
 148     AC_ARG_WITH(mixmaster, AC_HELP_STRING([--with-mixmaster[=PATH]], [Include Mixmaster support]),
 149     [   if test -x "$withval" ; then
 150             MIXMASTER="$withval"
 151         else
 152             MIXMASTER="mixmaster"
 153         fi
 154         OPS="$OPS \$(srcdir)/OPS.MIX"
 155         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS remailer.o"
 156         AC_DEFINE_UNQUOTED(MIXMASTER,"$MIXMASTER", [ Where to find mixmaster on your system. ])
 157     ])
 158
 159 # We now require all OPS
 160 OPS="$OPS \$(srcdir)/OPS.PGP \$(srcdir)/OPS.SMIME \$(srcdir)/OPS.CRYPT "
 161 AC_SUBST([OPS])
 162
 163
 164 AC_SUBST(SMIMEAUX_TARGET)
 165
 166 AC_PATH_PROG(ISPELL, ispell, no)
 167 if test $ISPELL != no; then
 168     AC_DEFINE_UNQUOTED(ISPELL,"$ISPELL",[ Where to find ispell on your system. ])
 169 fi
 170
 171 AC_ARG_WITH(slang, AC_HELP_STRING([--with-slang[=DIR]], [Use S-Lang instead of ncurses]),
 172     [AC_CACHE_CHECK([if this is a BSD system], mutt_cv_bsdish,
 173         [AC_TRY_RUN([#include <sys/param.h>
 174
 175 main ()
 176 {
 177 #ifdef BSD
 178         exit (0);
 179 #else
 180         exit (1);
 181 #endif
 182 }],
 183         mutt_cv_bsdish=yes,
 184         mutt_cv_bsdish=no,
 185         mutt_cv_bsdish=no)])
 186
 187         AC_MSG_CHECKING(for S-Lang)
 188         if test $withval = yes; then
 189             if test -d $srcdir/../slang; then
 190                 mutt_cv_slang=$srcdir/../slang/src
 191                 CFLAGS="$CFLAGS -I${mutt_cv_slang}"
 192                 LDFLAGS="$LDFLAGS -L${mutt_cv_slang}/objs"
 193             else
 194                 if test -d $mutt_cv_prefix/include/slang; then
 195                     CFLAGS="$CFLAGS -I$mutt_cv_prefix/include/slang"
 196                 elif test -d /usr/include/slang; then
 197                     CFLAGS="$CFLAGS -I/usr/include/slang"
 198                 fi
 199                 mutt_cv_slang=yes
 200             fi
 201         else
 202             dnl ---Check to see if $withval is a source directory
 203             if test -f $withval/src/slang.h; then
 204                 mutt_cv_slang=$withval/src
 205                 CFLAGS="$CFLAGS -I${mutt_cv_slang}"
 206                 LDFLAGS="$LDFLAGS -L${mutt_cv_slang}/objs"
 207             else
 208                 dnl ---Must be installed somewhere
 209                 mutt_cv_slang=$withval
 210                 if test -d $withval/include/slang; then
 211                         CFLAGS="$CFLAGS -I${withval}/include/slang"
 212                 elif test -d $withval/include; then
 213                         CFLAGS="$CFLAGS -I${withval}/include"
 214                 fi
 215                 LDFLAGS="$LDFLAGS -L${withval}/lib"
 216             fi
 217         fi
 218         AC_MSG_RESULT($mutt_cv_slang)
 219         if test $mutt_cv_bsdish = yes; then
 220             AC_CHECK_LIB(termlib, main)
 221         fi
 222         AC_DEFINE(USE_SLANG_CURSES,1, [ Define if you compile with SLang instead of curses/ncurses. ])
 223         AC_DEFINE(HAVE_COLOR,1,[ Define if your curses library supports color. ])
 224         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS resize.o"
 225
 226         dnl --- now that we've found it, check the link
 227
 228         AC_CHECK_LIB(slang, SLtt_get_terminfo,
 229             [MUTTLIBS="$MUTTLIBS -lslang -lm"],
 230             [AC_MSG_ERROR(unable to compile.  check config.log)], -lm)
 231         ],
 232
 233         [   mutt_cv_curses=/usr
 234             AC_ARG_WITH(curses, AC_HELP_STRING([--with-curses=DIR], [Where ncurses is installed]),
 235             [   if test $withval != yes; then
 236                     mutt_cv_curses=$withval
 237                 fi
 238                 if test x$mutt_cv_curses != x/usr; then
 239                     LDFLAGS="-L${mutt_cv_curses}/lib $LDFLAGS"
 240                     CPPFLAGS="$CPPFLAGS -I${mutt_cv_curses}/include"
 241                 fi
 242             ])
 243
 244             AC_CHECK_FUNC(initscr,,[
 245             cf_ncurses="ncurses"
 246             for lib in ncursesw ncurses; do
 247                 AC_CHECK_LIB($lib, waddnwstr, [cf_ncurses="$lib"; break])
 248             done
 249             AC_CHECK_LIB($cf_ncurses, initscr,
 250                 [   MUTTLIBS="$MUTTLIBS -l$cf_ncurses"
 251                     if test x$mutt_cv_curses = x/usr -a -d /usr/include/ncurses; then
 252                         CPPFLAGS="$CPPFLAGS -I/usr/include/ncurses"
 253                     fi
 254
 255                     if test "$cf_ncurses" = ncursesw; then
 256                         AC_CHECK_HEADERS(ncurses/ncurses.h,[cf_cv_ncurses_header="ncurses/ncurses.h"])
 257                         AC_CHECK_HEADERS(ncursesw/ncurses.h,[cf_cv_ncurses_header="ncursesw/ncurses.h"])
 258                     else
 259                         AC_CHECK_HEADERS(ncurses.h,[cf_cv_ncurses_header="ncurses.h"])
 260                     fi
 261                 ],
 262                 [CF_CURSES_LIBS])
 263             ])
 264
 265             old_LIBS="$LIBS"
 266             LIBS="$LIBS $MUTTLIBS"
 267             CF_CHECK_FUNCDECLS([#include <${cf_cv_ncurses_header-curses.h}>],
 268                                [start_color typeahead bkgdset curs_set meta use_default_colors resizeterm])
 269             if test "$ac_cv_func_decl_start_color" = yes; then
 270                 AC_DEFINE(HAVE_COLOR,1,[ Define if your curses library supports color. ])
 271             fi
 272             if test "$ac_cv_func_decl_resizeterm" = yes; then
 273                 MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS resize.o"
 274             fi
 275             LIBS="$old_LIBS"
 276         ])
 277
 278 AC_HEADER_STDC
 279
 280 AC_CHECK_HEADERS(stdarg.h sys/ioctl.h ioctl.h sysexits.h)
 281 AC_CHECK_HEADERS(sys/time.h sys/resource.h)
 282 AC_CHECK_HEADERS(unix.h)
 283
 284 AC_CHECK_FUNCS(setrlimit getsid isctype)
 285
 286 AC_TYPE_SIGNAL
 287
 288 AC_MSG_CHECKING(for sig_atomic_t in signal.h)
 289 AC_EGREP_HEADER(sig_atomic_t,signal.h,
 290     [   ac_cv_type_sig_atomic_t=yes;
 291         AC_EGREP_HEADER(volatile.*sig_atomic_t,
 292                         signal.h,
 293                         [is_sig_atomic_t_volatile=yes; AC_MSG_RESULT([yes, volatile])],
 294                         [is_sig_atomic_t_volatile=no;  AC_MSG_RESULT([yes, non volatile])])
 295     ],
 296     [   AC_MSG_RESULT(no)
 297         AC_CHECK_TYPE(sig_atomic_t, int)
 298         is_sig_atomic_t_volatile=no
 299     ])
 300 if test $is_sig_atomic_t_volatile = 'yes'
 301 then
 302     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, sig_atomic_t)
 303 else
 304     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, [volatile sig_atomic_t])
 305 fi
 306
 307 AC_DECL_SYS_SIGLIST
 308
 309 AC_TYPE_PID_T
 310 dnl AC_CHECK_TYPE(ssize_t, int)
 311
 312 AC_CHECK_FUNCS(fgetpos memmove setegid srand48 strerror)
 313 AC_REPLACE_FUNCS(strcasecmp setenv)
 314 AC_CHECK_FUNCS(snprintf vsnprintf)
 315
 316 AC_CHECK_FUNC(getopt)
 317 if test $ac_cv_func_getopt = yes; then
 318     AC_CHECK_HEADERS(getopt.h)
 319 fi
 320
 321 dnl SCO uses chsize() instead of ftruncate()
 322 AC_CHECK_FUNCS(ftruncate, , [AC_CHECK_LIB(x, chsize)])
 323
 324 dnl SCO has strftime() in libintl
 325 AC_CHECK_FUNCS(strftime, , [AC_CHECK_LIB(intl, strftime)])
 326
 327 dnl AIX may not have fchdir()
 328 AC_CHECK_FUNCS(fchdir, , [mutt_cv_fchdir=no])
 329
 330 AC_ARG_WITH(regex, AC_HELP_STRING([--with-regex], [Use the GNU regex library]),
 331         [mutt_cv_regex=yes],
 332         [AC_CHECK_FUNCS(regcomp, mutt_cv_regex=no, mutt_cv_regex=yes)])
 333
 334 if test $mutt_cv_regex = no ; then
 335     AC_CACHE_CHECK([whether your system's regexp library is completely broken],
 336         [mutt_cv_regex_broken],
 337         AC_TRY_RUN([
 338 #include <unistd.h>
 339 #include <regex.h>
 340 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
 341         mutt_cv_regex_broken=no, mutt_cv_regex_broken=yes, mutt_cv_regex_broken=yes))
 342     if test $mutt_cv_regex_broken = yes ; then
 343         echo "Using the included GNU regex instead." >&AC_FD_MSG
 344         mutt_cv_regex=yes
 345     fi
 346 fi
 347
 348 if test $mutt_cv_regex = yes; then
 349     AC_DEFINE(USE_GNU_REGEX,1,[ Define if you want to use the included regex.c. ])
 350     AC_LIBOBJ(regex)
 351 fi
 352
 353
 354 AC_ARG_WITH(homespool,
 355             AC_HELP_STRING([--with-homespool[=FILE]],
 356                            [File in user's directory where new mail is spooled]),
 357                            with_homespool=${withval})
 358 if test x$with_homespool != x; then
 359     if test $with_homespool = yes; then
 360             with_homespool=mailbox
 361     fi
 362     AC_DEFINE_UNQUOTED(MAILPATH,"$with_homespool",[ Where new mail is spooled. ])
 363     AC_DEFINE(HOMESPOOL,1,
 364     [   Is mail spooled to the user's home directory?  If defined,
 365         MAILPATH should be set to the filename of the spool mailbox
 366         relative the the home directory.
 367         use: configure --with-homespool=FILE
 368     ])
 369     AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 370     mutt_cv_setgid=no
 371 else
 372     AC_ARG_WITH(mailpath, AC_HELP_STRING([--with-mailpath=DIR], [Directory where spool mailboxes are located]),
 373         [mutt_cv_mailpath=$withval],
 374         [ AC_CACHE_CHECK(where new mail is stored, mutt_cv_mailpath,
 375             [mutt_cv_mailpath=no
 376             if test -d /var/mail; then
 377                 mutt_cv_mailpath=/var/mail
 378             elif test -d /var/spool/mail; then
 379                 mutt_cv_mailpath=/var/spool/mail
 380             elif test -d /usr/spool/mail; then
 381                 mutt_cv_mailpath=/usr/spool/mail
 382             elif test -d /usr/mail; then
 383                 mutt_cv_mailpath=/usr/mail
 384             fi])
 385         ])
 386     if test "$mutt_cv_mailpath" = no; then
 387         AC_MSG_ERROR("Could not determine where new mail is stored.")
 388     fi
 389     AC_DEFINE_UNQUOTED(MAILPATH,"$mutt_cv_mailpath",[ Where new mail is spooled. ])
 390
 391     AC_CACHE_CHECK(if $mutt_cv_mailpath is world writable, mutt_cv_worldwrite, [AC_TRY_RUN([#include <sys/types.h>
 392 #include <sys/stat.h>
 393
 394 int main (int argc, char **argv)
 395 {
 396         struct stat s;
 397
 398         stat ("$mutt_cv_mailpath", &s);
 399         if (s.st_mode & S_IWOTH) exit (0);
 400         exit (1);
 401 }], mutt_cv_worldwrite=yes, mutt_cv_worldwrite=no, mutt_cv_worldwrite=no)])
 402
 403         mutt_cv_setgid=no
 404         if test $mutt_cv_worldwrite = yes; then
 405                 AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 406         else
 407
 408                 AC_CACHE_CHECK(if $mutt_cv_mailpath is group writable, mutt_cv_groupwrite, [AC_TRY_RUN([#include <sys/types.h>
 409 #include <sys/stat.h>
 410
 411 int main (int argc, char **argv)
 412 {
 413         struct stat s;
 414
 415         stat ("$mutt_cv_mailpath", &s);
 416         if (s.st_mode & S_IWGRP) exit (0);
 417         exit (1);
 418 }], mutt_cv_groupwrite=yes, mutt_cv_groupwrite=no, mutt_cv_groupwrite=no)])
 419
 420         if test $mutt_cv_groupwrite = yes; then
 421             AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 422             AC_DEFINE(USE_SETGID,1,[ Define if mutt should run setgid "mail". ])
 423             mutt_cv_setgid=yes
 424         fi
 425     fi
 426 fi
 427
 428 AC_MSG_CHECKING(where to put the documentation)
 429 AC_ARG_WITH(docdir, AC_HELP_STRING([--with-docdir=PATH], [Specify where to put the documentation]),
 430         [mutt_cv_docdir=$withval],
 431         [mutt_cv_docdir="${prefix}/doc/muttng"])
 432 AC_MSG_RESULT($mutt_cv_docdir)
 433
 434 docdir=$mutt_cv_docdir
 435 AC_SUBST(docdir)
 436
 437 if test x$mutt_cv_setgid = xyes; then
 438     DOTLOCK_GROUP='mail'
 439     DOTLOCK_PERMISSION=2755
 440 else
 441     DOTLOCK_GROUP=''
 442     DOTLOCK_PERMISSION=755
 443 fi
 444 AC_SUBST(DOTLOCK_GROUP)
 445 AC_SUBST(DOTLOCK_PERMISSION)
 446
 447 AC_ARG_WITH(domain, AC_HELP_STRING([--with-domain=DOMAIN], [Specify your DNS domain name]),
 448         [if test $withval != yes; then
 449          if test $withval != no; then
 450            AC_DEFINE_UNQUOTED(DOMAIN,"$withval",[ Define your domain name. ])
 451          fi
 452         fi])
 453
 454 need_socket="no"
 455
 456 dnl -- socket dependencies --
 457
 458 AC_ARG_ENABLE(pop,  AC_HELP_STRING([--enable-pop], [Enable POP3 support]),
 459 [   if test x$enableval = xyes ; then
 460         AC_DEFINE(USE_POP,1,[ Define if you want support for the POP3 protocol. ])
 461         LIBPOP="-Lpop -lpop"
 462         LIBPOPDEPS="\$(top_srcdir)/pop/pop.h pop/libpop.a"
 463         need_socket="yes"
 464         need_pop="yes"
 465         need_md5="yes"
 466     fi
 467 ])
 468 AM_CONDITIONAL(BUILD_POP, test x$need_pop = xyes)
 469
 470 AC_ARG_ENABLE(imap, AC_HELP_STRING([--enable-imap], [Enable IMAP support]),
 471 [   if test x$enableval = xyes ; then
 472         AC_DEFINE(USE_IMAP,1,[ Define if you want support for the IMAP protocol. ])
 473         LIBIMAP="-Limap -limap"
 474         LIBIMAPDEPS="\$(top_srcdir)/imap/imap.h imap/libimap.a"
 475         need_imap="yes"
 476         need_socket="yes"
 477         need_md5="yes"
 478     fi
 479 ])
 480 AM_CONDITIONAL(BUILD_IMAP, test x$need_imap = xyes)
 481
 482 AC_ARG_ENABLE(nntp, [  --enable-nntp              Enable NNTP support],
 483 [   if test x$enableval = xyes ; then
 484         AC_DEFINE(USE_NNTP,1,[ Compiling with newsreading support with NNTP ])
 485         LIBNNTP="-Lnntp -lnntp"
 486         LIBNNTPDEPS="\$(top_srcdir)/nntp/nntp.h nntp/libnntp.a"
 487         need_nntp="yes"
 488         need_socket="yes"
 489     fi
 490 ])
 491 AM_CONDITIONAL(BUILD_NNTP, test x$need_nntp = xyes)
 492
 493 dnl -- end socket dependencies --
 494
 495 if test "$need_socket" = "yes"
 496 then
 497     AC_MSG_CHECKING([for socklen_t])
 498     AC_EGREP_HEADER(socklen_t, sys/socket.h, AC_MSG_RESULT([yes]),
 499             AC_MSG_RESULT([no])
 500             AC_DEFINE(socklen_t,int, [ Define to 'int' if <sys/socket.h> doesn't have it. ]))
 501     AC_CHECK_FUNC(gethostent, , AC_CHECK_LIB(nsl, gethostent))
 502     AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt))
 503     AC_CHECK_FUNCS(getaddrinfo)
 504     AC_DEFINE(USE_SOCKET,1,
 505             [ Include code for socket support. Set automatically if you enable POP3 or IMAP ])
 506     MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS account.o mutt_socket.o mutt_tunnel.o"
 507 fi
 508
 509 dnl -- imap dependencies --
 510
 511 AC_ARG_WITH(gss, AC_HELP_STRING([--with-gss[=PFX]], [Compile in GSSAPI authentication for IMAP]),
 512     gss_prefix="$withval", gss_prefix="no")
 513 if test "$gss_prefix" != "no"
 514 then
 515   if test "$need_imap" = "yes"
 516   then
 517     MUTT_AM_PATH_GSSAPI(gss_prefix)
 518     AC_MSG_CHECKING(GSSAPI implementation)
 519     AC_MSG_RESULT($GSSAPI_IMPL)
 520     if test "$GSSAPI_IMPL" = "none"
 521     then
 522       AC_CACHE_SAVE
 523       AC_MSG_RESULT([GSSAPI libraries not found])
 524     fi
 525     if test "$GSSAPI_IMPL" = "Heimdal"
 526     then
 527       AC_DEFINE(HAVE_HEIMDAL,1,[ Define if your GSSAPI implementation is Heimdal ])
 528     fi
 529     CPPFLAGS="$CPPFLAGS $GSSAPI_CFLAGS"
 530     MUTTLIBS="$MUTTLIBS $GSSAPI_LIBS"
 531     AC_DEFINE(USE_GSS,1,[ Define if you have GSSAPI libraries available ])
 532     need_gss="yes"
 533   else
 534     AC_MSG_WARN([GSS was requested but IMAP is not enabled])
 535   fi
 536 fi
 537 AM_CONDITIONAL(USE_GSS, test x$need_gss = xyes)
 538
 539 dnl -- end imap dependencies --
 540
 541 AC_ARG_WITH(ssl, AC_HELP_STRING([--with-ssl[=PFX]], [Compile in SSL support for POP/IMAP]),
 542 [       if test "$with_ssl" != "no"
 543         then
 544           if test "$need_socket" != "yes"; then
 545            AC_MSG_ERROR([SSL support is only useful with POP or IMAP support])
 546           fi
 547
 548           if test "$with_ssl" != "yes"
 549           then
 550            LDFLAGS="$LDFLAGS -L$withval/lib"
 551            CPPFLAGS="$CPPFLAGS -I$withval/include"
 552           fi
 553           saved_LIBS="$LIBS"
 554
 555           AC_CHECK_LIB(crypto, X509_new,, AC_MSG_ERROR([Unable to find SSL library]))
 556           AC_CHECK_LIB(ssl, SSL_new,, AC_MSG_ERROR([Unable to find SSL library]), -lcrypto)
 557
 558           AC_CHECK_FUNCS(RAND_status RAND_egd)
 559
 560           AC_DEFINE(USE_SSL,1,[ Define if you want support for SSL. ])
 561           LIBS="$saved_LIBS"
 562           MUTTLIBS="$MUTTLIBS -lssl -lcrypto"
 563           MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_ssl.o"
 564           need_ssl=yes
 565
 566         fi
 567 ])
 568
 569 AC_ARG_WITH([gnutls], AC_HELP_STRING([--with-gnutls[=PFX]], [Enable SSL support using gnutls]),
 570     [gnutls_prefix="$withval"], [gnutls_prefix="no"])
 571 if test "$gnutls_prefix" != "no"
 572 then
 573   if test "$need_socket" != "yes"
 574   then
 575     AC_MSG_ERROR([SSL support is only useful with POP or IMAP support])
 576   fi
 577   if test x"$need_ssl" = x"yes"
 578   then
 579     AC_MSG_ERROR([Only either OpenSSL or GNUTLS may be used])
 580   fi
 581   MUTT_AM_PATH_GNUTLS([$gnutls_prefix],
 582     [dnl GNUTLS found
 583     CPPFLAGS="$CPPFLAGS $LIBGNUTLS_CFLAGS"
 584     MUTTLIBS="$MUTTLIBS $LIBGNUTLS_LIBS"
 585     AC_DEFINE(USE_GNUTLS, 1, [Define if you want support for SSL via the gnutls library.])
 586
 587     MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_ssl_gnutls.o"
 588     need_ssl=yes],
 589     [dnl GNUTLS not found
 590       AC_MSG_ERROR([could not find libgnutls])
 591     ])
 592 fi
 593
 594 AM_CONDITIONAL(USE_SSL, test x$need_ssl = xyes)
 595
 596 AC_ARG_WITH(sasl2, AC_HELP_STRING([--with-sasl2[=PFX]], [Use Cyrus SASL library version 2 for POP/IMAP authentication]),
 597         [
 598         if test "$with_sasl2" != "no" -a "$need_imap" != "yes" -a "$need_pop" != "yes"
 599         then
 600           AC_MSG_ERROR([SASL2 support is only useful with POP or IMAP support])
 601         fi
 602
 603         if test "$with_sasl2" != "no"
 604         then
 605           if test "$with_sasl2" != "yes"
 606           then
 607             CPPFLAGS="$CPPFLAGS -I$with_sasl2/include"
 608             LDFLAGS="$LDFLAGS -L$with_sasl2/lib"
 609           fi
 610
 611           saved_LIBS="$LIBS"
 612
 613           AC_CHECK_LIB(sasl2, sasl_client_init,,
 614             AC_MSG_ERROR([could not find libsasl2]),)
 615
 616           MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_sasl.o"
 617           MUTTLIBS="$MUTTLIBS -lsasl2"
 618           LIBS="$saved_LIBS"
 619           AC_DEFINE(USE_SASL,1,
 620                   [ Define if want to use version 2 of the Cyrus SASL library. ])
 621           need_sasl=yes
 622         fi
 623         ])
 624 AM_CONDITIONAL(USE_SASL, test x$need_sasl = xyes)
 625
 626 AC_ARG_WITH(idn, AC_HELP_STRING([--with-idn=[PFX]], [Use GNU libidn for domain names]),
 627                  [
 628                   if test "$with_idn" != "no" ; then
 629                         if test "$with_idn" != "yes" ; then
 630                            CPPFLAGS="$CPPFLAGS -I$with_idn/include"
 631                            LDFLAGS="$LDFLAGS -L$with_idn/lib"
 632                         fi
 633                   fi
 634                  ]
 635 )
 636
 637 if test "x$with_idn" != "xno"; then
 638    AC_CHECK_LIB(idn, stringprep_check_version)
 639    AC_CHECK_FUNCS(idna_to_unicode_utf8_from_utf8 idna_to_unicode_8z8z)
 640    AC_CHECK_FUNCS(idna_to_ascii_from_utf8 idna_to_ascii_8z)
 641    AC_CHECK_FUNCS(idna_to_ascii_lz idna_to_ascii_from_locale)
 642 fi
 643
 644 dnl -- end socket --
 645
 646 AC_ARG_ENABLE(debug, AC_HELP_STRING([--enable-debug], [Enable debugging support]),
 647         [ if test x$enableval = xyes ; then
 648                 AC_DEFINE(DEBUG,1,[ Define to enable debugging info. ])
 649           fi
 650          ])
 651
 652 AC_ARG_ENABLE(flock, AC_HELP_STRING([--enable-flock], [Use flock() to lock files]),
 653         [if test $enableval = yes; then
 654                 AC_DEFINE(USE_FLOCK,1, [ Define to use flock() to lock mailboxes. ])
 655         fi])
 656
 657 mutt_cv_fcntl=yes
 658 AC_ARG_ENABLE(fcntl, AC_HELP_STRING([--disable-fcntl], [Do NOT use fcntl() to lock files]),
 659         [if test $enableval = no; then mutt_cv_fcntl=no; fi])
 660
 661 if test $mutt_cv_fcntl = yes; then
 662         AC_DEFINE(USE_FCNTL,1, [ Define to use fcntl() to lock folders. ])
 663 fi
 664
 665 AC_MSG_CHECKING(whether struct dirent defines d_ino)
 666 ac_cv_dirent_d_ino=no
 667 AC_TRY_LINK([#include <dirent.h>],[struct dirent dp; (void)dp.d_ino],[ac_cv_dirent_d_ino=yes])
 668 if test x$ac_cv_dirent_d_ino = xyes ; then
 669   AC_DEFINE(HAVE_DIRENT_D_INO,1,
 670             [Define to 1 if your system has the dirent::d_ino member])
 671 fi
 672 AC_MSG_RESULT($ac_cv_dirent_d_ino)
 673
 674 dnl This may look cumbersome -- please keep it that way, so we can
 675 dnl quickly change the default to "yes" again.
 676 mutt_cv_inodesort=no
 677 AC_ARG_ENABLE(inodesort,  AC_HELP_STRING([--enable-inodesort], [Read files in maildir folders sorted by inode.]),
 678        [if test x$enableval = xyes -a x$ac_cv_dirent_d_ino = xyes ; then mutt_cv_inodesort=yes; fi])
 679
 680 if test $mutt_cv_inodesort = yes; then
 681         AC_DEFINE(USE_INODESORT, 1, [ Define to sort files in a maildir by inode number. ])
 682 fi
 683
 684 mutt_cv_warnings=yes
 685 AC_ARG_ENABLE(warnings, AC_HELP_STRING([--disable-warnings], [Turn off compiler warnings (not recommended)]),
 686 [if test $enableval = no; then
 687         mutt_cv_warnings=no
 688 fi])
 689
 690 if test x$GCC = xyes -a $mutt_cv_warnings = yes; then
 691         CFLAGS="-Wall -pedantic $CFLAGS"
 692 fi
 693
 694 AC_ARG_ENABLE(nfs-fix, AC_HELP_STRING([--enable-nfs-fix], [Work around an NFS with broken attributes caching]),
 695         [if test x$enableval = xyes; then
 696                 AC_DEFINE(NFS_ATTRIBUTE_HACK,1,
 697                   [Define if you have problems with mutt not detecting
 698                    new/old mailboxes over NFS.  Some NFS implementations
 699                    incorrectly cache the attributes of small files.])
 700         fi])
 701
 702 AC_ARG_ENABLE(buffy-size, AC_HELP_STRING([--enable-buffy-size], [Use file size attribute instead of access time]),
 703         [if test x$enableval = xyes; then
 704                 AC_DEFINE(BUFFY_SIZE,1,[ Define to enable the "buffy_size" feature. ])
 705         fi])
 706
 707 AC_ARG_ENABLE(mailtool, AC_HELP_STRING([--enable-mailtool], [Enable Sun mailtool attachments support ]),
 708         [if test x$enableval = xyes; then
 709                 AC_DEFINE(SUN_ATTACHMENT,1,[ Define to enable Sun mailtool attachments support. ])
 710         fi])
 711
 712 AC_ARG_ENABLE(compressed, [  --enable-compressed        Enable compressed folders support ],
 713         [if test x$enableval = xyes; then
 714                 AC_DEFINE(USE_COMPRESSED,1,[ The compressed mailboxes support ])
 715         fi])
 716
 717 AC_ARG_ENABLE(locales-fix, AC_HELP_STRING([--enable-locales-fix], [The result of isprint() is unreliable ]),
 718         [if test x$enableval = xyes; then
 719                 AC_DEFINE(LOCALES_HACK,1,[ Define if the result of isprint() is unreliable. ])
 720         fi])
 721
 722 AC_ARG_WITH(exec-shell, AC_HELP_STRING([--with-exec-shell=SHELL], [Specify alternate shell (ONLY if /bin/sh is broken)]),
 723         [if test $withval != yes; then
 724                 AC_DEFINE_UNQUOTED(EXECSHELL, "$withval",
 725                  [program to use for shell commands])
 726          else
 727                 AC_DEFINE_UNQUOTED(EXECSHELL, "/bin/sh")
 728         fi],
 729         [AC_DEFINE_UNQUOTED(EXECSHELL, "/bin/sh")])
 730
 731 dnl -- start cache --
 732 AC_ARG_ENABLE(hcache, AC_HELP_STRING([--enable-hcache], [Enable header caching]),
 733 [if test x$enableval = xyes; then
 734     AC_DEFINE(USE_HCACHE, 1, [Enable header caching])
 735
 736     OLDCPPFLAGS="$CPPFLAGS"
 737     OLDLIBS="$LIBS"
 738
 739     need_md5="yes"
 740
 741     ac_prefer_qdbm=yes
 742     AC_ARG_WITH(qdbm, AC_HELP_STRING([--without-qdbm], [Don't use qdbm even if it is available]),
 743         ac_prefer_qdbm=$withval)
 744     if test x$ac_prefer_qdbm != xno; then
 745         ac_cv_vlopen=no
 746         QDBM_DIRS="$mutt_cv_prefix /usr/local /usr"
 747         AC_MSG_CHECKING([for vlopen])
 748         for d in $QDBM_DIRS; do
 749           if test x$ac_cv_vlopen = xno && test -d "$d/include" && test -d "$d/lib"; then
 750             QDBM_INC="-I$d/include"
 751             QDBM_LIB="-L$d/lib"
 752             CPPFLAGS="$OLDCPPFLAGS $QDBM_INC"
 753             LIBS="$OLDLIBS $QDBM_LIB -lqdbm"
 754             AC_TRY_LINK([#include <villa.h>],[vlopen(0,0,0);],[ac_cv_vlopen=yes])
 755           fi
 756         done
 757         if test x$ac_cv_vlopen = xyes; then
 758           AC_MSG_RESULT(yes)
 759         else
 760           AC_MSG_RESULT(no)
 761         fi
 762     fi
 763
 764     ac_prefer_gdbm=yes
 765     AC_ARG_WITH(gdbm, AC_HELP_STRING([--without-gdbm], [Don't use gdbm even if it is available]),
 766         ac_prefer_gdbm=$withval)
 767     if test x$ac_prefer_gdbm != xno -a x$ac_cv_vlopen != xyes; then
 768         ac_cv_gdbmopen=no
 769         GDBM_DIRS="$mutt_cv_prefix /usr/local /usr"
 770         AC_MSG_CHECKING([for gdbm_open])
 771         for d in $GDBM_DIRS; do
 772           if test x$ac_cv_gdbmopen = xno && test -d "$d/include" && test -d "$d/lib"; then
 773             GDBM_INC="-I$d/include"
 774             GDBM_LIB="-L$d/lib"
 775             CPPFLAGS="$OLDCPPFLAGS $GDBM_INC"
 776             LIBS="$OLDLIBS $GDBM_LIB -lgdbm"
 777             AC_TRY_LINK([#include <gdbm.h>],[gdbm_open(0,0,0,0,0);],[ac_cv_gdbmopen=yes])
 778           fi
 779         done
 780         if test x$ac_cv_gdbmopen = xyes; then
 781           AC_MSG_RESULT(yes)
 782         else
 783           AC_MSG_RESULT(no)
 784         fi
 785     fi
 786
 787     ac_bdb_prefix=yes
 788     AC_ARG_WITH(bdb, AC_HELP_STRING([--with-bdb[=DIR]], [Use BerkeleyDB4 if gdbm is not available ]),
 789         ac_bdb_prefix=$withval)
 790     if test x$ac_bdb_prefix != xno -a x$ac_cv_gdbmopen != xyes -a x$ac_cv_vlopen != xyes; then
 791         test x$ac_bdb_prefix = xyes && ac_bdb_prefix="$mutt_cv_prefix /opt/csw/bdb4 /opt /usr/local /usr"
 792         for d in $ac_bdb_prefix; do
 793             bdbpfx="$bdbpfx $d"
 794             for v in BerkeleyDB.4.3 BerkeleyDB.4.2 BerkeleyDB.4.1; do
 795                 bdbpfx="$bdbpfx $d/$v"
 796             done
 797         done
 798         BDB_VERSIONS="db-4 db4 db-4.3 db4.3 db43 db-4.2 db4.2 db42 db-4.1 db4.1 db41 db ''"
 799         AC_MSG_CHECKING([for BerkeleyDB > 4.0])
 800         for d in $bdbpfx; do
 801             BDB_INCLUDE_DIR=""
 802             BDB_LIB_DIR=""
 803             for v in / $BDB_VERSIONS; do
 804                 if test -r "$d/include/$v/db.h"; then
 805                     BDB_INCLUDE_DIR="$d/include/$v"
 806                     if test -d "$d/lib/$v"; then
 807                         BDB_LIB_DIR="$d/lib/$v"
 808                         for l in `echo $BDB_VERSIONS`; do
 809                             CPPFLAGS="-I$BDB_INCLUDE_DIR $OLDCPPFLAGS"
 810                             LIBS="$OLDLIBS -L$BDB_LIB_DIR -l$l"
 811                             AC_TRY_LINK([
 812                                 #include <stdlib.h>
 813                                 #include <db.h>
 814                             ],[
 815                                 DB *db = NULL;
 816                                 db->open(db,NULL,NULL,NULL,0,0,0);
 817                             ],[
 818                                 ac_cv_dbcreate=yes
 819                                 BDB_LIB="$l"
 820                                 break
 821                             ])
 822                         done
 823                         test x$ac_cv_dbcreate = xyes && break
 824                     fi
 825                 fi
 826             done
 827             test x$BDB_LIB != x && break
 828         done
 829         if test x$ac_cv_dbcreate = xyes; then
 830             AC_MSG_RESULT(yes)
 831         else
 832             AC_MSG_RESULT(no)
 833         fi
 834     fi
 835
 836     if test x$ac_cv_vlopen = xyes; then
 837         CPPFLAGS="$OLDCPPFLAGS $QDBM_INC"
 838         LIBS="$OLDLIBS $QDBM_LIB -lqdbm"
 839         AC_DEFINE(HAVE_QDBM, 1, [QDBM Support])
 840     elif test x$ac_cv_gdbmopen = xyes; then
 841         CPPFLAGS="$OLDCPPFLAGS $GDBM_INC"
 842         LIBS="$OLDLIBS $GDBM_LIB -lgdbm";
 843         AC_DEFINE(HAVE_GDBM, 1, [GDBM Support])
 844     elif test x$ac_cv_dbcreate = xyes; then
 845         CPPFLAGS="-I$BDB_INCLUDE_DIR $OLDCPPFLAGS"
 846         LIBS="$OLDLIBS -L$BDB_LIB_DIR -l$BDB_LIB"
 847         AC_DEFINE(HAVE_DB4, 1, [Sleepycat DB4 Support])
 848     else
 849         AC_MSG_ERROR([You need one of: QDBM, GDBM or Sleepycat DB4 for --enable-hcache])
 850     fi
 851 fi])
 852 dnl -- end cache --
 853
 854 AC_SUBST(MUTTLIBS)
 855 AC_SUBST(MUTT_LIB_OBJECTS)
 856 AC_SUBST(LIBIMAP)
 857 AC_SUBST(LIBIMAPDEPS)
 858 AC_SUBST(LIBPOP)
 859 AC_SUBST(LIBPOPDEPS)
 860 AC_SUBST(LIBNNTP)
 861 AC_SUBST(LIBNNTPDEPS)
 862
 863 dnl -- iconv/gettext --
 864
 865 AC_ARG_ENABLE(iconv, AC_HELP_STRING([--disable-iconv], [Disable iconv support]),
 866         [if test x$enableval = xno ; then
 867                 am_cv_func_iconv=no
 868         fi
 869 ])
 870
 871 AM_GNU_GETTEXT
 872
 873 if test "$am_cv_func_iconv" != "yes"
 874 then
 875   AC_MSG_WARN([Configuring without iconv support. See INSTALL for details])
 876 else
 877
 878 AC_CHECK_HEADERS(iconv.h,
 879         [AC_MSG_CHECKING(whether iconv.h defines iconv_t)
 880          AC_EGREP_HEADER([typedef.*iconv_t],iconv.h,
 881                 [AC_MSG_RESULT(yes)
 882                  AC_DEFINE(HAVE_ICONV_T_DEF, 1,
 883                         [Define if <iconv.h> defines iconv_t.])],
 884                  AC_MSG_RESULT(no))])
 885
 886 dnl (1) Some implementations of iconv won't convert from UTF-8 to UTF-8.
 887 dnl (2) In glibc-2.1.2 and earlier there is a bug that messes up ob and
 888 dnl     obl when args 2 and 3 are 0 (fixed in glibc-2.1.3).
 889 AC_CACHE_CHECK([whether this iconv is good enough], mutt_cv_iconv_good,
 890         mutt_save_LIBS="$LIBS"
 891         LIBS="$LIBS $LIBICONV"
 892         AC_TRY_RUN([
 893 #include <iconv.h>
 894 int main()
 895 {
 896   iconv_t cd;
 897 changequote(, )dnl
 898   char buf[4];
 899 changequote([, ])dnl
 900   char *ob;
 901   size_t obl;
 902   ob = buf, obl = sizeof(buf);
 903   return ((cd = iconv_open("UTF-8", "UTF-8")) != (iconv_t)(-1) &&
 904           (iconv(cd, 0, 0, &ob, &obl) ||
 905            !(ob == buf && obl == sizeof(buf)) ||
 906            iconv_close(cd)));
 907 }
 908                 ],
 909                 mutt_cv_iconv_good=yes,
 910                 mutt_cv_iconv_good=no,
 911                 mutt_cv_iconv_good=yes)
 912         LIBS="$mutt_save_LIBS")
 913 if test "$mutt_cv_iconv_good" = no; then
 914   AC_MSG_ERROR(Try using libiconv instead)
 915 fi
 916
 917 dnl This is to detect implementations such as the one in glibc-2.1,
 918 dnl which always convert exactly but return the number of characters
 919 dnl converted instead of the number converted inexactly.
 920 AC_CACHE_CHECK([whether iconv is non-transcribing], mutt_cv_iconv_nontrans,
 921         mutt_save_LIBS="$LIBS"
 922         LIBS="$LIBS $LIBICONV"
 923         AC_TRY_RUN([
 924 #include <iconv.h>
 925 #include <string.h>
 926 int main()
 927 {
 928   iconv_t cd;
 929   const char *ib;
 930   char *ob;
 931   size_t ibl, obl;
 932   const char *s = "\304\211";
 933 changequote(, )dnl
 934   char t[3];
 935 changequote([, ])dnl
 936   ib = s, ibl = 2, ob = t, obl = 3;
 937   return ((cd = iconv_open("UTF-8", "UTF-8")) == (iconv_t)(-1) ||
 938           iconv(cd, &ib, &ibl, &ob, &obl));
 939 }
 940                 ],
 941                 mutt_cv_iconv_nontrans=no,
 942                 mutt_cv_iconv_nontrans=yes,
 943                 mutt_cv_iconv_nontrans=no)
 944         LIBS="$mutt_save_LIBS")
 945 if test "$mutt_cv_iconv_nontrans" = yes; then
 946   AC_DEFINE(ICONV_NONTRANS, 1)
 947 else
 948   AC_DEFINE(ICONV_NONTRANS, 0)
 949 fi
 950
 951 CPPFLAGS="$CPPFLAGS -I\$(top_srcdir)/intl"
 952
 953 if test "$BUILD_INCLUDED_LIBINTL" = "yes"; then
 954   AC_DEFINE(HAVE_BIND_TEXTDOMAIN_CODESET,1,
 955           [ Define if your gettext has bind_textdomain_codeset. ])
 956 else
 957   AC_CHECK_FUNCS(bind_textdomain_codeset)
 958 fi
 959
 960 fi # libiconv
 961
 962 dnl -- locales --
 963
 964 AC_CHECK_HEADERS(wchar.h)
 965
 966 AC_CACHE_CHECK([for wchar_t], mutt_cv_wchar_t,
 967         AC_TRY_COMPILE([
 968 #include <stddef.h>
 969 #include <stdlib.h>
 970 #ifdef HAVE_WCHAR_H
 971 #include <wchar.h>
 972 #endif
 973                 ],
 974                 [ wchar_t wc; return 0; ],
 975                 mutt_cv_wchar_t=yes,
 976                 mutt_cv_wchar_t=no))
 977
 978 if test "$mutt_cv_wchar_t" = no; then
 979         AC_DEFINE(wchar_t,int,[ Define to 'int' if system headers don't define. ])
 980 fi
 981
 982 AC_CACHE_CHECK([for wint_t], mutt_cv_wint_t,
 983         AC_TRY_COMPILE([
 984 #include <stddef.h>
 985 #include <stdlib.h>
 986 #ifdef HAVE_WCHAR_H
 987 #include <wchar.h>
 988 #endif
 989                 ],
 990                 [ wint_t wc; return 0; ],
 991                 mutt_cv_wint_t=yes,
 992                 mutt_cv_wint_t=no))
 993
 994 if test "$mutt_cv_wint_t" = no; then
 995         AC_DEFINE(wint_t,int,[ Define to 'int' if system headers don't define. ])
 996 fi
 997
 998 AC_CHECK_HEADERS(wctype.h)
 999 AC_CHECK_FUNCS(iswalnum iswalpha  iswcntrl iswdigit)
1000 AC_CHECK_FUNCS(iswgraph iswlower iswprint iswpunct iswspace iswupper)
1001 AC_CHECK_FUNCS(iswxdigit towupper towlower)
1002
1003 AC_CACHE_CHECK([for mbstate_t], mutt_cv_mbstate_t,
1004         AC_TRY_COMPILE([
1005 #include <stddef.h>
1006 #include <stdlib.h>
1007 #ifdef HAVE_WCHAR_H
1008 #include <wchar.h>
1009 #endif
1010                 ],
1011                 [ mbstate_t s; return 0; ],
1012                 mutt_cv_mbstate_t=yes,
1013                 mutt_cv_mbstate_t=no))
1014
1015 if test "$mutt_cv_mbstate_t" = no; then
1016         AC_DEFINE(mbstate_t,int,[ Define to 'int' if system headers don't define. ])
1017 fi
1018
1019 wc_funcs=maybe
1020 AC_ARG_WITH(wc-funcs, AC_HELP_STRING([--without-wc-funcs], [Do not use the system's wchar_t functions]),
1021         wc_funcs=$withval)
1022
1023 if test "$wc_funcs" != yes -a "$wc_funcs" != no; then
1024         AC_CACHE_CHECK([for wchar_t functions], mutt_cv_wc_funcs,
1025                 mutt_cv_wc_funcs=no
1026                 AC_TRY_LINK([
1027 #define _XOPEN_SOURCE 1
1028 #include <stddef.h>
1029 #include <stdlib.h>
1030 #ifdef HAVE_WCTYPE_H
1031 #include <wctype.h>
1032 #endif
1033 #ifdef HAVE_WCHAR_H
1034 #include <wchar.h>
1035 #endif],
1036                         [mbrtowc(0, 0, 0, 0); wctomb(0, 0); wcwidth(0);
1037         iswprint(0); iswspace(0); towlower(0); towupper(0); iswalnum(0)],
1038                         mutt_cv_wc_funcs=yes))
1039         wc_funcs=$mutt_cv_wc_funcs
1040 fi
1041
1042 if test $wc_funcs = yes; then
1043         AC_DEFINE(HAVE_WC_FUNCS,1,[ Define if you are using the system's wchar_t functions. ])
1044 fi
1045
1046 AC_CACHE_CHECK([for nl_langinfo and CODESET], mutt_cv_langinfo_codeset,
1047   [AC_TRY_LINK([#include <langinfo.h>],
1048     [char* cs = nl_langinfo(CODESET);],
1049     mutt_cv_langinfo_codeset=yes,
1050     mutt_cv_langinfo_codeset=no)])
1051 if test $mutt_cv_langinfo_codeset = yes; then
1052   AC_DEFINE(HAVE_LANGINFO_CODESET,1,[ Define if you have <langinfo.h> and nl_langinfo(CODESET). ])
1053 fi
1054
1055 AC_CACHE_CHECK([for nl_langinfo and YESEXPR], mutt_cv_langinfo_yesexpr,
1056   [AC_TRY_LINK([#include <langinfo.h>],
1057     [char* cs = nl_langinfo(YESEXPR);],
1058     mutt_cv_langinfo_yesexpr=yes,
1059     mutt_cv_langinfo_yesexpr=no)])
1060 if test $mutt_cv_langinfo_yesexpr = yes; then
1061   AC_DEFINE(HAVE_LANGINFO_YESEXPR,1,[ Define if you have <langinfo.h> and nl_langinfo(YESEXPR). ])
1062 fi
1063
1064 dnl -- libesmtp --
1065 MUTT_AM_LIBESMTP
1066 if test x$use_libesmtp = xyes; then
1067     CFLAGS="$CFLAGS $mutt_libesmtp_cflags"
1068     MUTTLIBS="$MUTTLIBS $mutt_libesmtp_libs"
1069     MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_libesmtp.o"
1070
1071     AC_DEFINE(USE_LIBESMTP,
1072               1,
1073               [Define to enable the use of libesmtp])
1074 fi
1075 dnl -- end libesmtp --
1076
1077 dnl -- sgml tools --
1078
1079 dnl Documentation tools
1080 have_openjade="no"
1081 AC_PATH_PROG([OSPCAT], [ospcat], [none])
1082 if test "$OSPCAT" != "none"
1083 then
1084   AC_MSG_CHECKING([for openjade docbook stylesheets])
1085   dslosfile=`ospcat --public-id="-//Norman Walsh//DOCUMENT DocBook Print Stylesheet//EN"`
1086   DSLROOT=`echo $dslosfile | sed -n -e "s/.*SOIBASE='\(@<:@^'@:>@*\)\/catalog'.*/\1/p"`
1087   # ospcat may spit out an absolute path without an SOIBASE
1088   if test -z "$DSLROOT"
1089   then
1090     DSLROOT=`echo $dslosfile | sed -e 's|<OSFILE>\(.*\)/print/docbook.dsl|\1|'`
1091   fi
1092   if test -f $DSLROOT/print/docbook.dsl
1093   then
1094     AC_MSG_RESULT([in $DSLROOT])
1095     have_openjade="yes"
1096   else
1097     AC_MSG_RESULT([not found: PDF documentation will not be built.])
1098   fi
1099 fi
1100 AC_SUBST(DSLROOT)
1101
1102 AC_MSG_CHECKING([for lynx])
1103 AC_PATH_PROG([HTML2TXT_CMD], [lynx], [none])
1104 if test x"$HTML2TXT_CMD" = x"none"
1105 then
1106   AC_MSG_CHECKING([for w3m])
1107   AC_PATH_PROG([HTML2TXT_CMD], [w3m], [none])
1108 fi
1109 if test x"$HTML2TXT_CMD" = x"none"
1110 then
1111   AC_MSG_CHECKING([for elinks])
1112   AC_PATH_PROG([HTML2TXT_CMD], [elinks], [none])
1113 fi
1114 case "$HTML2TXT_CMD" in
1115   *elinks*)
1116     HTML2TXT_CMD="$HTML2TXT_CMD -dump -no-numbering -no-references \$^ > \$@"
1117     ;;
1118   *lynx*)
1119     HTML2TXT_CMD="$HTML2TXT_CMD -dump -nolist -with_backspaces \$^ > \$@"
1120     ;;
1121   *w3m*)
1122     HTML2TXT_CMD="$HTML2TXT_CMD -dump \$^ > \$@"
1123     ;;
1124   *)
1125     HTML2TXT_CMD="true"
1126     ;;
1127 esac
1128 AC_SUBST(HTML2TXT_CMD)
1129
1130 AC_MSG_CHECKING([for tidy])
1131 AC_PATH_PROG([HTMLCLEAN_CMD], [tidy], [none])
1132
1133 if test x"$HTMLCLEAN_CMD" != x"none"
1134 then
1135   HTMLCLEAN_CMD="$HTMLCLEAN_CMD -q -i -m -asxml -utf8 "
1136 else
1137   HTMLCLEAN_CMD="echo "
1138 fi
1139 AC_SUBST(HTMLCLEAN_CMD)
1140
1141 AC_OUTPUT(Makefile intl/Makefile m4/Makefile
1142         po/Makefile.in doc/Makefile contrib/Makefile
1143         muttbug.sh
1144         lib-lib/Makefile
1145         lib-mime/Makefile
1146         lib-hash/Makefile
1147         lib/Makefile
1148         imap/Makefile
1149         pop/Makefile
1150         nntp/Makefile
1151         Muttngrc.head
1152         doc/instdoc.sh)