configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl !!! WHEN ADDING NEW CONFIGURE TESTS, PLEASE ADD CODE TO MAIN.C !!!
   4 dnl !!! TO DUMP THEIR RESULTS WHEN MUTT -V IS CALLED            !!!
   5
   6 AC_PREREQ([2.50])
   7 AC_INIT([mutt.h])
   8 AM_CONFIG_HEADER(config.h)
   9 AM_INIT_AUTOMAKE(madmutt, `cat "$srcdir/VERSION.in"`)
  10
  11 AC_SUBST([CONFIGURE_DEPENDENCIES], ['$(top_srcdir)/VERSION.in'])
  12
  13 AC_GNU_SOURCE
  14
  15 ALL_LINGUAS="de ru it es uk fr pl nl cs id sk ko el zh_TW zh_CN pt_BR eo gl sv da lt tr ja hu et ca bg"
  16
  17 AC_CANONICAL_HOST
  18
  19 AC_PROG_CPP
  20 AC_PROG_CC_C99
  21 AC_ISC_POSIX
  22 AC_HEADER_STDC
  23
  24 PKG_PROG_PKG_CONFIG
  25 AC_PROG_MAKE_SET
  26 AC_PROG_INSTALL
  27 AC_PROG_RANLIB
  28 AC_PROG_GPERF
  29 AC_CHECK_TOOL(AR, ar, ar)
  30
  31 AC_SYS_LARGEFILE
  32 AC_FUNC_FSEEKO
  33 AC_CHECK_SIZEOF(off_t)
  34
  35 AH_TEMPLATE([sig_atomic_t],
  36             [Define to 'int' if <signal.h> doesn't define.])
  37 AH_TEMPLATE([HAVE_START_COLOR],
  38             [Define if you have start_color, as a function or macro.])
  39 AH_TEMPLATE([HAVE_TYPEAHEAD],
  40             [Define if you have typeahead, as a function or macro.])
  41 AH_TEMPLATE([HAVE_BKGDSET],
  42             [Define if you have bkgdset, as a function or macro.])
  43 AH_TEMPLATE([HAVE_CURS_SET],
  44             [Define if you have curs_set, as a function or macro.])
  45 AH_TEMPLATE([HAVE_META],
  46             [Define if you have meta, as a function or macro.])
  47 AH_TEMPLATE([HAVE_USE_DEFAULT_COLORS],
  48             [Define if you have use_default_colors, as a function or macro.])
  49 AH_TEMPLATE([HAVE_RESIZETERM],
  50             [Define if you have resizeterm, as a function or macro.])
  51 AH_TEMPLATE([SIG_ATOMIC_VOLATILE_T],
  52             [Some systems declare sig_atomic_t as volatile, some others -- no.
  53              This define will have value `sig_atomic_t' or
  54              `volatile sig_atomic_t' accordingly.])
  55 AH_TEMPLATE([ICONV_NONTRANS],
  56             [Define as 1 if iconv() only converts exactly and we should treat
  57              all return values other than (size_t)(-1) as equivalent.])
  58
  59 dnl ---------------- sendmail ----------------
  60
  61 ac_aux_path_sendmail=/usr/sbin:/usr/lib
  62 AC_PATH_PROG(SENDMAIL, sendmail, /usr/sbin/sendmail, $PATH:$ac_aux_path_sendmail)
  63 AC_DEFINE_UNQUOTED(SENDMAIL,"$ac_cv_path_SENDMAIL",[ Where to find sendmail on your system. ])
  64
  65 OPS="\$(srcdir)/OPS"
  66
  67 dnl ---------------- gpgme ----------------
  68
  69 AC_ARG_ENABLE(gpgme, AC_HELP_STRING([--enable-gpgme], [Enable GPGME support]),[
  70     if test x$enableval = xyes; then
  71         AM_PATH_GPGME(,,[AC_MSG_ERROR(GPGME not found)])
  72         MUTTLIBS="$MUTTLIBS $GPGME_LIBS"
  73         AC_DEFINE(CRYPT_BACKEND_GPGME, 1, [Defined, if GPGME support is enabled])
  74         AM_CONDITIONAL(BUILD_GPGME, true)
  75     else
  76         AM_CONDITIONAL(BUILD_GPGME, false)
  77     fi
  78 ])
  79
  80 dnl ---------------- mixmaster ----------------
  81
  82 AC_ARG_WITH(mixmaster, AC_HELP_STRING([--with-mixmaster[=PATH]], [Include Mixmaster support]), [
  83     MIXMASTER=${withval:-"mixmaster"}
  84     OPS="$OPS \$(srcdir)/OPS.MIX"
  85     MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS remailer.o"
  86     AC_DEFINE_UNQUOTED(MIXMASTER,"$MIXMASTER",[Where to find mixmaster on your system.])
  87 ])
  88
  89 AC_SUBST([OPS])
  90
  91 AC_PATH_PROG(ISPELL, ispell, no)
  92 if test $ISPELL != no; then
  93     AC_DEFINE_UNQUOTED(ISPELL,"$ISPELL",[Where to find ispell on your system.])
  94 fi
  95
  96 AC_ARG_WITH(slang, AC_HELP_STRING([--with-slang[=DIR]], [Use S-Lang instead of ncurses]),
  97     [AC_CACHE_CHECK([if this is a BSD system], mutt_cv_bsdish,
  98         [AC_TRY_RUN([#include <sys/param.h>
  99
 100 main ()
 101 {
 102 #ifdef BSD
 103         exit (0);
 104 #else
 105         exit (1);
 106 #endif
 107 }],
 108         mutt_cv_bsdish=yes,
 109         mutt_cv_bsdish=no,
 110         mutt_cv_bsdish=no)])
 111
 112         AC_MSG_CHECKING(for S-Lang)
 113         if test $withval = yes; then
 114             if test -d $srcdir/../slang; then
 115                 mutt_cv_slang=$srcdir/../slang/src
 116                 CFLAGS="$CFLAGS -I${mutt_cv_slang}"
 117                 LDFLAGS="$LDFLAGS -L${mutt_cv_slang}/objs"
 118             else
 119                 if test -d ${prefix}/include/slang; then
 120                     CFLAGS="$CFLAGS -I${prefix}/include/slang"
 121                 elif test -d /usr/include/slang; then
 122                     CFLAGS="$CFLAGS -I/usr/include/slang"
 123                 fi
 124                 mutt_cv_slang=yes
 125             fi
 126         else
 127             dnl ---Check to see if $withval is a source directory
 128             if test -f $withval/src/slang.h; then
 129                 mutt_cv_slang=$withval/src
 130                 CFLAGS="$CFLAGS -I${mutt_cv_slang}"
 131                 LDFLAGS="$LDFLAGS -L${mutt_cv_slang}/objs"
 132             else
 133                 dnl ---Must be installed somewhere
 134                 mutt_cv_slang=$withval
 135                 if test -d $withval/include/slang; then
 136                         CFLAGS="$CFLAGS -I${withval}/include/slang"
 137                 elif test -d $withval/include; then
 138                         CFLAGS="$CFLAGS -I${withval}/include"
 139                 fi
 140                 LDFLAGS="$LDFLAGS -L${withval}/lib"
 141             fi
 142         fi
 143         AC_MSG_RESULT($mutt_cv_slang)
 144         if test $mutt_cv_bsdish = yes; then
 145             AC_CHECK_LIB(termlib, main)
 146         fi
 147         AC_DEFINE(USE_SLANG_CURSES,1, [ Define if you compile with SLang instead of curses/ncurses. ])
 148         AC_DEFINE(HAVE_COLOR,1,[ Define if your curses library supports color. ])
 149
 150         dnl --- now that we've found it, check the link
 151
 152         AC_CHECK_LIB(slang, SLtt_get_terminfo,
 153             [MUTTLIBS="$MUTTLIBS -lslang -lm"],
 154             [AC_MSG_ERROR(unable to compile.  check config.log)], -lm)
 155     ],
 156     [   mutt_cv_curses=/usr
 157         AC_ARG_WITH(curses, AC_HELP_STRING([--with-curses=DIR], [Where ncurses is installed]), [
 158             if test $withval != yes; then
 159                 mutt_cv_curses=$withval
 160             fi
 161             if test x$mutt_cv_curses != x/usr; then
 162                 LDFLAGS="-L${mutt_cv_curses}/lib $LDFLAGS"
 163                 CPPFLAGS="$CPPFLAGS -I${mutt_cv_curses}/include"
 164             fi
 165         ])
 166
 167         AC_CHECK_FUNC(initscr,,[
 168         cf_ncurses="ncurses"
 169         for lib in ncursesw ncurses; do
 170             AC_CHECK_LIB($lib, waddnwstr, [cf_ncurses="$lib"; break])
 171         done
 172         AC_CHECK_LIB($cf_ncurses, initscr,
 173             [   MUTTLIBS="$MUTTLIBS -l$cf_ncurses"
 174                 if test x$mutt_cv_curses = x/usr -a -d /usr/include/ncurses; then
 175                     CPPFLAGS="$CPPFLAGS -I/usr/include/ncurses"
 176                 fi
 177
 178                 if test "$cf_ncurses" = ncursesw; then
 179                     AC_CHECK_HEADERS(ncurses/ncurses.h,[cf_cv_ncurses_header="ncurses/ncurses.h"])
 180                     AC_CHECK_HEADERS(ncursesw/ncurses.h,[cf_cv_ncurses_header="ncursesw/ncurses.h"])
 181                 else
 182                     AC_CHECK_HEADERS(ncurses.h,[cf_cv_ncurses_header="ncurses.h"])
 183                 fi
 184             ],
 185             [CF_CURSES_LIBS])
 186         ])
 187
 188         old_LIBS="$LIBS"
 189         LIBS="$LIBS $MUTTLIBS"
 190         CF_CHECK_FUNCDECLS([#include <${cf_cv_ncurses_header-curses.h}>],
 191                            [start_color typeahead bkgdset curs_set meta use_default_colors resizeterm])
 192         if test "$ac_cv_func_decl_start_color" = yes; then
 193             AC_DEFINE(HAVE_COLOR,1,[ Define if your curses library supports color. ])
 194         fi
 195         LIBS="$old_LIBS"
 196     ])
 197
 198 AC_CHECK_HEADERS(stdarg.h sys/ioctl.h ioctl.h sysexits.h)
 199 AC_CHECK_HEADERS(sys/time.h sys/resource.h)
 200 AC_CHECK_HEADERS(unix.h)
 201
 202 AC_CHECK_FUNCS(setrlimit getsid isctype)
 203
 204 AC_TYPE_SIGNAL
 205
 206 AC_MSG_CHECKING(for sig_atomic_t in signal.h)
 207 AC_EGREP_HEADER(sig_atomic_t,signal.h,
 208     [   ac_cv_type_sig_atomic_t=yes;
 209         AC_EGREP_HEADER(volatile.*sig_atomic_t,
 210                         signal.h,
 211                         [is_sig_atomic_t_volatile=yes; AC_MSG_RESULT([yes, volatile])],
 212                         [is_sig_atomic_t_volatile=no;  AC_MSG_RESULT([yes, non volatile])])
 213     ],
 214     [   AC_MSG_RESULT(no)
 215         AC_CHECK_TYPE(sig_atomic_t, int)
 216         is_sig_atomic_t_volatile=no
 217     ])
 218 if test $is_sig_atomic_t_volatile = 'yes'
 219 then
 220     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, sig_atomic_t)
 221 else
 222     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, [volatile sig_atomic_t])
 223 fi
 224
 225 AC_DECL_SYS_SIGLIST
 226 AC_TYPE_PID_T
 227
 228 AC_CHECK_FUNC(getopt)
 229 if test $ac_cv_func_getopt = yes; then
 230     AC_CHECK_HEADERS(getopt.h)
 231 fi
 232
 233 AC_CHECK_FUNC(regcomp)
 234 if test $ac_cv_func_regcomp = yes; then
 235    AC_CHECK_HEADERS(regex.h)
 236 fi
 237
 238 AC_ARG_WITH(homespool,
 239             AC_HELP_STRING([--with-homespool[=FILE]],
 240                            [File in user's directory where new mail is spooled]),
 241                            with_homespool=${withval})
 242 if test x$with_homespool != x; then
 243     if test $with_homespool = yes; then
 244             with_homespool=mailbox
 245     fi
 246     AC_DEFINE_UNQUOTED(MAILPATH,"$with_homespool",[ Where new mail is spooled. ])
 247     AC_DEFINE(HOMESPOOL,1,
 248     [   Is mail spooled to the user's home directory?  If defined,
 249         MAILPATH should be set to the filename of the spool mailbox
 250         relative the the home directory.
 251         use: configure --with-homespool=FILE
 252     ])
 253     AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 254     mutt_cv_setgid=no
 255 else
 256     AC_ARG_WITH(mailpath, AC_HELP_STRING([--with-mailpath=DIR], [Directory where spool mailboxes are located]),
 257         [mutt_cv_mailpath=$withval],
 258         [ AC_CACHE_CHECK(where new mail is stored, mutt_cv_mailpath,
 259             [mutt_cv_mailpath=no
 260             if test -d /var/mail; then
 261                 mutt_cv_mailpath=/var/mail
 262             elif test -d /var/spool/mail; then
 263                 mutt_cv_mailpath=/var/spool/mail
 264             elif test -d /usr/spool/mail; then
 265                 mutt_cv_mailpath=/usr/spool/mail
 266             elif test -d /usr/mail; then
 267                 mutt_cv_mailpath=/usr/mail
 268             fi])
 269         ])
 270     if test "$mutt_cv_mailpath" = no; then
 271         AC_MSG_ERROR("Could not determine where new mail is stored.")
 272     fi
 273     AC_DEFINE_UNQUOTED(MAILPATH,"$mutt_cv_mailpath",[ Where new mail is spooled. ])
 274
 275     AC_CACHE_CHECK(if $mutt_cv_mailpath is world writable, mutt_cv_worldwrite, [AC_TRY_RUN([#include <sys/types.h>
 276 #include <sys/stat.h>
 277
 278 int main (int argc, char **argv)
 279 {
 280         struct stat s;
 281
 282         stat ("$mutt_cv_mailpath", &s);
 283         if (s.st_mode & S_IWOTH) exit (0);
 284         exit (1);
 285 }], mutt_cv_worldwrite=yes, mutt_cv_worldwrite=no, mutt_cv_worldwrite=no)])
 286
 287         mutt_cv_setgid=no
 288         if test $mutt_cv_worldwrite = yes; then
 289                 AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 290         else
 291                 AC_CACHE_CHECK(if $mutt_cv_mailpath is group writable, mutt_cv_groupwrite, [AC_TRY_RUN([#include <sys/types.h>
 292 #include <sys/stat.h>
 293
 294 int main (int argc, char **argv)
 295 {
 296         struct stat s;
 297
 298         stat ("$mutt_cv_mailpath", &s);
 299         if (s.st_mode & S_IWGRP) exit (0);
 300         exit (1);
 301 }], mutt_cv_groupwrite=yes, mutt_cv_groupwrite=no, mutt_cv_groupwrite=no)])
 302
 303         if test $mutt_cv_groupwrite = yes; then
 304             AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 305             AC_DEFINE(USE_SETGID,1,[ Define if mutt should run setgid "mail". ])
 306             mutt_cv_setgid=yes
 307         fi
 308     fi
 309 fi
 310
 311 AC_MSG_CHECKING(where to put the documentation)
 312 AC_ARG_WITH(docdir, AC_HELP_STRING([--with-docdir=PATH], [Specify where to put the documentation]),
 313         [mutt_cv_docdir=$withval],
 314         [mutt_cv_docdir="${prefix}/doc/madmutt"])
 315 AC_MSG_RESULT($mutt_cv_docdir)
 316
 317 docdir=$mutt_cv_docdir
 318 AC_SUBST(docdir)
 319
 320 if test x$mutt_cv_setgid = xyes; then
 321     DOTLOCK_GROUP='mail'
 322     DOTLOCK_PERMISSION=2755
 323 else
 324     DOTLOCK_GROUP=''
 325     DOTLOCK_PERMISSION=755
 326 fi
 327 AC_SUBST(DOTLOCK_GROUP)
 328 AC_SUBST(DOTLOCK_PERMISSION)
 329
 330 dnl -- socket dependencies --
 331
 332 AC_ARG_ENABLE(nntp, AC_HELP_STRING([--enable-nntp],[Enable NNTP support]),[
 333     if test x$enableval = xyes ; then
 334         AC_DEFINE(USE_NNTP,1,[ Compiling with newsreading support with NNTP ])
 335         LIBNNTP="-Lnntp -lnntp"
 336         LIBNNTPDEPS="\$(top_srcdir)/nntp/nntp.h nntp/libnntp.a"
 337         need_nntp="yes"
 338     fi
 339 ])
 340 AM_CONDITIONAL(BUILD_NNTP, test x$need_nntp = xyes)
 341
 342 AC_MSG_CHECKING([for socklen_t])
 343 AC_EGREP_HEADER(socklen_t, sys/socket.h, AC_MSG_RESULT([yes]),
 344         AC_MSG_RESULT([no])
 345         AC_DEFINE(socklen_t,int, [ Define to 'int' if <sys/socket.h> doesn't have it. ]))
 346 AC_CHECK_FUNC(gethostent, , AC_CHECK_LIB(nsl, gethostent))
 347 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt))
 348 AC_CHECK_FUNCS(getaddrinfo)
 349
 350 dnl -- imap dependencies --
 351
 352 AC_ARG_WITH(gss, AC_HELP_STRING([--with-gss], [Compile in GSSAPI authentication for IMAP]),[
 353     if test x$with_gss != xno; then
 354         PKG_CHECK_MODULES(GSSAPI,libgssapi,[
 355             CPPFLAGS="$CPPFLAGS $GSSAPI_CFLAGS"
 356             MUTTLIBS="$MUTTLIBS $GSSAPI_LIBS"
 357             AC_DEFINE(USE_GSS,1,[ Define if you have GSSAPI libraries available ])
 358             AC_CHECK_HEADERS(xom.h)
 359         ],[
 360            AC_MSG_ERROR([could not find libgssapi])
 361         ])
 362     fi
 363 ])
 364
 365 AC_ARG_WITH(ssl, AC_HELP_STRING([--with-ssl[=PFX]], [Compile in SSL support for POP/IMAP]),
 366 [   if test "$with_ssl" != "no"; then
 367         if test "$with_ssl" != "yes"; then
 368             LDFLAGS="$LDFLAGS -L$withval/lib"
 369             CPPFLAGS="$CPPFLAGS -I$withval/include"
 370         fi
 371         saved_LIBS="$LIBS"
 372
 373         AC_CHECK_LIB(crypto, X509_new,, AC_MSG_ERROR([Unable to find SSL library]))
 374         AC_CHECK_LIB(ssl, SSL_new,, AC_MSG_ERROR([Unable to find SSL library]), -lcrypto)
 375
 376         AC_CHECK_FUNCS(RAND_status RAND_egd)
 377
 378         AC_DEFINE(USE_SSL,1,[ Define if you want support for SSL. ])
 379         LIBS="$saved_LIBS"
 380         MUTTLIBS="$MUTTLIBS -lssl -lcrypto"
 381         need_ssl=yes
 382     fi
 383 ])
 384
 385 AC_ARG_WITH([gnutls], AC_HELP_STRING([--with-gnutls], [Enable SSL support using gnutls]),
 386             [gnutls_prefix="$withval"], [gnutls_prefix="no"])
 387 if test "$gnutls_prefix" != "no"; then
 388     if test x"$need_ssl" = x"yes"; then
 389         AC_MSG_ERROR([Only either OpenSSL or GNUTLS may be used])
 390     fi
 391     AM_PATH_LIBGNUTLS(,[
 392         CPPFLAGS="$CPPFLAGS $LIBGNUTLS_CFLAGS"
 393         MUTTLIBS="$MUTTLIBS $LIBGNUTLS_LIBS"
 394         AC_DEFINE(USE_GNUTLS, 1, [Define if you want support for SSL via the gnutls library.])
 395         need_ssl=yes],
 396         [AC_MSG_ERROR([could not find libgnutls])
 397     ])
 398 fi
 399 AM_CONDITIONAL(USE_SSL, test x$need_ssl = xyes)
 400 AC_SUBST(MUTT_SSL_OBJECTS)
 401
 402 AC_ARG_WITH(sasl2, AC_HELP_STRING([--with-sasl2[=PFX]],
 403             [Use Cyrus SASL library version 2 for POP/IMAP authentication]),[
 404     if test "$with_sasl2" != "no"; then
 405         if test "$with_sasl2" != "yes"; then
 406             CPPFLAGS="$CPPFLAGS -I$with_sasl2/include"
 407             LDFLAGS="$LDFLAGS -L$with_sasl2/lib"
 408         fi
 409
 410         saved_LIBS="$LIBS"
 411
 412         AC_CHECK_LIB(sasl2, sasl_client_init,,AC_MSG_ERROR([could not find libsasl2]))
 413
 414         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_sasl.o"
 415         MUTTLIBS="$MUTTLIBS -lsasl2"
 416         LIBS="$saved_LIBS"
 417         AC_DEFINE(USE_SASL,1,
 418                   [Define if want to use version 2 of the Cyrus SASL library.])
 419         need_sasl=yes
 420     fi
 421 ])
 422 AM_CONDITIONAL(USE_SASL, test x$need_sasl = xyes)
 423
 424 AC_ARG_WITH(idn, AC_HELP_STRING([--with-idn], [Use GNU libidn for domain names]),[
 425     if test x$with_idn != xno ; then
 426         PKG_CHECK_MODULES(IDN,libidn,[
 427             if $PKG_CONFIG --atleast-version=0.6; then
 428                 AC_MSG_ERROR([libidn is too old, want 0.6 at least])
 429             fi
 430             CPPFLAGS="$CPPFLAGS $IDN_CFLAGS"
 431             LDFLAGS="$LDFLAGS $IDN_LIBS"
 432         ],[AC_MSG_ERROR([could not find libidn])])
 433     fi
 434 ])
 435
 436 dnl -- end socket --
 437
 438 AC_ARG_ENABLE(flock, AC_HELP_STRING([--enable-flock], [Use flock() to lock files]),
 439         [if test $enableval = yes; then
 440                 AC_DEFINE(USE_FLOCK,1, [ Define to use flock() to lock mailboxes. ])
 441         fi])
 442
 443 mutt_cv_fcntl=yes
 444 AC_ARG_ENABLE(fcntl, AC_HELP_STRING([--disable-fcntl], [Do NOT use fcntl() to lock files]),
 445         [if test $enableval = no; then mutt_cv_fcntl=no; fi])
 446
 447 if test $mutt_cv_fcntl = yes; then
 448         AC_DEFINE(USE_FCNTL,1, [ Define to use fcntl() to lock folders. ])
 449 fi
 450
 451 AC_MSG_CHECKING(whether struct dirent defines d_ino)
 452 ac_cv_dirent_d_ino=no
 453 AC_TRY_LINK([#include <dirent.h>],[struct dirent dp; (void)dp.d_ino],[ac_cv_dirent_d_ino=yes])
 454 if test x$ac_cv_dirent_d_ino = xyes ; then
 455   AC_DEFINE(HAVE_DIRENT_D_INO,1,
 456             [Define to 1 if your system has the dirent::d_ino member])
 457 fi
 458 AC_MSG_RESULT($ac_cv_dirent_d_ino)
 459
 460 dnl -- start cache --
 461 AC_ARG_ENABLE(hcache, AC_HELP_STRING([--enable-hcache], [Enable header caching]),
 462 [if test x$enableval = xyes; then
 463     AC_DEFINE(USE_HCACHE, 1, [Enable header caching])
 464
 465     OLDCPPFLAGS="$CPPFLAGS"
 466     OLDLIBS="$LIBS"
 467
 468     need_md5="yes"
 469
 470     ac_prefer_qdbm=yes
 471     AC_ARG_WITH(qdbm, AC_HELP_STRING([--without-qdbm], [Don't use qdbm even if it is available]),
 472         ac_prefer_qdbm=$withval)
 473     if test x$ac_prefer_qdbm != xno; then
 474         PKG_CHECK_MODULES(QDBM,qdbm,[ac_qdbm_here=yes],[ac_qdbm_here=no])
 475     fi
 476
 477     ac_prefer_gdbm=yes
 478     AC_ARG_WITH(gdbm, AC_HELP_STRING([--without-gdbm], [Don't use gdbm even if it is available]),
 479         ac_prefer_gdbm=$withval)
 480     if test x$ac_prefer_gdbm != xno -a x$ac_qdbm_here != xyes; then
 481         ac_cv_gdbmopen=no
 482         GDBM_DIRS="${prefix} /usr/local /usr"
 483         AC_MSG_CHECKING([for gdbm_open])
 484         for d in $GDBM_DIRS; do
 485           if test x$ac_cv_gdbmopen = xno && test -d "$d/include" && test -d "$d/lib"; then
 486             GDBM_INC="-I$d/include"
 487             GDBM_LIB="-L$d/lib"
 488             CPPFLAGS="$OLDCPPFLAGS $GDBM_INC"
 489             LIBS="$OLDLIBS $GDBM_LIB -lgdbm"
 490             AC_TRY_LINK([#include <gdbm.h>],[gdbm_open(0,0,0,0,0);],[ac_cv_gdbmopen=yes])
 491           fi
 492         done
 493         if test x$ac_cv_gdbmopen = xyes; then
 494           AC_MSG_RESULT(yes)
 495         else
 496           AC_MSG_RESULT(no)
 497         fi
 498     fi
 499
 500     ac_bdb_prefix=yes
 501     AC_ARG_WITH(bdb, AC_HELP_STRING([--with-bdb[=DIR]], [Use BerkeleyDB4 if gdbm is not available ]),
 502         ac_bdb_prefix=$withval)
 503     if test x$ac_bdb_prefix != xno -a x$ac_cv_gdbmopen != xyes -a x$ac_qdbm_here != xyes; then
 504         test x$ac_bdb_prefix = xyes && ac_bdb_prefix="${prefix} /opt/csw/bdb4 /opt /usr/local /usr"
 505         for d in $ac_bdb_prefix; do
 506             bdbpfx="$bdbpfx $d"
 507             for v in BerkeleyDB.4.3 BerkeleyDB.4.2 BerkeleyDB.4.1; do
 508                 bdbpfx="$bdbpfx $d/$v"
 509             done
 510         done
 511         BDB_VERSIONS="db-4 db4 db-4.3 db4.3 db43 db-4.2 db4.2 db42 db-4.1 db4.1 db41 db ''"
 512         AC_MSG_CHECKING([for BerkeleyDB > 4.0])
 513         for d in $bdbpfx; do
 514             BDB_INCLUDE_DIR=""
 515             BDB_LIB_DIR=""
 516             for v in / $BDB_VERSIONS; do
 517                 if test -r "$d/include/$v/db.h"; then
 518                     BDB_INCLUDE_DIR="$d/include/$v"
 519                     if test -d "$d/lib/$v"; then
 520                         BDB_LIB_DIR="$d/lib/$v"
 521                         for l in `echo $BDB_VERSIONS`; do
 522                             CPPFLAGS="-I$BDB_INCLUDE_DIR $OLDCPPFLAGS"
 523                             LIBS="$OLDLIBS -L$BDB_LIB_DIR -l$l"
 524                             AC_TRY_LINK([
 525                                 #include <stdlib.h>
 526                                 #include <db.h>
 527                             ],[
 528                                 DB *db = NULL;
 529                                 db->open(db,NULL,NULL,NULL,0,0,0);
 530                             ],[
 531                                 ac_cv_dbcreate=yes
 532                                 BDB_LIB="$l"
 533                                 break
 534                             ])
 535                         done
 536                         test x$ac_cv_dbcreate = xyes && break
 537                     fi
 538                 fi
 539             done
 540             test x$BDB_LIB != x && break
 541         done
 542         if test x$ac_cv_dbcreate = xyes; then
 543             AC_MSG_RESULT(yes)
 544         else
 545             AC_MSG_RESULT(no)
 546         fi
 547     fi
 548
 549     if test x$ac_qdbm_here = xyes; then
 550         CPPFLAGS="$OLDCPPFLAGS $QDBM_CFLAGS"
 551         LIBS="$OLDLIBS $QDBM_LIBS"
 552         AC_DEFINE(HAVE_QDBM, 1, [QDBM Support])
 553     elif test x$ac_cv_gdbmopen = xyes; then
 554         CPPFLAGS="$OLDCPPFLAGS $GDBM_INC"
 555         LIBS="$OLDLIBS $GDBM_LIB -lgdbm";
 556         AC_DEFINE(HAVE_GDBM, 1, [GDBM Support])
 557     elif test x$ac_cv_dbcreate = xyes; then
 558         CPPFLAGS="-I$BDB_INCLUDE_DIR $OLDCPPFLAGS"
 559         LIBS="$OLDLIBS -L$BDB_LIB_DIR -l$BDB_LIB"
 560         AC_DEFINE(HAVE_DB4, 1, [Sleepycat DB4 Support])
 561     else
 562         AC_MSG_ERROR([You need one of: QDBM, GDBM or Sleepycat DB4 for --enable-hcache])
 563     fi
 564 fi])
 565 dnl -- end cache --
 566
 567 AC_SUBST(MUTTLIBS)
 568 AC_SUBST(MUTT_LIB_OBJECTS)
 569 AC_SUBST(LIBNNTP)
 570 AC_SUBST(LIBNNTPDEPS)
 571
 572 dnl -- iconv/gettext --
 573
 574 AC_ARG_ENABLE(iconv, AC_HELP_STRING([--disable-iconv], [Disable iconv support]),
 575         [if test x$enableval = xno ; then
 576                 am_cv_func_iconv=no
 577         fi
 578 ])
 579
 580 AM_GNU_GETTEXT
 581
 582 if test "$am_cv_func_iconv" != "yes"; then
 583     AC_MSG_WARN([Configuring without iconv support. See INSTALL for details])
 584 else
 585
 586     AC_CHECK_HEADERS(iconv.h,
 587         [AC_MSG_CHECKING(whether iconv.h defines iconv_t)
 588          AC_EGREP_HEADER([typedef.*iconv_t],iconv.h,
 589                 [AC_MSG_RESULT(yes)
 590                  AC_DEFINE(HAVE_ICONV_T_DEF, 1,
 591                         [Define if <iconv.h> defines iconv_t.])],
 592                  AC_MSG_RESULT(no))])
 593
 594     dnl (1) Some implementations of iconv won't convert from UTF-8 to UTF-8.
 595     dnl (2) In glibc-2.1.2 and earlier there is a bug that messes up ob and
 596     dnl     obl when args 2 and 3 are 0 (fixed in glibc-2.1.3).
 597     AC_CACHE_CHECK([whether this iconv is good enough], mutt_cv_iconv_good,
 598                    mutt_save_LIBS="$LIBS"
 599                    LIBS="$LIBS $LIBICONV"
 600                    AC_TRY_RUN([
 601 #include <iconv.h>
 602 int main()
 603 {
 604   iconv_t cd;
 605 changequote(, )dnl
 606   char buf[4];
 607 changequote([, ])dnl
 608   char *ob;
 609   size_t obl;
 610   ob = buf, obl = sizeof(buf);
 611   return ((cd = iconv_open("UTF-8", "UTF-8")) != (iconv_t)(-1) &&
 612           (iconv(cd, 0, 0, &ob, &obl) ||
 613            !(ob == buf && obl == sizeof(buf)) ||
 614            iconv_close(cd)));
 615 }
 616                    ],
 617                    mutt_cv_iconv_good=yes,
 618                    mutt_cv_iconv_good=no,
 619                    mutt_cv_iconv_good=yes)
 620                    LIBS="$mutt_save_LIBS")
 621     if test "$mutt_cv_iconv_good" = no; then
 622         AC_MSG_ERROR(Try using libiconv instead)
 623     fi
 624
 625 fi # libiconv
 626
 627 dnl -- locales --
 628
 629 AC_CHECK_HEADERS(locale.h wchar.h wctype.h)
 630 AC_CHECK_FUNCS(iswalnum iswalpha  iswcntrl iswdigit)
 631 AC_CHECK_FUNCS(iswgraph iswlower iswprint iswpunct iswspace iswupper)
 632 AC_CHECK_FUNCS(iswxdigit towupper towlower)
 633 AC_TYPE_MBSTATE_T
 634
 635 AC_CACHE_CHECK([for nl_langinfo and CODESET], mutt_cv_langinfo_codeset,
 636                [AC_TRY_LINK([#include <langinfo.h>],
 637                             [char* cs = nl_langinfo(CODESET);],
 638                             mutt_cv_langinfo_codeset=yes,
 639                             mutt_cv_langinfo_codeset=no)])
 640 if test $mutt_cv_langinfo_codeset = yes; then
 641     AC_DEFINE(HAVE_LANGINFO_CODESET,1,
 642               [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
 643 fi
 644
 645 AC_CACHE_CHECK([for nl_langinfo and YESEXPR], mutt_cv_langinfo_yesexpr,
 646                [AC_TRY_LINK([#include <langinfo.h>],
 647                             [char* cs = nl_langinfo(YESEXPR);],
 648                             mutt_cv_langinfo_yesexpr=yes,
 649                             mutt_cv_langinfo_yesexpr=no)])
 650 if test $mutt_cv_langinfo_yesexpr = yes; then
 651     AC_DEFINE(HAVE_LANGINFO_YESEXPR,1,
 652               [Define if you have <langinfo.h> and nl_langinfo(YESEXPR).])
 653 fi
 654
 655 dnl -- libesmtp --
 656 MUTT_AM_LIBESMTP
 657 if test x$use_libesmtp = xyes; then
 658     CFLAGS="$CFLAGS $mutt_libesmtp_cflags"
 659     MUTTLIBS="$MUTTLIBS $mutt_libesmtp_libs"
 660     MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_libesmtp.o"
 661     AC_DEFINE(USE_LIBESMTP, 1, [Define to enable the use of libesmtp])
 662 fi
 663 dnl -- end libesmtp --
 664
 665 dnl -- sgml tools --
 666
 667 dnl Documentation tools
 668 have_openjade="no"
 669 AC_PATH_PROG([OSPCAT], [ospcat], [none])
 670 if test "x$OSPCAT" != "xnone"; then
 671     AC_MSG_CHECKING([for openjade docbook stylesheets])
 672     dslosfile=`ospcat --public-id="-//Norman Walsh//DOCUMENT DocBook Print Stylesheet//EN"`
 673     DSLROOT=`echo $dslosfile | sed -n -e "s/.*SOIBASE='\(@<:@^'@:>@*\)\/catalog'.*/\1/p"`
 674     # ospcat may spit out an absolute path without an SOIBASE
 675     if test -z "$DSLROOT"; then
 676         DSLROOT=`echo $dslosfile | sed -e 's|<OSFILE>\(.*\)/print/docbook.dsl|\1|'`
 677     fi
 678     if test -f $DSLROOT/print/docbook.dsl; then
 679         AC_MSG_RESULT([in $DSLROOT])
 680         have_openjade="yes"
 681     else
 682         AC_MSG_RESULT([not found: PDF documentation will not be built.])
 683     fi
 684 fi
 685 AC_SUBST(DSLROOT)
 686
 687 AC_MSG_CHECKING([for lynx])
 688 AC_PATH_PROG([HTML2TXT_CMD], [lynx], [none])
 689 if test x"$HTML2TXT_CMD" = x"none"; then
 690     AC_MSG_CHECKING([for w3m])
 691     AC_PATH_PROG([HTML2TXT_CMD], [w3m], [none])
 692 fi
 693 if test x"$HTML2TXT_CMD" = x"none"; then
 694     AC_MSG_CHECKING([for elinks])
 695     AC_PATH_PROG([HTML2TXT_CMD], [elinks], [none])
 696 fi
 697 case "$HTML2TXT_CMD" in
 698   *elinks*)
 699     HTML2TXT_CMD="$HTML2TXT_CMD -dump -no-numbering -no-references \$^ > \$@"
 700     ;;
 701   *lynx*)
 702     HTML2TXT_CMD="$HTML2TXT_CMD -dump -nolist -with_backspaces \$^ > \$@"
 703     ;;
 704   *w3m*)
 705     HTML2TXT_CMD="$HTML2TXT_CMD -dump \$^ > \$@"
 706     ;;
 707   *)
 708     HTML2TXT_CMD="true"
 709     ;;
 710 esac
 711 AC_SUBST(HTML2TXT_CMD)
 712
 713 AC_MSG_CHECKING([for tidy])
 714 AC_PATH_PROG([HTMLCLEAN_CMD], [tidy], [none])
 715
 716 if test x"$HTMLCLEAN_CMD" != x"none"; then
 717     HTMLCLEAN_CMD="$HTMLCLEAN_CMD -q -i -m -asxml -utf8 "
 718 else
 719     HTMLCLEAN_CMD="echo "
 720 fi
 721 AC_SUBST(HTMLCLEAN_CMD)
 722
 723 AC_OUTPUT(Makefile
 724           Madmuttrc.head
 725
 726           intl/Makefile
 727           m4/Makefile
 728           po/Makefile.in
 729           doc/Makefile doc/instdoc.sh
 730           contrib/Makefile
 731           lib-lib/Makefile
 732           lib-mime/Makefile
 733           lib-crypt/Makefile
 734           lib-hash/Makefile
 735           lib-sys/Makefile
 736           lib-ui/Makefile
 737           lib/Makefile
 738           imap/Makefile
 739           pop/Makefile
 740           nntp/Makefile
 741 )