configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl !!! WHEN ADDING NEW CONFIGURE TESTS, PLEASE ADD CODE TO MAIN.C !!!
   4 dnl !!! TO DUMP THEIR RESULTS WHEN MUTT -V IS CALLED            !!!
   5
   6 AC_PREREQ([2.50])
   7 AC_INIT([mutt.h])
   8 AM_CONFIG_HEADER(config.h)
   9
  10 mutt_cv_version=`cat "$srcdir/VERSION.in"`
  11
  12 AM_INIT_AUTOMAKE(muttng, $mutt_cv_version)
  13 AC_SUBST([CONFIGURE_DEPENDENCIES], ['$(top_srcdir)/VERSION.in'])
  14
  15 dnl AC_GNU_SOURCE
  16
  17 ifdef([AC_LIBOBJ], , [define([AC_LIBOBJ], [LIB[]OBJS="$LIBOBJS $1.o"])])
  18
  19 ALL_LINGUAS="de ru it es uk fr pl nl cs id sk ko el zh_TW zh_CN pt_BR eo gl sv da lt tr ja hu et ca bg"
  20
  21 AC_CANONICAL_HOST
  22
  23 AC_MSG_CHECKING([for prefix])
  24 if test x$prefix = xNONE; then
  25         mutt_cv_prefix=$ac_default_prefix
  26 else
  27         mutt_cv_prefix=$prefix
  28 fi
  29 AC_MSG_RESULT($mutt_cv_prefix)
  30
  31 AC_PROG_CC
  32 AC_ISC_POSIX
  33 AM_C_PROTOTYPES
  34 if test "x$U" != "x"; then
  35   AC_MSG_ERROR(Compiler not ANSI compliant)
  36 fi
  37 AC_PROG_CPP
  38 AC_PROG_MAKE_SET
  39 AC_PROG_INSTALL
  40 AC_PROG_RANLIB
  41 AC_CHECK_TOOL(AR, ar, ar)
  42
  43 AC_C_INLINE
  44 AC_C_CONST
  45
  46 AC_SYS_LARGEFILE
  47 AC_FUNC_FSEEKO
  48 AC_CHECK_SIZEOF(off_t)
  49
  50 AC_PATH_PROG(DBX, dbx, no)
  51 AC_PATH_PROG(GDB, gdb, no)
  52 AC_PATH_PROG(SDB, sdb, no)
  53
  54 if test $GDB != no ; then
  55         DEBUGGER=$GDB
  56 elif test $DBX != no ; then
  57         DEBUGGER=$DBX
  58 elif test $SDB != no ; then
  59         DEBUGGER=$SDB
  60 else
  61         DEBUGGER=no
  62 fi
  63
  64 AC_SUBST([DEBUGGER])
  65
  66 AH_TEMPLATE([sig_atomic_t],
  67             [/* Define to `int' if <signal.h> doesn't define.])
  68 AH_TEMPLATE([HAVE_START_COLOR],
  69             [Define if you have start_color, as a function or macro.])
  70 AH_TEMPLATE([HAVE_TYPEAHEAD],
  71             [Define if you have typeahead, as a function or macro.])
  72 AH_TEMPLATE([HAVE_BKGDSET],
  73             [Define if you have bkgdset, as a function or macro.])
  74 AH_TEMPLATE([HAVE_CURS_SET],
  75             [Define if you have curs_set, as a function or macro.])
  76 AH_TEMPLATE([HAVE_META],
  77             [Define if you have meta, as a function or macro.])
  78 AH_TEMPLATE([HAVE_USE_DEFAULT_COLORS],
  79             [Define if you have use_default_colors, as a function or macro.])
  80 AH_TEMPLATE([HAVE_RESIZETERM],
  81             [Define if you have resizeterm, as a function or macro.])
  82 AH_TEMPLATE([SIG_ATOMIC_VOLATILE_T],
  83             [Some systems declare sig_atomic_t as volatile, some others -- no.
  84              This define will have value `sig_atomic_t' or
  85              `volatile sig_atomic_t' accordingly.])
  86 AH_TEMPLATE([ICONV_NONTRANS],
  87             [Define as 1 if iconv() only converts exactly and we should treat
  88              all return values other than (size_t)(-1) as equivalent.])
  89
  90 AH_BOTTOM([/* fseeko portability defines */
  91 #ifdef HAVE_FSEEKO
  92 # define LOFF_T off_t
  93 # if SIZEOF_OFF_T == 8
  94 # define OFF_T_FMT "%lld"
  95 # else
  96 # define OFF_T_FMT "%ld"
  97 # endif
  98 #else
  99 # define LOFF_T long
 100 # define fseeko fseek
 101 # define ftello ftell
 102 # define OFF_T_FMT "%ld"
 103 #endif
 104 ])
 105 MUTT_C99_INTTYPES
 106
 107 ac_aux_path_sendmail=/usr/sbin:/usr/lib
 108 AC_PATH_PROG(SENDMAIL, sendmail, /usr/sbin/sendmail, $PATH:$ac_aux_path_sendmail)
 109 AC_DEFINE_UNQUOTED(SENDMAIL,"$ac_cv_path_SENDMAIL",[ Where to find sendmail on your system. ])
 110
 111 OPS='$(srcdir)/OPS'
 112
 113         AC_ARG_ENABLE(gpgme, AC_HELP_STRING([--enable-gpgme], [Enable GPGME support]),
 114         [       if test x$enableval = xyes; then
 115                         have_gpgme=yes
 116                 fi
 117         ])
 118         AC_ARG_WITH(gpgme-prefix, AC_HELP_STRING([--with-gpgme-prefix=PFX], [prefix where GPGME is installed (optional)]),
 119         gpgme_config_prefix="$withval", gpgme_config_prefix="")
 120
 121         if test x$have_gpgme = xyes; then
 122                 if test x$gpgme_config_prefix != x; then
 123                         GPGME_CONFIG="$gpgme_config_prefix/bin/gpgme-config"
 124                 else
 125                         AC_PATH_PROG(GPGME_CONFIG, gpgme-config, no)
 126                 fi
 127                 if test "x$GPGME_CONFIG" = "xno"; then
 128                         AC_MSG_ERROR([GPGME not found])
 129                 else
 130                         LIBGPGME_CFLAGS=`$GPGME_CONFIG --cflags`
 131                         LIBGPGME_LIBS=`$GPGME_CONFIG --libs`
 132       MUTTLIBS="$MUTTLIBS $LIBGPGME_LIBS"
 133                         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS crypt-gpgme.o crypt-mod-pgp-gpgme.o crypt-mod-smime-gpgme.o"
 134                         AC_DEFINE(CRYPT_BACKEND_GPGME, 1,
 135                                   [Defined, if GPGME support is enabled])
 136                 fi
 137         fi
 138         AC_SUBST(LIBGPGME_CFLAGS)
 139         AC_SUBST(LIBGPGME_LIBS)
 140
 141         AC_ARG_ENABLE(pgp, AC_HELP_STRING([--disable-pgp], [Disable PGP support]),
 142         [       if test x$enableval = xno ; then
 143                         have_pgp=no
 144                 fi
 145         ])
 146
 147         if test x$have_pgp != xno ; then
 148                 AC_DEFINE(CRYPT_BACKEND_CLASSIC_PGP,1,
 149                     [ Define if you want classic PGP support. ])
 150                 PGPAUX_TARGET="pgpringng\$(EXEEXT) pgpewrapng\$(EXEEXT)"
 151                 MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS pgp.o pgpinvoke.o pgpkey.o pgplib.o gnupgparse.o pgpmicalg.o pgppacket.o crypt-mod-pgp-classic.o"
 152         fi
 153
 154         AC_ARG_ENABLE(smime, AC_HELP_STRING([--disable-smime], [Disable SMIME support]),
 155         [       if test x$enableval = xno ; then
 156                         have_smime=no
 157                 fi
 158         ])
 159
 160         if test x$have_smime != xno ; then
 161                 AC_DEFINE(CRYPT_BACKEND_CLASSIC_SMIME,1,
 162                   [ Define if you want clasic S/MIME support. ])
 163                 MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS smime.o crypt-mod-smime-classic.o"
 164                 SMIMEAUX_TARGET="smime_keysng"
 165         fi
 166
 167         AC_ARG_WITH(mixmaster, AC_HELP_STRING([--with-mixmaster[=PATH]], [Include Mixmaster support]),
 168                 [if test -x "$withval" ; then
 169                         MIXMASTER="$withval"
 170                  else
 171                         MIXMASTER="mixmaster"
 172                  fi
 173                  OPS="$OPS \$(srcdir)/OPS.MIX"
 174                  MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS remailer.o"
 175                  AC_DEFINE_UNQUOTED(MIXMASTER,"$MIXMASTER",
 176                          [ Where to find mixmaster on your system. ])
 177                 ])
 178
 179 # We now require all OPS
 180 OPS="$OPS \$(srcdir)/OPS.PGP \$(srcdir)/OPS.SMIME \$(srcdir)/OPS.CRYPT "
 181 AC_SUBST([OPS])
 182
 183
 184 AC_SUBST(PGPAUX_TARGET)
 185 AC_SUBST(SMIMEAUX_TARGET)
 186
 187 AC_PATH_PROG(ISPELL, ispell, no)
 188 if test $ISPELL != no; then
 189         AC_DEFINE_UNQUOTED(ISPELL,"$ISPELL",[ Where to find ispell on your system. ])
 190 fi
 191
 192 AC_ARG_WITH(slang, AC_HELP_STRING([--with-slang[=DIR]], [Use S-Lang instead of ncurses]),
 193         [AC_CACHE_CHECK([if this is a BSD system], mutt_cv_bsdish,
 194                 [AC_TRY_RUN([#include <sys/param.h>
 195
 196 main ()
 197 {
 198 #ifdef BSD
 199         exit (0);
 200 #else
 201         exit (1);
 202 #endif
 203 }],
 204                         mutt_cv_bsdish=yes,
 205                         mutt_cv_bsdish=no,
 206                         mutt_cv_bsdish=no)])
 207
 208         AC_MSG_CHECKING(for S-Lang)
 209         if test $withval = yes; then
 210                 if test -d $srcdir/../slang; then
 211                         mutt_cv_slang=$srcdir/../slang/src
 212                         CFLAGS="$CFLAGS -I${mutt_cv_slang}"
 213                         LDFLAGS="$LDFLAGS -L${mutt_cv_slang}/objs"
 214                 else
 215                         if test -d $mutt_cv_prefix/include/slang; then
 216                                 CFLAGS="$CFLAGS -I$mutt_cv_prefix/include/slang"
 217                         elif test -d /usr/include/slang; then
 218                                 CFLAGS="$CFLAGS -I/usr/include/slang"
 219                         fi
 220                         mutt_cv_slang=yes
 221                 fi
 222         else
 223                 dnl ---Check to see if $withval is a source directory
 224                 if test -f $withval/src/slang.h; then
 225                         mutt_cv_slang=$withval/src
 226                         CFLAGS="$CFLAGS -I${mutt_cv_slang}"
 227                         LDFLAGS="$LDFLAGS -L${mutt_cv_slang}/objs"
 228                 else
 229                         dnl ---Must be installed somewhere
 230                         mutt_cv_slang=$withval
 231                         if test -d $withval/include/slang; then
 232                                 CFLAGS="$CFLAGS -I${withval}/include/slang"
 233                         elif test -d $withval/include; then
 234                                 CFLAGS="$CFLAGS -I${withval}/include"
 235                         fi
 236                         LDFLAGS="$LDFLAGS -L${withval}/lib"
 237                 fi
 238         fi
 239         AC_MSG_RESULT($mutt_cv_slang)
 240         if test $mutt_cv_bsdish = yes; then
 241                 AC_CHECK_LIB(termlib, main)
 242         fi
 243         AC_DEFINE(USE_SLANG_CURSES,1,
 244                 [ Define if you compile with SLang instead of curses/ncurses. ])
 245         AC_DEFINE(HAVE_COLOR,1,[ Define if your curses library supports color. ])
 246         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS resize.o"
 247
 248         dnl --- now that we've found it, check the link
 249
 250         AC_CHECK_LIB(slang, SLtt_get_terminfo,
 251                 [MUTTLIBS="$MUTTLIBS -lslang -lm"],
 252                 [AC_MSG_ERROR(unable to compile.  check config.log)], -lm)
 253
 254         ],
 255
 256         [mutt_cv_curses=/usr
 257         AC_ARG_WITH(curses, AC_HELP_STRING([--with-curses=DIR], [Where ncurses is installed]),
 258                 [if test $withval != yes; then
 259                         mutt_cv_curses=$withval
 260                 fi
 261                 if test x$mutt_cv_curses != x/usr; then
 262                         LDFLAGS="-L${mutt_cv_curses}/lib $LDFLAGS"
 263                         CPPFLAGS="$CPPFLAGS -I${mutt_cv_curses}/include"
 264                 fi])
 265
 266         AC_CHECK_FUNC(initscr,,[
 267         cf_ncurses="ncurses"
 268         for lib in ncursesw ncurses
 269         do
 270                 AC_CHECK_LIB($lib, waddnwstr, [cf_ncurses="$lib"; break])
 271         done
 272         AC_CHECK_LIB($cf_ncurses, initscr,
 273                 [MUTTLIBS="$MUTTLIBS -l$cf_ncurses"
 274                 if test x$mutt_cv_curses = x/usr -a -d /usr/include/ncurses; then
 275                         CPPFLAGS="$CPPFLAGS -I/usr/include/ncurses"
 276                 fi
 277
 278                 if test "$cf_ncurses" = ncursesw; then
 279                         AC_CHECK_HEADERS(ncurses/ncurses.h,[cf_cv_ncurses_header="ncurses/ncurses.h"])
 280                         AC_CHECK_HEADERS(ncursesw/ncurses.h,[cf_cv_ncurses_header="ncursesw/ncurses.h"])
 281                 else
 282                         AC_CHECK_HEADERS(ncurses.h,[cf_cv_ncurses_header="ncurses.h"])
 283                 fi],
 284
 285                 [CF_CURSES_LIBS])
 286                 ])
 287
 288         old_LIBS="$LIBS"
 289         LIBS="$LIBS $MUTTLIBS"
 290         CF_CHECK_FUNCDECLS([#include <${cf_cv_ncurses_header-curses.h}>],
 291                            [start_color typeahead bkgdset curs_set meta use_default_colors resizeterm])
 292         if test "$ac_cv_func_decl_start_color" = yes; then
 293                 AC_DEFINE(HAVE_COLOR,1,[ Define if your curses library supports color. ])
 294         fi
 295         if test "$ac_cv_func_decl_resizeterm" = yes; then
 296                 MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS resize.o"
 297         fi
 298         LIBS="$old_LIBS"
 299         ])
 300
 301 AC_HEADER_STDC
 302
 303 AC_CHECK_HEADERS(stdarg.h sys/ioctl.h ioctl.h sysexits.h)
 304 AC_CHECK_HEADERS(sys/time.h sys/resource.h)
 305 AC_CHECK_HEADERS(unix.h)
 306
 307 AC_CHECK_FUNCS(setrlimit getsid isctype)
 308
 309 AC_TYPE_SIGNAL
 310
 311 AC_MSG_CHECKING(for sig_atomic_t in signal.h)
 312 AC_EGREP_HEADER(sig_atomic_t,signal.h,
 313   [
 314     ac_cv_type_sig_atomic_t=yes;
 315     AC_EGREP_HEADER(volatile.*sig_atomic_t,
 316                     signal.h,
 317                     [
 318                         is_sig_atomic_t_volatile=yes;
 319                         AC_MSG_RESULT([yes, volatile])
 320                     ],
 321                     [
 322                         is_sig_atomic_t_volatile=no;
 323                         AC_MSG_RESULT([yes, non volatile])
 324                     ])
 325   ],
 326   [
 327     AC_MSG_RESULT(no)
 328     AC_CHECK_TYPE(sig_atomic_t, int)
 329     is_sig_atomic_t_volatile=no
 330   ])
 331 if test $is_sig_atomic_t_volatile = 'yes'
 332 then
 333     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, sig_atomic_t)
 334 else
 335     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, [volatile sig_atomic_t])
 336 fi
 337
 338 AC_DECL_SYS_SIGLIST
 339
 340 AC_TYPE_PID_T
 341 dnl AC_CHECK_TYPE(ssize_t, int)
 342
 343 AC_CHECK_FUNCS(fgetpos memmove setegid srand48 strerror)
 344
 345 AC_REPLACE_FUNCS(strcasecmp strdup setenv)
 346
 347 AC_CHECK_FUNC(getopt)
 348 if test $ac_cv_func_getopt = yes; then
 349         AC_CHECK_HEADERS(getopt.h)
 350 fi
 351
 352 mutt_cv_snprintf=no
 353 SNPRINTFOBJS=""
 354 AC_CHECK_FUNCS(snprintf, , [mutt_cv_snprintf=yes])
 355 AC_CHECK_FUNCS(vsnprintf, , [mutt_cv_snprintf=yes])
 356 if test $mutt_cv_snprintf = yes; then
 357         AC_LIBOBJ(snprintf)
 358 fi
 359
 360 dnl SCO uses chsize() instead of ftruncate()
 361 AC_CHECK_FUNCS(ftruncate, , [AC_CHECK_LIB(x, chsize)])
 362
 363 dnl SCO has strftime() in libintl
 364 AC_CHECK_FUNCS(strftime, , [AC_CHECK_LIB(intl, strftime)])
 365
 366 dnl AIX may not have fchdir()
 367 AC_CHECK_FUNCS(fchdir, , [mutt_cv_fchdir=no])
 368
 369 AC_ARG_WITH(regex, AC_HELP_STRING([--with-regex], [Use the GNU regex library]),
 370         [mutt_cv_regex=yes],
 371         [AC_CHECK_FUNCS(regcomp, mutt_cv_regex=no, mutt_cv_regex=yes)])
 372
 373 if test $mutt_cv_regex = no ; then
 374 AC_CACHE_CHECK([whether your system's regexp library is completely broken],
 375         [mutt_cv_regex_broken],
 376         AC_TRY_RUN([
 377 #include <unistd.h>
 378 #include <regex.h>
 379 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
 380         mutt_cv_regex_broken=no, mutt_cv_regex_broken=yes, mutt_cv_regex_broken=yes))
 381         if test $mutt_cv_regex_broken = yes ; then
 382                 echo "Using the included GNU regex instead." >&AC_FD_MSG
 383                 mutt_cv_regex=yes
 384         fi
 385 fi
 386
 387 if test $mutt_cv_regex = yes; then
 388         AC_DEFINE(USE_GNU_REGEX,1,[ Define if you want to use the included regex.c. ])
 389         AC_LIBOBJ(regex)
 390 fi
 391
 392
 393 AC_ARG_WITH(homespool,
 394   AC_HELP_STRING([--with-homespool[=FILE]], [File in user's directory where new mail is spooled]), with_homespool=${withval})
 395 if test x$with_homespool != x; then
 396         if test $with_homespool = yes; then
 397                 with_homespool=mailbox
 398         fi
 399         AC_DEFINE_UNQUOTED(MAILPATH,"$with_homespool",[ Where new mail is spooled. ])
 400         AC_DEFINE(HOMESPOOL,1,
 401           [Is mail spooled to the user's home directory?  If defined,
 402            MAILPATH should be set to the filename of the spool mailbox
 403            relative the the home directory.
 404            use: configure --with-homespool=FILE])
 405         AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 406         mutt_cv_setgid=no
 407 else
 408         AC_ARG_WITH(mailpath, AC_HELP_STRING([--with-mailpath=DIR], [Directory where spool mailboxes are located]),
 409                 [mutt_cv_mailpath=$withval],
 410                 [ AC_CACHE_CHECK(where new mail is stored, mutt_cv_mailpath,
 411                         [mutt_cv_mailpath=no
 412                         if test -d /var/mail; then
 413                                 mutt_cv_mailpath=/var/mail
 414                         elif test -d /var/spool/mail; then
 415                                 mutt_cv_mailpath=/var/spool/mail
 416                         elif test -d /usr/spool/mail; then
 417                                 mutt_cv_mailpath=/usr/spool/mail
 418                         elif test -d /usr/mail; then
 419                                 mutt_cv_mailpath=/usr/mail
 420                         fi])
 421                 ])
 422         if test "$mutt_cv_mailpath" = no; then
 423                 AC_MSG_ERROR("Could not determine where new mail is stored.")
 424         fi
 425         AC_DEFINE_UNQUOTED(MAILPATH,"$mutt_cv_mailpath",[ Where new mail is spooled. ])
 426
 427         AC_CACHE_CHECK(if $mutt_cv_mailpath is world writable, mutt_cv_worldwrite, [AC_TRY_RUN([#include <sys/types.h>
 428 #include <sys/stat.h>
 429
 430 int main (int argc, char **argv)
 431 {
 432         struct stat s;
 433
 434         stat ("$mutt_cv_mailpath", &s);
 435         if (s.st_mode & S_IWOTH) exit (0);
 436         exit (1);
 437 }], mutt_cv_worldwrite=yes, mutt_cv_worldwrite=no, mutt_cv_worldwrite=no)])
 438
 439         mutt_cv_setgid=no
 440         if test $mutt_cv_worldwrite = yes; then
 441                 AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 442         else
 443
 444                 AC_CACHE_CHECK(if $mutt_cv_mailpath is group writable, mutt_cv_groupwrite, [AC_TRY_RUN([#include <sys/types.h>
 445 #include <sys/stat.h>
 446
 447 int main (int argc, char **argv)
 448 {
 449         struct stat s;
 450
 451         stat ("$mutt_cv_mailpath", &s);
 452         if (s.st_mode & S_IWGRP) exit (0);
 453         exit (1);
 454 }], mutt_cv_groupwrite=yes, mutt_cv_groupwrite=no, mutt_cv_groupwrite=no)])
 455
 456                 if test $mutt_cv_groupwrite = yes; then
 457                         AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 458                         AC_DEFINE(USE_SETGID,1,[ Define if mutt should run setgid "mail". ])
 459                         mutt_cv_setgid=yes
 460                 fi
 461         fi
 462 fi
 463
 464 AC_ARG_ENABLE(external_dotlock, AC_HELP_STRING([--enable-external-dotlock], [Force use of an external dotlock program]),
 465         [mutt_cv_external_dotlock="$enableval"])
 466
 467 if test "x$mutt_cv_setgid" = "xyes" || test "x$mutt_cv_fchdir" = "xno" \
 468         || test "x$mutt_cv_external_dotlock" = "xyes"
 469 then
 470         AC_DEFINE(DL_STANDALONE,1,[ Define if you want to use an external dotlocking program. ])
 471         DOTLOCK_TARGET="muttng_dotlock"
 472 else
 473         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS dotlock.o"
 474 fi
 475
 476 AC_SUBST(DOTLOCK_TARGET)
 477
 478
 479 AC_MSG_CHECKING(where to put the documentation)
 480 AC_ARG_WITH(docdir, AC_HELP_STRING([--with-docdir=PATH], [Specify where to put the documentation]),
 481         [mutt_cv_docdir=$withval],
 482         [mutt_cv_docdir="${prefix}/doc/muttng"])
 483 AC_MSG_RESULT($mutt_cv_docdir)
 484
 485 docdir=$mutt_cv_docdir
 486 AC_SUBST(docdir)
 487
 488 if test x$mutt_cv_setgid = xyes; then
 489         DOTLOCK_GROUP='mail'
 490         DOTLOCK_PERMISSION=2755
 491 else
 492         DOTLOCK_GROUP=''
 493         DOTLOCK_PERMISSION=755
 494 fi
 495 AC_SUBST(DOTLOCK_GROUP)
 496 AC_SUBST(DOTLOCK_PERMISSION)
 497
 498 AC_ARG_WITH(domain, AC_HELP_STRING([--with-domain=DOMAIN], [Specify your DNS domain name]),
 499         [if test $withval != yes; then
 500          if test $withval != no; then
 501            AC_DEFINE_UNQUOTED(DOMAIN,"$withval",[ Define your domain name. ])
 502          fi
 503         fi])
 504
 505 need_socket="no"
 506
 507 dnl -- socket dependencies --
 508
 509 AC_ARG_ENABLE(pop,  AC_HELP_STRING([--enable-pop], [Enable POP3 support]),
 510 [       if test x$enableval = xyes ; then
 511                 AC_DEFINE(USE_POP,1,[ Define if you want support for the POP3 protocol. ])
 512                 LIBPOP="-Lpop -lpop"
 513                 LIBPOPDEPS="\$(top_srcdir)/pop/pop.h pop/libpop.a"
 514                 need_socket="yes"
 515                 need_pop="yes"
 516                 need_md5="yes"
 517         fi
 518 ])
 519 AM_CONDITIONAL(BUILD_POP, test x$need_pop = xyes)
 520
 521 AC_ARG_ENABLE(imap, AC_HELP_STRING([--enable-imap], [Enable IMAP support]),
 522 [       if test x$enableval = xyes ; then
 523                 AC_DEFINE(USE_IMAP,1,[ Define if you want support for the IMAP protocol. ])
 524                 LIBIMAP="-Limap -limap"
 525                 LIBIMAPDEPS="\$(top_srcdir)/imap/imap.h imap/libimap.a"
 526                 need_imap="yes"
 527                 need_socket="yes"
 528                 need_md5="yes"
 529         fi
 530 ])
 531 AM_CONDITIONAL(BUILD_IMAP, test x$need_imap = xyes)
 532
 533 AC_ARG_ENABLE(nntp, [  --enable-nntp              Enable NNTP support],
 534 [       if test x$enableval = xyes ; then
 535                 AC_DEFINE(USE_NNTP,1,[ Compiling with newsreading support with NNTP ])
 536                 LIBNNTP="-Lnntp -lnntp"
 537                 LIBNNTPDEPS="\$(top_srcdir)/nntp/nntp.h nntp/libnntp.a"
 538                 need_nntp="yes"
 539                 need_socket="yes"
 540         fi
 541 ])
 542 AM_CONDITIONAL(BUILD_NNTP, test x$need_nntp = xyes)
 543
 544 dnl -- end socket dependencies --
 545
 546 if test "$need_socket" = "yes"
 547 then
 548         AC_MSG_CHECKING([for socklen_t])
 549         AC_EGREP_HEADER(socklen_t, sys/socket.h, AC_MSG_RESULT([yes]),
 550                 AC_MSG_RESULT([no])
 551                 AC_DEFINE(socklen_t,int,
 552                         [ Define to 'int' if <sys/socket.h> doesn't have it. ]))
 553         AC_CHECK_FUNC(gethostent, , AC_CHECK_LIB(nsl, gethostent))
 554         AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt))
 555         AC_CHECK_FUNCS(getaddrinfo)
 556         AC_DEFINE(USE_SOCKET,1,
 557                 [ Include code for socket support. Set automatically if you enable POP3 or IMAP ])
 558         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS account.o mutt_socket.o mutt_tunnel.o"
 559 fi
 560
 561 dnl -- imap dependencies --
 562
 563 AC_ARG_WITH(gss, AC_HELP_STRING([--with-gss[=PFX]], [Compile in GSSAPI authentication for IMAP]),
 564     gss_prefix="$withval", gss_prefix="no")
 565 if test "$gss_prefix" != "no"
 566 then
 567   if test "$need_imap" = "yes"
 568   then
 569     MUTT_AM_PATH_GSSAPI(gss_prefix)
 570     AC_MSG_CHECKING(GSSAPI implementation)
 571     AC_MSG_RESULT($GSSAPI_IMPL)
 572     if test "$GSSAPI_IMPL" = "none"
 573     then
 574       AC_CACHE_SAVE
 575       AC_MSG_RESULT([GSSAPI libraries not found])
 576     fi
 577     if test "$GSSAPI_IMPL" = "Heimdal"
 578     then
 579       AC_DEFINE(HAVE_HEIMDAL,1,[ Define if your GSSAPI implementation is Heimdal ])
 580     fi
 581     CPPFLAGS="$CPPFLAGS $GSSAPI_CFLAGS"
 582     MUTTLIBS="$MUTTLIBS $GSSAPI_LIBS"
 583     AC_DEFINE(USE_GSS,1,[ Define if you have GSSAPI libraries available ])
 584     need_gss="yes"
 585   else
 586     AC_MSG_WARN([GSS was requested but IMAP is not enabled])
 587   fi
 588 fi
 589 AM_CONDITIONAL(USE_GSS, test x$need_gss = xyes)
 590
 591 dnl -- end imap dependencies --
 592
 593 AC_ARG_WITH(ssl, AC_HELP_STRING([--with-ssl[=PFX]], [Compile in SSL support for POP/IMAP]),
 594 [       if test "$with_ssl" != "no"
 595         then
 596           if test "$need_socket" != "yes"; then
 597            AC_MSG_ERROR([SSL support is only useful with POP or IMAP support])
 598           fi
 599
 600           if test "$with_ssl" != "yes"
 601           then
 602            LDFLAGS="$LDFLAGS -L$withval/lib"
 603            CPPFLAGS="$CPPFLAGS -I$withval/include"
 604           fi
 605           saved_LIBS="$LIBS"
 606
 607           AC_CHECK_LIB(crypto, X509_new,, AC_MSG_ERROR([Unable to find SSL library]))
 608           AC_CHECK_LIB(ssl, SSL_new,, AC_MSG_ERROR([Unable to find SSL library]), -lcrypto)
 609
 610           AC_CHECK_FUNCS(RAND_status RAND_egd)
 611
 612           AC_DEFINE(USE_SSL,1,[ Define if you want support for SSL. ])
 613           LIBS="$saved_LIBS"
 614           MUTTLIBS="$MUTTLIBS -lssl -lcrypto"
 615           MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_ssl.o"
 616           need_ssl=yes
 617
 618         fi
 619 ])
 620
 621 AC_ARG_WITH([gnutls], AC_HELP_STRING([--with-gnutls[=PFX]], [Enable SSL support using gnutls]),
 622     [gnutls_prefix="$withval"], [gnutls_prefix="no"])
 623 if test "$gnutls_prefix" != "no"
 624 then
 625   if test "$need_socket" != "yes"
 626   then
 627     AC_MSG_ERROR([SSL support is only useful with POP or IMAP support])
 628   fi
 629   if test x"$need_ssl" = x"yes"
 630   then
 631     AC_MSG_ERROR([Only either OpenSSL or GNUTLS may be used])
 632   fi
 633   MUTT_AM_PATH_GNUTLS([$gnutls_prefix],
 634     [dnl GNUTLS found
 635     CPPFLAGS="$CPPFLAGS $LIBGNUTLS_CFLAGS"
 636     MUTTLIBS="$MUTTLIBS $LIBGNUTLS_LIBS"
 637     AC_DEFINE(USE_GNUTLS, 1, [Define if you want support for SSL via the gnutls library.])
 638
 639     MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_ssl_gnutls.o"
 640     need_ssl=yes],
 641     [dnl GNUTLS not found
 642       AC_MSG_ERROR([could not find libgnutls])
 643     ])
 644 fi
 645
 646 AM_CONDITIONAL(USE_SSL, test x$need_ssl = xyes)
 647
 648 AC_ARG_WITH(sasl2, AC_HELP_STRING([--with-sasl2[=PFX]], [Use Cyrus SASL library version 2 for POP/IMAP authentication]),
 649         [
 650         if test "$with_sasl2" != "no" -a "$need_imap" != "yes" -a "$need_pop" != "yes"
 651         then
 652           AC_MSG_ERROR([SASL2 support is only useful with POP or IMAP support])
 653         fi
 654
 655         if test "$with_sasl2" != "no"
 656         then
 657           if test "$with_sasl2" != "yes"
 658           then
 659             CPPFLAGS="$CPPFLAGS -I$with_sasl2/include"
 660             LDFLAGS="$LDFLAGS -L$with_sasl2/lib"
 661           fi
 662
 663           saved_LIBS="$LIBS"
 664
 665           AC_CHECK_LIB(sasl2, sasl_client_init,,
 666             AC_MSG_ERROR([could not find libsasl2]),)
 667
 668           MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_sasl.o"
 669           MUTTLIBS="$MUTTLIBS -lsasl2"
 670           LIBS="$saved_LIBS"
 671           AC_DEFINE(USE_SASL,1,
 672                   [ Define if want to use version 2 of the Cyrus SASL library. ])
 673           need_sasl=yes
 674         fi
 675         ])
 676 AM_CONDITIONAL(USE_SASL, test x$need_sasl = xyes)
 677
 678 AC_ARG_WITH(idn, AC_HELP_STRING([--with-idn=[PFX]], [Use GNU libidn for domain names]),
 679                  [
 680                   if test "$with_idn" != "no" ; then
 681                         if test "$with_idn" != "yes" ; then
 682                            CPPFLAGS="$CPPFLAGS -I$with_idn/include"
 683                            LDFLAGS="$LDFLAGS -L$with_idn/lib"
 684                         fi
 685                   fi
 686                  ]
 687 )
 688
 689 if test "x$with_idn" != "xno"; then
 690    AC_CHECK_LIB(idn, stringprep_check_version)
 691    AC_CHECK_FUNCS(idna_to_unicode_utf8_from_utf8 idna_to_unicode_8z8z)
 692    AC_CHECK_FUNCS(idna_to_ascii_from_utf8 idna_to_ascii_8z)
 693    AC_CHECK_FUNCS(idna_to_ascii_lz idna_to_ascii_from_locale)
 694 fi
 695
 696 dnl -- end socket --
 697
 698 AC_ARG_ENABLE(debug, AC_HELP_STRING([--enable-debug], [Enable debugging support]),
 699         [ if test x$enableval = xyes ; then
 700                 AC_DEFINE(DEBUG,1,[ Define to enable debugging info. ])
 701           fi
 702          ])
 703
 704 AC_ARG_ENABLE(flock, AC_HELP_STRING([--enable-flock], [Use flock() to lock files]),
 705         [if test $enableval = yes; then
 706                 AC_DEFINE(USE_FLOCK,1, [ Define to use flock() to lock mailboxes. ])
 707         fi])
 708
 709 mutt_cv_fcntl=yes
 710 AC_ARG_ENABLE(fcntl, AC_HELP_STRING([--disable-fcntl], [Do NOT use fcntl() to lock files]),
 711         [if test $enableval = no; then mutt_cv_fcntl=no; fi])
 712
 713 if test $mutt_cv_fcntl = yes; then
 714         AC_DEFINE(USE_FCNTL,1, [ Define to use fcntl() to lock folders. ])
 715 fi
 716
 717 AC_MSG_CHECKING(whether struct dirent defines d_ino)
 718 ac_cv_dirent_d_ino=no
 719 AC_TRY_LINK([#include <dirent.h>],[struct dirent dp; (void)dp.d_ino],[ac_cv_dirent_d_ino=yes])
 720 if test x$ac_cv_dirent_d_ino = xyes ; then
 721   AC_DEFINE(HAVE_DIRENT_D_INO,1,
 722             [Define to 1 if your system has the dirent::d_ino member])
 723 fi
 724 AC_MSG_RESULT($ac_cv_dirent_d_ino)
 725
 726 dnl This may look cumbersome -- please keep it that way, so we can
 727 dnl quickly change the default to "yes" again.
 728 mutt_cv_inodesort=no
 729 AC_ARG_ENABLE(inodesort,  AC_HELP_STRING([--enable-inodesort], [Read files in maildir folders sorted by inode.]),
 730        [if test x$enableval = xyes -a x$ac_cv_dirent_d_ino = xyes ; then mutt_cv_inodesort=yes; fi])
 731
 732 if test $mutt_cv_inodesort = yes; then
 733         AC_DEFINE(USE_INODESORT, 1, [ Define to sort files in a maildir by inode number. ])
 734 fi
 735
 736 mutt_cv_warnings=yes
 737 AC_ARG_ENABLE(warnings, AC_HELP_STRING([--disable-warnings], [Turn off compiler warnings (not recommended)]),
 738 [if test $enableval = no; then
 739         mutt_cv_warnings=no
 740 fi])
 741
 742 if test x$GCC = xyes -a $mutt_cv_warnings = yes; then
 743         CFLAGS="-Wall -pedantic $CFLAGS"
 744 fi
 745
 746 AC_ARG_ENABLE(nfs-fix, AC_HELP_STRING([--enable-nfs-fix], [Work around an NFS with broken attributes caching]),
 747         [if test x$enableval = xyes; then
 748                 AC_DEFINE(NFS_ATTRIBUTE_HACK,1,
 749                   [Define if you have problems with mutt not detecting
 750                    new/old mailboxes over NFS.  Some NFS implementations
 751                    incorrectly cache the attributes of small files.])
 752         fi])
 753
 754 AC_ARG_ENABLE(buffy-size, AC_HELP_STRING([--enable-buffy-size], [Use file size attribute instead of access time]),
 755         [if test x$enableval = xyes; then
 756                 AC_DEFINE(BUFFY_SIZE,1,[ Define to enable the "buffy_size" feature. ])
 757         fi])
 758
 759 AC_ARG_ENABLE(mailtool, AC_HELP_STRING([--enable-mailtool], [Enable Sun mailtool attachments support ]),
 760         [if test x$enableval = xyes; then
 761                 AC_DEFINE(SUN_ATTACHMENT,1,[ Define to enable Sun mailtool attachments support. ])
 762         fi])
 763
 764 AC_ARG_ENABLE(compressed, [  --enable-compressed        Enable compressed folders support ],
 765         [if test x$enableval = xyes; then
 766                 AC_DEFINE(USE_COMPRESSED,1,[ The compressed mailboxes support ])
 767         fi])
 768
 769 AC_ARG_ENABLE(locales-fix, AC_HELP_STRING([--enable-locales-fix], [The result of isprint() is unreliable ]),
 770         [if test x$enableval = xyes; then
 771                 AC_DEFINE(LOCALES_HACK,1,[ Define if the result of isprint() is unreliable. ])
 772         fi])
 773
 774 AC_ARG_WITH(exec-shell, AC_HELP_STRING([--with-exec-shell=SHELL], [Specify alternate shell (ONLY if /bin/sh is broken)]),
 775         [if test $withval != yes; then
 776                 AC_DEFINE_UNQUOTED(EXECSHELL, "$withval",
 777                  [program to use for shell commands])
 778          else
 779                 AC_DEFINE_UNQUOTED(EXECSHELL, "/bin/sh")
 780         fi],
 781         [AC_DEFINE_UNQUOTED(EXECSHELL, "/bin/sh")])
 782
 783 dnl -- start cache --
 784 AC_ARG_ENABLE(hcache, AC_HELP_STRING([--enable-hcache], [Enable header caching]),
 785 [if test x$enableval = xyes; then
 786     AC_DEFINE(USE_HCACHE, 1, [Enable header caching])
 787
 788     OLDCPPFLAGS="$CPPFLAGS"
 789     OLDLIBS="$LIBS"
 790
 791     need_md5="yes"
 792
 793     ac_prefer_qdbm=yes
 794     AC_ARG_WITH(qdbm, AC_HELP_STRING([--without-qdbm], [Don't use qdbm even if it is available]),
 795         ac_prefer_qdbm=$withval)
 796     if test x$ac_prefer_qdbm != xno; then
 797         ac_cv_vlopen=no
 798         QDBM_DIRS="$mutt_cv_prefix /usr/local /usr"
 799         AC_MSG_CHECKING([for vlopen])
 800         for d in $QDBM_DIRS; do
 801           if test x$ac_cv_vlopen = xno && test -d "$d/include" && test -d "$d/lib"; then
 802             QDBM_INC="-I$d/include"
 803             QDBM_LIB="-L$d/lib"
 804             CPPFLAGS="$OLDCPPFLAGS $QDBM_INC"
 805             LIBS="$OLDLIBS $QDBM_LIB -lqdbm"
 806             AC_TRY_LINK([#include <villa.h>],[vlopen(0,0,0);],[ac_cv_vlopen=yes])
 807           fi
 808         done
 809         if test x$ac_cv_vlopen = xyes; then
 810           AC_MSG_RESULT(yes)
 811         else
 812           AC_MSG_RESULT(no)
 813         fi
 814     fi
 815
 816     ac_prefer_gdbm=yes
 817     AC_ARG_WITH(gdbm, AC_HELP_STRING([--without-gdbm], [Don't use gdbm even if it is available]),
 818         ac_prefer_gdbm=$withval)
 819     if test x$ac_prefer_gdbm != xno -a x$ac_cv_vlopen != xyes; then
 820         ac_cv_gdbmopen=no
 821         GDBM_DIRS="$mutt_cv_prefix /usr/local /usr"
 822         AC_MSG_CHECKING([for gdbm_open])
 823         for d in $GDBM_DIRS; do
 824           if test x$ac_cv_gdbmopen = xno && test -d "$d/include" && test -d "$d/lib"; then
 825             GDBM_INC="-I$d/include"
 826             GDBM_LIB="-L$d/lib"
 827             CPPFLAGS="$OLDCPPFLAGS $GDBM_INC"
 828             LIBS="$OLDLIBS $GDBM_LIB -lgdbm"
 829             AC_TRY_LINK([#include <gdbm.h>],[gdbm_open(0,0,0,0,0);],[ac_cv_gdbmopen=yes])
 830           fi
 831         done
 832         if test x$ac_cv_gdbmopen = xyes; then
 833           AC_MSG_RESULT(yes)
 834         else
 835           AC_MSG_RESULT(no)
 836         fi
 837     fi
 838
 839     ac_bdb_prefix=yes
 840     AC_ARG_WITH(bdb, AC_HELP_STRING([--with-bdb[=DIR]], [Use BerkeleyDB4 if gdbm is not available ]),
 841         ac_bdb_prefix=$withval)
 842     if test x$ac_bdb_prefix != xno -a x$ac_cv_gdbmopen != xyes -a x$ac_cv_vlopen != xyes; then
 843         test x$ac_bdb_prefix = xyes && ac_bdb_prefix="$mutt_cv_prefix /opt/csw/bdb4 /opt /usr/local /usr"
 844         for d in $ac_bdb_prefix; do
 845             bdbpfx="$bdbpfx $d"
 846             for v in BerkeleyDB.4.3 BerkeleyDB.4.2 BerkeleyDB.4.1; do
 847                 bdbpfx="$bdbpfx $d/$v"
 848             done
 849         done
 850         BDB_VERSIONS="db-4 db4 db-4.3 db4.3 db43 db-4.2 db4.2 db42 db-4.1 db4.1 db41 db ''"
 851         AC_MSG_CHECKING([for BerkeleyDB > 4.0])
 852         for d in $bdbpfx; do
 853             BDB_INCLUDE_DIR=""
 854             BDB_LIB_DIR=""
 855             for v in / $BDB_VERSIONS; do
 856                 if test -r "$d/include/$v/db.h"; then
 857                     BDB_INCLUDE_DIR="$d/include/$v"
 858                     if test -d "$d/lib/$v"; then
 859                         BDB_LIB_DIR="$d/lib/$v"
 860                         for l in `echo $BDB_VERSIONS`; do
 861                             CPPFLAGS="-I$BDB_INCLUDE_DIR $OLDCPPFLAGS"
 862                             LIBS="$OLDLIBS -L$BDB_LIB_DIR -l$l"
 863                             AC_TRY_LINK([
 864                                 #include <stdlib.h>
 865                                 #include <db.h>
 866                             ],[
 867                                 DB *db = NULL;
 868                                 db->open(db,NULL,NULL,NULL,0,0,0);
 869                             ],[
 870                                 ac_cv_dbcreate=yes
 871                                 BDB_LIB="$l"
 872                                 break
 873                             ])
 874                         done
 875                         test x$ac_cv_dbcreate = xyes && break
 876                     fi
 877                 fi
 878             done
 879             test x$BDB_LIB != x && break
 880         done
 881         if test x$ac_cv_dbcreate = xyes; then
 882             AC_MSG_RESULT(yes)
 883         else
 884             AC_MSG_RESULT(no)
 885         fi
 886     fi
 887
 888     if test x$ac_cv_vlopen = xyes; then
 889         CPPFLAGS="$OLDCPPFLAGS $QDBM_INC"
 890         LIBS="$OLDLIBS $QDBM_LIB -lqdbm"
 891         AC_DEFINE(HAVE_QDBM, 1, [QDBM Support])
 892     elif test x$ac_cv_gdbmopen = xyes; then
 893         CPPFLAGS="$OLDCPPFLAGS $GDBM_INC"
 894         LIBS="$OLDLIBS $GDBM_LIB -lgdbm";
 895         AC_DEFINE(HAVE_GDBM, 1, [GDBM Support])
 896     elif test x$ac_cv_dbcreate = xyes; then
 897         CPPFLAGS="-I$BDB_INCLUDE_DIR $OLDCPPFLAGS"
 898         LIBS="$OLDLIBS -L$BDB_LIB_DIR -l$BDB_LIB"
 899         AC_DEFINE(HAVE_DB4, 1, [Sleepycat DB4 Support])
 900     else
 901         AC_MSG_ERROR([You need one of: QDBM, GDBM or Sleepycat DB4 for --enable-hcache])
 902     fi
 903 fi])
 904 dnl -- end cache --
 905
 906 AC_SUBST(MUTTLIBS)
 907 AC_SUBST(MUTT_LIB_OBJECTS)
 908 AC_SUBST(LIBIMAP)
 909 AC_SUBST(LIBIMAPDEPS)
 910 AC_SUBST(LIBPOP)
 911 AC_SUBST(LIBPOPDEPS)
 912 AC_SUBST(LIBNNTP)
 913 AC_SUBST(LIBNNTPDEPS)
 914
 915 dnl -- iconv/gettext --
 916
 917 AC_ARG_ENABLE(iconv, AC_HELP_STRING([--disable-iconv], [Disable iconv support]),
 918         [if test x$enableval = xno ; then
 919                 am_cv_func_iconv=no
 920         fi
 921 ])
 922
 923 MUTT_AM_GNU_GETTEXT
 924
 925 if test "$am_cv_func_iconv" != "yes"
 926 then
 927   AC_MSG_WARN([Configuring without iconv support. See INSTALL for details])
 928 else
 929
 930 AC_CHECK_HEADERS(iconv.h,
 931         [AC_MSG_CHECKING(whether iconv.h defines iconv_t)
 932          AC_EGREP_HEADER([typedef.*iconv_t],iconv.h,
 933                 [AC_MSG_RESULT(yes)
 934                  AC_DEFINE(HAVE_ICONV_T_DEF, 1,
 935                         [Define if <iconv.h> defines iconv_t.])],
 936                  AC_MSG_RESULT(no))])
 937
 938 dnl (1) Some implementations of iconv won't convert from UTF-8 to UTF-8.
 939 dnl (2) In glibc-2.1.2 and earlier there is a bug that messes up ob and
 940 dnl     obl when args 2 and 3 are 0 (fixed in glibc-2.1.3).
 941 AC_CACHE_CHECK([whether this iconv is good enough], mutt_cv_iconv_good,
 942         mutt_save_LIBS="$LIBS"
 943         LIBS="$LIBS $LIBICONV"
 944         AC_TRY_RUN([
 945 #include <iconv.h>
 946 int main()
 947 {
 948   iconv_t cd;
 949 changequote(, )dnl
 950   char buf[4];
 951 changequote([, ])dnl
 952   char *ob;
 953   size_t obl;
 954   ob = buf, obl = sizeof(buf);
 955   return ((cd = iconv_open("UTF-8", "UTF-8")) != (iconv_t)(-1) &&
 956           (iconv(cd, 0, 0, &ob, &obl) ||
 957            !(ob == buf && obl == sizeof(buf)) ||
 958            iconv_close(cd)));
 959 }
 960                 ],
 961                 mutt_cv_iconv_good=yes,
 962                 mutt_cv_iconv_good=no,
 963                 mutt_cv_iconv_good=yes)
 964         LIBS="$mutt_save_LIBS")
 965 if test "$mutt_cv_iconv_good" = no; then
 966   AC_MSG_ERROR(Try using libiconv instead)
 967 fi
 968
 969 dnl This is to detect implementations such as the one in glibc-2.1,
 970 dnl which always convert exactly but return the number of characters
 971 dnl converted instead of the number converted inexactly.
 972 AC_CACHE_CHECK([whether iconv is non-transcribing], mutt_cv_iconv_nontrans,
 973         mutt_save_LIBS="$LIBS"
 974         LIBS="$LIBS $LIBICONV"
 975         AC_TRY_RUN([
 976 #include <iconv.h>
 977 #include <string.h>
 978 int main()
 979 {
 980   iconv_t cd;
 981   const char *ib;
 982   char *ob;
 983   size_t ibl, obl;
 984   const char *s = "\304\211";
 985 changequote(, )dnl
 986   char t[3];
 987 changequote([, ])dnl
 988   ib = s, ibl = 2, ob = t, obl = 3;
 989   return ((cd = iconv_open("UTF-8", "UTF-8")) == (iconv_t)(-1) ||
 990           iconv(cd, &ib, &ibl, &ob, &obl));
 991 }
 992                 ],
 993                 mutt_cv_iconv_nontrans=no,
 994                 mutt_cv_iconv_nontrans=yes,
 995                 mutt_cv_iconv_nontrans=no)
 996         LIBS="$mutt_save_LIBS")
 997 if test "$mutt_cv_iconv_nontrans" = yes; then
 998   AC_DEFINE(ICONV_NONTRANS, 1)
 999 else
1000   AC_DEFINE(ICONV_NONTRANS, 0)
1001 fi
1002
1003 CPPFLAGS="$CPPFLAGS -I\$(top_srcdir)/intl"
1004
1005 if test "$BUILD_INCLUDED_LIBINTL" = "yes"; then
1006   AC_DEFINE(HAVE_BIND_TEXTDOMAIN_CODESET,1,
1007           [ Define if your gettext has bind_textdomain_codeset. ])
1008 else
1009   AC_CHECK_FUNCS(bind_textdomain_codeset)
1010 fi
1011
1012 fi # libiconv
1013
1014 dnl -- locales --
1015
1016 AC_CHECK_HEADERS(wchar.h)
1017
1018 AC_CACHE_CHECK([for wchar_t], mutt_cv_wchar_t,
1019         AC_TRY_COMPILE([
1020 #include <stddef.h>
1021 #include <stdlib.h>
1022 #ifdef HAVE_WCHAR_H
1023 #include <wchar.h>
1024 #endif
1025                 ],
1026                 [ wchar_t wc; return 0; ],
1027                 mutt_cv_wchar_t=yes,
1028                 mutt_cv_wchar_t=no))
1029
1030 if test "$mutt_cv_wchar_t" = no; then
1031         AC_DEFINE(wchar_t,int,[ Define to 'int' if system headers don't define. ])
1032 fi
1033
1034 AC_CACHE_CHECK([for wint_t], mutt_cv_wint_t,
1035         AC_TRY_COMPILE([
1036 #include <stddef.h>
1037 #include <stdlib.h>
1038 #ifdef HAVE_WCHAR_H
1039 #include <wchar.h>
1040 #endif
1041                 ],
1042                 [ wint_t wc; return 0; ],
1043                 mutt_cv_wint_t=yes,
1044                 mutt_cv_wint_t=no))
1045
1046 if test "$mutt_cv_wint_t" = no; then
1047         AC_DEFINE(wint_t,int,[ Define to 'int' if system headers don't define. ])
1048 fi
1049
1050 AC_CHECK_HEADERS(wctype.h)
1051 AC_CHECK_FUNCS(iswalnum iswalpha  iswcntrl iswdigit)
1052 AC_CHECK_FUNCS(iswgraph iswlower iswprint iswpunct iswspace iswupper)
1053 AC_CHECK_FUNCS(iswxdigit towupper towlower)
1054
1055 AC_CACHE_CHECK([for mbstate_t], mutt_cv_mbstate_t,
1056         AC_TRY_COMPILE([
1057 #include <stddef.h>
1058 #include <stdlib.h>
1059 #ifdef HAVE_WCHAR_H
1060 #include <wchar.h>
1061 #endif
1062                 ],
1063                 [ mbstate_t s; return 0; ],
1064                 mutt_cv_mbstate_t=yes,
1065                 mutt_cv_mbstate_t=no))
1066
1067 if test "$mutt_cv_mbstate_t" = no; then
1068         AC_DEFINE(mbstate_t,int,[ Define to 'int' if system headers don't define. ])
1069 fi
1070
1071 wc_funcs=maybe
1072 AC_ARG_WITH(wc-funcs, AC_HELP_STRING([--without-wc-funcs], [Do not use the system's wchar_t functions]),
1073         wc_funcs=$withval)
1074
1075 if test "$wc_funcs" != yes -a "$wc_funcs" != no; then
1076         AC_CACHE_CHECK([for wchar_t functions], mutt_cv_wc_funcs,
1077                 mutt_cv_wc_funcs=no
1078                 AC_TRY_LINK([
1079 #define _XOPEN_SOURCE 1
1080 #include <stddef.h>
1081 #include <stdlib.h>
1082 #ifdef HAVE_WCTYPE_H
1083 #include <wctype.h>
1084 #endif
1085 #ifdef HAVE_WCHAR_H
1086 #include <wchar.h>
1087 #endif],
1088                         [mbrtowc(0, 0, 0, 0); wctomb(0, 0); wcwidth(0);
1089         iswprint(0); iswspace(0); towlower(0); towupper(0); iswalnum(0)],
1090                         mutt_cv_wc_funcs=yes))
1091         wc_funcs=$mutt_cv_wc_funcs
1092 fi
1093
1094 if test $wc_funcs = yes; then
1095         AC_DEFINE(HAVE_WC_FUNCS,1,[ Define if you are using the system's wchar_t functions. ])
1096 fi
1097
1098 AC_CACHE_CHECK([for nl_langinfo and CODESET], mutt_cv_langinfo_codeset,
1099   [AC_TRY_LINK([#include <langinfo.h>],
1100     [char* cs = nl_langinfo(CODESET);],
1101     mutt_cv_langinfo_codeset=yes,
1102     mutt_cv_langinfo_codeset=no)])
1103 if test $mutt_cv_langinfo_codeset = yes; then
1104   AC_DEFINE(HAVE_LANGINFO_CODESET,1,[ Define if you have <langinfo.h> and nl_langinfo(CODESET). ])
1105 fi
1106
1107 AC_CACHE_CHECK([for nl_langinfo and YESEXPR], mutt_cv_langinfo_yesexpr,
1108   [AC_TRY_LINK([#include <langinfo.h>],
1109     [char* cs = nl_langinfo(YESEXPR);],
1110     mutt_cv_langinfo_yesexpr=yes,
1111     mutt_cv_langinfo_yesexpr=no)])
1112 if test $mutt_cv_langinfo_yesexpr = yes; then
1113   AC_DEFINE(HAVE_LANGINFO_YESEXPR,1,[ Define if you have <langinfo.h> and nl_langinfo(YESEXPR). ])
1114 fi
1115
1116 dnl -- libesmtp --
1117 MUTT_AM_LIBESMTP
1118 if test x$use_libesmtp = xyes; then
1119     CFLAGS="$CFLAGS $mutt_libesmtp_cflags"
1120     MUTTLIBS="$MUTTLIBS $mutt_libesmtp_libs"
1121     MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_libesmtp.o"
1122
1123     AC_DEFINE(USE_LIBESMTP,
1124               1,
1125               [Define to enable the use of libesmtp])
1126 fi
1127 dnl -- end libesmtp --
1128
1129 dnl -- sgml tools --
1130
1131 dnl Documentation tools
1132 have_openjade="no"
1133 AC_PATH_PROG([OSPCAT], [ospcat], [none])
1134 if test "$OSPCAT" != "none"
1135 then
1136   AC_MSG_CHECKING([for openjade docbook stylesheets])
1137   dslosfile=`ospcat --public-id="-//Norman Walsh//DOCUMENT DocBook Print Stylesheet//EN"`
1138   DSLROOT=`echo $dslosfile | sed -n -e "s/.*SOIBASE='\(@<:@^'@:>@*\)\/catalog'.*/\1/p"`
1139   # ospcat may spit out an absolute path without an SOIBASE
1140   if test -z "$DSLROOT"
1141   then
1142     DSLROOT=`echo $dslosfile | sed -e 's|<OSFILE>\(.*\)/print/docbook.dsl|\1|'`
1143   fi
1144   if test -f $DSLROOT/print/docbook.dsl
1145   then
1146     AC_MSG_RESULT([in $DSLROOT])
1147     have_openjade="yes"
1148   else
1149     AC_MSG_RESULT([not found: PDF documentation will not be built.])
1150   fi
1151 fi
1152 AC_SUBST(DSLROOT)
1153
1154 AC_MSG_CHECKING([for lynx])
1155 AC_PATH_PROG([HTML2TXT_CMD], [lynx], [none])
1156 if test x"$HTML2TXT_CMD" = x"none"
1157 then
1158   AC_MSG_CHECKING([for w3m])
1159   AC_PATH_PROG([HTML2TXT_CMD], [w3m], [none])
1160 fi
1161 if test x"$HTML2TXT_CMD" = x"none"
1162 then
1163   AC_MSG_CHECKING([for elinks])
1164   AC_PATH_PROG([HTML2TXT_CMD], [elinks], [none])
1165 fi
1166 case "$HTML2TXT_CMD" in
1167   *elinks*)
1168     HTML2TXT_CMD="$HTML2TXT_CMD -dump -no-numbering -no-references \$^ > \$@"
1169     ;;
1170   *lynx*)
1171     HTML2TXT_CMD="$HTML2TXT_CMD -dump -nolist -with_backspaces \$^ > \$@"
1172     ;;
1173   *w3m*)
1174     HTML2TXT_CMD="$HTML2TXT_CMD -dump \$^ > \$@"
1175     ;;
1176   *)
1177     HTML2TXT_CMD="true"
1178     ;;
1179 esac
1180 AC_SUBST(HTML2TXT_CMD)
1181
1182 AC_MSG_CHECKING([for tidy])
1183 AC_PATH_PROG([HTMLCLEAN_CMD], [tidy], [none])
1184
1185 if test x"$HTMLCLEAN_CMD" != x"none"
1186 then
1187   HTMLCLEAN_CMD="$HTMLCLEAN_CMD -q -i -m -asxml -utf8 "
1188 else
1189   HTMLCLEAN_CMD="echo "
1190 fi
1191 AC_SUBST(HTMLCLEAN_CMD)
1192
1193 AC_OUTPUT(Makefile intl/Makefile m4/Makefile
1194         po/Makefile.in doc/Makefile contrib/Makefile
1195         muttbug.sh
1196         lib/Makefile
1197         imap/Makefile
1198         pop/Makefile
1199         nntp/Makefile
1200         Muttngrc.head
1201         doc/instdoc.sh)