configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl !!! WHEN ADDING NEW CONFIGURE TESTS, PLEASE ADD CODE TO MAIN.C !!!
   4 dnl !!! TO DUMP THEIR RESULTS WHEN MUTT -V IS CALLED            !!!
   5
   6 AC_PREREQ([2.50])
   7 AC_INIT([mutt.h])
   8 AM_CONFIG_HEADER(config.h)
   9
  10 mutt_cv_version=`cat $srcdir/VERSION`
  11
  12 AM_INIT_AUTOMAKE(muttng, $mutt_cv_version)
  13 dnl AC_GNU_SOURCE
  14
  15 ifdef([AC_LIBOBJ], , [define([AC_LIBOBJ], [LIB[]OBJS="$LIBOBJS $1.o"])])
  16
  17 ALL_LINGUAS="de ru it es uk fr pl nl cs id sk ko el zh_TW zh_CN pt_BR eo gl sv da lt tr ja hu et ca bg"
  18
  19 AC_CANONICAL_HOST
  20
  21 AC_MSG_CHECKING([for prefix])
  22 if test x$prefix = xNONE; then
  23         mutt_cv_prefix=$ac_default_prefix
  24 else
  25         mutt_cv_prefix=$prefix
  26 fi
  27 AC_MSG_RESULT($mutt_cv_prefix)
  28
  29 AC_PROG_CC
  30 AC_ISC_POSIX
  31 AM_C_PROTOTYPES
  32 if test "x$U" != "x"; then
  33   AC_MSG_ERROR(Compiler not ANSI compliant)
  34 fi
  35 AC_PROG_CPP
  36 AC_PROG_MAKE_SET
  37 AC_PROG_INSTALL
  38 AC_PROG_RANLIB
  39 AC_CHECK_TOOL(AR, ar, ar)
  40
  41 AC_C_INLINE
  42 AC_C_CONST
  43
  44 AC_SYS_LARGEFILE
  45
  46 AC_PATH_PROG(DBX, dbx, no)
  47 AC_PATH_PROG(GDB, gdb, no)
  48 AC_PATH_PROG(SDB, sdb, no)
  49
  50 if test $GDB != no ; then
  51         DEBUGGER=$GDB
  52 elif test $DBX != no ; then
  53         DEBUGGER=$DBX
  54 elif test $SDB != no ; then
  55         DEBUGGER=$SDB
  56 else
  57         DEBUGGER=no
  58 fi
  59
  60 AC_SUBST([DEBUGGER])
  61
  62 AH_TEMPLATE([sig_atomic_t],
  63             [/* Define to `int' if <signal.h> doesn't define.])
  64 AH_TEMPLATE([HAVE_START_COLOR],
  65             [Define if you have start_color, as a function or macro.])
  66 AH_TEMPLATE([HAVE_TYPEAHEAD],
  67             [Define if you have typeahead, as a function or macro.])
  68 AH_TEMPLATE([HAVE_BKGDSET],
  69             [Define if you have bkgdset, as a function or macro.])
  70 AH_TEMPLATE([HAVE_CURS_SET],
  71             [Define if you have curs_set, as a function or macro.])
  72 AH_TEMPLATE([HAVE_META],
  73             [Define if you have meta, as a function or macro.])
  74 AH_TEMPLATE([HAVE_USE_DEFAULT_COLORS],
  75             [Define if you have use_default_colors, as a function or macro.])
  76 AH_TEMPLATE([HAVE_RESIZETERM],
  77             [Define if you have resizeterm, as a function or macro.])
  78 AH_TEMPLATE([SIG_ATOMIC_VOLATILE_T],
  79             [Some systems declare sig_atomic_t as volatile, some others -- no.
  80              This define will have value `sig_atomic_t' or
  81              `volatile sig_atomic_t' accordingly.])
  82 AH_TEMPLATE([ICONV_NONTRANS],
  83             [Define as 1 if iconv() only converts exactly and we should treat
  84              all return values other than (size_t)(-1) as equivalent.])
  85
  86 MUTT_C99_INTTYPES
  87
  88 ac_aux_path_sendmail=/usr/sbin:/usr/lib
  89 AC_PATH_PROG(SENDMAIL, sendmail, /usr/sbin/sendmail, $PATH:$ac_aux_path_sendmail)
  90 AC_DEFINE_UNQUOTED(SENDMAIL,"$ac_cv_path_SENDMAIL",[ Where to find sendmail on your system. ])
  91
  92 OPS='$(srcdir)/OPS'
  93 if test -f $srcdir/EXPORTABLE ; then
  94         SUBVERSION="us"
  95 else
  96         SUBVERSION="i"
  97
  98         AC_ARG_ENABLE(gpgme, [  --enable-gpgme           Enable GPGME support],
  99         [       if test x$enableval = xyes; then
 100                         have_gpgme=yes
 101                 fi
 102         ])
 103         AC_ARG_WITH(gpgme-prefix, [  --with-gpgme-prefix=PFX    prefix where GPGME is installed (optional)],
 104         gpgme_config_prefix="$withval", gpgme_config_prefix="")
 105
 106         if test x$have_gpgme = xyes; then
 107                 if test x$gpgme_config_prefix != x; then
 108                         GPGME_CONFIG="$gpgme_config_prefix/bin/gpgme-config"
 109                 else
 110                         AC_PATH_PROG(GPGME_CONFIG, gpgme-config, no)
 111                 fi
 112                 if test "x$GPGME_CONFIG" = "xno"; then
 113                         AC_MSG_ERROR([GPGME not found])
 114                 else
 115                         LIBGPGME_CFLAGS=`$GPGME_CONFIG --cflags`
 116                         LIBGPGME_LIBS=`$GPGME_CONFIG --libs`
 117                         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS crypt-gpgme.o crypt-mod-pgp-gpgme.o crypt-mod-smime-gpgme.o"
 118                         AC_DEFINE(CRYPT_BACKEND_GPGME, 1,
 119                                   [Defined, if GPGME support is enabled])
 120                 fi
 121         fi
 122         AC_SUBST(LIBGPGME_CFLAGS)
 123         AC_SUBST(LIBGPGME_LIBS)
 124
 125         AC_ARG_ENABLE(pgp, [  --disable-pgp              Disable PGP support],
 126         [       if test x$enableval = xno ; then
 127                         have_pgp=no
 128                 fi
 129         ])
 130
 131         if test x$have_pgp != xno ; then
 132                 AC_DEFINE(CRYPT_BACKEND_CLASSIC_PGP,1,
 133                     [ Define if you want classic PGP support. ])
 134                 PGPAUX_TARGET="pgpring pgpewrap"
 135                 MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS pgp.o pgpinvoke.o pgpkey.o pgplib.o gnupgparse.o pgpmicalg.o pgppacket.o crypt-mod-pgp-classic.o"
 136         fi
 137
 138         AC_ARG_ENABLE(smime, [  --disable-smime            Disable SMIME support],
 139         [       if test x$enableval = xno ; then
 140                         have_smime=no
 141                 fi
 142         ])
 143
 144         if test x$have_smime != xno ; then
 145                 AC_DEFINE(CRYPT_BACKEND_CLASSIC_SMIME,1,
 146                   [ Define if you want clasic S/MIME support. ])
 147                 MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS smime.o crypt-mod-smime-classic.o"
 148                 SMIMEAUX_TARGET="smime_keys"
 149         fi
 150
 151         AC_ARG_WITH(mixmaster, [  --with-mixmaster[=PATH]    Include Mixmaster support],
 152                 [if test -x "$withval" ; then
 153                         MIXMASTER="$withval"
 154                  else
 155                         MIXMASTER="mixmaster"
 156                  fi
 157                  OPS="$OPS \$(srcdir)/OPS.MIX"
 158                  MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS remailer.o"
 159                  AC_DEFINE_UNQUOTED(MIXMASTER,"$MIXMASTER",
 160                          [ Where to find mixmaster on your system. ])
 161                 ])
 162
 163 fi
 164 # We now require all OPS
 165 OPS="$OPS \$(srcdir)/OPS.PGP \$(srcdir)/OPS.SMIME \$(srcdir)/OPS.CRYPT "
 166 AC_SUBST([OPS])
 167
 168
 169 AC_SUBST(PGPAUX_TARGET)
 170 AC_SUBST(SMIMEAUX_TARGET)
 171
 172 AC_DEFINE_UNQUOTED(SUBVERSION,"$SUBVERSION",[ Is this the international version? ])
 173 AC_SUBST([SUBVERSION])
 174
 175 AC_PATH_PROG(ISPELL, ispell, no)
 176 if test $ISPELL != no; then
 177         AC_DEFINE_UNQUOTED(ISPELL,"$ISPELL",[ Where to find ispell on your system. ])
 178 fi
 179
 180 AC_ARG_WITH(slang, [  --with-slang[=DIR]         Use S-Lang instead of ncurses],
 181         [AC_CACHE_CHECK([if this is a BSD system], mutt_cv_bsdish,
 182                 [AC_TRY_RUN([#include <sys/param.h>
 183
 184 main ()
 185 {
 186 #ifdef BSD
 187         exit (0);
 188 #else
 189         exit (1);
 190 #endif
 191 }],
 192                         mutt_cv_bsdish=yes,
 193                         mutt_cv_bsdish=no,
 194                         mutt_cv_bsdish=no)])
 195
 196         AC_MSG_CHECKING(for S-Lang)
 197         if test $withval = yes; then
 198                 if test -d $srcdir/../slang; then
 199                         mutt_cv_slang=$srcdir/../slang/src
 200                         CPPFLAGS="$CPPFLAGS -I${mutt_cv_slang}"
 201                         LDFLAGS="$LDFLAGS -L${mutt_cv_slang}/objs"
 202                 else
 203                         if test -d $mutt_cv_prefix/include/slang; then
 204                                 CPPFLAGS="$CPPFLAGS -I$mutt_cv_prefix/include/slang"
 205                         elif test -d /usr/include/slang; then
 206                                 CPPFLAGS="$CPPFLAGS -I/usr/include/slang"
 207                         fi
 208                         mutt_cv_slang=yes
 209                 fi
 210         else
 211                 dnl ---Check to see if $withval is a source directory
 212                 if test -f $withval/src/slang.h; then
 213                         mutt_cv_slang=$withval/src
 214                         CPPFLAGS="$CPPFLAGS -I${mutt_cv_slang}"
 215                         LDFLAGS="$LDFLAGS -L${mutt_cv_slang}/objs"
 216                 else
 217                         dnl ---Must be installed somewhere
 218                         mutt_cv_slang=$withval
 219                         if test -d $withval/include/slang; then
 220                                 CPPFLAGS="$CPPFLAGS -I${withval}/include/slang"
 221                         elif test -d $withval/include; then
 222                                 CPPFLAGS="$CPPFLAGS -I${withval}/include"
 223                         fi
 224                         LDFLAGS="$LDFLAGS -L${withval}/lib"
 225                 fi
 226         fi
 227         AC_MSG_RESULT($mutt_cv_slang)
 228         if test $mutt_cv_bsdish = yes; then
 229                 AC_CHECK_LIB(termlib, main)
 230         fi
 231         AC_DEFINE(USE_SLANG_CURSES,1,
 232                 [ Define if you compile with SLang instead of curses/ncurses. ])
 233         AC_DEFINE(HAVE_COLOR,1,[ Define if your curses library supports color. ])
 234         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS resize.o"
 235
 236         dnl --- now that we've found it, check the link
 237
 238         AC_CHECK_LIB(slang, SLtt_get_terminfo,
 239                 [MUTTLIBS="$MUTTLIBS -lslang -lm"],
 240                 [AC_MSG_ERROR(unable to compile.  check config.log)], -lm)
 241
 242         ],
 243
 244         [mutt_cv_curses=/usr
 245         AC_ARG_WITH(curses, [  --with-curses=DIR          Where ncurses is installed ],
 246                 [if test $withval != yes; then
 247                         mutt_cv_curses=$withval
 248                 fi
 249                 if test x$mutt_cv_curses != x/usr; then
 250                         LDFLAGS="-L${mutt_cv_curses}/lib $LDFLAGS"
 251                         CPPFLAGS="$CPPFLAGS -I${mutt_cv_curses}/include"
 252                 fi])
 253
 254         AC_CHECK_FUNC(initscr,,[
 255         cf_ncurses="ncurses"
 256         for lib in ncurses ncursesw
 257         do
 258                 AC_CHECK_LIB($lib, waddnwstr, [cf_ncurses="$lib"; break])
 259         done
 260         AC_CHECK_LIB($cf_ncurses, initscr,
 261                 [MUTTLIBS="$MUTTLIBS -l$cf_ncurses"
 262                 if test x$mutt_cv_curses = x/usr -a -d /usr/include/ncurses; then
 263                         CPPFLAGS="$CPPFLAGS -I/usr/include/ncurses"
 264                 fi
 265
 266                 if test "$cf_ncurses" = ncursesw; then
 267                         AC_CHECK_HEADERS(ncursesw/ncurses.h,[cf_cv_ncurses_header="ncursesw/ncurses.h"])
 268                 else
 269                         AC_CHECK_HEADERS(ncurses.h,[cf_cv_ncurses_header="ncurses.h"])
 270                 fi],
 271
 272                 [CF_CURSES_LIBS])
 273                 ])
 274
 275         old_LIBS="$LIBS"
 276         LIBS="$LIBS $MUTTLIBS"
 277         CF_CHECK_FUNCDECLS([#include <${cf_cv_ncurses_header-curses.h}>],
 278                            [start_color typeahead bkgdset curs_set meta use_default_colors resizeterm])
 279         if test "$ac_cv_func_decl_start_color" = yes; then
 280                 AC_DEFINE(HAVE_COLOR,1,[ Define if your curses library supports color. ])
 281         fi
 282         if test "$ac_cv_func_decl_resizeterm" = yes; then
 283                 MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS resize.o"
 284         fi
 285         LIBS="$old_LIBS"
 286         ])
 287
 288 AC_HEADER_STDC
 289
 290 AC_CHECK_HEADERS(stdarg.h sys/ioctl.h ioctl.h sysexits.h)
 291 AC_CHECK_HEADERS(sys/time.h sys/resource.h)
 292 AC_CHECK_HEADERS(unix.h)
 293
 294 AC_CHECK_FUNCS(setrlimit getsid isctype)
 295
 296 AC_TYPE_SIGNAL
 297
 298 AC_MSG_CHECKING(for sig_atomic_t in signal.h)
 299 AC_EGREP_HEADER(sig_atomic_t,signal.h,
 300   [
 301     ac_cv_type_sig_atomic_t=yes;
 302     AC_EGREP_HEADER(volatile.*sig_atomic_t,
 303                     signal.h,
 304                     [
 305                         is_sig_atomic_t_volatile=yes;
 306                         AC_MSG_RESULT([yes, volatile])
 307                     ],
 308                     [
 309                         is_sig_atomic_t_volatile=no;
 310                         AC_MSG_RESULT([yes, non volatile])
 311                     ])
 312   ],
 313   [
 314     AC_MSG_RESULT(no)
 315     AC_CHECK_TYPE(sig_atomic_t, int)
 316     is_sig_atomic_t_volatile=no
 317   ])
 318 if test $is_sig_atomic_t_volatile = 'yes'
 319 then
 320     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, sig_atomic_t)
 321 else
 322     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, [volatile sig_atomic_t])
 323 fi
 324
 325 AC_DECL_SYS_SIGLIST
 326
 327 AC_TYPE_PID_T
 328 dnl AC_CHECK_TYPE(ssize_t, int)
 329
 330 AC_CHECK_FUNCS(fgetpos memmove setegid srand48 strerror)
 331
 332 AC_REPLACE_FUNCS(strcasecmp strdup)
 333
 334 AC_CHECK_FUNC(getopt)
 335 if test $ac_cv_func_getopt = yes; then
 336         AC_CHECK_HEADERS(getopt.h)
 337 fi
 338
 339 mutt_cv_snprintf=no
 340 SNPRINTFOBJS=""
 341 AC_CHECK_FUNCS(snprintf, , [mutt_cv_snprintf=yes])
 342 AC_CHECK_FUNCS(vsnprintf, , [mutt_cv_snprintf=yes])
 343 if test $mutt_cv_snprintf = yes; then
 344         AC_LIBOBJ(snprintf)
 345 fi
 346
 347 dnl SCO uses chsize() instead of ftruncate()
 348 AC_CHECK_FUNCS(ftruncate, , [AC_CHECK_LIB(x, chsize)])
 349
 350 dnl SCO has strftime() in libintl
 351 AC_CHECK_FUNCS(strftime, , [AC_CHECK_LIB(intl, strftime)])
 352
 353 dnl AIX may not have fchdir()
 354 AC_CHECK_FUNCS(fchdir, , [mutt_cv_fchdir=no])
 355
 356 AC_ARG_WITH(regex, [  --with-regex               Use the GNU regex library ],
 357         [mutt_cv_regex=yes],
 358         [AC_CHECK_FUNCS(regcomp, mutt_cv_regex=no, mutt_cv_regex=yes)])
 359
 360 if test $mutt_cv_regex = no ; then
 361 AC_CACHE_CHECK([whether your system's regexp library is completely broken],
 362         [mutt_cv_regex_broken],
 363         AC_TRY_RUN([
 364 #include <unistd.h>
 365 #include <regex.h>
 366 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
 367         mutt_cv_regex_broken=no, mutt_cv_regex_broken=yes, mutt_cv_regex_broken=yes))
 368         if test $mutt_cv_regex_broken = yes ; then
 369                 echo "Using the included GNU regex instead." >&AC_FD_MSG
 370                 mutt_cv_regex=yes
 371         fi
 372 fi
 373
 374 if test $mutt_cv_regex = yes; then
 375         AC_DEFINE(USE_GNU_REGEX,1,[ Define if you want to use the included regex.c. ])
 376         AC_LIBOBJ(regex)
 377 fi
 378
 379
 380 AC_ARG_WITH(homespool, [  --with-homespool[=FILE]    File in user's directory where new mail is spooled], with_homespool=${withval})
 381 if test x$with_homespool != x; then
 382         if test $with_homespool = yes; then
 383                 with_homespool=mailbox
 384         fi
 385         AC_DEFINE_UNQUOTED(MAILPATH,"$with_homespool",[ Where new mail is spooled. ])
 386         AC_DEFINE(HOMESPOOL,1,
 387           [Is mail spooled to the user's home directory?  If defined,
 388            MAILPATH should be set to the filename of the spool mailbox
 389            relative the the home directory.
 390            use: configure --with-homespool=FILE])
 391         AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 392         mutt_cv_setgid=no
 393 else
 394         AC_ARG_WITH(mailpath, [  --with-mailpath=DIR        Directory where spool mailboxes are located],
 395                 [mutt_cv_mailpath=$withval],
 396                 [ AC_CACHE_CHECK(where new mail is stored, mutt_cv_mailpath,
 397                         [mutt_cv_mailpath=no
 398                         if test -d /var/mail; then
 399                                 mutt_cv_mailpath=/var/mail
 400                         elif test -d /var/spool/mail; then
 401                                 mutt_cv_mailpath=/var/spool/mail
 402                         elif test -d /usr/spool/mail; then
 403                                 mutt_cv_mailpath=/usr/spool/mail
 404                         elif test -d /usr/mail; then
 405                                 mutt_cv_mailpath=/usr/mail
 406                         fi])
 407                 ])
 408         if test "$mutt_cv_mailpath" = no; then
 409                 AC_MSG_ERROR("Could not determine where new mail is stored.")
 410         fi
 411         AC_DEFINE_UNQUOTED(MAILPATH,"$mutt_cv_mailpath",[ Where new mail is spooled. ])
 412
 413         AC_CACHE_CHECK(if $mutt_cv_mailpath is world writable, mutt_cv_worldwrite, [AC_TRY_RUN([#include <sys/types.h>
 414 #include <sys/stat.h>
 415
 416 int main (int argc, char **argv)
 417 {
 418         struct stat s;
 419
 420         stat ("$mutt_cv_mailpath", &s);
 421         if (s.st_mode & S_IWOTH) exit (0);
 422         exit (1);
 423 }], mutt_cv_worldwrite=yes, mutt_cv_worldwrite=no, mutt_cv_worldwrite=no)])
 424
 425         mutt_cv_setgid=no
 426         if test $mutt_cv_worldwrite = yes; then
 427                 AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 428         else
 429
 430                 AC_CACHE_CHECK(if $mutt_cv_mailpath is group writable, mutt_cv_groupwrite, [AC_TRY_RUN([#include <sys/types.h>
 431 #include <sys/stat.h>
 432
 433 int main (int argc, char **argv)
 434 {
 435         struct stat s;
 436
 437         stat ("$mutt_cv_mailpath", &s);
 438         if (s.st_mode & S_IWGRP) exit (0);
 439         exit (1);
 440 }], mutt_cv_groupwrite=yes, mutt_cv_groupwrite=no, mutt_cv_groupwrite=no)])
 441
 442                 if test $mutt_cv_groupwrite = yes; then
 443                         AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 444                         AC_DEFINE(USE_SETGID,1,[ Define if mutt should run setgid "mail". ])
 445                         mutt_cv_setgid=yes
 446                 fi
 447         fi
 448 fi
 449
 450 AC_ARG_ENABLE(external_dotlock, [  --enable-external-dotlock  Force use of an external dotlock program],
 451         [mutt_cv_external_dotlock="$enableval"])
 452
 453 if test "x$mutt_cv_setgid" = "xyes" || test "x$mutt_cv_fchdir" = "xno" \
 454         || test "x$mutt_cv_external_dotlock" = "xyes"
 455 then
 456         AC_DEFINE(DL_STANDALONE,1,[ Define if you want to use an external dotlocking program. ])
 457         DOTLOCK_TARGET="muttng_dotlock"
 458 else
 459         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS dotlock.o"
 460 fi
 461
 462 AC_SUBST(DOTLOCK_TARGET)
 463
 464
 465 AC_MSG_CHECKING(where to put the documentation)
 466 AC_ARG_WITH(docdir, [  --with-docdir=PATH         Specify where to put the documentation],
 467         [mutt_cv_docdir=$withval],
 468         [mutt_cv_docdir="$mutt_cv_prefix/doc/muttng"])
 469 AC_MSG_RESULT($mutt_cv_docdir)
 470
 471 docdir=$mutt_cv_docdir
 472 AC_SUBST(docdir)
 473
 474 if test x$mutt_cv_setgid = xyes; then
 475         DOTLOCK_GROUP='mail'
 476         DOTLOCK_PERMISSION=2755
 477 else
 478         DOTLOCK_GROUP=''
 479         DOTLOCK_PERMISSION=755
 480 fi
 481 AC_SUBST(DOTLOCK_GROUP)
 482 AC_SUBST(DOTLOCK_PERMISSION)
 483
 484 AC_ARG_WITH(domain, [  --with-domain=DOMAIN       Specify your DNS domain name],
 485         [if test $withval != yes; then
 486                 AC_DEFINE_UNQUOTED(DOMAIN,"$withval",[ Define your domain name. ])
 487         fi])
 488
 489 need_socket="no"
 490
 491 dnl -- socket dependencies --
 492
 493 AC_ARG_ENABLE(pop,  [  --enable-pop               Enable POP3 support],
 494 [       if test x$enableval = xyes ; then
 495                 AC_DEFINE(USE_POP,1,[ Define if you want support for the POP3 protocol. ])
 496                 MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS pop.o pop_lib.o pop_auth.o"
 497                 need_socket="yes"
 498                 need_pop="yes"
 499                 need_md5="yes"
 500         fi
 501 ])
 502
 503 AC_ARG_ENABLE(imap, [  --enable-imap              Enable IMAP support],
 504 [       if test x$enableval = xyes ; then
 505                 AC_DEFINE(USE_IMAP,1,[ Define if you want support for the IMAP protocol. ])
 506                 LIBIMAP="-Limap -limap"
 507                 LIBIMAPDEPS="\$(top_srcdir)/imap/imap.h imap/libimap.a"
 508                 need_imap="yes"
 509                 need_socket="yes"
 510                 need_md5="yes"
 511         fi
 512 ])
 513 AM_CONDITIONAL(BUILD_IMAP, test x$need_imap = xyes)
 514
 515 AC_ARG_ENABLE(nntp, [  --enable-nntp              Enable NNTP support],
 516 [       if test x$enableval = xyes ; then
 517                 AC_DEFINE(USE_NNTP)
 518                 MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS nntp.o newsrc.o"
 519                 need_socket="yes"
 520         fi
 521 ])
 522
 523 dnl -- end socket dependencies --
 524
 525 if test "$need_socket" = "yes"
 526 then
 527         AC_MSG_CHECKING([for socklen_t])
 528         AC_EGREP_HEADER(socklen_t, sys/socket.h, AC_MSG_RESULT([yes]),
 529                 AC_MSG_RESULT([no])
 530                 AC_DEFINE(socklen_t,int,
 531                         [ Define to 'int' if <sys/socket.h> doesn't have it. ]))
 532         AC_CHECK_FUNC(gethostent, , AC_CHECK_LIB(nsl, gethostent))
 533         AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt))
 534         AC_CHECK_FUNCS(getaddrinfo)
 535         AC_DEFINE(USE_SOCKET,1,
 536                 [ Include code for socket support. Set automatically if you enable POP3 or IMAP ])
 537         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS account.o mutt_socket.o mutt_tunnel.o"
 538 fi
 539
 540 dnl -- imap dependencies --
 541
 542 AC_ARG_WITH(gss, [  --with-gss[=PFX]           Compile in GSSAPI authentication for IMAP],
 543     gss_prefix="$withval", gss_prefix="no")
 544 if test "$gss_prefix" != "no"
 545 then
 546   if test "$need_imap" = "yes"
 547   then
 548     MUTT_AM_PATH_GSSAPI(gss_prefix)
 549     AC_MSG_CHECKING(GSSAPI implementation)
 550     AC_MSG_RESULT($GSSAPI_IMPL)
 551     if test "$GSSAPI_IMPL" = "none"
 552     then
 553       AC_CACHE_SAVE
 554       AC_MSG_RESULT([GSSAPI libraries not found])
 555     fi
 556     if test "$GSSAPI_IMPL" = "Heimdal"
 557     then
 558       AC_DEFINE(HAVE_HEIMDAL,1,[ Define if your GSSAPI implementation is Heimdal ])
 559     fi
 560     CPPFLAGS="$CPPFLAGS $GSSAPI_CFLAGS"
 561     MUTTLIBS="$MUTTLIBS $GSSAPI_LIBS"
 562     AC_DEFINE(USE_GSS,1,[ Define if you have GSSAPI libraries available ])
 563     need_gss="yes"
 564   else
 565     AC_MSG_WARN([GSS was requested but IMAP is not enabled])
 566   fi
 567 fi
 568 AM_CONDITIONAL(USE_GSS, test x$need_gss = xyes)
 569
 570 dnl -- end imap dependencies --
 571
 572 AC_ARG_WITH(ssl, [  --with-ssl[=PFX]           Compile in SSL support for POP/IMAP],
 573 [       if test "$with_ssl" != "no"
 574         then
 575           if test "$need_socket" != "yes"; then
 576            AC_MSG_ERROR([SSL support is only useful with POP or IMAP support])
 577           fi
 578
 579           if test "$with_ssl" != "yes"
 580           then
 581            LDFLAGS="$LDFLAGS -L$withval/lib"
 582            CPPFLAGS="$CPPFLAGS -I$withval/include"
 583           fi
 584           saved_LIBS="$LIBS"
 585
 586           AC_CHECK_LIB(crypto, X509_new,, AC_MSG_ERROR([Unable to find SSL library]))
 587           AC_CHECK_LIB(ssl, SSL_new,, AC_MSG_ERROR([Unable to find SSL library]), -lcrypto)
 588
 589           AC_CHECK_FUNCS(RAND_status RAND_egd)
 590
 591           AC_DEFINE(USE_SSL,1,[ Define if you want support for SSL. ])
 592           LIBS="$saved_LIBS"
 593           MUTTLIBS="$MUTTLIBS -lssl -lcrypto"
 594           MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_ssl.o"
 595           need_ssl=yes
 596
 597         fi
 598 ])
 599 AM_CONDITIONAL(USE_SSL, test x$need_ssl = xyes)
 600
 601 AC_ARG_WITH(gnutls, [  --with-gnutls[=PFX]        Compile in GNU TLS support for POP/IMAP],
 602 [   if test "$need_ssl" = "yes"
 603     then
 604       AC_MSG_ERROR([In order to compile in GNU TLS support, you must first disable SSL support])
 605     fi
 606     if test "$with_gnutls" != "no"
 607     then
 608       if test "$need_socket" != "yes"; then
 609         AC_MSG_ERROR([GNU TLS support is only useful with POP or IMAP support])
 610       fi
 611       if test "$with_gnutls" != "yes"
 612       then
 613         LDFLAGS="$LDFLAGS -L$withval/lib"
 614         CPPFLAGS="$CPPFLAGS -I$withval/include"
 615       fi
 616 #saved_LIBS="$LIBS"
 617
 618       AC_CHECK_LIB([gnutls], [gnutls_init],, AC_MSG_ERROR(Unable to find GNU TLS library))
 619
 620       AC_DEFINE(USE_GNUTLS,1,[ Define if you want support for GNU TLS. ])
 621 #LIBS="$saved_LIBS"
 622 #MUTTLIBS="$MUTTLIBS -lgnutls"
 623       MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_ssl_gnutls.o"
 624       need_gnutls=yes
 625     fi
 626 ])
 627 AM_CONDITIONAL(USE_GNUTLS, test x$need_gnutls = xyes)
 628
 629 dnl SSL support via NSS
 630 AC_ARG_WITH(nss, [  --with-nss[=PFX]           Compile in SSL support for POP/IMAP via NSS],
 631 [       if test "$with_nss" != no
 632         then
 633           if test "$need_socket" != "yes"; then
 634            AC_MSG_ERROR([SSL support is only useful with POP or IMAP support])
 635           fi
 636
 637           if test "$with_nss" != "yes"
 638           then
 639            LDFLAGS="$LDFLAGS -L$withval/lib"
 640            CPPFLAGS="$CPPFLAGS -I$withval/include -I$withval/public/security"
 641           fi
 642
 643           AC_DEFINE(USE_NSS,1,[ Define if you want support for SSL via the NSS library. ])
 644           MUTTLIBS="$MUTTLIBS -lssl -lnss -lcertdb -lcerthi -lcryptohi"
 645           MUTTLIBS="$MUTTLIBS -lpk11wrap -lsoftoken -lsecutil -ldbm -lplds4 -lplc4 -lfreebl"
 646           MUTTLIBS="$MUTTLIBS -lnspr4"
 647
 648           MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_ssl_nss.o"
 649           need_ssl=yes
 650         fi
 651 ])
 652
 653 AC_ARG_WITH([gnutls], [  --with-gnutls[=PFX]        Enable SSL support using gnutls],
 654     [gnutls_prefix="$withval"], [gnutls_prefix="no"])
 655 if test "$gnutls_prefix" != "no"
 656 then
 657   if test "$need_socket" != "yes"
 658   then
 659     AC_MSG_ERROR([SSL support is only useful with POP or IMAP support])
 660   fi
 661   MUTT_AM_PATH_GNUTLS([$gnutls_prefix],
 662     [dnl GNUTLS found
 663     CPPFLAGS="$CPPFLAGS $LIBGNUTLS_CFLAGS"
 664     MUTTLIBS="$MUTTLIBS $LIBGNUTLS_LIBS"
 665     AC_DEFINE(USE_GNUTLS, 1, [Define if you want support for SSL via the gnutls library.])
 666
 667     MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_ssl_gnutls.o"
 668     need_ssl=yes],
 669     [dnl GNUTLS not found
 670       AC_MSG_ERROR([could not find libgnutls])
 671     ])
 672 fi
 673
 674 AC_ARG_WITH(sasl, [  --with-sasl[=PFX]          Use Cyrus SASL library for POP/IMAP authentication],
 675         [
 676         if test "$with_sasl" != "no" -a "$need_imap" != "yes" -a "$need_pop" != "yes"
 677         then
 678           AC_MSG_ERROR([SASL support is only useful with POP or IMAP support])
 679         fi
 680
 681         if test "$with_sasl" != "no"
 682         then
 683           if test "$with_sasl" != "yes"
 684           then
 685             CPPFLAGS="$CPPFLAGS -I$with_sasl/include"
 686             LDFLAGS="$LDFLAGS -L$with_sasl/lib"
 687           fi
 688
 689           saved_LIBS="$LIBS"
 690
 691           AC_CHECK_LIB(sasl, sasl_client_init,,
 692             AC_MSG_ERROR([could not find libsasl]),)
 693
 694           MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_sasl.o"
 695           MUTTLIBS="$MUTTLIBS -lsasl"
 696           LIBS="$saved_LIBS"
 697           AC_DEFINE(USE_SASL,1,
 698                   [ Define if want to use the Cyrus SASL library for POP/IMAP authentication. ])
 699           need_sasl=yes
 700         fi
 701         ])
 702 AM_CONDITIONAL(USE_SASL, test x$need_sasl = xyes)
 703
 704 AC_ARG_WITH(sasl2, [  --with-sasl2[=PFX]         Use Cyrus SASL library version 2 for POP/IMAP authentication],
 705         [
 706         if test "$with_sasl2" != "no" -a "$need_imap" != "yes" -a "$need_pop" != "yes"
 707         then
 708           AC_MSG_ERROR([SASL2 support is only useful with POP or IMAP support])
 709         fi
 710
 711         if test "$with_sasl2" != "no"
 712         then
 713           if test "$with_sasl2" != "yes"
 714           then
 715             CPPFLAGS="$CPPFLAGS -I$with_sasl2/include"
 716             LDFLAGS="$LDFLAGS -L$with_sasl2/lib"
 717           fi
 718
 719           saved_LIBS="$LIBS"
 720
 721           AC_CHECK_LIB(sasl2, sasl_client_init,,
 722             AC_MSG_ERROR([could not find libsasl2]),)
 723
 724           MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_sasl.o"
 725           MUTTLIBS="$MUTTLIBS -lsasl2"
 726           LIBS="$saved_LIBS"
 727           AC_DEFINE(USE_SASL,1,
 728                   [ Define if want to use the Cyrus SASL library for POP/IMAP authentication. ])
 729           AC_DEFINE(USE_SASL2,1,
 730                   [ Define if want to use version 2 of the Cyrus SASL library. ])
 731           need_sasl=yes
 732         fi
 733         ])
 734 AM_CONDITIONAL(USE_SASL, test x$need_sasl = xyes)
 735
 736 AC_ARG_WITH(idn, [  --with-idn=[PFX]           Use GNU libidn for domain names],
 737                  [
 738                   if test "$with_idn" != "no" ; then
 739                         if test "$with_idn" != "yes" ; then
 740                            CPPFLAGS="$CPPFLAGS -I$with_idn/include"
 741                            LDFLAGS="$LDFLAGS -L$with_idn/lib"
 742                         fi
 743                   fi
 744                  ]
 745 )
 746
 747 if test "x$with_idn" != "xno"; then
 748    AC_CHECK_LIB(idn, stringprep_check_version)
 749    AC_CHECK_FUNCS(idna_to_unicode_utf8_from_utf8 idna_to_unicode_8z8z)
 750    AC_CHECK_FUNCS(idna_to_ascii_from_utf8 idna_to_ascii_8z)
 751    AC_CHECK_FUNCS(idna_to_ascii_lz idna_to_ascii_from_locale)
 752 fi
 753
 754 dnl -- end socket --
 755
 756 AC_ARG_ENABLE(debug, [  --enable-debug             Enable debugging support],
 757         [ if test x$enableval = xyes ; then
 758                 AC_DEFINE(DEBUG,1,[ Define to enable debugging info. ])
 759           fi
 760          ])
 761
 762 AC_ARG_ENABLE(flock, [  --enable-flock             Use flock() to lock files],
 763         [if test $enableval = yes; then
 764                 AC_DEFINE(USE_FLOCK,1, [ Define to use flock() to lock mailboxes. ])
 765         fi])
 766
 767 mutt_cv_fcntl=yes
 768 AC_ARG_ENABLE(fcntl, [  --disable-fcntl            Do NOT use fcntl() to lock files ],
 769         [if test $enableval = no; then mutt_cv_fcntl=no; fi])
 770
 771 if test $mutt_cv_fcntl = yes; then
 772         AC_DEFINE(USE_FCNTL,1, [ Define to use fcntl() to lock folders. ])
 773 fi
 774
 775 dnl This may look cumbersome -- please keep it that way, so we can
 776 dnl quickly change the default to "yes" again.
 777 mutt_cv_inodesort=no
 778 AC_ARG_ENABLE(inodesort,  [  --enable-inodesort        Read files in maildir folders sorted by inode. ],
 779        [if test x$enableval = xyes ; then mutt_cv_inodesort=yes; fi])
 780
 781 if test $mutt_cv_inodesort = yes; then
 782         AC_DEFINE(USE_INODESORT, 1, [ Define to sort files in a maildir by inode number. ])
 783 fi
 784
 785 mutt_cv_warnings=yes
 786 AC_ARG_ENABLE(warnings, [  --disable-warnings         Turn off compiler warnings (not recommended)],
 787 [if test $enableval = no; then
 788         mutt_cv_warnings=no
 789 fi])
 790
 791 if test x$GCC = xyes -a $mutt_cv_warnings = yes; then
 792         CFLAGS="-Wall -pedantic $CFLAGS"
 793 fi
 794
 795 AC_ARG_ENABLE(nfs-fix, [  --enable-nfs-fix           Work around an NFS with broken attributes caching ],
 796         [if test x$enableval = xyes; then
 797                 AC_DEFINE(NFS_ATTRIBUTE_HACK,1,
 798                   [Define if you have problems with mutt not detecting
 799                    new/old mailboxes over NFS.  Some NFS implementations
 800                    incorrectly cache the attributes of small files.])
 801         fi])
 802
 803 AC_ARG_ENABLE(buffy-size, [  --enable-buffy-size        Use file size attribute instead of access time ],
 804         [if test x$enableval = xyes; then
 805                 AC_DEFINE(BUFFY_SIZE,1,[ Define to enable the "buffy_size" feature. ])
 806         fi])
 807
 808 AC_ARG_ENABLE(mailtool, [  --enable-mailtool          Enable Sun mailtool attachments support ],
 809         [if test x$enableval = xyes; then
 810                 AC_DEFINE(SUN_ATTACHMENT,1,[ Define to enable Sun mailtool attachments support. ])
 811         fi])
 812
 813 AC_ARG_ENABLE(compressed, [  --enable-compressed        Enable compressed folders support ],
 814         [if test x$enableval = xyes; then
 815                 AC_DEFINE(USE_COMPRESSED)
 816         fi])
 817
 818 AC_ARG_ENABLE(locales-fix, [  --enable-locales-fix       The result of isprint() is unreliable ],
 819         [if test x$enableval = xyes; then
 820                 AC_DEFINE(LOCALES_HACK,1,[ Define if the result of isprint() is unreliable. ])
 821         fi])
 822
 823 AC_ARG_WITH(exec-shell, [  --with-exec-shell=SHELL    Specify alternate shell (ONLY if /bin/sh is broken)],
 824         [if test $withval != yes; then
 825                 AC_DEFINE_UNQUOTED(EXECSHELL, "$withval",
 826                  [program to use for shell commands])
 827          else
 828                 AC_DEFINE_UNQUOTED(EXECSHELL, "/bin/sh")
 829         fi],
 830         [AC_DEFINE_UNQUOTED(EXECSHELL, "/bin/sh")])
 831
 832 AC_ARG_ENABLE(exact-address, [  --enable-exact-address     Enable regeneration of email addresses],
 833         [if test $enableval = yes; then
 834                 AC_DEFINE(EXACT_ADDRESS,1,
 835                   [Enable exact regeneration of email addresses as parsed?
 836                    NOTE: this requires significant more memory when defined.])
 837
 838         fi])
 839
 840 dnl -- start cache --
 841 AC_ARG_ENABLE(hcache, [  --enable-hcache            Enable header caching],
 842 [if test x$enableval = xyes; then
 843     AC_DEFINE(USE_HCACHE, 1, [Enable header caching])
 844
 845     OLDCPPFLAGS="$CPPFLAGS"
 846     OLDLIBS="$LIBS"
 847
 848     need_md5="yes"
 849     ac_prefer_gdbm=yes
 850     AC_ARG_WITH(gdbm, [  --without-gdbm             Get rid of gdbm even if it is available ],
 851         ac_prefer_gdbm=$withval)
 852     if test x$ac_prefer_gdbm != xno; then
 853         CPPFLAGS="$OLDCPPFLAGS"
 854         LIBS="$OLDLIBS -lgdbm";
 855         AC_CACHE_CHECK(for gdbm_open, ac_cv_gdbmopen,[
 856             ac_cv_gdbmopen=no
 857             AC_TRY_LINK([#include <gdbm.h>],[gdbm_open(0,0,0,0,0);],[ac_cv_gdbmopen=yes])
 858         ])
 859     fi
 860
 861     ac_bdb_prefix=yes
 862     AC_ARG_WITH(bdb, [  --with-bdb[=DIR]           Use BerkeleyDB4 if gdbm is not available ],
 863         ac_bdb_prefix=$withval)
 864     if test x$ac_bdb_prefix != xno -a x$ac_cv_gdbmopen != xyes; then
 865         test x$ac_bdb_prefix = xyes && ac_bdb_prefix="$mutt_cv_prefix /opt/csw/bdb4 /opt /usr/local /usr"
 866         for d in $ac_bdb_prefix; do
 867             bdbpfx="$bdbpfx $d"
 868             for v in BerkeleyDB.4.3 BerkeleyDB.4.2 BerkeleyDB.4.1; do
 869                 bdbpfx="$bdbpfx $d/$v"
 870             done
 871         done
 872         BDB_VERSIONS="db-4 db4 db-4.3 db4.3 db43 db-4.2 db4.2 db42 db-4.1 db4.1 db41 db ''"
 873         AC_MSG_CHECKING([for BerkeleyDB > 4.0])
 874         for d in $bdbpfx; do
 875             BDB_INCLUDE_DIR=""
 876             BDB_LIB_DIR=""
 877             for v in / $BDB_VERSIONS; do
 878                 if test -r "$d/include/$v/db.h"; then
 879                     BDB_INCLUDE_DIR="$d/include/$v"
 880                     if test -d "$d/lib/$v"; then
 881                         BDB_LIB_DIR="$d/lib/$v"
 882                         for l in `echo $BDB_VERSIONS`; do
 883                             CPPFLAGS="-I$BDB_INCLUDE_DIR $OLDCPPFLAGS"
 884                             LIBS="$OLDLIBS -L$BDB_LIB_DIR -l$l"
 885                             AC_TRY_LINK([
 886                                 #include <stdlib.h>
 887                                 #include <db.h>
 888                             ],[
 889                                 DB *db = NULL;
 890                                 db->open(db,NULL,NULL,NULL,0,0,0);
 891                             ],[
 892                                 ac_cv_dbcreate=yes
 893                                 BDB_LIB="$l"
 894                                 break
 895                             ])
 896                         done
 897                         test x$ac_dbcreate = xyes && break
 898                     fi
 899                 fi
 900             done
 901             test x$BDB_LIB != x && break
 902         done
 903         if test x$ac_cv_dbcreate = xyes; then
 904             AC_MSG_RESULT(yes)
 905         else
 906             AC_MSG_RESULT(no)
 907         fi
 908     fi
 909
 910     if test x$ac_cv_gdbmopen = xyes; then
 911         CPPFLAGS="$OLDCPPFLAGS"
 912         LIBS="$OLDLIBS -lgdbm";
 913         AC_DEFINE(HAVE_GDBM, 1, [GDBM Support])
 914     elif test x$ac_cv_dbcreate = xyes; then
 915         CPPFLAGS="-I$BDB_INCLUDE_DIR $OLDCPPFLAGS"
 916         LIBS="$OLDLIBS -L$BDB_LIB_DIR -l$BDB_LIB"
 917         AC_DEFINE(HAVE_DB4, 1, [Sleepycat DB4 Support])
 918     else
 919         AC_MSG_ERROR(You need Sleepycat DB4 or GDBM for --enable-hcache)
 920     fi
 921 fi])
 922 dnl -- end cache --
 923
 924 AC_SUBST(MUTTLIBS)
 925 AC_SUBST(MUTT_LIB_OBJECTS)
 926 AC_SUBST(LIBIMAP)
 927 AC_SUBST(LIBIMAPDEPS)
 928
 929 dnl -- iconv/gettext --
 930
 931 AC_ARG_ENABLE(iconv, [  --disable-iconv            Disable iconv support],
 932         [if test x$enableval = xno ; then
 933                 am_cv_func_iconv=no
 934         fi
 935 ])
 936
 937 MUTT_AM_GNU_GETTEXT
 938
 939 if test "$am_cv_func_iconv" != "yes"
 940 then
 941   AC_MSG_WARN([Configuring without iconv support. See INSTALL for details])
 942 else
 943
 944 AC_CHECK_HEADERS(iconv.h,
 945         [AC_MSG_CHECKING(whether iconv.h defines iconv_t)
 946          AC_EGREP_HEADER([typedef.*iconv_t],iconv.h,
 947                 [AC_MSG_RESULT(yes)
 948                  AC_DEFINE(HAVE_ICONV_T_DEF, 1,
 949                         [Define if <iconv.h> defines iconv_t.])],
 950                  AC_MSG_RESULT(no))])
 951
 952 dnl (1) Some implementations of iconv won't convert from UTF-8 to UTF-8.
 953 dnl (2) In glibc-2.1.2 and earlier there is a bug that messes up ob and
 954 dnl     obl when args 2 and 3 are 0 (fixed in glibc-2.1.3).
 955 AC_CACHE_CHECK([whether this iconv is good enough], mutt_cv_iconv_good,
 956         mutt_save_LIBS="$LIBS"
 957         LIBS="$LIBS $LIBICONV"
 958         AC_TRY_RUN([
 959 #include <iconv.h>
 960 int main()
 961 {
 962   iconv_t cd;
 963 changequote(, )dnl
 964   char buf[4];
 965 changequote([, ])dnl
 966   char *ob;
 967   size_t obl;
 968   ob = buf, obl = sizeof(buf);
 969   return ((cd = iconv_open("UTF-8", "UTF-8")) != (iconv_t)(-1) &&
 970           (iconv(cd, 0, 0, &ob, &obl) ||
 971            !(ob == buf && obl == sizeof(buf)) ||
 972            iconv_close(cd)));
 973 }
 974                 ],
 975                 mutt_cv_iconv_good=yes,
 976                 mutt_cv_iconv_good=no,
 977                 mutt_cv_iconv_good=yes)
 978         LIBS="$mutt_save_LIBS")
 979 if test "$mutt_cv_iconv_good" = no; then
 980   AC_MSG_ERROR(Try using libiconv instead)
 981 fi
 982
 983 dnl This is to detect implementations such as the one in glibc-2.1,
 984 dnl which always convert exactly but return the number of characters
 985 dnl converted instead of the number converted inexactly.
 986 AC_CACHE_CHECK([whether iconv is non-transcribing], mutt_cv_iconv_nontrans,
 987         mutt_save_LIBS="$LIBS"
 988         LIBS="$LIBS $LIBICONV"
 989         AC_TRY_RUN([
 990 #include <iconv.h>
 991 #include <string.h>
 992 int main()
 993 {
 994   iconv_t cd;
 995   const char *ib;
 996   char *ob;
 997   size_t ibl, obl;
 998   const char *s = "\304\211";
 999 changequote(, )dnl
1000   char t[3];
1001 changequote([, ])dnl
1002   ib = s, ibl = 2, ob = t, obl = 3;
1003   return ((cd = iconv_open("UTF-8", "UTF-8")) == (iconv_t)(-1) ||
1004           iconv(cd, &ib, &ibl, &ob, &obl));
1005 }
1006                 ],
1007                 mutt_cv_iconv_nontrans=no,
1008                 mutt_cv_iconv_nontrans=yes,
1009                 mutt_cv_iconv_nontrans=no)
1010         LIBS="$mutt_save_LIBS")
1011 if test "$mutt_cv_iconv_nontrans" = yes; then
1012   AC_DEFINE(ICONV_NONTRANS, 1)
1013 else
1014   AC_DEFINE(ICONV_NONTRANS, 0)
1015 fi
1016
1017 CPPFLAGS="$CPPFLAGS -I\$(top_srcdir)/intl"
1018
1019 if test "$BUILD_INCLUDED_LIBINTL" = "yes"; then
1020   AC_DEFINE(HAVE_BIND_TEXTDOMAIN_CODESET,1,
1021           [ Define if your gettext has bind_textdomain_codeset. ])
1022 else
1023   AC_CHECK_FUNCS(bind_textdomain_codeset)
1024 fi
1025
1026 fi # libiconv
1027
1028 dnl -- locales --
1029
1030 AC_CHECK_HEADERS(wchar.h)
1031
1032 AC_CACHE_CHECK([for wchar_t], mutt_cv_wchar_t,
1033         AC_TRY_COMPILE([
1034 #include <stddef.h>
1035 #include <stdlib.h>
1036 #ifdef HAVE_WCHAR_H
1037 #include <wchar.h>
1038 #endif
1039                 ],
1040                 [ wchar_t wc; return 0; ],
1041                 mutt_cv_wchar_t=yes,
1042                 mutt_cv_wchar_t=no))
1043
1044 if test "$mutt_cv_wchar_t" = no; then
1045         AC_DEFINE(wchar_t,int,[ Define to 'int' if system headers don't define. ])
1046 fi
1047
1048 AC_CACHE_CHECK([for wint_t], mutt_cv_wint_t,
1049         AC_TRY_COMPILE([
1050 #include <stddef.h>
1051 #include <stdlib.h>
1052 #ifdef HAVE_WCHAR_H
1053 #include <wchar.h>
1054 #endif
1055                 ],
1056                 [ wint_t wc; return 0; ],
1057                 mutt_cv_wint_t=yes,
1058                 mutt_cv_wint_t=no))
1059
1060 if test "$mutt_cv_wint_t" = no; then
1061         AC_DEFINE(wint_t,int,[ Define to 'int' if system headers don't define. ])
1062 fi
1063
1064 AC_CHECK_HEADERS(wctype.h)
1065 AC_CHECK_FUNCS(iswalnum iswalpha  iswcntrl iswdigit)
1066 AC_CHECK_FUNCS(iswgraph iswlower iswprint iswpunct iswspace iswupper)
1067 AC_CHECK_FUNCS(iswxdigit towupper towlower)
1068
1069 AC_CACHE_CHECK([for mbstate_t], mutt_cv_mbstate_t,
1070         AC_TRY_COMPILE([
1071 #include <stddef.h>
1072 #include <stdlib.h>
1073 #ifdef HAVE_WCHAR_H
1074 #include <wchar.h>
1075 #endif
1076                 ],
1077                 [ mbstate_t s; return 0; ],
1078                 mutt_cv_mbstate_t=yes,
1079                 mutt_cv_mbstate_t=no))
1080
1081 if test "$mutt_cv_mbstate_t" = no; then
1082         AC_DEFINE(mbstate_t,int,[ Define to 'int' if system headers don't define. ])
1083 fi
1084
1085 wc_funcs=maybe
1086 AC_ARG_WITH(wc-funcs, [  --without-wc-funcs         Do not use the system's wchar_t functions],
1087         wc_funcs=$withval)
1088
1089 if test "$wc_funcs" != yes -a "$wc_funcs" != no; then
1090         AC_CACHE_CHECK([for wchar_t functions], mutt_cv_wc_funcs,
1091                 mutt_cv_wc_funcs=no
1092                 AC_TRY_LINK([
1093 #define _XOPEN_SOURCE 1
1094 #include <stddef.h>
1095 #include <stdlib.h>
1096 #ifdef HAVE_WCTYPE_H
1097 #include <wctype.h>
1098 #endif
1099 #ifdef HAVE_WCHAR_H
1100 #include <wchar.h>
1101 #endif],
1102                         [mbrtowc(0, 0, 0, 0); wctomb(0, 0); wcwidth(0);
1103         iswprint(0); iswspace(0); towlower(0); towupper(0); iswalnum(0)],
1104                         mutt_cv_wc_funcs=yes))
1105         wc_funcs=$mutt_cv_wc_funcs
1106 fi
1107
1108 if test $wc_funcs = yes; then
1109         AC_DEFINE(HAVE_WC_FUNCS,1,[ Define if you are using the system's wchar_t functions. ])
1110 fi
1111
1112 AC_CACHE_CHECK([for nl_langinfo and CODESET], mutt_cv_langinfo_codeset,
1113   [AC_TRY_LINK([#include <langinfo.h>],
1114     [char* cs = nl_langinfo(CODESET);],
1115     mutt_cv_langinfo_codeset=yes,
1116     mutt_cv_langinfo_codeset=no)])
1117 if test $mutt_cv_langinfo_codeset = yes; then
1118   AC_DEFINE(HAVE_LANGINFO_CODESET,1,[ Define if you have <langinfo.h> and nl_langinfo(CODESET). ])
1119 fi
1120
1121 AC_CACHE_CHECK([for nl_langinfo and YESEXPR], mutt_cv_langinfo_yesexpr,
1122   [AC_TRY_LINK([#include <langinfo.h>],
1123     [char* cs = nl_langinfo(YESEXPR);],
1124     mutt_cv_langinfo_yesexpr=yes,
1125     mutt_cv_langinfo_yesexpr=no)])
1126 if test $mutt_cv_langinfo_yesexpr = yes; then
1127   AC_DEFINE(HAVE_LANGINFO_YESEXPR,1,[ Define if you have <langinfo.h> and nl_langinfo(YESEXPR). ])
1128 fi
1129
1130 dnl -- libesmtp --
1131 MUTT_AM_LIBESMTP
1132 if test x$use_libesmtp = xyes; then
1133     CFLAGS="$CFLAGS $mutt_libesmtp_cflags"
1134     MUTTLIBS="$MUTTLIBS $mutt_libesmtp_libs"
1135     MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_libesmtp.o"
1136
1137     AC_DEFINE(USE_LIBESMTP,
1138               1,
1139               [Define to enable the use of libesmtp])
1140 fi
1141 dnl -- end libesmtp --
1142
1143 AC_OUTPUT(Makefile intl/Makefile m4/Makefile
1144         po/Makefile.in doc/Makefile contrib/Makefile
1145         muttbug.sh
1146         imap/Makefile
1147         Muttngrc.head
1148         doc/instdoc.sh)