configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl !!! WHEN ADDING NEW CONFIGURE TESTS, PLEASE ADD CODE TO MAIN.C !!!
   4 dnl !!! TO DUMP THEIR RESULTS WHEN MUTT -V IS CALLED            !!!
   5
   6 AC_PREREQ([2.50])
   7 AC_INIT([mutt.h])
   8 AM_CONFIG_HEADER(config.h)
   9
  10 mutt_cv_version=`cat "$srcdir/VERSION.in"`
  11
  12 AM_INIT_AUTOMAKE(muttng, $mutt_cv_version)
  13 AC_SUBST([CONFIGURE_DEPENDENCIES], ['$(top_srcdir)/VERSION.in'])
  14
  15 AC_GNU_SOURCE
  16
  17 ifdef([AC_LIBOBJ], , [define([AC_LIBOBJ], [LIB[]OBJS="$LIBOBJS $1.o"])])
  18
  19 ALL_LINGUAS="de ru it es uk fr pl nl cs id sk ko el zh_TW zh_CN pt_BR eo gl sv da lt tr ja hu et ca bg"
  20
  21 AC_CANONICAL_HOST
  22
  23 AC_MSG_CHECKING([for prefix])
  24 if test x$prefix = xNONE; then
  25     mutt_cv_prefix=$ac_default_prefix
  26 else
  27     mutt_cv_prefix=$prefix
  28 fi
  29 AC_MSG_RESULT($mutt_cv_prefix)
  30
  31 AC_PROG_CC
  32 AC_ISC_POSIX
  33 AM_C_PROTOTYPES
  34 if test "x$U" != "x"; then
  35     AC_MSG_ERROR(Compiler not ANSI compliant)
  36 fi
  37 AC_PROG_CPP
  38 AC_PROG_MAKE_SET
  39 AC_PROG_INSTALL
  40 AC_PROG_RANLIB
  41 AC_CHECK_TOOL(AR, ar, ar)
  42
  43 AC_C_INLINE
  44 AC_C_CONST
  45
  46 AC_SYS_LARGEFILE
  47 AC_FUNC_FSEEKO
  48 AC_CHECK_SIZEOF(off_t)
  49
  50 AC_PATH_PROG(DBX, dbx, no)
  51 AC_PATH_PROG(GDB, gdb, no)
  52 AC_PATH_PROG(SDB, sdb, no)
  53
  54 if test $GDB != no ; then
  55     DEBUGGER=$GDB
  56 elif test $DBX != no ; then
  57     DEBUGGER=$DBX
  58 elif test $SDB != no ; then
  59     DEBUGGER=$SDB
  60 else
  61     DEBUGGER=no
  62 fi
  63
  64 AC_SUBST([DEBUGGER])
  65
  66 AH_TEMPLATE([sig_atomic_t],
  67             [Define to 'int' if <signal.h> doesn't define.])
  68 AH_TEMPLATE([HAVE_START_COLOR],
  69             [Define if you have start_color, as a function or macro.])
  70 AH_TEMPLATE([HAVE_TYPEAHEAD],
  71             [Define if you have typeahead, as a function or macro.])
  72 AH_TEMPLATE([HAVE_BKGDSET],
  73             [Define if you have bkgdset, as a function or macro.])
  74 AH_TEMPLATE([HAVE_CURS_SET],
  75             [Define if you have curs_set, as a function or macro.])
  76 AH_TEMPLATE([HAVE_META],
  77             [Define if you have meta, as a function or macro.])
  78 AH_TEMPLATE([HAVE_USE_DEFAULT_COLORS],
  79             [Define if you have use_default_colors, as a function or macro.])
  80 AH_TEMPLATE([HAVE_RESIZETERM],
  81             [Define if you have resizeterm, as a function or macro.])
  82 AH_TEMPLATE([SIG_ATOMIC_VOLATILE_T],
  83             [Some systems declare sig_atomic_t as volatile, some others -- no.
  84              This define will have value `sig_atomic_t' or
  85              `volatile sig_atomic_t' accordingly.])
  86 AH_TEMPLATE([ICONV_NONTRANS],
  87             [Define as 1 if iconv() only converts exactly and we should treat
  88              all return values other than (size_t)(-1) as equivalent.])
  89
  90 MUTT_C99_INTTYPES
  91
  92 dnl ---------------- sendmail ----------------
  93
  94 ac_aux_path_sendmail=/usr/sbin:/usr/lib
  95 AC_PATH_PROG(SENDMAIL, sendmail, /usr/sbin/sendmail, $PATH:$ac_aux_path_sendmail)
  96 AC_DEFINE_UNQUOTED(SENDMAIL,"$ac_cv_path_SENDMAIL",[ Where to find sendmail on your system. ])
  97
  98
  99 OPS='$(srcdir)/OPS'
 100
 101 dnl ---------------- gpgme ----------------
 102
 103     AC_ARG_ENABLE(gpgme, AC_HELP_STRING([--enable-gpgme], [Enable GPGME support]),
 104     [   if test x$enableval = xyes; then
 105             have_gpgme=yes
 106         fi
 107     ])
 108     AC_ARG_WITH(gpgme-prefix, AC_HELP_STRING([--with-gpgme-prefix=PFX], [prefix where GPGME is installed (optional)]),
 109     gpgme_config_prefix="$withval", gpgme_config_prefix="")
 110
 111     if test x$have_gpgme = xyes; then
 112         if test x$gpgme_config_prefix != x; then
 113             GPGME_CONFIG="$gpgme_config_prefix/bin/gpgme-config"
 114         else
 115             AC_PATH_PROG(GPGME_CONFIG, gpgme-config, no)
 116         fi
 117         if test "x$GPGME_CONFIG" = "xno"; then
 118             AC_MSG_ERROR([GPGME not found])
 119         else
 120             LIBGPGME_CFLAGS=`$GPGME_CONFIG --cflags`
 121             LIBGPGME_LIBS=`$GPGME_CONFIG --libs`
 122             MUTTLIBS="$MUTTLIBS $LIBGPGME_LIBS"
 123             MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS crypt-gpgme.o crypt-mod-pgp-gpgme.o crypt-mod-smime-gpgme.o"
 124             AC_DEFINE(CRYPT_BACKEND_GPGME, 1, [Defined, if GPGME support is enabled])
 125         fi
 126     fi
 127     AC_SUBST(LIBGPGME_CFLAGS)
 128     AC_SUBST(LIBGPGME_LIBS)
 129
 130 dnl ---------------- mixmaster ----------------
 131
 132     AC_ARG_WITH(mixmaster, AC_HELP_STRING([--with-mixmaster[=PATH]], [Include Mixmaster support]),
 133     [   if test -x "$withval" ; then
 134             MIXMASTER="$withval"
 135         else
 136             MIXMASTER="mixmaster"
 137         fi
 138         OPS="$OPS \$(srcdir)/OPS.MIX"
 139         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS remailer.o"
 140         AC_DEFINE_UNQUOTED(MIXMASTER,"$MIXMASTER", [ Where to find mixmaster on your system. ])
 141     ])
 142
 143 # We now require all OPS
 144 OPS="$OPS \$(srcdir)/OPS.PGP \$(srcdir)/OPS.SMIME \$(srcdir)/OPS.CRYPT "
 145 AC_SUBST([OPS])
 146
 147 AC_PATH_PROG(ISPELL, ispell, no)
 148 if test $ISPELL != no; then
 149     AC_DEFINE_UNQUOTED(ISPELL,"$ISPELL",[ Where to find ispell on your system. ])
 150 fi
 151
 152 AC_ARG_WITH(slang, AC_HELP_STRING([--with-slang[=DIR]], [Use S-Lang instead of ncurses]),
 153     [AC_CACHE_CHECK([if this is a BSD system], mutt_cv_bsdish,
 154         [AC_TRY_RUN([#include <sys/param.h>
 155
 156 main ()
 157 {
 158 #ifdef BSD
 159         exit (0);
 160 #else
 161         exit (1);
 162 #endif
 163 }],
 164         mutt_cv_bsdish=yes,
 165         mutt_cv_bsdish=no,
 166         mutt_cv_bsdish=no)])
 167
 168         AC_MSG_CHECKING(for S-Lang)
 169         if test $withval = yes; then
 170             if test -d $srcdir/../slang; then
 171                 mutt_cv_slang=$srcdir/../slang/src
 172                 CFLAGS="$CFLAGS -I${mutt_cv_slang}"
 173                 LDFLAGS="$LDFLAGS -L${mutt_cv_slang}/objs"
 174             else
 175                 if test -d $mutt_cv_prefix/include/slang; then
 176                     CFLAGS="$CFLAGS -I$mutt_cv_prefix/include/slang"
 177                 elif test -d /usr/include/slang; then
 178                     CFLAGS="$CFLAGS -I/usr/include/slang"
 179                 fi
 180                 mutt_cv_slang=yes
 181             fi
 182         else
 183             dnl ---Check to see if $withval is a source directory
 184             if test -f $withval/src/slang.h; then
 185                 mutt_cv_slang=$withval/src
 186                 CFLAGS="$CFLAGS -I${mutt_cv_slang}"
 187                 LDFLAGS="$LDFLAGS -L${mutt_cv_slang}/objs"
 188             else
 189                 dnl ---Must be installed somewhere
 190                 mutt_cv_slang=$withval
 191                 if test -d $withval/include/slang; then
 192                         CFLAGS="$CFLAGS -I${withval}/include/slang"
 193                 elif test -d $withval/include; then
 194                         CFLAGS="$CFLAGS -I${withval}/include"
 195                 fi
 196                 LDFLAGS="$LDFLAGS -L${withval}/lib"
 197             fi
 198         fi
 199         AC_MSG_RESULT($mutt_cv_slang)
 200         if test $mutt_cv_bsdish = yes; then
 201             AC_CHECK_LIB(termlib, main)
 202         fi
 203         AC_DEFINE(USE_SLANG_CURSES,1, [ Define if you compile with SLang instead of curses/ncurses. ])
 204         AC_DEFINE(HAVE_COLOR,1,[ Define if your curses library supports color. ])
 205         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS resize.o"
 206
 207         dnl --- now that we've found it, check the link
 208
 209         AC_CHECK_LIB(slang, SLtt_get_terminfo,
 210             [MUTTLIBS="$MUTTLIBS -lslang -lm"],
 211             [AC_MSG_ERROR(unable to compile.  check config.log)], -lm)
 212         ],
 213
 214         [   mutt_cv_curses=/usr
 215             AC_ARG_WITH(curses, AC_HELP_STRING([--with-curses=DIR], [Where ncurses is installed]),
 216             [   if test $withval != yes; then
 217                     mutt_cv_curses=$withval
 218                 fi
 219                 if test x$mutt_cv_curses != x/usr; then
 220                     LDFLAGS="-L${mutt_cv_curses}/lib $LDFLAGS"
 221                     CPPFLAGS="$CPPFLAGS -I${mutt_cv_curses}/include"
 222                 fi
 223             ])
 224
 225             AC_CHECK_FUNC(initscr,,[
 226             cf_ncurses="ncurses"
 227             for lib in ncursesw ncurses; do
 228                 AC_CHECK_LIB($lib, waddnwstr, [cf_ncurses="$lib"; break])
 229             done
 230             AC_CHECK_LIB($cf_ncurses, initscr,
 231                 [   MUTTLIBS="$MUTTLIBS -l$cf_ncurses"
 232                     if test x$mutt_cv_curses = x/usr -a -d /usr/include/ncurses; then
 233                         CPPFLAGS="$CPPFLAGS -I/usr/include/ncurses"
 234                     fi
 235
 236                     if test "$cf_ncurses" = ncursesw; then
 237                         AC_CHECK_HEADERS(ncurses/ncurses.h,[cf_cv_ncurses_header="ncurses/ncurses.h"])
 238                         AC_CHECK_HEADERS(ncursesw/ncurses.h,[cf_cv_ncurses_header="ncursesw/ncurses.h"])
 239                     else
 240                         AC_CHECK_HEADERS(ncurses.h,[cf_cv_ncurses_header="ncurses.h"])
 241                     fi
 242                 ],
 243                 [CF_CURSES_LIBS])
 244             ])
 245
 246             old_LIBS="$LIBS"
 247             LIBS="$LIBS $MUTTLIBS"
 248             CF_CHECK_FUNCDECLS([#include <${cf_cv_ncurses_header-curses.h}>],
 249                                [start_color typeahead bkgdset curs_set meta use_default_colors resizeterm])
 250             if test "$ac_cv_func_decl_start_color" = yes; then
 251                 AC_DEFINE(HAVE_COLOR,1,[ Define if your curses library supports color. ])
 252             fi
 253             if test "$ac_cv_func_decl_resizeterm" = yes; then
 254                 MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS resize.o"
 255             fi
 256             LIBS="$old_LIBS"
 257         ])
 258
 259 AC_HEADER_STDC
 260
 261 AC_CHECK_HEADERS(stdarg.h sys/ioctl.h ioctl.h sysexits.h)
 262 AC_CHECK_HEADERS(sys/time.h sys/resource.h)
 263 AC_CHECK_HEADERS(unix.h)
 264
 265 AC_CHECK_FUNCS(setrlimit getsid isctype)
 266
 267 AC_TYPE_SIGNAL
 268
 269 AC_MSG_CHECKING(for sig_atomic_t in signal.h)
 270 AC_EGREP_HEADER(sig_atomic_t,signal.h,
 271     [   ac_cv_type_sig_atomic_t=yes;
 272         AC_EGREP_HEADER(volatile.*sig_atomic_t,
 273                         signal.h,
 274                         [is_sig_atomic_t_volatile=yes; AC_MSG_RESULT([yes, volatile])],
 275                         [is_sig_atomic_t_volatile=no;  AC_MSG_RESULT([yes, non volatile])])
 276     ],
 277     [   AC_MSG_RESULT(no)
 278         AC_CHECK_TYPE(sig_atomic_t, int)
 279         is_sig_atomic_t_volatile=no
 280     ])
 281 if test $is_sig_atomic_t_volatile = 'yes'
 282 then
 283     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, sig_atomic_t)
 284 else
 285     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, [volatile sig_atomic_t])
 286 fi
 287
 288 AC_DECL_SYS_SIGLIST
 289
 290 AC_TYPE_PID_T
 291 dnl AC_CHECK_TYPE(ssize_t, int)
 292
 293 AC_CHECK_FUNCS(fgetpos memmove setegid srand48 strerror)
 294 AC_REPLACE_FUNCS(strcasecmp setenv)
 295 AC_CHECK_FUNCS(snprintf vsnprintf)
 296
 297 AC_CHECK_FUNC(getopt)
 298 if test $ac_cv_func_getopt = yes; then
 299     AC_CHECK_HEADERS(getopt.h)
 300 fi
 301
 302 dnl SCO uses chsize() instead of ftruncate()
 303 AC_CHECK_FUNCS(ftruncate, , [AC_CHECK_LIB(x, chsize)])
 304
 305 dnl SCO has strftime() in libintl
 306 AC_CHECK_FUNCS(strftime, , [AC_CHECK_LIB(intl, strftime)])
 307
 308 dnl AIX may not have fchdir()
 309 AC_CHECK_FUNCS(fchdir, , [mutt_cv_fchdir=no])
 310
 311 AC_ARG_WITH(regex, AC_HELP_STRING([--with-regex], [Use the GNU regex library]),
 312         [mutt_cv_regex=yes],
 313         [AC_CHECK_FUNCS(regcomp, mutt_cv_regex=no, mutt_cv_regex=yes)])
 314
 315 if test $mutt_cv_regex = no ; then
 316     AC_CACHE_CHECK([whether your system's regexp library is completely broken],
 317         [mutt_cv_regex_broken],
 318         AC_TRY_RUN([
 319 #include <unistd.h>
 320 #include <regex.h>
 321 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
 322         mutt_cv_regex_broken=no, mutt_cv_regex_broken=yes, mutt_cv_regex_broken=yes))
 323     if test $mutt_cv_regex_broken = yes ; then
 324         echo "Using the included GNU regex instead." >&AC_FD_MSG
 325         mutt_cv_regex=yes
 326     fi
 327 fi
 328
 329 if test $mutt_cv_regex = yes; then
 330     AC_DEFINE(USE_GNU_REGEX,1,[ Define if you want to use the included regex.c. ])
 331     AC_LIBOBJ(regex)
 332 fi
 333
 334
 335 AC_ARG_WITH(homespool,
 336             AC_HELP_STRING([--with-homespool[=FILE]],
 337                            [File in user's directory where new mail is spooled]),
 338                            with_homespool=${withval})
 339 if test x$with_homespool != x; then
 340     if test $with_homespool = yes; then
 341             with_homespool=mailbox
 342     fi
 343     AC_DEFINE_UNQUOTED(MAILPATH,"$with_homespool",[ Where new mail is spooled. ])
 344     AC_DEFINE(HOMESPOOL,1,
 345     [   Is mail spooled to the user's home directory?  If defined,
 346         MAILPATH should be set to the filename of the spool mailbox
 347         relative the the home directory.
 348         use: configure --with-homespool=FILE
 349     ])
 350     AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 351     mutt_cv_setgid=no
 352 else
 353     AC_ARG_WITH(mailpath, AC_HELP_STRING([--with-mailpath=DIR], [Directory where spool mailboxes are located]),
 354         [mutt_cv_mailpath=$withval],
 355         [ AC_CACHE_CHECK(where new mail is stored, mutt_cv_mailpath,
 356             [mutt_cv_mailpath=no
 357             if test -d /var/mail; then
 358                 mutt_cv_mailpath=/var/mail
 359             elif test -d /var/spool/mail; then
 360                 mutt_cv_mailpath=/var/spool/mail
 361             elif test -d /usr/spool/mail; then
 362                 mutt_cv_mailpath=/usr/spool/mail
 363             elif test -d /usr/mail; then
 364                 mutt_cv_mailpath=/usr/mail
 365             fi])
 366         ])
 367     if test "$mutt_cv_mailpath" = no; then
 368         AC_MSG_ERROR("Could not determine where new mail is stored.")
 369     fi
 370     AC_DEFINE_UNQUOTED(MAILPATH,"$mutt_cv_mailpath",[ Where new mail is spooled. ])
 371
 372     AC_CACHE_CHECK(if $mutt_cv_mailpath is world writable, mutt_cv_worldwrite, [AC_TRY_RUN([#include <sys/types.h>
 373 #include <sys/stat.h>
 374
 375 int main (int argc, char **argv)
 376 {
 377         struct stat s;
 378
 379         stat ("$mutt_cv_mailpath", &s);
 380         if (s.st_mode & S_IWOTH) exit (0);
 381         exit (1);
 382 }], mutt_cv_worldwrite=yes, mutt_cv_worldwrite=no, mutt_cv_worldwrite=no)])
 383
 384         mutt_cv_setgid=no
 385         if test $mutt_cv_worldwrite = yes; then
 386                 AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 387         else
 388
 389                 AC_CACHE_CHECK(if $mutt_cv_mailpath is group writable, mutt_cv_groupwrite, [AC_TRY_RUN([#include <sys/types.h>
 390 #include <sys/stat.h>
 391
 392 int main (int argc, char **argv)
 393 {
 394         struct stat s;
 395
 396         stat ("$mutt_cv_mailpath", &s);
 397         if (s.st_mode & S_IWGRP) exit (0);
 398         exit (1);
 399 }], mutt_cv_groupwrite=yes, mutt_cv_groupwrite=no, mutt_cv_groupwrite=no)])
 400
 401         if test $mutt_cv_groupwrite = yes; then
 402             AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 403             AC_DEFINE(USE_SETGID,1,[ Define if mutt should run setgid "mail". ])
 404             mutt_cv_setgid=yes
 405         fi
 406     fi
 407 fi
 408
 409 AC_MSG_CHECKING(where to put the documentation)
 410 AC_ARG_WITH(docdir, AC_HELP_STRING([--with-docdir=PATH], [Specify where to put the documentation]),
 411         [mutt_cv_docdir=$withval],
 412         [mutt_cv_docdir="${prefix}/doc/muttng"])
 413 AC_MSG_RESULT($mutt_cv_docdir)
 414
 415 docdir=$mutt_cv_docdir
 416 AC_SUBST(docdir)
 417
 418 if test x$mutt_cv_setgid = xyes; then
 419     DOTLOCK_GROUP='mail'
 420     DOTLOCK_PERMISSION=2755
 421 else
 422     DOTLOCK_GROUP=''
 423     DOTLOCK_PERMISSION=755
 424 fi
 425 AC_SUBST(DOTLOCK_GROUP)
 426 AC_SUBST(DOTLOCK_PERMISSION)
 427
 428 AC_ARG_WITH(domain, AC_HELP_STRING([--with-domain=DOMAIN], [Specify your DNS domain name]),
 429         [if test $withval != yes; then
 430          if test $withval != no; then
 431            AC_DEFINE_UNQUOTED(DOMAIN,"$withval",[ Define your domain name. ])
 432          fi
 433         fi])
 434
 435 need_socket="no"
 436
 437 dnl -- socket dependencies --
 438
 439 AC_ARG_ENABLE(pop,  AC_HELP_STRING([--enable-pop], [Enable POP3 support]),
 440 [   if test x$enableval = xyes ; then
 441         AC_DEFINE(USE_POP,1,[ Define if you want support for the POP3 protocol. ])
 442         LIBPOP="-Lpop -lpop"
 443         LIBPOPDEPS="\$(top_srcdir)/pop/pop.h pop/libpop.a"
 444         need_socket="yes"
 445         need_pop="yes"
 446         need_md5="yes"
 447     fi
 448 ])
 449 AM_CONDITIONAL(BUILD_POP, test x$need_pop = xyes)
 450
 451 AC_ARG_ENABLE(imap, AC_HELP_STRING([--enable-imap], [Enable IMAP support]),
 452 [   if test x$enableval = xyes ; then
 453         AC_DEFINE(USE_IMAP,1,[ Define if you want support for the IMAP protocol. ])
 454         LIBIMAP="-Limap -limap"
 455         LIBIMAPDEPS="\$(top_srcdir)/imap/imap.h imap/libimap.a"
 456         need_imap="yes"
 457         need_socket="yes"
 458         need_md5="yes"
 459     fi
 460 ])
 461 AM_CONDITIONAL(BUILD_IMAP, test x$need_imap = xyes)
 462
 463 AC_ARG_ENABLE(nntp, [  --enable-nntp              Enable NNTP support],
 464 [   if test x$enableval = xyes ; then
 465         AC_DEFINE(USE_NNTP,1,[ Compiling with newsreading support with NNTP ])
 466         LIBNNTP="-Lnntp -lnntp"
 467         LIBNNTPDEPS="\$(top_srcdir)/nntp/nntp.h nntp/libnntp.a"
 468         need_nntp="yes"
 469         need_socket="yes"
 470     fi
 471 ])
 472 AM_CONDITIONAL(BUILD_NNTP, test x$need_nntp = xyes)
 473
 474 dnl -- end socket dependencies --
 475
 476 if test "$need_socket" = "yes"
 477 then
 478     AC_MSG_CHECKING([for socklen_t])
 479     AC_EGREP_HEADER(socklen_t, sys/socket.h, AC_MSG_RESULT([yes]),
 480             AC_MSG_RESULT([no])
 481             AC_DEFINE(socklen_t,int, [ Define to 'int' if <sys/socket.h> doesn't have it. ]))
 482     AC_CHECK_FUNC(gethostent, , AC_CHECK_LIB(nsl, gethostent))
 483     AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt))
 484     AC_CHECK_FUNCS(getaddrinfo)
 485     AC_DEFINE(USE_SOCKET,1,
 486             [ Include code for socket support. Set automatically if you enable POP3 or IMAP ])
 487     MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS account.o mutt_socket.o mutt_tunnel.o"
 488 fi
 489
 490 dnl -- imap dependencies --
 491
 492 AC_ARG_WITH(gss, AC_HELP_STRING([--with-gss[=PFX]], [Compile in GSSAPI authentication for IMAP]),
 493     gss_prefix="$withval", gss_prefix="no")
 494 if test "$gss_prefix" != "no"
 495 then
 496   if test "$need_imap" = "yes"
 497   then
 498     MUTT_AM_PATH_GSSAPI(gss_prefix)
 499     AC_MSG_CHECKING(GSSAPI implementation)
 500     AC_MSG_RESULT($GSSAPI_IMPL)
 501     if test "$GSSAPI_IMPL" = "none"
 502     then
 503       AC_CACHE_SAVE
 504       AC_MSG_RESULT([GSSAPI libraries not found])
 505     fi
 506     if test "$GSSAPI_IMPL" = "Heimdal"
 507     then
 508       AC_DEFINE(HAVE_HEIMDAL,1,[ Define if your GSSAPI implementation is Heimdal ])
 509     fi
 510     CPPFLAGS="$CPPFLAGS $GSSAPI_CFLAGS"
 511     MUTTLIBS="$MUTTLIBS $GSSAPI_LIBS"
 512     AC_DEFINE(USE_GSS,1,[ Define if you have GSSAPI libraries available ])
 513     need_gss="yes"
 514   else
 515     AC_MSG_WARN([GSS was requested but IMAP is not enabled])
 516   fi
 517 fi
 518 AM_CONDITIONAL(USE_GSS, test x$need_gss = xyes)
 519
 520 dnl -- end imap dependencies --
 521
 522 AC_ARG_WITH(ssl, AC_HELP_STRING([--with-ssl[=PFX]], [Compile in SSL support for POP/IMAP]),
 523 [       if test "$with_ssl" != "no"
 524         then
 525           if test "$need_socket" != "yes"; then
 526            AC_MSG_ERROR([SSL support is only useful with POP or IMAP support])
 527           fi
 528
 529           if test "$with_ssl" != "yes"
 530           then
 531            LDFLAGS="$LDFLAGS -L$withval/lib"
 532            CPPFLAGS="$CPPFLAGS -I$withval/include"
 533           fi
 534           saved_LIBS="$LIBS"
 535
 536           AC_CHECK_LIB(crypto, X509_new,, AC_MSG_ERROR([Unable to find SSL library]))
 537           AC_CHECK_LIB(ssl, SSL_new,, AC_MSG_ERROR([Unable to find SSL library]), -lcrypto)
 538
 539           AC_CHECK_FUNCS(RAND_status RAND_egd)
 540
 541           AC_DEFINE(USE_SSL,1,[ Define if you want support for SSL. ])
 542           LIBS="$saved_LIBS"
 543           MUTTLIBS="$MUTTLIBS -lssl -lcrypto"
 544           MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_ssl.o"
 545           need_ssl=yes
 546
 547         fi
 548 ])
 549
 550 AC_ARG_WITH([gnutls], AC_HELP_STRING([--with-gnutls[=PFX]], [Enable SSL support using gnutls]),
 551     [gnutls_prefix="$withval"], [gnutls_prefix="no"])
 552 if test "$gnutls_prefix" != "no"
 553 then
 554   if test "$need_socket" != "yes"
 555   then
 556     AC_MSG_ERROR([SSL support is only useful with POP or IMAP support])
 557   fi
 558   if test x"$need_ssl" = x"yes"
 559   then
 560     AC_MSG_ERROR([Only either OpenSSL or GNUTLS may be used])
 561   fi
 562   MUTT_AM_PATH_GNUTLS([$gnutls_prefix],
 563     [dnl GNUTLS found
 564     CPPFLAGS="$CPPFLAGS $LIBGNUTLS_CFLAGS"
 565     MUTTLIBS="$MUTTLIBS $LIBGNUTLS_LIBS"
 566     AC_DEFINE(USE_GNUTLS, 1, [Define if you want support for SSL via the gnutls library.])
 567
 568     MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_ssl_gnutls.o"
 569     need_ssl=yes],
 570     [dnl GNUTLS not found
 571       AC_MSG_ERROR([could not find libgnutls])
 572     ])
 573 fi
 574
 575 AM_CONDITIONAL(USE_SSL, test x$need_ssl = xyes)
 576
 577 AC_ARG_WITH(sasl2, AC_HELP_STRING([--with-sasl2[=PFX]], [Use Cyrus SASL library version 2 for POP/IMAP authentication]),
 578         [
 579         if test "$with_sasl2" != "no" -a "$need_imap" != "yes" -a "$need_pop" != "yes"
 580         then
 581           AC_MSG_ERROR([SASL2 support is only useful with POP or IMAP support])
 582         fi
 583
 584         if test "$with_sasl2" != "no"
 585         then
 586           if test "$with_sasl2" != "yes"
 587           then
 588             CPPFLAGS="$CPPFLAGS -I$with_sasl2/include"
 589             LDFLAGS="$LDFLAGS -L$with_sasl2/lib"
 590           fi
 591
 592           saved_LIBS="$LIBS"
 593
 594           AC_CHECK_LIB(sasl2, sasl_client_init,,
 595             AC_MSG_ERROR([could not find libsasl2]),)
 596
 597           MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_sasl.o"
 598           MUTTLIBS="$MUTTLIBS -lsasl2"
 599           LIBS="$saved_LIBS"
 600           AC_DEFINE(USE_SASL,1,
 601                   [ Define if want to use version 2 of the Cyrus SASL library. ])
 602           need_sasl=yes
 603         fi
 604         ])
 605 AM_CONDITIONAL(USE_SASL, test x$need_sasl = xyes)
 606
 607 AC_ARG_WITH(idn, AC_HELP_STRING([--with-idn=[PFX]], [Use GNU libidn for domain names]),
 608                  [
 609                   if test "$with_idn" != "no" ; then
 610                         if test "$with_idn" != "yes" ; then
 611                            CPPFLAGS="$CPPFLAGS -I$with_idn/include"
 612                            LDFLAGS="$LDFLAGS -L$with_idn/lib"
 613                         fi
 614                   fi
 615                  ]
 616 )
 617
 618 if test "x$with_idn" != "xno"; then
 619    AC_CHECK_LIB(idn, stringprep_check_version)
 620    AC_CHECK_FUNCS(idna_to_unicode_utf8_from_utf8 idna_to_unicode_8z8z)
 621    AC_CHECK_FUNCS(idna_to_ascii_from_utf8 idna_to_ascii_8z)
 622    AC_CHECK_FUNCS(idna_to_ascii_lz idna_to_ascii_from_locale)
 623 fi
 624
 625 dnl -- end socket --
 626
 627 AC_ARG_ENABLE(debug, AC_HELP_STRING([--enable-debug], [Enable debugging support]),
 628         [ if test x$enableval = xyes ; then
 629                 AC_DEFINE(DEBUG,1,[ Define to enable debugging info. ])
 630           fi
 631          ])
 632
 633 AC_ARG_ENABLE(flock, AC_HELP_STRING([--enable-flock], [Use flock() to lock files]),
 634         [if test $enableval = yes; then
 635                 AC_DEFINE(USE_FLOCK,1, [ Define to use flock() to lock mailboxes. ])
 636         fi])
 637
 638 mutt_cv_fcntl=yes
 639 AC_ARG_ENABLE(fcntl, AC_HELP_STRING([--disable-fcntl], [Do NOT use fcntl() to lock files]),
 640         [if test $enableval = no; then mutt_cv_fcntl=no; fi])
 641
 642 if test $mutt_cv_fcntl = yes; then
 643         AC_DEFINE(USE_FCNTL,1, [ Define to use fcntl() to lock folders. ])
 644 fi
 645
 646 AC_MSG_CHECKING(whether struct dirent defines d_ino)
 647 ac_cv_dirent_d_ino=no
 648 AC_TRY_LINK([#include <dirent.h>],[struct dirent dp; (void)dp.d_ino],[ac_cv_dirent_d_ino=yes])
 649 if test x$ac_cv_dirent_d_ino = xyes ; then
 650   AC_DEFINE(HAVE_DIRENT_D_INO,1,
 651             [Define to 1 if your system has the dirent::d_ino member])
 652 fi
 653 AC_MSG_RESULT($ac_cv_dirent_d_ino)
 654
 655 AC_ARG_ENABLE(buffy-size, AC_HELP_STRING([--enable-buffy-size], [Use file size attribute instead of access time]),
 656         [if test x$enableval = xyes; then
 657                 AC_DEFINE(BUFFY_SIZE,1,[ Define to enable the "buffy_size" feature. ])
 658         fi])
 659
 660 AC_ARG_ENABLE(locales-fix, AC_HELP_STRING([--enable-locales-fix], [The result of isprint() is unreliable ]),
 661         [if test x$enableval = xyes; then
 662                 AC_DEFINE(LOCALES_HACK,1,[ Define if the result of isprint() is unreliable. ])
 663         fi])
 664
 665 AC_ARG_WITH(exec-shell, AC_HELP_STRING([--with-exec-shell=SHELL], [Specify alternate shell (ONLY if /bin/sh is broken)]),
 666         [if test $withval != yes; then
 667                 AC_DEFINE_UNQUOTED(EXECSHELL, "$withval",
 668                  [program to use for shell commands])
 669          else
 670                 AC_DEFINE_UNQUOTED(EXECSHELL, "/bin/sh")
 671         fi],
 672         [AC_DEFINE_UNQUOTED(EXECSHELL, "/bin/sh")])
 673
 674 dnl -- start cache --
 675 AC_ARG_ENABLE(hcache, AC_HELP_STRING([--enable-hcache], [Enable header caching]),
 676 [if test x$enableval = xyes; then
 677     AC_DEFINE(USE_HCACHE, 1, [Enable header caching])
 678
 679     OLDCPPFLAGS="$CPPFLAGS"
 680     OLDLIBS="$LIBS"
 681
 682     need_md5="yes"
 683
 684     ac_prefer_qdbm=yes
 685     AC_ARG_WITH(qdbm, AC_HELP_STRING([--without-qdbm], [Don't use qdbm even if it is available]),
 686         ac_prefer_qdbm=$withval)
 687     if test x$ac_prefer_qdbm != xno; then
 688         ac_cv_vlopen=no
 689         QDBM_DIRS="$mutt_cv_prefix /usr/local /usr"
 690         AC_MSG_CHECKING([for vlopen])
 691         for d in $QDBM_DIRS; do
 692           if test x$ac_cv_vlopen = xno && test -d "$d/include" && test -d "$d/lib"; then
 693             QDBM_INC="-I$d/include"
 694             QDBM_LIB="-L$d/lib"
 695             CPPFLAGS="$OLDCPPFLAGS $QDBM_INC"
 696             LIBS="$OLDLIBS $QDBM_LIB -lqdbm"
 697             AC_TRY_LINK([#include <villa.h>],[vlopen(0,0,0);],[ac_cv_vlopen=yes])
 698           fi
 699         done
 700         if test x$ac_cv_vlopen = xyes; then
 701           AC_MSG_RESULT(yes)
 702         else
 703           AC_MSG_RESULT(no)
 704         fi
 705     fi
 706
 707     ac_prefer_gdbm=yes
 708     AC_ARG_WITH(gdbm, AC_HELP_STRING([--without-gdbm], [Don't use gdbm even if it is available]),
 709         ac_prefer_gdbm=$withval)
 710     if test x$ac_prefer_gdbm != xno -a x$ac_cv_vlopen != xyes; then
 711         ac_cv_gdbmopen=no
 712         GDBM_DIRS="$mutt_cv_prefix /usr/local /usr"
 713         AC_MSG_CHECKING([for gdbm_open])
 714         for d in $GDBM_DIRS; do
 715           if test x$ac_cv_gdbmopen = xno && test -d "$d/include" && test -d "$d/lib"; then
 716             GDBM_INC="-I$d/include"
 717             GDBM_LIB="-L$d/lib"
 718             CPPFLAGS="$OLDCPPFLAGS $GDBM_INC"
 719             LIBS="$OLDLIBS $GDBM_LIB -lgdbm"
 720             AC_TRY_LINK([#include <gdbm.h>],[gdbm_open(0,0,0,0,0);],[ac_cv_gdbmopen=yes])
 721           fi
 722         done
 723         if test x$ac_cv_gdbmopen = xyes; then
 724           AC_MSG_RESULT(yes)
 725         else
 726           AC_MSG_RESULT(no)
 727         fi
 728     fi
 729
 730     ac_bdb_prefix=yes
 731     AC_ARG_WITH(bdb, AC_HELP_STRING([--with-bdb[=DIR]], [Use BerkeleyDB4 if gdbm is not available ]),
 732         ac_bdb_prefix=$withval)
 733     if test x$ac_bdb_prefix != xno -a x$ac_cv_gdbmopen != xyes -a x$ac_cv_vlopen != xyes; then
 734         test x$ac_bdb_prefix = xyes && ac_bdb_prefix="$mutt_cv_prefix /opt/csw/bdb4 /opt /usr/local /usr"
 735         for d in $ac_bdb_prefix; do
 736             bdbpfx="$bdbpfx $d"
 737             for v in BerkeleyDB.4.3 BerkeleyDB.4.2 BerkeleyDB.4.1; do
 738                 bdbpfx="$bdbpfx $d/$v"
 739             done
 740         done
 741         BDB_VERSIONS="db-4 db4 db-4.3 db4.3 db43 db-4.2 db4.2 db42 db-4.1 db4.1 db41 db ''"
 742         AC_MSG_CHECKING([for BerkeleyDB > 4.0])
 743         for d in $bdbpfx; do
 744             BDB_INCLUDE_DIR=""
 745             BDB_LIB_DIR=""
 746             for v in / $BDB_VERSIONS; do
 747                 if test -r "$d/include/$v/db.h"; then
 748                     BDB_INCLUDE_DIR="$d/include/$v"
 749                     if test -d "$d/lib/$v"; then
 750                         BDB_LIB_DIR="$d/lib/$v"
 751                         for l in `echo $BDB_VERSIONS`; do
 752                             CPPFLAGS="-I$BDB_INCLUDE_DIR $OLDCPPFLAGS"
 753                             LIBS="$OLDLIBS -L$BDB_LIB_DIR -l$l"
 754                             AC_TRY_LINK([
 755                                 #include <stdlib.h>
 756                                 #include <db.h>
 757                             ],[
 758                                 DB *db = NULL;
 759                                 db->open(db,NULL,NULL,NULL,0,0,0);
 760                             ],[
 761                                 ac_cv_dbcreate=yes
 762                                 BDB_LIB="$l"
 763                                 break
 764                             ])
 765                         done
 766                         test x$ac_cv_dbcreate = xyes && break
 767                     fi
 768                 fi
 769             done
 770             test x$BDB_LIB != x && break
 771         done
 772         if test x$ac_cv_dbcreate = xyes; then
 773             AC_MSG_RESULT(yes)
 774         else
 775             AC_MSG_RESULT(no)
 776         fi
 777     fi
 778
 779     if test x$ac_cv_vlopen = xyes; then
 780         CPPFLAGS="$OLDCPPFLAGS $QDBM_INC"
 781         LIBS="$OLDLIBS $QDBM_LIB -lqdbm"
 782         AC_DEFINE(HAVE_QDBM, 1, [QDBM Support])
 783     elif test x$ac_cv_gdbmopen = xyes; then
 784         CPPFLAGS="$OLDCPPFLAGS $GDBM_INC"
 785         LIBS="$OLDLIBS $GDBM_LIB -lgdbm";
 786         AC_DEFINE(HAVE_GDBM, 1, [GDBM Support])
 787     elif test x$ac_cv_dbcreate = xyes; then
 788         CPPFLAGS="-I$BDB_INCLUDE_DIR $OLDCPPFLAGS"
 789         LIBS="$OLDLIBS -L$BDB_LIB_DIR -l$BDB_LIB"
 790         AC_DEFINE(HAVE_DB4, 1, [Sleepycat DB4 Support])
 791     else
 792         AC_MSG_ERROR([You need one of: QDBM, GDBM or Sleepycat DB4 for --enable-hcache])
 793     fi
 794 fi])
 795 dnl -- end cache --
 796
 797 AC_SUBST(MUTTLIBS)
 798 AC_SUBST(MUTT_LIB_OBJECTS)
 799 AC_SUBST(LIBIMAP)
 800 AC_SUBST(LIBIMAPDEPS)
 801 AC_SUBST(LIBPOP)
 802 AC_SUBST(LIBPOPDEPS)
 803 AC_SUBST(LIBNNTP)
 804 AC_SUBST(LIBNNTPDEPS)
 805
 806 dnl -- iconv/gettext --
 807
 808 AC_ARG_ENABLE(iconv, AC_HELP_STRING([--disable-iconv], [Disable iconv support]),
 809         [if test x$enableval = xno ; then
 810                 am_cv_func_iconv=no
 811         fi
 812 ])
 813
 814 AM_GNU_GETTEXT
 815
 816 if test "$am_cv_func_iconv" != "yes"
 817 then
 818   AC_MSG_WARN([Configuring without iconv support. See INSTALL for details])
 819 else
 820
 821 AC_CHECK_HEADERS(iconv.h,
 822         [AC_MSG_CHECKING(whether iconv.h defines iconv_t)
 823          AC_EGREP_HEADER([typedef.*iconv_t],iconv.h,
 824                 [AC_MSG_RESULT(yes)
 825                  AC_DEFINE(HAVE_ICONV_T_DEF, 1,
 826                         [Define if <iconv.h> defines iconv_t.])],
 827                  AC_MSG_RESULT(no))])
 828
 829 dnl (1) Some implementations of iconv won't convert from UTF-8 to UTF-8.
 830 dnl (2) In glibc-2.1.2 and earlier there is a bug that messes up ob and
 831 dnl     obl when args 2 and 3 are 0 (fixed in glibc-2.1.3).
 832 AC_CACHE_CHECK([whether this iconv is good enough], mutt_cv_iconv_good,
 833         mutt_save_LIBS="$LIBS"
 834         LIBS="$LIBS $LIBICONV"
 835         AC_TRY_RUN([
 836 #include <iconv.h>
 837 int main()
 838 {
 839   iconv_t cd;
 840 changequote(, )dnl
 841   char buf[4];
 842 changequote([, ])dnl
 843   char *ob;
 844   size_t obl;
 845   ob = buf, obl = sizeof(buf);
 846   return ((cd = iconv_open("UTF-8", "UTF-8")) != (iconv_t)(-1) &&
 847           (iconv(cd, 0, 0, &ob, &obl) ||
 848            !(ob == buf && obl == sizeof(buf)) ||
 849            iconv_close(cd)));
 850 }
 851                 ],
 852                 mutt_cv_iconv_good=yes,
 853                 mutt_cv_iconv_good=no,
 854                 mutt_cv_iconv_good=yes)
 855         LIBS="$mutt_save_LIBS")
 856 if test "$mutt_cv_iconv_good" = no; then
 857   AC_MSG_ERROR(Try using libiconv instead)
 858 fi
 859
 860 dnl This is to detect implementations such as the one in glibc-2.1,
 861 dnl which always convert exactly but return the number of characters
 862 dnl converted instead of the number converted inexactly.
 863 AC_CACHE_CHECK([whether iconv is non-transcribing], mutt_cv_iconv_nontrans,
 864         mutt_save_LIBS="$LIBS"
 865         LIBS="$LIBS $LIBICONV"
 866         AC_TRY_RUN([
 867 #include <iconv.h>
 868 #include <string.h>
 869 int main()
 870 {
 871   iconv_t cd;
 872   const char *ib;
 873   char *ob;
 874   size_t ibl, obl;
 875   const char *s = "\304\211";
 876 changequote(, )dnl
 877   char t[3];
 878 changequote([, ])dnl
 879   ib = s, ibl = 2, ob = t, obl = 3;
 880   return ((cd = iconv_open("UTF-8", "UTF-8")) == (iconv_t)(-1) ||
 881           iconv(cd, &ib, &ibl, &ob, &obl));
 882 }
 883                 ],
 884                 mutt_cv_iconv_nontrans=no,
 885                 mutt_cv_iconv_nontrans=yes,
 886                 mutt_cv_iconv_nontrans=no)
 887         LIBS="$mutt_save_LIBS")
 888 if test "$mutt_cv_iconv_nontrans" = yes; then
 889   AC_DEFINE(ICONV_NONTRANS, 1)
 890 else
 891   AC_DEFINE(ICONV_NONTRANS, 0)
 892 fi
 893
 894 CPPFLAGS="$CPPFLAGS -I\$(top_srcdir)/intl"
 895
 896 if test "$BUILD_INCLUDED_LIBINTL" = "yes"; then
 897   AC_DEFINE(HAVE_BIND_TEXTDOMAIN_CODESET,1,
 898           [ Define if your gettext has bind_textdomain_codeset. ])
 899 else
 900   AC_CHECK_FUNCS(bind_textdomain_codeset)
 901 fi
 902
 903 fi # libiconv
 904
 905 dnl -- locales --
 906
 907 AC_CHECK_HEADERS(wchar.h)
 908
 909 AC_CACHE_CHECK([for wchar_t], mutt_cv_wchar_t,
 910         AC_TRY_COMPILE([
 911 #include <stddef.h>
 912 #include <stdlib.h>
 913 #ifdef HAVE_WCHAR_H
 914 #include <wchar.h>
 915 #endif
 916                 ],
 917                 [ wchar_t wc; return 0; ],
 918                 mutt_cv_wchar_t=yes,
 919                 mutt_cv_wchar_t=no))
 920
 921 if test "$mutt_cv_wchar_t" = no; then
 922         AC_DEFINE(wchar_t,int,[ Define to 'int' if system headers don't define. ])
 923 fi
 924
 925 AC_CACHE_CHECK([for wint_t], mutt_cv_wint_t,
 926         AC_TRY_COMPILE([
 927 #include <stddef.h>
 928 #include <stdlib.h>
 929 #ifdef HAVE_WCHAR_H
 930 #include <wchar.h>
 931 #endif
 932                 ],
 933                 [ wint_t wc; return 0; ],
 934                 mutt_cv_wint_t=yes,
 935                 mutt_cv_wint_t=no))
 936
 937 if test "$mutt_cv_wint_t" = no; then
 938         AC_DEFINE(wint_t,int,[ Define to 'int' if system headers don't define. ])
 939 fi
 940
 941 AC_CHECK_HEADERS(wctype.h)
 942 AC_CHECK_FUNCS(iswalnum iswalpha  iswcntrl iswdigit)
 943 AC_CHECK_FUNCS(iswgraph iswlower iswprint iswpunct iswspace iswupper)
 944 AC_CHECK_FUNCS(iswxdigit towupper towlower)
 945
 946 AC_CACHE_CHECK([for mbstate_t], mutt_cv_mbstate_t,
 947         AC_TRY_COMPILE([
 948 #include <stddef.h>
 949 #include <stdlib.h>
 950 #ifdef HAVE_WCHAR_H
 951 #include <wchar.h>
 952 #endif
 953                 ],
 954                 [ mbstate_t s; return 0; ],
 955                 mutt_cv_mbstate_t=yes,
 956                 mutt_cv_mbstate_t=no))
 957
 958 if test "$mutt_cv_mbstate_t" = no; then
 959         AC_DEFINE(mbstate_t,int,[ Define to 'int' if system headers don't define. ])
 960 fi
 961
 962 wc_funcs=maybe
 963 AC_ARG_WITH(wc-funcs, AC_HELP_STRING([--without-wc-funcs], [Do not use the system's wchar_t functions]),
 964         wc_funcs=$withval)
 965
 966 if test "$wc_funcs" != yes -a "$wc_funcs" != no; then
 967         AC_CACHE_CHECK([for wchar_t functions], mutt_cv_wc_funcs,
 968                 mutt_cv_wc_funcs=no
 969                 AC_TRY_LINK([
 970 #define _XOPEN_SOURCE 1
 971 #include <stddef.h>
 972 #include <stdlib.h>
 973 #ifdef HAVE_WCTYPE_H
 974 #include <wctype.h>
 975 #endif
 976 #ifdef HAVE_WCHAR_H
 977 #include <wchar.h>
 978 #endif],
 979                         [mbrtowc(0, 0, 0, 0); wctomb(0, 0); wcwidth(0);
 980         iswprint(0); iswspace(0); towlower(0); towupper(0); iswalnum(0)],
 981                         mutt_cv_wc_funcs=yes))
 982         wc_funcs=$mutt_cv_wc_funcs
 983 fi
 984
 985 if test $wc_funcs = yes; then
 986         AC_DEFINE(HAVE_WC_FUNCS,1,[ Define if you are using the system's wchar_t functions. ])
 987 fi
 988
 989 AC_CACHE_CHECK([for nl_langinfo and CODESET], mutt_cv_langinfo_codeset,
 990   [AC_TRY_LINK([#include <langinfo.h>],
 991     [char* cs = nl_langinfo(CODESET);],
 992     mutt_cv_langinfo_codeset=yes,
 993     mutt_cv_langinfo_codeset=no)])
 994 if test $mutt_cv_langinfo_codeset = yes; then
 995   AC_DEFINE(HAVE_LANGINFO_CODESET,1,[ Define if you have <langinfo.h> and nl_langinfo(CODESET). ])
 996 fi
 997
 998 AC_CACHE_CHECK([for nl_langinfo and YESEXPR], mutt_cv_langinfo_yesexpr,
 999   [AC_TRY_LINK([#include <langinfo.h>],
1000     [char* cs = nl_langinfo(YESEXPR);],
1001     mutt_cv_langinfo_yesexpr=yes,
1002     mutt_cv_langinfo_yesexpr=no)])
1003 if test $mutt_cv_langinfo_yesexpr = yes; then
1004   AC_DEFINE(HAVE_LANGINFO_YESEXPR,1,[ Define if you have <langinfo.h> and nl_langinfo(YESEXPR). ])
1005 fi
1006
1007 dnl -- libesmtp --
1008 MUTT_AM_LIBESMTP
1009 if test x$use_libesmtp = xyes; then
1010     CFLAGS="$CFLAGS $mutt_libesmtp_cflags"
1011     MUTTLIBS="$MUTTLIBS $mutt_libesmtp_libs"
1012     MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_libesmtp.o"
1013
1014     AC_DEFINE(USE_LIBESMTP,
1015               1,
1016               [Define to enable the use of libesmtp])
1017 fi
1018 dnl -- end libesmtp --
1019
1020 dnl -- sgml tools --
1021
1022 dnl Documentation tools
1023 have_openjade="no"
1024 AC_PATH_PROG([OSPCAT], [ospcat], [none])
1025 if test "$OSPCAT" != "none"
1026 then
1027   AC_MSG_CHECKING([for openjade docbook stylesheets])
1028   dslosfile=`ospcat --public-id="-//Norman Walsh//DOCUMENT DocBook Print Stylesheet//EN"`
1029   DSLROOT=`echo $dslosfile | sed -n -e "s/.*SOIBASE='\(@<:@^'@:>@*\)\/catalog'.*/\1/p"`
1030   # ospcat may spit out an absolute path without an SOIBASE
1031   if test -z "$DSLROOT"
1032   then
1033     DSLROOT=`echo $dslosfile | sed -e 's|<OSFILE>\(.*\)/print/docbook.dsl|\1|'`
1034   fi
1035   if test -f $DSLROOT/print/docbook.dsl
1036   then
1037     AC_MSG_RESULT([in $DSLROOT])
1038     have_openjade="yes"
1039   else
1040     AC_MSG_RESULT([not found: PDF documentation will not be built.])
1041   fi
1042 fi
1043 AC_SUBST(DSLROOT)
1044
1045 AC_MSG_CHECKING([for lynx])
1046 AC_PATH_PROG([HTML2TXT_CMD], [lynx], [none])
1047 if test x"$HTML2TXT_CMD" = x"none"
1048 then
1049   AC_MSG_CHECKING([for w3m])
1050   AC_PATH_PROG([HTML2TXT_CMD], [w3m], [none])
1051 fi
1052 if test x"$HTML2TXT_CMD" = x"none"
1053 then
1054   AC_MSG_CHECKING([for elinks])
1055   AC_PATH_PROG([HTML2TXT_CMD], [elinks], [none])
1056 fi
1057 case "$HTML2TXT_CMD" in
1058   *elinks*)
1059     HTML2TXT_CMD="$HTML2TXT_CMD -dump -no-numbering -no-references \$^ > \$@"
1060     ;;
1061   *lynx*)
1062     HTML2TXT_CMD="$HTML2TXT_CMD -dump -nolist -with_backspaces \$^ > \$@"
1063     ;;
1064   *w3m*)
1065     HTML2TXT_CMD="$HTML2TXT_CMD -dump \$^ > \$@"
1066     ;;
1067   *)
1068     HTML2TXT_CMD="true"
1069     ;;
1070 esac
1071 AC_SUBST(HTML2TXT_CMD)
1072
1073 AC_MSG_CHECKING([for tidy])
1074 AC_PATH_PROG([HTMLCLEAN_CMD], [tidy], [none])
1075
1076 if test x"$HTMLCLEAN_CMD" != x"none"
1077 then
1078   HTMLCLEAN_CMD="$HTMLCLEAN_CMD -q -i -m -asxml -utf8 "
1079 else
1080   HTMLCLEAN_CMD="echo "
1081 fi
1082 AC_SUBST(HTMLCLEAN_CMD)
1083
1084 AC_OUTPUT(Makefile intl/Makefile m4/Makefile
1085         po/Makefile.in doc/Makefile contrib/Makefile
1086         muttbug.sh
1087         lib-lib/Makefile
1088         lib-mime/Makefile
1089         lib-hash/Makefile
1090         lib/Makefile
1091         imap/Makefile
1092         pop/Makefile
1093         nntp/Makefile
1094         Muttngrc.head
1095         doc/instdoc.sh)