configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl !!! WHEN ADDING NEW CONFIGURE TESTS, PLEASE ADD CODE TO MAIN.C !!!
   4 dnl !!! TO DUMP THEIR RESULTS WHEN MUTT -V IS CALLED            !!!
   5
   6 AC_PREREQ([2.50])
   7 AC_INIT([mutt.h])
   8 AM_CONFIG_HEADER(config.h)
   9 AM_INIT_AUTOMAKE(madmutt, `cat "$srcdir/VERSION.in"`)
  10
  11 AC_SUBST([CONFIGURE_DEPENDENCIES], ['$(top_srcdir)/VERSION.in'])
  12
  13 AC_GNU_SOURCE
  14
  15 ALL_LINGUAS="de ru it es uk fr pl nl cs id sk ko el zh_TW zh_CN pt_BR eo gl sv da lt tr ja hu et ca bg"
  16
  17 AC_CANONICAL_HOST
  18
  19 AC_MSG_CHECKING([for prefix])
  20 if test x$prefix = xNONE; then
  21     mutt_cv_prefix=$ac_default_prefix
  22 else
  23     mutt_cv_prefix=$prefix
  24 fi
  25 AC_MSG_RESULT($mutt_cv_prefix)
  26
  27 AC_PROG_CPP
  28 AC_PROG_CC_C99
  29
  30 AM_C_PROTOTYPES
  31 AC_C_INLINE
  32 AC_C_CONST
  33 if test "x$U" != "x"; then
  34     AC_MSG_ERROR(Compiler not ANSI compliant)
  35 fi
  36 AC_ISC_POSIX
  37 AC_HEADER_STDC
  38
  39 AC_PROG_MAKE_SET
  40 AC_PROG_INSTALL
  41 AC_PROG_RANLIB
  42 AC_PROG_GPERF
  43 PKG_PROG_PKG_CONFIG
  44 AC_CHECK_TOOL(AR, ar, ar)
  45
  46 AC_SYS_LARGEFILE
  47 AC_FUNC_FSEEKO
  48 AC_CHECK_SIZEOF(off_t)
  49
  50 AH_TEMPLATE([sig_atomic_t],
  51             [Define to 'int' if <signal.h> doesn't define.])
  52 AH_TEMPLATE([HAVE_START_COLOR],
  53             [Define if you have start_color, as a function or macro.])
  54 AH_TEMPLATE([HAVE_TYPEAHEAD],
  55             [Define if you have typeahead, as a function or macro.])
  56 AH_TEMPLATE([HAVE_BKGDSET],
  57             [Define if you have bkgdset, as a function or macro.])
  58 AH_TEMPLATE([HAVE_CURS_SET],
  59             [Define if you have curs_set, as a function or macro.])
  60 AH_TEMPLATE([HAVE_META],
  61             [Define if you have meta, as a function or macro.])
  62 AH_TEMPLATE([HAVE_USE_DEFAULT_COLORS],
  63             [Define if you have use_default_colors, as a function or macro.])
  64 AH_TEMPLATE([HAVE_RESIZETERM],
  65             [Define if you have resizeterm, as a function or macro.])
  66 AH_TEMPLATE([SIG_ATOMIC_VOLATILE_T],
  67             [Some systems declare sig_atomic_t as volatile, some others -- no.
  68              This define will have value `sig_atomic_t' or
  69              `volatile sig_atomic_t' accordingly.])
  70 AH_TEMPLATE([ICONV_NONTRANS],
  71             [Define as 1 if iconv() only converts exactly and we should treat
  72              all return values other than (size_t)(-1) as equivalent.])
  73
  74 MUTT_C99_INTTYPES
  75
  76 dnl ---------------- sendmail ----------------
  77
  78 ac_aux_path_sendmail=/usr/sbin:/usr/lib
  79 AC_PATH_PROG(SENDMAIL, sendmail, /usr/sbin/sendmail, $PATH:$ac_aux_path_sendmail)
  80 AC_DEFINE_UNQUOTED(SENDMAIL,"$ac_cv_path_SENDMAIL",[ Where to find sendmail on your system. ])
  81
  82 OPS='$(srcdir)/OPS'
  83
  84 dnl ---------------- gpgme ----------------
  85
  86 AC_ARG_ENABLE(gpgme, AC_HELP_STRING([--enable-gpgme], [Enable GPGME support]),[
  87     if test x$enableval = xyes; then
  88         AM_PATH_GPGME(,,[AC_MSG_ERROR(GPGME not found)])
  89         MUTTLIBS="$MUTTLIBS $GPGME_LIBS"
  90         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS crypt-gpgme.o crypt-mod-pgp-gpgme.o crypt-mod-smime-gpgme.o"
  91         AC_DEFINE(CRYPT_BACKEND_GPGME, 1, [Defined, if GPGME support is enabled])
  92     fi
  93 ])
  94
  95 dnl ---------------- mixmaster ----------------
  96
  97 AC_ARG_WITH(mixmaster, AC_HELP_STRING([--with-mixmaster[=PATH]], [Include Mixmaster support]), [
  98     MIXMASTER=${withval:-"mixmaster"}
  99     OPS="$OPS \$(srcdir)/OPS.MIX"
 100     MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS remailer.o"
 101     AC_DEFINE_UNQUOTED(MIXMASTER,"$MIXMASTER",[Where to find mixmaster on your system.])
 102 ])
 103
 104 # We now require all OPS
 105 OPS="$OPS \$(srcdir)/OPS.PGP \$(srcdir)/OPS.SMIME \$(srcdir)/OPS.CRYPT "
 106 AC_SUBST([OPS])
 107
 108 AC_PATH_PROG(ISPELL, ispell, no)
 109 if test $ISPELL != no; then
 110     AC_DEFINE_UNQUOTED(ISPELL,"$ISPELL",[Where to find ispell on your system.])
 111 fi
 112
 113 AC_ARG_WITH(slang, AC_HELP_STRING([--with-slang[=DIR]], [Use S-Lang instead of ncurses]),
 114     [AC_CACHE_CHECK([if this is a BSD system], mutt_cv_bsdish,
 115         [AC_TRY_RUN([#include <sys/param.h>
 116
 117 main ()
 118 {
 119 #ifdef BSD
 120         exit (0);
 121 #else
 122         exit (1);
 123 #endif
 124 }],
 125         mutt_cv_bsdish=yes,
 126         mutt_cv_bsdish=no,
 127         mutt_cv_bsdish=no)])
 128
 129         AC_MSG_CHECKING(for S-Lang)
 130         if test $withval = yes; then
 131             if test -d $srcdir/../slang; then
 132                 mutt_cv_slang=$srcdir/../slang/src
 133                 CFLAGS="$CFLAGS -I${mutt_cv_slang}"
 134                 LDFLAGS="$LDFLAGS -L${mutt_cv_slang}/objs"
 135             else
 136                 if test -d $mutt_cv_prefix/include/slang; then
 137                     CFLAGS="$CFLAGS -I$mutt_cv_prefix/include/slang"
 138                 elif test -d /usr/include/slang; then
 139                     CFLAGS="$CFLAGS -I/usr/include/slang"
 140                 fi
 141                 mutt_cv_slang=yes
 142             fi
 143         else
 144             dnl ---Check to see if $withval is a source directory
 145             if test -f $withval/src/slang.h; then
 146                 mutt_cv_slang=$withval/src
 147                 CFLAGS="$CFLAGS -I${mutt_cv_slang}"
 148                 LDFLAGS="$LDFLAGS -L${mutt_cv_slang}/objs"
 149             else
 150                 dnl ---Must be installed somewhere
 151                 mutt_cv_slang=$withval
 152                 if test -d $withval/include/slang; then
 153                         CFLAGS="$CFLAGS -I${withval}/include/slang"
 154                 elif test -d $withval/include; then
 155                         CFLAGS="$CFLAGS -I${withval}/include"
 156                 fi
 157                 LDFLAGS="$LDFLAGS -L${withval}/lib"
 158             fi
 159         fi
 160         AC_MSG_RESULT($mutt_cv_slang)
 161         if test $mutt_cv_bsdish = yes; then
 162             AC_CHECK_LIB(termlib, main)
 163         fi
 164         AC_DEFINE(USE_SLANG_CURSES,1, [ Define if you compile with SLang instead of curses/ncurses. ])
 165         AC_DEFINE(HAVE_COLOR,1,[ Define if your curses library supports color. ])
 166         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS resize.o"
 167
 168         dnl --- now that we've found it, check the link
 169
 170         AC_CHECK_LIB(slang, SLtt_get_terminfo,
 171             [MUTTLIBS="$MUTTLIBS -lslang -lm"],
 172             [AC_MSG_ERROR(unable to compile.  check config.log)], -lm)
 173         ],
 174
 175         [   mutt_cv_curses=/usr
 176             AC_ARG_WITH(curses, AC_HELP_STRING([--with-curses=DIR], [Where ncurses is installed]),
 177             [   if test $withval != yes; then
 178                     mutt_cv_curses=$withval
 179                 fi
 180                 if test x$mutt_cv_curses != x/usr; then
 181                     LDFLAGS="-L${mutt_cv_curses}/lib $LDFLAGS"
 182                     CPPFLAGS="$CPPFLAGS -I${mutt_cv_curses}/include"
 183                 fi
 184             ])
 185
 186             AC_CHECK_FUNC(initscr,,[
 187             cf_ncurses="ncurses"
 188             for lib in ncursesw ncurses; do
 189                 AC_CHECK_LIB($lib, waddnwstr, [cf_ncurses="$lib"; break])
 190             done
 191             AC_CHECK_LIB($cf_ncurses, initscr,
 192                 [   MUTTLIBS="$MUTTLIBS -l$cf_ncurses"
 193                     if test x$mutt_cv_curses = x/usr -a -d /usr/include/ncurses; then
 194                         CPPFLAGS="$CPPFLAGS -I/usr/include/ncurses"
 195                     fi
 196
 197                     if test "$cf_ncurses" = ncursesw; then
 198                         AC_CHECK_HEADERS(ncurses/ncurses.h,[cf_cv_ncurses_header="ncurses/ncurses.h"])
 199                         AC_CHECK_HEADERS(ncursesw/ncurses.h,[cf_cv_ncurses_header="ncursesw/ncurses.h"])
 200                     else
 201                         AC_CHECK_HEADERS(ncurses.h,[cf_cv_ncurses_header="ncurses.h"])
 202                     fi
 203                 ],
 204                 [CF_CURSES_LIBS])
 205             ])
 206
 207             old_LIBS="$LIBS"
 208             LIBS="$LIBS $MUTTLIBS"
 209             CF_CHECK_FUNCDECLS([#include <${cf_cv_ncurses_header-curses.h}>],
 210                                [start_color typeahead bkgdset curs_set meta use_default_colors resizeterm])
 211             if test "$ac_cv_func_decl_start_color" = yes; then
 212                 AC_DEFINE(HAVE_COLOR,1,[ Define if your curses library supports color. ])
 213             fi
 214             if test "$ac_cv_func_decl_resizeterm" = yes; then
 215                 MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS resize.o"
 216             fi
 217             LIBS="$old_LIBS"
 218         ])
 219
 220 AC_CHECK_HEADERS(stdarg.h sys/ioctl.h ioctl.h sysexits.h)
 221 AC_CHECK_HEADERS(sys/time.h sys/resource.h)
 222 AC_CHECK_HEADERS(unix.h)
 223
 224 AC_CHECK_FUNCS(setrlimit getsid isctype)
 225
 226 AC_TYPE_SIGNAL
 227
 228 AC_MSG_CHECKING(for sig_atomic_t in signal.h)
 229 AC_EGREP_HEADER(sig_atomic_t,signal.h,
 230     [   ac_cv_type_sig_atomic_t=yes;
 231         AC_EGREP_HEADER(volatile.*sig_atomic_t,
 232                         signal.h,
 233                         [is_sig_atomic_t_volatile=yes; AC_MSG_RESULT([yes, volatile])],
 234                         [is_sig_atomic_t_volatile=no;  AC_MSG_RESULT([yes, non volatile])])
 235     ],
 236     [   AC_MSG_RESULT(no)
 237         AC_CHECK_TYPE(sig_atomic_t, int)
 238         is_sig_atomic_t_volatile=no
 239     ])
 240 if test $is_sig_atomic_t_volatile = 'yes'
 241 then
 242     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, sig_atomic_t)
 243 else
 244     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, [volatile sig_atomic_t])
 245 fi
 246
 247 AC_DECL_SYS_SIGLIST
 248
 249 AC_TYPE_PID_T
 250
 251 AC_CHECK_FUNCS(fgetpos memmove setegid srand48 strerror)
 252 AC_REPLACE_FUNCS(strcasecmp setenv)
 253 AC_CHECK_FUNCS(snprintf vsnprintf)
 254
 255 AC_CHECK_FUNC(getopt)
 256 if test $ac_cv_func_getopt = yes; then
 257     AC_CHECK_HEADERS(getopt.h)
 258 fi
 259
 260 AC_ARG_WITH(regex, AC_HELP_STRING([--with-regex], [Use the GNU regex library]),
 261         [mutt_cv_regex=yes],
 262         [AC_CHECK_FUNCS(regcomp, mutt_cv_regex=no, mutt_cv_regex=yes)])
 263
 264 if test $mutt_cv_regex = no ; then
 265     AC_CACHE_CHECK([whether your system's regexp library is completely broken],
 266         [mutt_cv_regex_broken],
 267         AC_TRY_RUN([
 268 #include <unistd.h>
 269 #include <regex.h>
 270 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
 271         mutt_cv_regex_broken=no, mutt_cv_regex_broken=yes, mutt_cv_regex_broken=yes))
 272     if test $mutt_cv_regex_broken = yes ; then
 273         echo "Using the included GNU regex instead." >&AC_FD_MSG
 274         mutt_cv_regex=yes
 275     fi
 276 fi
 277
 278 if test $mutt_cv_regex = yes; then
 279     AC_DEFINE(USE_GNU_REGEX,1,[ Define if you want to use the included regex.c. ])
 280     LIBOBJS="$LIBOBJS regex.o"
 281 fi
 282
 283
 284 AC_ARG_WITH(homespool,
 285             AC_HELP_STRING([--with-homespool[=FILE]],
 286                            [File in user's directory where new mail is spooled]),
 287                            with_homespool=${withval})
 288 if test x$with_homespool != x; then
 289     if test $with_homespool = yes; then
 290             with_homespool=mailbox
 291     fi
 292     AC_DEFINE_UNQUOTED(MAILPATH,"$with_homespool",[ Where new mail is spooled. ])
 293     AC_DEFINE(HOMESPOOL,1,
 294     [   Is mail spooled to the user's home directory?  If defined,
 295         MAILPATH should be set to the filename of the spool mailbox
 296         relative the the home directory.
 297         use: configure --with-homespool=FILE
 298     ])
 299     AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 300     mutt_cv_setgid=no
 301 else
 302     AC_ARG_WITH(mailpath, AC_HELP_STRING([--with-mailpath=DIR], [Directory where spool mailboxes are located]),
 303         [mutt_cv_mailpath=$withval],
 304         [ AC_CACHE_CHECK(where new mail is stored, mutt_cv_mailpath,
 305             [mutt_cv_mailpath=no
 306             if test -d /var/mail; then
 307                 mutt_cv_mailpath=/var/mail
 308             elif test -d /var/spool/mail; then
 309                 mutt_cv_mailpath=/var/spool/mail
 310             elif test -d /usr/spool/mail; then
 311                 mutt_cv_mailpath=/usr/spool/mail
 312             elif test -d /usr/mail; then
 313                 mutt_cv_mailpath=/usr/mail
 314             fi])
 315         ])
 316     if test "$mutt_cv_mailpath" = no; then
 317         AC_MSG_ERROR("Could not determine where new mail is stored.")
 318     fi
 319     AC_DEFINE_UNQUOTED(MAILPATH,"$mutt_cv_mailpath",[ Where new mail is spooled. ])
 320
 321     AC_CACHE_CHECK(if $mutt_cv_mailpath is world writable, mutt_cv_worldwrite, [AC_TRY_RUN([#include <sys/types.h>
 322 #include <sys/stat.h>
 323
 324 int main (int argc, char **argv)
 325 {
 326         struct stat s;
 327
 328         stat ("$mutt_cv_mailpath", &s);
 329         if (s.st_mode & S_IWOTH) exit (0);
 330         exit (1);
 331 }], mutt_cv_worldwrite=yes, mutt_cv_worldwrite=no, mutt_cv_worldwrite=no)])
 332
 333         mutt_cv_setgid=no
 334         if test $mutt_cv_worldwrite = yes; then
 335                 AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 336         else
 337                 AC_CACHE_CHECK(if $mutt_cv_mailpath is group writable, mutt_cv_groupwrite, [AC_TRY_RUN([#include <sys/types.h>
 338 #include <sys/stat.h>
 339
 340 int main (int argc, char **argv)
 341 {
 342         struct stat s;
 343
 344         stat ("$mutt_cv_mailpath", &s);
 345         if (s.st_mode & S_IWGRP) exit (0);
 346         exit (1);
 347 }], mutt_cv_groupwrite=yes, mutt_cv_groupwrite=no, mutt_cv_groupwrite=no)])
 348
 349         if test $mutt_cv_groupwrite = yes; then
 350             AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 351             AC_DEFINE(USE_SETGID,1,[ Define if mutt should run setgid "mail". ])
 352             mutt_cv_setgid=yes
 353         fi
 354     fi
 355 fi
 356
 357 AC_MSG_CHECKING(where to put the documentation)
 358 AC_ARG_WITH(docdir, AC_HELP_STRING([--with-docdir=PATH], [Specify where to put the documentation]),
 359         [mutt_cv_docdir=$withval],
 360         [mutt_cv_docdir="${prefix}/doc/madmutt"])
 361 AC_MSG_RESULT($mutt_cv_docdir)
 362
 363 docdir=$mutt_cv_docdir
 364 AC_SUBST(docdir)
 365
 366 if test x$mutt_cv_setgid = xyes; then
 367     DOTLOCK_GROUP='mail'
 368     DOTLOCK_PERMISSION=2755
 369 else
 370     DOTLOCK_GROUP=''
 371     DOTLOCK_PERMISSION=755
 372 fi
 373 AC_SUBST(DOTLOCK_GROUP)
 374 AC_SUBST(DOTLOCK_PERMISSION)
 375
 376 dnl -- socket dependencies --
 377
 378 AC_ARG_ENABLE(nntp, AC_HELP_STRING([--enable-nntp],[Enable NNTP support]),[
 379     if test x$enableval = xyes ; then
 380         AC_DEFINE(USE_NNTP,1,[ Compiling with newsreading support with NNTP ])
 381         LIBNNTP="-Lnntp -lnntp"
 382         LIBNNTPDEPS="\$(top_srcdir)/nntp/nntp.h nntp/libnntp.a"
 383         need_nntp="yes"
 384     fi
 385 ])
 386 AM_CONDITIONAL(BUILD_NNTP, test x$need_nntp = xyes)
 387
 388 dnl -- end socket dependencies --
 389
 390 AC_MSG_CHECKING([for socklen_t])
 391 AC_EGREP_HEADER(socklen_t, sys/socket.h, AC_MSG_RESULT([yes]),
 392         AC_MSG_RESULT([no])
 393         AC_DEFINE(socklen_t,int, [ Define to 'int' if <sys/socket.h> doesn't have it. ]))
 394 AC_CHECK_FUNC(gethostent, , AC_CHECK_LIB(nsl, gethostent))
 395 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt))
 396 AC_CHECK_FUNCS(getaddrinfo)
 397
 398 dnl -- imap dependencies --
 399
 400 AC_ARG_WITH(gss, AC_HELP_STRING([--with-gss[=PFX]], [Compile in GSSAPI authentication for IMAP]),
 401     gss_prefix="$withval", gss_prefix="no")
 402 if test "$gss_prefix" != "no"
 403 then
 404     MUTT_AM_PATH_GSSAPI(gss_prefix)
 405     AC_MSG_CHECKING(GSSAPI implementation)
 406     AC_MSG_RESULT($GSSAPI_IMPL)
 407     if test "$GSSAPI_IMPL" = "none"
 408     then
 409       AC_CACHE_SAVE
 410       AC_MSG_RESULT([GSSAPI libraries not found])
 411     fi
 412     if test "$GSSAPI_IMPL" = "Heimdal"
 413     then
 414       AC_DEFINE(HAVE_HEIMDAL,1,[ Define if your GSSAPI implementation is Heimdal ])
 415     fi
 416     CPPFLAGS="$CPPFLAGS $GSSAPI_CFLAGS"
 417     MUTTLIBS="$MUTTLIBS $GSSAPI_LIBS"
 418     AC_DEFINE(USE_GSS,1,[ Define if you have GSSAPI libraries available ])
 419     need_gss="yes"
 420 fi
 421 AM_CONDITIONAL(USE_GSS, test x$need_gss = xyes)
 422
 423 dnl -- end imap dependencies --
 424
 425 AC_ARG_WITH(ssl, AC_HELP_STRING([--with-ssl[=PFX]], [Compile in SSL support for POP/IMAP]),
 426 [       if test "$with_ssl" != "no"
 427         then
 428           if test "$with_ssl" != "yes"
 429           then
 430            LDFLAGS="$LDFLAGS -L$withval/lib"
 431            CPPFLAGS="$CPPFLAGS -I$withval/include"
 432           fi
 433           saved_LIBS="$LIBS"
 434
 435           AC_CHECK_LIB(crypto, X509_new,, AC_MSG_ERROR([Unable to find SSL library]))
 436           AC_CHECK_LIB(ssl, SSL_new,, AC_MSG_ERROR([Unable to find SSL library]), -lcrypto)
 437
 438           AC_CHECK_FUNCS(RAND_status RAND_egd)
 439
 440           AC_DEFINE(USE_SSL,1,[ Define if you want support for SSL. ])
 441           LIBS="$saved_LIBS"
 442           MUTTLIBS="$MUTTLIBS -lssl -lcrypto"
 443           MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_ssl.o"
 444           need_ssl=yes
 445
 446         fi
 447 ])
 448
 449 AC_ARG_WITH([gnutls], AC_HELP_STRING([--with-gnutls], [Enable SSL support using gnutls]),
 450             [gnutls_prefix="$withval"], [gnutls_prefix="no"])
 451 if test "$gnutls_prefix" != "no"; then
 452     if test x"$need_ssl" = x"yes"; then
 453         AC_MSG_ERROR([Only either OpenSSL or GNUTLS may be used])
 454     fi
 455     AM_PATH_LIBGNUTLS(,[
 456         CPPFLAGS="$CPPFLAGS $LIBGNUTLS_CFLAGS"
 457         MUTTLIBS="$MUTTLIBS $LIBGNUTLS_LIBS"
 458         AC_DEFINE(USE_GNUTLS, 1, [Define if you want support for SSL via the gnutls library.])
 459         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_ssl_gnutls.o"
 460         need_ssl=yes],
 461         [AC_MSG_ERROR([could not find libgnutls])
 462     ])
 463 fi
 464 AM_CONDITIONAL(USE_SSL, test x$need_ssl = xyes)
 465
 466 AC_ARG_WITH(sasl2, AC_HELP_STRING([--with-sasl2[=PFX]],
 467             [Use Cyrus SASL library version 2 for POP/IMAP authentication]),[
 468     if test "$with_sasl2" != "no"; then
 469         if test "$with_sasl2" != "yes"; then
 470             CPPFLAGS="$CPPFLAGS -I$with_sasl2/include"
 471             LDFLAGS="$LDFLAGS -L$with_sasl2/lib"
 472         fi
 473
 474         saved_LIBS="$LIBS"
 475
 476         AC_CHECK_LIB(sasl2, sasl_client_init,,
 477                      AC_MSG_ERROR([could not find libsasl2]),)
 478
 479         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_sasl.o"
 480         MUTTLIBS="$MUTTLIBS -lsasl2"
 481         LIBS="$saved_LIBS"
 482         AC_DEFINE(USE_SASL,1,
 483                   [Define if want to use version 2 of the Cyrus SASL library.])
 484         need_sasl=yes
 485     fi
 486 ])
 487 AM_CONDITIONAL(USE_SASL, test x$need_sasl = xyes)
 488
 489 AC_ARG_WITH(idn, AC_HELP_STRING([--with-idn=[PFX]], [Use GNU libidn for domain names]),[
 490     if test x$with_idn != xno ; then
 491         PKG_CHECK_MODULES(IDN,libidn,[
 492             if $PKG_CONFIG --atleast-version=0.6; then
 493                 AC_MSG_ERROR([libidn is too old, want 0.6 at least])
 494             fi
 495             CPPFLAGS="$CPPFLAGS $IDN_CFLAGS"
 496             LDFLAGS="$LDFLAGS $IDN_LIBS"
 497         ],[AC_MSG_ERROR([could not find libidn])])
 498     fi
 499 ])
 500
 501 dnl -- end socket --
 502
 503 AC_ARG_ENABLE(debug, AC_HELP_STRING([--enable-debug], [Enable debugging support]),
 504     [ if test x$enableval = xyes ; then
 505             AC_DEFINE(DEBUG,1,[ Define to enable debugging info. ])
 506       fi
 507      ])
 508
 509 AC_ARG_ENABLE(flock, AC_HELP_STRING([--enable-flock], [Use flock() to lock files]),
 510         [if test $enableval = yes; then
 511                 AC_DEFINE(USE_FLOCK,1, [ Define to use flock() to lock mailboxes. ])
 512         fi])
 513
 514 mutt_cv_fcntl=yes
 515 AC_ARG_ENABLE(fcntl, AC_HELP_STRING([--disable-fcntl], [Do NOT use fcntl() to lock files]),
 516         [if test $enableval = no; then mutt_cv_fcntl=no; fi])
 517
 518 if test $mutt_cv_fcntl = yes; then
 519         AC_DEFINE(USE_FCNTL,1, [ Define to use fcntl() to lock folders. ])
 520 fi
 521
 522 AC_MSG_CHECKING(whether struct dirent defines d_ino)
 523 ac_cv_dirent_d_ino=no
 524 AC_TRY_LINK([#include <dirent.h>],[struct dirent dp; (void)dp.d_ino],[ac_cv_dirent_d_ino=yes])
 525 if test x$ac_cv_dirent_d_ino = xyes ; then
 526   AC_DEFINE(HAVE_DIRENT_D_INO,1,
 527             [Define to 1 if your system has the dirent::d_ino member])
 528 fi
 529 AC_MSG_RESULT($ac_cv_dirent_d_ino)
 530
 531 AC_ARG_ENABLE(buffy-size, AC_HELP_STRING([--enable-buffy-size], [Use file size attribute instead of access time]),
 532         [if test x$enableval = xyes; then
 533                 AC_DEFINE(BUFFY_SIZE,1,[ Define to enable the "buffy_size" feature. ])
 534         fi])
 535
 536 dnl -- start cache --
 537 AC_ARG_ENABLE(hcache, AC_HELP_STRING([--enable-hcache], [Enable header caching]),
 538 [if test x$enableval = xyes; then
 539     AC_DEFINE(USE_HCACHE, 1, [Enable header caching])
 540
 541     OLDCPPFLAGS="$CPPFLAGS"
 542     OLDLIBS="$LIBS"
 543
 544     need_md5="yes"
 545
 546     ac_prefer_qdbm=yes
 547     AC_ARG_WITH(qdbm, AC_HELP_STRING([--without-qdbm], [Don't use qdbm even if it is available]),
 548         ac_prefer_qdbm=$withval)
 549     if test x$ac_prefer_qdbm != xno; then
 550         PKG_CHECK_MODULES(QDBM,qdbm,[ac_qdbm_here=yes],[ac_qdbm_here=no])
 551     fi
 552
 553     ac_prefer_gdbm=yes
 554     AC_ARG_WITH(gdbm, AC_HELP_STRING([--without-gdbm], [Don't use gdbm even if it is available]),
 555         ac_prefer_gdbm=$withval)
 556     if test x$ac_prefer_gdbm != xno -a x$ac_qdbm_here != xyes; then
 557         ac_cv_gdbmopen=no
 558         GDBM_DIRS="$mutt_cv_prefix /usr/local /usr"
 559         AC_MSG_CHECKING([for gdbm_open])
 560         for d in $GDBM_DIRS; do
 561           if test x$ac_cv_gdbmopen = xno && test -d "$d/include" && test -d "$d/lib"; then
 562             GDBM_INC="-I$d/include"
 563             GDBM_LIB="-L$d/lib"
 564             CPPFLAGS="$OLDCPPFLAGS $GDBM_INC"
 565             LIBS="$OLDLIBS $GDBM_LIB -lgdbm"
 566             AC_TRY_LINK([#include <gdbm.h>],[gdbm_open(0,0,0,0,0);],[ac_cv_gdbmopen=yes])
 567           fi
 568         done
 569         if test x$ac_cv_gdbmopen = xyes; then
 570           AC_MSG_RESULT(yes)
 571         else
 572           AC_MSG_RESULT(no)
 573         fi
 574     fi
 575
 576     ac_bdb_prefix=yes
 577     AC_ARG_WITH(bdb, AC_HELP_STRING([--with-bdb[=DIR]], [Use BerkeleyDB4 if gdbm is not available ]),
 578         ac_bdb_prefix=$withval)
 579     if test x$ac_bdb_prefix != xno -a x$ac_cv_gdbmopen != xyes -a x$ac_qdbm_here != xyes; then
 580         test x$ac_bdb_prefix = xyes && ac_bdb_prefix="$mutt_cv_prefix /opt/csw/bdb4 /opt /usr/local /usr"
 581         for d in $ac_bdb_prefix; do
 582             bdbpfx="$bdbpfx $d"
 583             for v in BerkeleyDB.4.3 BerkeleyDB.4.2 BerkeleyDB.4.1; do
 584                 bdbpfx="$bdbpfx $d/$v"
 585             done
 586         done
 587         BDB_VERSIONS="db-4 db4 db-4.3 db4.3 db43 db-4.2 db4.2 db42 db-4.1 db4.1 db41 db ''"
 588         AC_MSG_CHECKING([for BerkeleyDB > 4.0])
 589         for d in $bdbpfx; do
 590             BDB_INCLUDE_DIR=""
 591             BDB_LIB_DIR=""
 592             for v in / $BDB_VERSIONS; do
 593                 if test -r "$d/include/$v/db.h"; then
 594                     BDB_INCLUDE_DIR="$d/include/$v"
 595                     if test -d "$d/lib/$v"; then
 596                         BDB_LIB_DIR="$d/lib/$v"
 597                         for l in `echo $BDB_VERSIONS`; do
 598                             CPPFLAGS="-I$BDB_INCLUDE_DIR $OLDCPPFLAGS"
 599                             LIBS="$OLDLIBS -L$BDB_LIB_DIR -l$l"
 600                             AC_TRY_LINK([
 601                                 #include <stdlib.h>
 602                                 #include <db.h>
 603                             ],[
 604                                 DB *db = NULL;
 605                                 db->open(db,NULL,NULL,NULL,0,0,0);
 606                             ],[
 607                                 ac_cv_dbcreate=yes
 608                                 BDB_LIB="$l"
 609                                 break
 610                             ])
 611                         done
 612                         test x$ac_cv_dbcreate = xyes && break
 613                     fi
 614                 fi
 615             done
 616             test x$BDB_LIB != x && break
 617         done
 618         if test x$ac_cv_dbcreate = xyes; then
 619             AC_MSG_RESULT(yes)
 620         else
 621             AC_MSG_RESULT(no)
 622         fi
 623     fi
 624
 625     if test x$ac_qdbm_here = xyes; then
 626         CPPFLAGS="$OLDCPPFLAGS $QDBM_CFLAGS"
 627         LIBS="$OLDLIBS $QDBM_LIBS"
 628         AC_DEFINE(HAVE_QDBM, 1, [QDBM Support])
 629     elif test x$ac_cv_gdbmopen = xyes; then
 630         CPPFLAGS="$OLDCPPFLAGS $GDBM_INC"
 631         LIBS="$OLDLIBS $GDBM_LIB -lgdbm";
 632         AC_DEFINE(HAVE_GDBM, 1, [GDBM Support])
 633     elif test x$ac_cv_dbcreate = xyes; then
 634         CPPFLAGS="-I$BDB_INCLUDE_DIR $OLDCPPFLAGS"
 635         LIBS="$OLDLIBS -L$BDB_LIB_DIR -l$BDB_LIB"
 636         AC_DEFINE(HAVE_DB4, 1, [Sleepycat DB4 Support])
 637     else
 638         AC_MSG_ERROR([You need one of: QDBM, GDBM or Sleepycat DB4 for --enable-hcache])
 639     fi
 640 fi])
 641 dnl -- end cache --
 642
 643 AC_SUBST(MUTTLIBS)
 644 AC_SUBST(MUTT_LIB_OBJECTS)
 645 AC_SUBST(LIBNNTP)
 646 AC_SUBST(LIBNNTPDEPS)
 647
 648 dnl -- iconv/gettext --
 649
 650 AC_ARG_ENABLE(iconv, AC_HELP_STRING([--disable-iconv], [Disable iconv support]),
 651         [if test x$enableval = xno ; then
 652                 am_cv_func_iconv=no
 653         fi
 654 ])
 655
 656 AM_GNU_GETTEXT
 657
 658 if test "$am_cv_func_iconv" != "yes"
 659 then
 660   AC_MSG_WARN([Configuring without iconv support. See INSTALL for details])
 661 else
 662
 663 AC_CHECK_HEADERS(iconv.h,
 664         [AC_MSG_CHECKING(whether iconv.h defines iconv_t)
 665          AC_EGREP_HEADER([typedef.*iconv_t],iconv.h,
 666                 [AC_MSG_RESULT(yes)
 667                  AC_DEFINE(HAVE_ICONV_T_DEF, 1,
 668                         [Define if <iconv.h> defines iconv_t.])],
 669                  AC_MSG_RESULT(no))])
 670
 671 dnl (1) Some implementations of iconv won't convert from UTF-8 to UTF-8.
 672 dnl (2) In glibc-2.1.2 and earlier there is a bug that messes up ob and
 673 dnl     obl when args 2 and 3 are 0 (fixed in glibc-2.1.3).
 674 AC_CACHE_CHECK([whether this iconv is good enough], mutt_cv_iconv_good,
 675         mutt_save_LIBS="$LIBS"
 676         LIBS="$LIBS $LIBICONV"
 677         AC_TRY_RUN([
 678 #include <iconv.h>
 679 int main()
 680 {
 681   iconv_t cd;
 682 changequote(, )dnl
 683   char buf[4];
 684 changequote([, ])dnl
 685   char *ob;
 686   size_t obl;
 687   ob = buf, obl = sizeof(buf);
 688   return ((cd = iconv_open("UTF-8", "UTF-8")) != (iconv_t)(-1) &&
 689           (iconv(cd, 0, 0, &ob, &obl) ||
 690            !(ob == buf && obl == sizeof(buf)) ||
 691            iconv_close(cd)));
 692 }
 693                 ],
 694                 mutt_cv_iconv_good=yes,
 695                 mutt_cv_iconv_good=no,
 696                 mutt_cv_iconv_good=yes)
 697         LIBS="$mutt_save_LIBS")
 698 if test "$mutt_cv_iconv_good" = no; then
 699   AC_MSG_ERROR(Try using libiconv instead)
 700 fi
 701
 702 dnl This is to detect implementations such as the one in glibc-2.1,
 703 dnl which always convert exactly but return the number of characters
 704 dnl converted instead of the number converted inexactly.
 705 AC_CACHE_CHECK([whether iconv is non-transcribing], mutt_cv_iconv_nontrans,
 706         mutt_save_LIBS="$LIBS"
 707         LIBS="$LIBS $LIBICONV"
 708         AC_TRY_RUN([
 709 #include <iconv.h>
 710 #include <string.h>
 711 int main()
 712 {
 713   iconv_t cd;
 714   const char *ib;
 715   char *ob;
 716   size_t ibl, obl;
 717   const char *s = "\304\211";
 718 changequote(, )dnl
 719   char t[3];
 720 changequote([, ])dnl
 721   ib = s, ibl = 2, ob = t, obl = 3;
 722   return ((cd = iconv_open("UTF-8", "UTF-8")) == (iconv_t)(-1) ||
 723           iconv(cd, &ib, &ibl, &ob, &obl));
 724 }
 725                 ],
 726                 mutt_cv_iconv_nontrans=no,
 727                 mutt_cv_iconv_nontrans=yes,
 728                 mutt_cv_iconv_nontrans=no)
 729         LIBS="$mutt_save_LIBS")
 730 if test "$mutt_cv_iconv_nontrans" = yes; then
 731   AC_DEFINE(ICONV_NONTRANS, 1)
 732 else
 733   AC_DEFINE(ICONV_NONTRANS, 0)
 734 fi
 735
 736 CPPFLAGS="$CPPFLAGS -I\$(top_srcdir)/intl"
 737
 738 if test "$BUILD_INCLUDED_LIBINTL" = "yes"; then
 739   AC_DEFINE(HAVE_BIND_TEXTDOMAIN_CODESET,1,
 740           [ Define if your gettext has bind_textdomain_codeset. ])
 741 else
 742   AC_CHECK_FUNCS(bind_textdomain_codeset)
 743 fi
 744
 745 fi # libiconv
 746
 747 dnl -- locales --
 748
 749 AC_CHECK_HEADERS(wchar.h)
 750
 751 AC_CACHE_CHECK([for wchar_t], mutt_cv_wchar_t,
 752         AC_TRY_COMPILE([
 753 #include <stddef.h>
 754 #include <stdlib.h>
 755 #ifdef HAVE_WCHAR_H
 756 #include <wchar.h>
 757 #endif
 758                 ],
 759                 [ wchar_t wc; return 0; ],
 760                 mutt_cv_wchar_t=yes,
 761                 mutt_cv_wchar_t=no))
 762
 763 if test "$mutt_cv_wchar_t" = no; then
 764         AC_DEFINE(wchar_t,int,[ Define to 'int' if system headers don't define. ])
 765 fi
 766
 767 AC_CACHE_CHECK([for wint_t], mutt_cv_wint_t,
 768         AC_TRY_COMPILE([
 769 #include <stddef.h>
 770 #include <stdlib.h>
 771 #ifdef HAVE_WCHAR_H
 772 #include <wchar.h>
 773 #endif
 774                 ],
 775                 [ wint_t wc; return 0; ],
 776                 mutt_cv_wint_t=yes,
 777                 mutt_cv_wint_t=no))
 778
 779 if test "$mutt_cv_wint_t" = no; then
 780         AC_DEFINE(wint_t,int,[ Define to 'int' if system headers don't define. ])
 781 fi
 782
 783 AC_CHECK_HEADERS(wctype.h)
 784 AC_CHECK_FUNCS(iswalnum iswalpha  iswcntrl iswdigit)
 785 AC_CHECK_FUNCS(iswgraph iswlower iswprint iswpunct iswspace iswupper)
 786 AC_CHECK_FUNCS(iswxdigit towupper towlower)
 787
 788 AC_CACHE_CHECK([for mbstate_t], mutt_cv_mbstate_t,
 789         AC_TRY_COMPILE([
 790 #include <stddef.h>
 791 #include <stdlib.h>
 792 #ifdef HAVE_WCHAR_H
 793 #include <wchar.h>
 794 #endif
 795                 ],
 796                 [ mbstate_t s; return 0; ],
 797                 mutt_cv_mbstate_t=yes,
 798                 mutt_cv_mbstate_t=no))
 799
 800 if test "$mutt_cv_mbstate_t" = no; then
 801         AC_DEFINE(mbstate_t,int,[ Define to 'int' if system headers don't define. ])
 802 fi
 803
 804 wc_funcs=maybe
 805 AC_ARG_WITH(wc-funcs, AC_HELP_STRING([--without-wc-funcs], [Do not use the system's wchar_t functions]),
 806         wc_funcs=$withval)
 807
 808 if test "$wc_funcs" != yes -a "$wc_funcs" != no; then
 809         AC_CACHE_CHECK([for wchar_t functions], mutt_cv_wc_funcs,
 810                 mutt_cv_wc_funcs=no
 811                 AC_TRY_LINK([
 812 #define _XOPEN_SOURCE 1
 813 #include <stddef.h>
 814 #include <stdlib.h>
 815 #ifdef HAVE_WCTYPE_H
 816 #include <wctype.h>
 817 #endif
 818 #ifdef HAVE_WCHAR_H
 819 #include <wchar.h>
 820 #endif],
 821                         [mbrtowc(0, 0, 0, 0); wctomb(0, 0); wcwidth(0);
 822         iswprint(0); iswspace(0); towlower(0); towupper(0); iswalnum(0)],
 823                         mutt_cv_wc_funcs=yes))
 824         wc_funcs=$mutt_cv_wc_funcs
 825 fi
 826
 827 if test $wc_funcs = yes; then
 828         AC_DEFINE(HAVE_WC_FUNCS,1,[ Define if you are using the system's wchar_t functions. ])
 829 fi
 830
 831 AC_CACHE_CHECK([for nl_langinfo and CODESET], mutt_cv_langinfo_codeset,
 832   [AC_TRY_LINK([#include <langinfo.h>],
 833     [char* cs = nl_langinfo(CODESET);],
 834     mutt_cv_langinfo_codeset=yes,
 835     mutt_cv_langinfo_codeset=no)])
 836 if test $mutt_cv_langinfo_codeset = yes; then
 837   AC_DEFINE(HAVE_LANGINFO_CODESET,1,[ Define if you have <langinfo.h> and nl_langinfo(CODESET). ])
 838 fi
 839
 840 AC_CACHE_CHECK([for nl_langinfo and YESEXPR], mutt_cv_langinfo_yesexpr,
 841   [AC_TRY_LINK([#include <langinfo.h>],
 842     [char* cs = nl_langinfo(YESEXPR);],
 843     mutt_cv_langinfo_yesexpr=yes,
 844     mutt_cv_langinfo_yesexpr=no)])
 845 if test $mutt_cv_langinfo_yesexpr = yes; then
 846   AC_DEFINE(HAVE_LANGINFO_YESEXPR,1,[ Define if you have <langinfo.h> and nl_langinfo(YESEXPR). ])
 847 fi
 848
 849 dnl -- libesmtp --
 850 MUTT_AM_LIBESMTP
 851 if test x$use_libesmtp = xyes; then
 852     CFLAGS="$CFLAGS $mutt_libesmtp_cflags"
 853     MUTTLIBS="$MUTTLIBS $mutt_libesmtp_libs"
 854     MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_libesmtp.o"
 855
 856     AC_DEFINE(USE_LIBESMTP,
 857               1,
 858               [Define to enable the use of libesmtp])
 859 fi
 860 dnl -- end libesmtp --
 861
 862 dnl -- sgml tools --
 863
 864 dnl Documentation tools
 865 have_openjade="no"
 866 AC_PATH_PROG([OSPCAT], [ospcat], [none])
 867 if test "$OSPCAT" != "none"
 868 then
 869   AC_MSG_CHECKING([for openjade docbook stylesheets])
 870   dslosfile=`ospcat --public-id="-//Norman Walsh//DOCUMENT DocBook Print Stylesheet//EN"`
 871   DSLROOT=`echo $dslosfile | sed -n -e "s/.*SOIBASE='\(@<:@^'@:>@*\)\/catalog'.*/\1/p"`
 872   # ospcat may spit out an absolute path without an SOIBASE
 873   if test -z "$DSLROOT"
 874   then
 875     DSLROOT=`echo $dslosfile | sed -e 's|<OSFILE>\(.*\)/print/docbook.dsl|\1|'`
 876   fi
 877   if test -f $DSLROOT/print/docbook.dsl
 878   then
 879     AC_MSG_RESULT([in $DSLROOT])
 880     have_openjade="yes"
 881   else
 882     AC_MSG_RESULT([not found: PDF documentation will not be built.])
 883   fi
 884 fi
 885 AC_SUBST(DSLROOT)
 886
 887 AC_MSG_CHECKING([for lynx])
 888 AC_PATH_PROG([HTML2TXT_CMD], [lynx], [none])
 889 if test x"$HTML2TXT_CMD" = x"none"
 890 then
 891   AC_MSG_CHECKING([for w3m])
 892   AC_PATH_PROG([HTML2TXT_CMD], [w3m], [none])
 893 fi
 894 if test x"$HTML2TXT_CMD" = x"none"
 895 then
 896   AC_MSG_CHECKING([for elinks])
 897   AC_PATH_PROG([HTML2TXT_CMD], [elinks], [none])
 898 fi
 899 case "$HTML2TXT_CMD" in
 900   *elinks*)
 901     HTML2TXT_CMD="$HTML2TXT_CMD -dump -no-numbering -no-references \$^ > \$@"
 902     ;;
 903   *lynx*)
 904     HTML2TXT_CMD="$HTML2TXT_CMD -dump -nolist -with_backspaces \$^ > \$@"
 905     ;;
 906   *w3m*)
 907     HTML2TXT_CMD="$HTML2TXT_CMD -dump \$^ > \$@"
 908     ;;
 909   *)
 910     HTML2TXT_CMD="true"
 911     ;;
 912 esac
 913 AC_SUBST(HTML2TXT_CMD)
 914
 915 AC_MSG_CHECKING([for tidy])
 916 AC_PATH_PROG([HTMLCLEAN_CMD], [tidy], [none])
 917
 918 if test x"$HTMLCLEAN_CMD" != x"none"
 919 then
 920   HTMLCLEAN_CMD="$HTMLCLEAN_CMD -q -i -m -asxml -utf8 "
 921 else
 922   HTMLCLEAN_CMD="echo "
 923 fi
 924 AC_SUBST(HTMLCLEAN_CMD)
 925
 926 AC_OUTPUT(Makefile intl/Makefile m4/Makefile
 927         po/Makefile.in doc/Makefile contrib/Makefile
 928         lib-lib/Makefile
 929         lib-mime/Makefile
 930         lib-crypt/Makefile
 931         lib-hash/Makefile
 932         lib-ui/Makefile
 933         lib/Makefile
 934         imap/Makefile
 935         pop/Makefile
 936         nntp/Makefile
 937         Madmuttrc.head
 938         doc/instdoc.sh)