configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl !!! WHEN ADDING NEW CONFIGURE TESTS, PLEASE ADD CODE TO MAIN.C !!!
   4 dnl !!! TO DUMP THEIR RESULTS WHEN MUTT -V IS CALLED            !!!
   5
   6 AC_PREREQ([2.50])
   7 AC_INIT([mutt.h])
   8 AM_CONFIG_HEADER(config.h)
   9
  10 mutt_cv_version=`cat "$srcdir/VERSION.in"`
  11
  12 AM_INIT_AUTOMAKE(muttng, $mutt_cv_version)
  13 AC_SUBST([CONFIGURE_DEPENDENCIES], ['$(top_srcdir)/VERSION.in'])
  14
  15 dnl AC_GNU_SOURCE
  16
  17 ifdef([AC_LIBOBJ], , [define([AC_LIBOBJ], [LIB[]OBJS="$LIBOBJS $1.o"])])
  18
  19 ALL_LINGUAS="de ru it es uk fr pl nl cs id sk ko el zh_TW zh_CN pt_BR eo gl sv da lt tr ja hu et ca bg"
  20
  21 AC_CANONICAL_HOST
  22
  23 AC_MSG_CHECKING([for prefix])
  24 if test x$prefix = xNONE; then
  25         mutt_cv_prefix=$ac_default_prefix
  26 else
  27         mutt_cv_prefix=$prefix
  28 fi
  29 AC_MSG_RESULT($mutt_cv_prefix)
  30
  31 AC_PROG_CC
  32 AC_ISC_POSIX
  33 AM_C_PROTOTYPES
  34 if test "x$U" != "x"; then
  35   AC_MSG_ERROR(Compiler not ANSI compliant)
  36 fi
  37 AC_PROG_CPP
  38 AC_PROG_MAKE_SET
  39 AC_PROG_INSTALL
  40 AC_PROG_RANLIB
  41 AC_CHECK_TOOL(AR, ar, ar)
  42
  43 AC_C_INLINE
  44 AC_C_CONST
  45
  46 AC_SYS_LARGEFILE
  47
  48 AC_PATH_PROG(DBX, dbx, no)
  49 AC_PATH_PROG(GDB, gdb, no)
  50 AC_PATH_PROG(SDB, sdb, no)
  51
  52 if test $GDB != no ; then
  53         DEBUGGER=$GDB
  54 elif test $DBX != no ; then
  55         DEBUGGER=$DBX
  56 elif test $SDB != no ; then
  57         DEBUGGER=$SDB
  58 else
  59         DEBUGGER=no
  60 fi
  61
  62 AC_SUBST([DEBUGGER])
  63
  64 AH_TEMPLATE([sig_atomic_t],
  65             [/* Define to `int' if <signal.h> doesn't define.])
  66 AH_TEMPLATE([HAVE_START_COLOR],
  67             [Define if you have start_color, as a function or macro.])
  68 AH_TEMPLATE([HAVE_TYPEAHEAD],
  69             [Define if you have typeahead, as a function or macro.])
  70 AH_TEMPLATE([HAVE_BKGDSET],
  71             [Define if you have bkgdset, as a function or macro.])
  72 AH_TEMPLATE([HAVE_CURS_SET],
  73             [Define if you have curs_set, as a function or macro.])
  74 AH_TEMPLATE([HAVE_META],
  75             [Define if you have meta, as a function or macro.])
  76 AH_TEMPLATE([HAVE_USE_DEFAULT_COLORS],
  77             [Define if you have use_default_colors, as a function or macro.])
  78 AH_TEMPLATE([HAVE_RESIZETERM],
  79             [Define if you have resizeterm, as a function or macro.])
  80 AH_TEMPLATE([SIG_ATOMIC_VOLATILE_T],
  81             [Some systems declare sig_atomic_t as volatile, some others -- no.
  82              This define will have value `sig_atomic_t' or
  83              `volatile sig_atomic_t' accordingly.])
  84 AH_TEMPLATE([ICONV_NONTRANS],
  85             [Define as 1 if iconv() only converts exactly and we should treat
  86              all return values other than (size_t)(-1) as equivalent.])
  87
  88 MUTT_C99_INTTYPES
  89
  90 ac_aux_path_sendmail=/usr/sbin:/usr/lib
  91 AC_PATH_PROG(SENDMAIL, sendmail, /usr/sbin/sendmail, $PATH:$ac_aux_path_sendmail)
  92 AC_DEFINE_UNQUOTED(SENDMAIL,"$ac_cv_path_SENDMAIL",[ Where to find sendmail on your system. ])
  93
  94 OPS='$(srcdir)/OPS'
  95
  96         AC_ARG_ENABLE(gpgme, AC_HELP_STRING([--enable-gpgme], [Enable GPGME support]),
  97         [       if test x$enableval = xyes; then
  98                         have_gpgme=yes
  99                 fi
 100         ])
 101         AC_ARG_WITH(gpgme-prefix, AC_HELP_STRING([--with-gpgme-prefix=PFX], [prefix where GPGME is installed (optional)]),
 102         gpgme_config_prefix="$withval", gpgme_config_prefix="")
 103
 104         if test x$have_gpgme = xyes; then
 105                 if test x$gpgme_config_prefix != x; then
 106                         GPGME_CONFIG="$gpgme_config_prefix/bin/gpgme-config"
 107                 else
 108                         AC_PATH_PROG(GPGME_CONFIG, gpgme-config, no)
 109                 fi
 110                 if test "x$GPGME_CONFIG" = "xno"; then
 111                         AC_MSG_ERROR([GPGME not found])
 112                 else
 113                         LIBGPGME_CFLAGS=`$GPGME_CONFIG --cflags`
 114                         LIBGPGME_LIBS=`$GPGME_CONFIG --libs`
 115       MUTTLIBS="$MUTTLIBS $LIBGPGME_LIBS"
 116                         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS crypt-gpgme.o crypt-mod-pgp-gpgme.o crypt-mod-smime-gpgme.o"
 117                         AC_DEFINE(CRYPT_BACKEND_GPGME, 1,
 118                                   [Defined, if GPGME support is enabled])
 119                 fi
 120         fi
 121         AC_SUBST(LIBGPGME_CFLAGS)
 122         AC_SUBST(LIBGPGME_LIBS)
 123
 124         AC_ARG_ENABLE(pgp, AC_HELP_STRING([--disable-pgp], [Disable PGP support]),
 125         [       if test x$enableval = xno ; then
 126                         have_pgp=no
 127                 fi
 128         ])
 129
 130         if test x$have_pgp != xno ; then
 131                 AC_DEFINE(CRYPT_BACKEND_CLASSIC_PGP,1,
 132                     [ Define if you want classic PGP support. ])
 133                 PGPAUX_TARGET="pgpringng\$(EXEEXT) pgpewrapng\$(EXEEXT)"
 134                 MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS pgp.o pgpinvoke.o pgpkey.o pgplib.o gnupgparse.o pgpmicalg.o pgppacket.o crypt-mod-pgp-classic.o"
 135         fi
 136
 137         AC_ARG_ENABLE(smime, AC_HELP_STRING([--disable-smime], [Disable SMIME support]),
 138         [       if test x$enableval = xno ; then
 139                         have_smime=no
 140                 fi
 141         ])
 142
 143         if test x$have_smime != xno ; then
 144                 AC_DEFINE(CRYPT_BACKEND_CLASSIC_SMIME,1,
 145                   [ Define if you want clasic S/MIME support. ])
 146                 MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS smime.o crypt-mod-smime-classic.o"
 147                 SMIMEAUX_TARGET="smime_keysng"
 148         fi
 149
 150         AC_ARG_WITH(mixmaster, AC_HELP_STRING([--with-mixmaster[=PATH]], [Include Mixmaster support]),
 151                 [if test -x "$withval" ; then
 152                         MIXMASTER="$withval"
 153                  else
 154                         MIXMASTER="mixmaster"
 155                  fi
 156                  OPS="$OPS \$(srcdir)/OPS.MIX"
 157                  MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS remailer.o"
 158                  AC_DEFINE_UNQUOTED(MIXMASTER,"$MIXMASTER",
 159                          [ Where to find mixmaster on your system. ])
 160                 ])
 161
 162 # We now require all OPS
 163 OPS="$OPS \$(srcdir)/OPS.PGP \$(srcdir)/OPS.SMIME \$(srcdir)/OPS.CRYPT "
 164 AC_SUBST([OPS])
 165
 166
 167 AC_SUBST(PGPAUX_TARGET)
 168 AC_SUBST(SMIMEAUX_TARGET)
 169
 170 AC_PATH_PROG(ISPELL, ispell, no)
 171 if test $ISPELL != no; then
 172         AC_DEFINE_UNQUOTED(ISPELL,"$ISPELL",[ Where to find ispell on your system. ])
 173 fi
 174
 175 AC_ARG_WITH(slang, AC_HELP_STRING([--with-slang[=DIR]], [Use S-Lang instead of ncurses]),
 176         [AC_CACHE_CHECK([if this is a BSD system], mutt_cv_bsdish,
 177                 [AC_TRY_RUN([#include <sys/param.h>
 178
 179 main ()
 180 {
 181 #ifdef BSD
 182         exit (0);
 183 #else
 184         exit (1);
 185 #endif
 186 }],
 187                         mutt_cv_bsdish=yes,
 188                         mutt_cv_bsdish=no,
 189                         mutt_cv_bsdish=no)])
 190
 191         AC_MSG_CHECKING(for S-Lang)
 192         if test $withval = yes; then
 193                 if test -d $srcdir/../slang; then
 194                         mutt_cv_slang=$srcdir/../slang/src
 195                         CFLAGS="$CFLAGS -I${mutt_cv_slang}"
 196                         LDFLAGS="$LDFLAGS -L${mutt_cv_slang}/objs"
 197                 else
 198                         if test -d $mutt_cv_prefix/include/slang; then
 199                                 CFLAGS="$CFLAGS -I$mutt_cv_prefix/include/slang"
 200                         elif test -d /usr/include/slang; then
 201                                 CFLAGS="$CFLAGS -I/usr/include/slang"
 202                         fi
 203                         mutt_cv_slang=yes
 204                 fi
 205         else
 206                 dnl ---Check to see if $withval is a source directory
 207                 if test -f $withval/src/slang.h; then
 208                         mutt_cv_slang=$withval/src
 209                         CFLAGS="$CFLAGS -I${mutt_cv_slang}"
 210                         LDFLAGS="$LDFLAGS -L${mutt_cv_slang}/objs"
 211                 else
 212                         dnl ---Must be installed somewhere
 213                         mutt_cv_slang=$withval
 214                         if test -d $withval/include/slang; then
 215                                 CFLAGS="$CFLAGS -I${withval}/include/slang"
 216                         elif test -d $withval/include; then
 217                                 CFLAGS="$CFLAGS -I${withval}/include"
 218                         fi
 219                         LDFLAGS="$LDFLAGS -L${withval}/lib"
 220                 fi
 221         fi
 222         AC_MSG_RESULT($mutt_cv_slang)
 223         if test $mutt_cv_bsdish = yes; then
 224                 AC_CHECK_LIB(termlib, main)
 225         fi
 226         AC_DEFINE(USE_SLANG_CURSES,1,
 227                 [ Define if you compile with SLang instead of curses/ncurses. ])
 228         AC_DEFINE(HAVE_COLOR,1,[ Define if your curses library supports color. ])
 229         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS resize.o"
 230
 231         dnl --- now that we've found it, check the link
 232
 233         AC_CHECK_LIB(slang, SLtt_get_terminfo,
 234                 [MUTTLIBS="$MUTTLIBS -lslang -lm"],
 235                 [AC_MSG_ERROR(unable to compile.  check config.log)], -lm)
 236
 237         ],
 238
 239         [mutt_cv_curses=/usr
 240         AC_ARG_WITH(curses, AC_HELP_STRING([--with-curses=DIR], [Where ncurses is installed]),
 241                 [if test $withval != yes; then
 242                         mutt_cv_curses=$withval
 243                 fi
 244                 if test x$mutt_cv_curses != x/usr; then
 245                         LDFLAGS="-L${mutt_cv_curses}/lib $LDFLAGS"
 246                         CPPFLAGS="$CPPFLAGS -I${mutt_cv_curses}/include"
 247                 fi])
 248
 249         AC_CHECK_FUNC(initscr,,[
 250         cf_ncurses="ncurses"
 251         for lib in ncursesw ncurses
 252         do
 253                 AC_CHECK_LIB($lib, waddnwstr, [cf_ncurses="$lib"; break])
 254         done
 255         AC_CHECK_LIB($cf_ncurses, initscr,
 256                 [MUTTLIBS="$MUTTLIBS -l$cf_ncurses"
 257                 if test x$mutt_cv_curses = x/usr -a -d /usr/include/ncurses; then
 258                         CPPFLAGS="$CPPFLAGS -I/usr/include/ncurses"
 259                 fi
 260
 261                 if test "$cf_ncurses" = ncursesw; then
 262                         AC_CHECK_HEADERS(ncurses/ncurses.h,[cf_cv_ncurses_header="ncurses/ncurses.h"])
 263                         AC_CHECK_HEADERS(ncursesw/ncurses.h,[cf_cv_ncurses_header="ncursesw/ncurses.h"])
 264                 else
 265                         AC_CHECK_HEADERS(ncurses.h,[cf_cv_ncurses_header="ncurses.h"])
 266                 fi],
 267
 268                 [CF_CURSES_LIBS])
 269                 ])
 270
 271         old_LIBS="$LIBS"
 272         LIBS="$LIBS $MUTTLIBS"
 273         CF_CHECK_FUNCDECLS([#include <${cf_cv_ncurses_header-curses.h}>],
 274                            [start_color typeahead bkgdset curs_set meta use_default_colors resizeterm])
 275         if test "$ac_cv_func_decl_start_color" = yes; then
 276                 AC_DEFINE(HAVE_COLOR,1,[ Define if your curses library supports color. ])
 277         fi
 278         if test "$ac_cv_func_decl_resizeterm" = yes; then
 279                 MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS resize.o"
 280         fi
 281         LIBS="$old_LIBS"
 282         ])
 283
 284 AC_HEADER_STDC
 285
 286 AC_CHECK_HEADERS(stdarg.h sys/ioctl.h ioctl.h sysexits.h)
 287 AC_CHECK_HEADERS(sys/time.h sys/resource.h)
 288 AC_CHECK_HEADERS(unix.h)
 289
 290 AC_CHECK_FUNCS(setrlimit getsid isctype)
 291
 292 AC_TYPE_SIGNAL
 293
 294 AC_MSG_CHECKING(for sig_atomic_t in signal.h)
 295 AC_EGREP_HEADER(sig_atomic_t,signal.h,
 296   [
 297     ac_cv_type_sig_atomic_t=yes;
 298     AC_EGREP_HEADER(volatile.*sig_atomic_t,
 299                     signal.h,
 300                     [
 301                         is_sig_atomic_t_volatile=yes;
 302                         AC_MSG_RESULT([yes, volatile])
 303                     ],
 304                     [
 305                         is_sig_atomic_t_volatile=no;
 306                         AC_MSG_RESULT([yes, non volatile])
 307                     ])
 308   ],
 309   [
 310     AC_MSG_RESULT(no)
 311     AC_CHECK_TYPE(sig_atomic_t, int)
 312     is_sig_atomic_t_volatile=no
 313   ])
 314 if test $is_sig_atomic_t_volatile = 'yes'
 315 then
 316     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, sig_atomic_t)
 317 else
 318     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, [volatile sig_atomic_t])
 319 fi
 320
 321 AC_DECL_SYS_SIGLIST
 322
 323 AC_TYPE_PID_T
 324 dnl AC_CHECK_TYPE(ssize_t, int)
 325
 326 AC_CHECK_FUNCS(fgetpos memmove setegid srand48 strerror)
 327
 328 AC_REPLACE_FUNCS(strcasecmp strdup)
 329
 330 AC_CHECK_FUNC(getopt)
 331 if test $ac_cv_func_getopt = yes; then
 332         AC_CHECK_HEADERS(getopt.h)
 333 fi
 334
 335 mutt_cv_snprintf=no
 336 SNPRINTFOBJS=""
 337 AC_CHECK_FUNCS(snprintf, , [mutt_cv_snprintf=yes])
 338 AC_CHECK_FUNCS(vsnprintf, , [mutt_cv_snprintf=yes])
 339 if test $mutt_cv_snprintf = yes; then
 340         AC_LIBOBJ(snprintf)
 341 fi
 342
 343 dnl SCO uses chsize() instead of ftruncate()
 344 AC_CHECK_FUNCS(ftruncate, , [AC_CHECK_LIB(x, chsize)])
 345
 346 dnl SCO has strftime() in libintl
 347 AC_CHECK_FUNCS(strftime, , [AC_CHECK_LIB(intl, strftime)])
 348
 349 dnl AIX may not have fchdir()
 350 AC_CHECK_FUNCS(fchdir, , [mutt_cv_fchdir=no])
 351
 352 AC_ARG_WITH(regex, AC_HELP_STRING([--with-regex], [Use the GNU regex library]),
 353         [mutt_cv_regex=yes],
 354         [AC_CHECK_FUNCS(regcomp, mutt_cv_regex=no, mutt_cv_regex=yes)])
 355
 356 if test $mutt_cv_regex = no ; then
 357 AC_CACHE_CHECK([whether your system's regexp library is completely broken],
 358         [mutt_cv_regex_broken],
 359         AC_TRY_RUN([
 360 #include <unistd.h>
 361 #include <regex.h>
 362 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
 363         mutt_cv_regex_broken=no, mutt_cv_regex_broken=yes, mutt_cv_regex_broken=yes))
 364         if test $mutt_cv_regex_broken = yes ; then
 365                 echo "Using the included GNU regex instead." >&AC_FD_MSG
 366                 mutt_cv_regex=yes
 367         fi
 368 fi
 369
 370 if test $mutt_cv_regex = yes; then
 371         AC_DEFINE(USE_GNU_REGEX,1,[ Define if you want to use the included regex.c. ])
 372         AC_LIBOBJ(regex)
 373 fi
 374
 375
 376 AC_ARG_WITH(homespool,
 377   AC_HELP_STRING([--with-homespool[=FILE]], [File in user's directory where new mail is spooled]), with_homespool=${withval})
 378 if test x$with_homespool != x; then
 379         if test $with_homespool = yes; then
 380                 with_homespool=mailbox
 381         fi
 382         AC_DEFINE_UNQUOTED(MAILPATH,"$with_homespool",[ Where new mail is spooled. ])
 383         AC_DEFINE(HOMESPOOL,1,
 384           [Is mail spooled to the user's home directory?  If defined,
 385            MAILPATH should be set to the filename of the spool mailbox
 386            relative the the home directory.
 387            use: configure --with-homespool=FILE])
 388         AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 389         mutt_cv_setgid=no
 390 else
 391         AC_ARG_WITH(mailpath, AC_HELP_STRING([--with-mailpath=DIR], [Directory where spool mailboxes are located]),
 392                 [mutt_cv_mailpath=$withval],
 393                 [ AC_CACHE_CHECK(where new mail is stored, mutt_cv_mailpath,
 394                         [mutt_cv_mailpath=no
 395                         if test -d /var/mail; then
 396                                 mutt_cv_mailpath=/var/mail
 397                         elif test -d /var/spool/mail; then
 398                                 mutt_cv_mailpath=/var/spool/mail
 399                         elif test -d /usr/spool/mail; then
 400                                 mutt_cv_mailpath=/usr/spool/mail
 401                         elif test -d /usr/mail; then
 402                                 mutt_cv_mailpath=/usr/mail
 403                         fi])
 404                 ])
 405         if test "$mutt_cv_mailpath" = no; then
 406                 AC_MSG_ERROR("Could not determine where new mail is stored.")
 407         fi
 408         AC_DEFINE_UNQUOTED(MAILPATH,"$mutt_cv_mailpath",[ Where new mail is spooled. ])
 409
 410         AC_CACHE_CHECK(if $mutt_cv_mailpath is world writable, mutt_cv_worldwrite, [AC_TRY_RUN([#include <sys/types.h>
 411 #include <sys/stat.h>
 412
 413 int main (int argc, char **argv)
 414 {
 415         struct stat s;
 416
 417         stat ("$mutt_cv_mailpath", &s);
 418         if (s.st_mode & S_IWOTH) exit (0);
 419         exit (1);
 420 }], mutt_cv_worldwrite=yes, mutt_cv_worldwrite=no, mutt_cv_worldwrite=no)])
 421
 422         mutt_cv_setgid=no
 423         if test $mutt_cv_worldwrite = yes; then
 424                 AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 425         else
 426
 427                 AC_CACHE_CHECK(if $mutt_cv_mailpath is group writable, mutt_cv_groupwrite, [AC_TRY_RUN([#include <sys/types.h>
 428 #include <sys/stat.h>
 429
 430 int main (int argc, char **argv)
 431 {
 432         struct stat s;
 433
 434         stat ("$mutt_cv_mailpath", &s);
 435         if (s.st_mode & S_IWGRP) exit (0);
 436         exit (1);
 437 }], mutt_cv_groupwrite=yes, mutt_cv_groupwrite=no, mutt_cv_groupwrite=no)])
 438
 439                 if test $mutt_cv_groupwrite = yes; then
 440                         AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 441                         AC_DEFINE(USE_SETGID,1,[ Define if mutt should run setgid "mail". ])
 442                         mutt_cv_setgid=yes
 443                 fi
 444         fi
 445 fi
 446
 447 AC_ARG_ENABLE(external_dotlock, AC_HELP_STRING([--enable-external-dotlock], [Force use of an external dotlock program]),
 448         [mutt_cv_external_dotlock="$enableval"])
 449
 450 if test "x$mutt_cv_setgid" = "xyes" || test "x$mutt_cv_fchdir" = "xno" \
 451         || test "x$mutt_cv_external_dotlock" = "xyes"
 452 then
 453         AC_DEFINE(DL_STANDALONE,1,[ Define if you want to use an external dotlocking program. ])
 454         DOTLOCK_TARGET="muttng_dotlock"
 455 else
 456         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS dotlock.o"
 457 fi
 458
 459 AC_SUBST(DOTLOCK_TARGET)
 460
 461
 462 AC_MSG_CHECKING(where to put the documentation)
 463 AC_ARG_WITH(docdir, AC_HELP_STRING([--with-docdir=PATH], [Specify where to put the documentation]),
 464         [mutt_cv_docdir=$withval],
 465         [mutt_cv_docdir="${prefix}/doc/muttng"])
 466 AC_MSG_RESULT($mutt_cv_docdir)
 467
 468 docdir=$mutt_cv_docdir
 469 AC_SUBST(docdir)
 470
 471 if test x$mutt_cv_setgid = xyes; then
 472         DOTLOCK_GROUP='mail'
 473         DOTLOCK_PERMISSION=2755
 474 else
 475         DOTLOCK_GROUP=''
 476         DOTLOCK_PERMISSION=755
 477 fi
 478 AC_SUBST(DOTLOCK_GROUP)
 479 AC_SUBST(DOTLOCK_PERMISSION)
 480
 481 AC_ARG_WITH(domain, AC_HELP_STRING([--with-domain=DOMAIN], [Specify your DNS domain name]),
 482         [if test $withval != yes; then
 483          if test $withval != no; then
 484            AC_DEFINE_UNQUOTED(DOMAIN,"$withval",[ Define your domain name. ])
 485          fi
 486         fi])
 487
 488 need_socket="no"
 489
 490 dnl -- socket dependencies --
 491
 492 AC_ARG_ENABLE(pop,  AC_HELP_STRING([--enable-pop], [Enable POP3 support]),
 493 [       if test x$enableval = xyes ; then
 494                 AC_DEFINE(USE_POP,1,[ Define if you want support for the POP3 protocol. ])
 495                 LIBPOP="-Lpop -lpop"
 496                 LIBPOPDEPS="\$(top_srcdir)/pop/pop.h pop/libpop.a"
 497                 need_socket="yes"
 498                 need_pop="yes"
 499                 need_md5="yes"
 500         fi
 501 ])
 502 AM_CONDITIONAL(BUILD_POP, test x$need_pop = xyes)
 503
 504 AC_ARG_ENABLE(imap, AC_HELP_STRING([--enable-imap], [Enable IMAP support]),
 505 [       if test x$enableval = xyes ; then
 506                 AC_DEFINE(USE_IMAP,1,[ Define if you want support for the IMAP protocol. ])
 507                 LIBIMAP="-Limap -limap"
 508                 LIBIMAPDEPS="\$(top_srcdir)/imap/imap.h imap/libimap.a"
 509                 need_imap="yes"
 510                 need_socket="yes"
 511                 need_md5="yes"
 512         fi
 513 ])
 514 AM_CONDITIONAL(BUILD_IMAP, test x$need_imap = xyes)
 515
 516 AC_ARG_ENABLE(nntp, [  --enable-nntp              Enable NNTP support],
 517 [       if test x$enableval = xyes ; then
 518                 AC_DEFINE(USE_NNTP)
 519                 LIBNNTP="-Lnntp -lnntp"
 520                 LIBNNTPDEPS="\$(top_srcdir)/nntp/nntp.h nntp/libnntp.a"
 521                 need_nntp="yes"
 522                 need_socket="yes"
 523         fi
 524 ])
 525 AM_CONDITIONAL(BUILD_NNTP, test x$need_nntp = xyes)
 526
 527 dnl -- end socket dependencies --
 528
 529 if test "$need_socket" = "yes"
 530 then
 531         AC_MSG_CHECKING([for socklen_t])
 532         AC_EGREP_HEADER(socklen_t, sys/socket.h, AC_MSG_RESULT([yes]),
 533                 AC_MSG_RESULT([no])
 534                 AC_DEFINE(socklen_t,int,
 535                         [ Define to 'int' if <sys/socket.h> doesn't have it. ]))
 536         AC_CHECK_FUNC(gethostent, , AC_CHECK_LIB(nsl, gethostent))
 537         AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt))
 538         AC_CHECK_FUNCS(getaddrinfo)
 539         AC_DEFINE(USE_SOCKET,1,
 540                 [ Include code for socket support. Set automatically if you enable POP3 or IMAP ])
 541         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS account.o mutt_socket.o mutt_tunnel.o"
 542 fi
 543
 544 dnl -- imap dependencies --
 545
 546 AC_ARG_WITH(gss, AC_HELP_STRING([--with-gss[=PFX]], [Compile in GSSAPI authentication for IMAP]),
 547     gss_prefix="$withval", gss_prefix="no")
 548 if test "$gss_prefix" != "no"
 549 then
 550   if test "$need_imap" = "yes"
 551   then
 552     MUTT_AM_PATH_GSSAPI(gss_prefix)
 553     AC_MSG_CHECKING(GSSAPI implementation)
 554     AC_MSG_RESULT($GSSAPI_IMPL)
 555     if test "$GSSAPI_IMPL" = "none"
 556     then
 557       AC_CACHE_SAVE
 558       AC_MSG_RESULT([GSSAPI libraries not found])
 559     fi
 560     if test "$GSSAPI_IMPL" = "Heimdal"
 561     then
 562       AC_DEFINE(HAVE_HEIMDAL,1,[ Define if your GSSAPI implementation is Heimdal ])
 563     fi
 564     CPPFLAGS="$CPPFLAGS $GSSAPI_CFLAGS"
 565     MUTTLIBS="$MUTTLIBS $GSSAPI_LIBS"
 566     AC_DEFINE(USE_GSS,1,[ Define if you have GSSAPI libraries available ])
 567     need_gss="yes"
 568   else
 569     AC_MSG_WARN([GSS was requested but IMAP is not enabled])
 570   fi
 571 fi
 572 AM_CONDITIONAL(USE_GSS, test x$need_gss = xyes)
 573
 574 dnl -- end imap dependencies --
 575
 576 AC_ARG_WITH(ssl, AC_HELP_STRING([--with-ssl[=PFX]], [Compile in SSL support for POP/IMAP]),
 577 [       if test "$with_ssl" != "no"
 578         then
 579           if test "$need_socket" != "yes"; then
 580            AC_MSG_ERROR([SSL support is only useful with POP or IMAP support])
 581           fi
 582
 583           if test "$with_ssl" != "yes"
 584           then
 585            LDFLAGS="$LDFLAGS -L$withval/lib"
 586            CPPFLAGS="$CPPFLAGS -I$withval/include"
 587           fi
 588           saved_LIBS="$LIBS"
 589
 590           AC_CHECK_LIB(crypto, X509_new,, AC_MSG_ERROR([Unable to find SSL library]))
 591           AC_CHECK_LIB(ssl, SSL_new,, AC_MSG_ERROR([Unable to find SSL library]), -lcrypto)
 592
 593           AC_CHECK_FUNCS(RAND_status RAND_egd)
 594
 595           AC_DEFINE(USE_SSL,1,[ Define if you want support for SSL. ])
 596           LIBS="$saved_LIBS"
 597           MUTTLIBS="$MUTTLIBS -lssl -lcrypto"
 598           MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_ssl.o"
 599           need_ssl=yes
 600
 601         fi
 602 ])
 603
 604 AC_ARG_WITH([gnutls], AC_HELP_STRING([--with-gnutls[=PFX]], [Enable SSL support using gnutls]),
 605     [gnutls_prefix="$withval"], [gnutls_prefix="no"])
 606 if test "$gnutls_prefix" != "no"
 607 then
 608   if test "$need_socket" != "yes"
 609   then
 610     AC_MSG_ERROR([SSL support is only useful with POP or IMAP support])
 611   fi
 612   if test x"$need_ssl" = x"yes"
 613   then
 614     AC_MSG_ERROR([Only either OpenSSL or GNUTLS may be used])
 615   fi
 616   MUTT_AM_PATH_GNUTLS([$gnutls_prefix],
 617     [dnl GNUTLS found
 618     CPPFLAGS="$CPPFLAGS $LIBGNUTLS_CFLAGS"
 619     MUTTLIBS="$MUTTLIBS $LIBGNUTLS_LIBS"
 620     AC_DEFINE(USE_GNUTLS, 1, [Define if you want support for SSL via the gnutls library.])
 621
 622     MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_ssl_gnutls.o"
 623     need_ssl=yes],
 624     [dnl GNUTLS not found
 625       AC_MSG_ERROR([could not find libgnutls])
 626     ])
 627 fi
 628
 629 AM_CONDITIONAL(USE_SSL, test x$need_ssl = xyes)
 630
 631 AC_ARG_WITH(sasl2, AC_HELP_STRING([--with-sasl2[=PFX]], [Use Cyrus SASL library version 2 for POP/IMAP authentication]),
 632         [
 633         if test "$with_sasl2" != "no" -a "$need_imap" != "yes" -a "$need_pop" != "yes"
 634         then
 635           AC_MSG_ERROR([SASL2 support is only useful with POP or IMAP support])
 636         fi
 637
 638         if test "$with_sasl2" != "no"
 639         then
 640           if test "$with_sasl2" != "yes"
 641           then
 642             CPPFLAGS="$CPPFLAGS -I$with_sasl2/include"
 643             LDFLAGS="$LDFLAGS -L$with_sasl2/lib"
 644           fi
 645
 646           saved_LIBS="$LIBS"
 647
 648           AC_CHECK_LIB(sasl2, sasl_client_init,,
 649             AC_MSG_ERROR([could not find libsasl2]),)
 650
 651           MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_sasl.o"
 652           MUTTLIBS="$MUTTLIBS -lsasl2"
 653           LIBS="$saved_LIBS"
 654           AC_DEFINE(USE_SASL,1,
 655                   [ Define if want to use version 2 of the Cyrus SASL library. ])
 656           need_sasl=yes
 657         fi
 658         ])
 659 AM_CONDITIONAL(USE_SASL, test x$need_sasl = xyes)
 660
 661 AC_ARG_WITH(idn, AC_HELP_STRING([--with-idn=[PFX]], [Use GNU libidn for domain names]),
 662                  [
 663                   if test "$with_idn" != "no" ; then
 664                         if test "$with_idn" != "yes" ; then
 665                            CPPFLAGS="$CPPFLAGS -I$with_idn/include"
 666                            LDFLAGS="$LDFLAGS -L$with_idn/lib"
 667                         fi
 668                   fi
 669                  ]
 670 )
 671
 672 if test "x$with_idn" != "xno"; then
 673    AC_CHECK_LIB(idn, stringprep_check_version)
 674    AC_CHECK_FUNCS(idna_to_unicode_utf8_from_utf8 idna_to_unicode_8z8z)
 675    AC_CHECK_FUNCS(idna_to_ascii_from_utf8 idna_to_ascii_8z)
 676    AC_CHECK_FUNCS(idna_to_ascii_lz idna_to_ascii_from_locale)
 677 fi
 678
 679 dnl -- end socket --
 680
 681 AC_ARG_ENABLE(debug, AC_HELP_STRING([--enable-debug], [Enable debugging support]),
 682         [ if test x$enableval = xyes ; then
 683                 AC_DEFINE(DEBUG,1,[ Define to enable debugging info. ])
 684           fi
 685          ])
 686
 687 AC_ARG_ENABLE(flock, AC_HELP_STRING([--enable-flock], [Use flock() to lock files]),
 688         [if test $enableval = yes; then
 689                 AC_DEFINE(USE_FLOCK,1, [ Define to use flock() to lock mailboxes. ])
 690         fi])
 691
 692 mutt_cv_fcntl=yes
 693 AC_ARG_ENABLE(fcntl, AC_HELP_STRING([--disable-fcntl], [Do NOT use fcntl() to lock files]),
 694         [if test $enableval = no; then mutt_cv_fcntl=no; fi])
 695
 696 if test $mutt_cv_fcntl = yes; then
 697         AC_DEFINE(USE_FCNTL,1, [ Define to use fcntl() to lock folders. ])
 698 fi
 699
 700 dnl This may look cumbersome -- please keep it that way, so we can
 701 dnl quickly change the default to "yes" again.
 702 mutt_cv_inodesort=no
 703 AC_ARG_ENABLE(inodesort,  AC_HELP_STRING([--enable-inodesort], [Read files in maildir folders sorted by inode.]),
 704        [if test x$enableval = xyes ; then mutt_cv_inodesort=yes; fi])
 705
 706 if test $mutt_cv_inodesort = yes; then
 707         AC_DEFINE(USE_INODESORT, 1, [ Define to sort files in a maildir by inode number. ])
 708 fi
 709
 710 mutt_cv_warnings=yes
 711 AC_ARG_ENABLE(warnings, AC_HELP_STRING([--disable-warnings], [Turn off compiler warnings (not recommended)]),
 712 [if test $enableval = no; then
 713         mutt_cv_warnings=no
 714 fi])
 715
 716 if test x$GCC = xyes -a $mutt_cv_warnings = yes; then
 717         CFLAGS="-Wall -pedantic $CFLAGS"
 718 fi
 719
 720 AC_ARG_ENABLE(nfs-fix, AC_HELP_STRING([--enable-nfs-fix], [Work around an NFS with broken attributes caching]),
 721         [if test x$enableval = xyes; then
 722                 AC_DEFINE(NFS_ATTRIBUTE_HACK,1,
 723                   [Define if you have problems with mutt not detecting
 724                    new/old mailboxes over NFS.  Some NFS implementations
 725                    incorrectly cache the attributes of small files.])
 726         fi])
 727
 728 AC_ARG_ENABLE(buffy-size, AC_HELP_STRING([--enable-buffy-size], [Use file size attribute instead of access time]),
 729         [if test x$enableval = xyes; then
 730                 AC_DEFINE(BUFFY_SIZE,1,[ Define to enable the "buffy_size" feature. ])
 731         fi])
 732
 733 AC_ARG_ENABLE(mailtool, AC_HELP_STRING([--enable-mailtool], [Enable Sun mailtool attachments support ]),
 734         [if test x$enableval = xyes; then
 735                 AC_DEFINE(SUN_ATTACHMENT,1,[ Define to enable Sun mailtool attachments support. ])
 736         fi])
 737
 738 AC_ARG_ENABLE(compressed, [  --enable-compressed        Enable compressed folders support ],
 739         [if test x$enableval = xyes; then
 740                 AC_DEFINE(USE_COMPRESSED)
 741         fi])
 742
 743 AC_ARG_ENABLE(locales-fix, AC_HELP_STRING([--enable-locales-fix], [The result of isprint() is unreliable ]),
 744         [if test x$enableval = xyes; then
 745                 AC_DEFINE(LOCALES_HACK,1,[ Define if the result of isprint() is unreliable. ])
 746         fi])
 747
 748 AC_ARG_WITH(exec-shell, AC_HELP_STRING([--with-exec-shell=SHELL], [Specify alternate shell (ONLY if /bin/sh is broken)]),
 749         [if test $withval != yes; then
 750                 AC_DEFINE_UNQUOTED(EXECSHELL, "$withval",
 751                  [program to use for shell commands])
 752          else
 753                 AC_DEFINE_UNQUOTED(EXECSHELL, "/bin/sh")
 754         fi],
 755         [AC_DEFINE_UNQUOTED(EXECSHELL, "/bin/sh")])
 756
 757 dnl -- start cache --
 758 AC_ARG_ENABLE(hcache, AC_HELP_STRING([--enable-hcache], [Enable header caching]),
 759 [if test x$enableval = xyes; then
 760     AC_DEFINE(USE_HCACHE, 1, [Enable header caching])
 761
 762     OLDCPPFLAGS="$CPPFLAGS"
 763     OLDLIBS="$LIBS"
 764
 765     need_md5="yes"
 766
 767     ac_prefer_qdbm=yes
 768     AC_ARG_WITH(qdbm, AC_HELP_STRING([--without-qdbm], [Don't use qdbm even if it is available]),
 769         ac_prefer_qdbm=$withval)
 770     if test x$ac_prefer_qdbm != xno; then
 771         ac_cv_vlopen=no
 772         QDBM_DIRS="$mutt_cv_prefix /usr/local /usr"
 773         AC_MSG_CHECKING([for vlopen])
 774         for d in $QDBM_DIRS; do
 775           if test x$ac_cv_vlopen = xno && test -d "$d/include" && test -d "$d/lib"; then
 776             QDBM_INC="-I$d/include"
 777             QDBM_LIB="-L$d/lib"
 778             CPPFLAGS="$OLDCPPFLAGS $QDBM_INC"
 779             LIBS="$OLDLIBS $QDBM_LIB -lqdbm"
 780             AC_TRY_LINK([#include <villa.h>],[vlopen(0,0,0);],[ac_cv_vlopen=yes])
 781           fi
 782         done
 783         if test x$ac_cv_vlopen = xyes; then
 784           AC_MSG_RESULT(yes)
 785         else
 786           AC_MSG_RESULT(no)
 787         fi
 788     fi
 789
 790     ac_prefer_gdbm=yes
 791     AC_ARG_WITH(gdbm, AC_HELP_STRING([--without-gdbm], [Don't use gdbm even if it is available]),
 792         ac_prefer_gdbm=$withval)
 793     if test x$ac_prefer_gdbm != xno -a x$ac_cv_vlopen != xyes; then
 794         ac_cv_gdbmopen=no
 795         GDBM_DIRS="$mutt_cv_prefix /usr/local /usr"
 796         AC_MSG_CHECKING([for gdbm_open])
 797         for d in $GDBM_DIRS; do
 798           if test x$ac_cv_gdbmopen = xno && test -d "$d/include" && test -d "$d/lib"; then
 799             GDBM_INC="-I$d/include"
 800             GDBM_LIB="-L$d/lib"
 801             CPPFLAGS="$OLDCPPFLAGS $GDBM_INC"
 802             LIBS="$OLDLIBS $GDBM_LIB -lgdbm"
 803             AC_TRY_LINK([#include <gdbm.h>],[gdbm_open(0,0,0,0,0);],[ac_cv_gdbmopen=yes])
 804           fi
 805         done
 806         if test x$ac_cv_gdbmopen = xyes; then
 807           AC_MSG_RESULT(yes)
 808         else
 809           AC_MSG_RESULT(no)
 810         fi
 811     fi
 812
 813     ac_bdb_prefix=yes
 814     AC_ARG_WITH(bdb, AC_HELP_STRING([--with-bdb[=DIR]], [Use BerkeleyDB4 if gdbm is not available ]),
 815         ac_bdb_prefix=$withval)
 816     if test x$ac_bdb_prefix != xno -a x$ac_cv_gdbmopen != xyes -a x$ac_cv_vlopen != xyes; then
 817         test x$ac_bdb_prefix = xyes && ac_bdb_prefix="$mutt_cv_prefix /opt/csw/bdb4 /opt /usr/local /usr"
 818         for d in $ac_bdb_prefix; do
 819             bdbpfx="$bdbpfx $d"
 820             for v in BerkeleyDB.4.3 BerkeleyDB.4.2 BerkeleyDB.4.1; do
 821                 bdbpfx="$bdbpfx $d/$v"
 822             done
 823         done
 824         BDB_VERSIONS="db-4 db4 db-4.3 db4.3 db43 db-4.2 db4.2 db42 db-4.1 db4.1 db41 db ''"
 825         AC_MSG_CHECKING([for BerkeleyDB > 4.0])
 826         for d in $bdbpfx; do
 827             BDB_INCLUDE_DIR=""
 828             BDB_LIB_DIR=""
 829             for v in / $BDB_VERSIONS; do
 830                 if test -r "$d/include/$v/db.h"; then
 831                     BDB_INCLUDE_DIR="$d/include/$v"
 832                     if test -d "$d/lib/$v"; then
 833                         BDB_LIB_DIR="$d/lib/$v"
 834                         for l in `echo $BDB_VERSIONS`; do
 835                             CPPFLAGS="-I$BDB_INCLUDE_DIR $OLDCPPFLAGS"
 836                             LIBS="$OLDLIBS -L$BDB_LIB_DIR -l$l"
 837                             AC_TRY_LINK([
 838                                 #include <stdlib.h>
 839                                 #include <db.h>
 840                             ],[
 841                                 DB *db = NULL;
 842                                 db->open(db,NULL,NULL,NULL,0,0,0);
 843                             ],[
 844                                 ac_cv_dbcreate=yes
 845                                 BDB_LIB="$l"
 846                                 break
 847                             ])
 848                         done
 849                         test x$ac_cv_dbcreate = xyes && break
 850                     fi
 851                 fi
 852             done
 853             test x$BDB_LIB != x && break
 854         done
 855         if test x$ac_cv_dbcreate = xyes; then
 856             AC_MSG_RESULT(yes)
 857         else
 858             AC_MSG_RESULT(no)
 859         fi
 860     fi
 861
 862     if test x$ac_cv_vlopen = xyes; then
 863         CPPFLAGS="$OLDCPPFLAGS $QDBM_INC"
 864         LIBS="$OLDLIBS $QDBM_LIB -lqdbm"
 865         AC_DEFINE(HAVE_QDBM, 1, [QDBM Support])
 866     elif test x$ac_cv_gdbmopen = xyes; then
 867         CPPFLAGS="$OLDCPPFLAGS $GDBM_INC"
 868         LIBS="$OLDLIBS $GDBM_LIB -lgdbm";
 869         AC_DEFINE(HAVE_GDBM, 1, [GDBM Support])
 870     elif test x$ac_cv_dbcreate = xyes; then
 871         CPPFLAGS="-I$BDB_INCLUDE_DIR $OLDCPPFLAGS"
 872         LIBS="$OLDLIBS -L$BDB_LIB_DIR -l$BDB_LIB"
 873         AC_DEFINE(HAVE_DB4, 1, [Sleepycat DB4 Support])
 874     else
 875         AC_MSG_ERROR([You need one of: QDBM, GDBM or Sleepycat DB4 for --enable-hcache])
 876     fi
 877 fi])
 878 dnl -- end cache --
 879
 880 AC_SUBST(MUTTLIBS)
 881 AC_SUBST(MUTT_LIB_OBJECTS)
 882 AC_SUBST(LIBIMAP)
 883 AC_SUBST(LIBIMAPDEPS)
 884 AC_SUBST(LIBPOP)
 885 AC_SUBST(LIBPOPDEPS)
 886 AC_SUBST(LIBNNTP)
 887 AC_SUBST(LIBNNTPDEPS)
 888
 889 dnl -- iconv/gettext --
 890
 891 AC_ARG_ENABLE(iconv, AC_HELP_STRING([--disable-iconv], [Disable iconv support]),
 892         [if test x$enableval = xno ; then
 893                 am_cv_func_iconv=no
 894         fi
 895 ])
 896
 897 MUTT_AM_GNU_GETTEXT
 898
 899 if test "$am_cv_func_iconv" != "yes"
 900 then
 901   AC_MSG_WARN([Configuring without iconv support. See INSTALL for details])
 902 else
 903
 904 AC_CHECK_HEADERS(iconv.h,
 905         [AC_MSG_CHECKING(whether iconv.h defines iconv_t)
 906          AC_EGREP_HEADER([typedef.*iconv_t],iconv.h,
 907                 [AC_MSG_RESULT(yes)
 908                  AC_DEFINE(HAVE_ICONV_T_DEF, 1,
 909                         [Define if <iconv.h> defines iconv_t.])],
 910                  AC_MSG_RESULT(no))])
 911
 912 dnl (1) Some implementations of iconv won't convert from UTF-8 to UTF-8.
 913 dnl (2) In glibc-2.1.2 and earlier there is a bug that messes up ob and
 914 dnl     obl when args 2 and 3 are 0 (fixed in glibc-2.1.3).
 915 AC_CACHE_CHECK([whether this iconv is good enough], mutt_cv_iconv_good,
 916         mutt_save_LIBS="$LIBS"
 917         LIBS="$LIBS $LIBICONV"
 918         AC_TRY_RUN([
 919 #include <iconv.h>
 920 int main()
 921 {
 922   iconv_t cd;
 923 changequote(, )dnl
 924   char buf[4];
 925 changequote([, ])dnl
 926   char *ob;
 927   size_t obl;
 928   ob = buf, obl = sizeof(buf);
 929   return ((cd = iconv_open("UTF-8", "UTF-8")) != (iconv_t)(-1) &&
 930           (iconv(cd, 0, 0, &ob, &obl) ||
 931            !(ob == buf && obl == sizeof(buf)) ||
 932            iconv_close(cd)));
 933 }
 934                 ],
 935                 mutt_cv_iconv_good=yes,
 936                 mutt_cv_iconv_good=no,
 937                 mutt_cv_iconv_good=yes)
 938         LIBS="$mutt_save_LIBS")
 939 if test "$mutt_cv_iconv_good" = no; then
 940   AC_MSG_ERROR(Try using libiconv instead)
 941 fi
 942
 943 dnl This is to detect implementations such as the one in glibc-2.1,
 944 dnl which always convert exactly but return the number of characters
 945 dnl converted instead of the number converted inexactly.
 946 AC_CACHE_CHECK([whether iconv is non-transcribing], mutt_cv_iconv_nontrans,
 947         mutt_save_LIBS="$LIBS"
 948         LIBS="$LIBS $LIBICONV"
 949         AC_TRY_RUN([
 950 #include <iconv.h>
 951 #include <string.h>
 952 int main()
 953 {
 954   iconv_t cd;
 955   const char *ib;
 956   char *ob;
 957   size_t ibl, obl;
 958   const char *s = "\304\211";
 959 changequote(, )dnl
 960   char t[3];
 961 changequote([, ])dnl
 962   ib = s, ibl = 2, ob = t, obl = 3;
 963   return ((cd = iconv_open("UTF-8", "UTF-8")) == (iconv_t)(-1) ||
 964           iconv(cd, &ib, &ibl, &ob, &obl));
 965 }
 966                 ],
 967                 mutt_cv_iconv_nontrans=no,
 968                 mutt_cv_iconv_nontrans=yes,
 969                 mutt_cv_iconv_nontrans=no)
 970         LIBS="$mutt_save_LIBS")
 971 if test "$mutt_cv_iconv_nontrans" = yes; then
 972   AC_DEFINE(ICONV_NONTRANS, 1)
 973 else
 974   AC_DEFINE(ICONV_NONTRANS, 0)
 975 fi
 976
 977 CPPFLAGS="$CPPFLAGS -I\$(top_srcdir)/intl"
 978
 979 if test "$BUILD_INCLUDED_LIBINTL" = "yes"; then
 980   AC_DEFINE(HAVE_BIND_TEXTDOMAIN_CODESET,1,
 981           [ Define if your gettext has bind_textdomain_codeset. ])
 982 else
 983   AC_CHECK_FUNCS(bind_textdomain_codeset)
 984 fi
 985
 986 fi # libiconv
 987
 988 dnl -- locales --
 989
 990 AC_CHECK_HEADERS(wchar.h)
 991
 992 AC_CACHE_CHECK([for wchar_t], mutt_cv_wchar_t,
 993         AC_TRY_COMPILE([
 994 #include <stddef.h>
 995 #include <stdlib.h>
 996 #ifdef HAVE_WCHAR_H
 997 #include <wchar.h>
 998 #endif
 999                 ],
1000                 [ wchar_t wc; return 0; ],
1001                 mutt_cv_wchar_t=yes,
1002                 mutt_cv_wchar_t=no))
1003
1004 if test "$mutt_cv_wchar_t" = no; then
1005         AC_DEFINE(wchar_t,int,[ Define to 'int' if system headers don't define. ])
1006 fi
1007
1008 AC_CACHE_CHECK([for wint_t], mutt_cv_wint_t,
1009         AC_TRY_COMPILE([
1010 #include <stddef.h>
1011 #include <stdlib.h>
1012 #ifdef HAVE_WCHAR_H
1013 #include <wchar.h>
1014 #endif
1015                 ],
1016                 [ wint_t wc; return 0; ],
1017                 mutt_cv_wint_t=yes,
1018                 mutt_cv_wint_t=no))
1019
1020 if test "$mutt_cv_wint_t" = no; then
1021         AC_DEFINE(wint_t,int,[ Define to 'int' if system headers don't define. ])
1022 fi
1023
1024 AC_CHECK_HEADERS(wctype.h)
1025 AC_CHECK_FUNCS(iswalnum iswalpha  iswcntrl iswdigit)
1026 AC_CHECK_FUNCS(iswgraph iswlower iswprint iswpunct iswspace iswupper)
1027 AC_CHECK_FUNCS(iswxdigit towupper towlower)
1028
1029 AC_CACHE_CHECK([for mbstate_t], mutt_cv_mbstate_t,
1030         AC_TRY_COMPILE([
1031 #include <stddef.h>
1032 #include <stdlib.h>
1033 #ifdef HAVE_WCHAR_H
1034 #include <wchar.h>
1035 #endif
1036                 ],
1037                 [ mbstate_t s; return 0; ],
1038                 mutt_cv_mbstate_t=yes,
1039                 mutt_cv_mbstate_t=no))
1040
1041 if test "$mutt_cv_mbstate_t" = no; then
1042         AC_DEFINE(mbstate_t,int,[ Define to 'int' if system headers don't define. ])
1043 fi
1044
1045 wc_funcs=maybe
1046 AC_ARG_WITH(wc-funcs, AC_HELP_STRING([--without-wc-funcs], [Do not use the system's wchar_t functions]),
1047         wc_funcs=$withval)
1048
1049 if test "$wc_funcs" != yes -a "$wc_funcs" != no; then
1050         AC_CACHE_CHECK([for wchar_t functions], mutt_cv_wc_funcs,
1051                 mutt_cv_wc_funcs=no
1052                 AC_TRY_LINK([
1053 #define _XOPEN_SOURCE 1
1054 #include <stddef.h>
1055 #include <stdlib.h>
1056 #ifdef HAVE_WCTYPE_H
1057 #include <wctype.h>
1058 #endif
1059 #ifdef HAVE_WCHAR_H
1060 #include <wchar.h>
1061 #endif],
1062                         [mbrtowc(0, 0, 0, 0); wctomb(0, 0); wcwidth(0);
1063         iswprint(0); iswspace(0); towlower(0); towupper(0); iswalnum(0)],
1064                         mutt_cv_wc_funcs=yes))
1065         wc_funcs=$mutt_cv_wc_funcs
1066 fi
1067
1068 if test $wc_funcs = yes; then
1069         AC_DEFINE(HAVE_WC_FUNCS,1,[ Define if you are using the system's wchar_t functions. ])
1070 fi
1071
1072 AC_CACHE_CHECK([for nl_langinfo and CODESET], mutt_cv_langinfo_codeset,
1073   [AC_TRY_LINK([#include <langinfo.h>],
1074     [char* cs = nl_langinfo(CODESET);],
1075     mutt_cv_langinfo_codeset=yes,
1076     mutt_cv_langinfo_codeset=no)])
1077 if test $mutt_cv_langinfo_codeset = yes; then
1078   AC_DEFINE(HAVE_LANGINFO_CODESET,1,[ Define if you have <langinfo.h> and nl_langinfo(CODESET). ])
1079 fi
1080
1081 AC_CACHE_CHECK([for nl_langinfo and YESEXPR], mutt_cv_langinfo_yesexpr,
1082   [AC_TRY_LINK([#include <langinfo.h>],
1083     [char* cs = nl_langinfo(YESEXPR);],
1084     mutt_cv_langinfo_yesexpr=yes,
1085     mutt_cv_langinfo_yesexpr=no)])
1086 if test $mutt_cv_langinfo_yesexpr = yes; then
1087   AC_DEFINE(HAVE_LANGINFO_YESEXPR,1,[ Define if you have <langinfo.h> and nl_langinfo(YESEXPR). ])
1088 fi
1089
1090 dnl -- libesmtp --
1091 MUTT_AM_LIBESMTP
1092 if test x$use_libesmtp = xyes; then
1093     CFLAGS="$CFLAGS $mutt_libesmtp_cflags"
1094     MUTTLIBS="$MUTTLIBS $mutt_libesmtp_libs"
1095     MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_libesmtp.o"
1096
1097     AC_DEFINE(USE_LIBESMTP,
1098               1,
1099               [Define to enable the use of libesmtp])
1100 fi
1101 dnl -- end libesmtp --
1102
1103 dnl -- sgml tools --
1104
1105 dnl Documentation tools
1106 have_openjade="no"
1107 AC_PATH_PROG([OSPCAT], [ospcat], [none])
1108 if test "$OSPCAT" != "none"
1109 then
1110   AC_MSG_CHECKING([for openjade docbook stylesheets])
1111   dslosfile=`ospcat --public-id="-//Norman Walsh//DOCUMENT DocBook Print Stylesheet//EN"`
1112   DSLROOT=`echo $dslosfile | sed -n -e "s/.*SOIBASE='\(@<:@^'@:>@*\)\/catalog'.*/\1/p"`
1113   # ospcat may spit out an absolute path without an SOIBASE
1114   if test -z "$DSLROOT"
1115   then
1116     DSLROOT=`echo $dslosfile | sed -e 's|<OSFILE>\(.*\)/print/docbook.dsl|\1|'`
1117   fi
1118   if test -f $DSLROOT/print/docbook.dsl
1119   then
1120     AC_MSG_RESULT([in $DSLROOT])
1121     have_openjade="yes"
1122   else
1123     AC_MSG_RESULT([not found: PDF documentation will not be built.])
1124   fi
1125 fi
1126 AC_SUBST(DSLROOT)
1127
1128 AC_MSG_CHECKING([for elinks])
1129 AC_PATH_PROG([HTML2TXT_CMD], [elinks], [none])
1130 if test x"$HTML2TXT_CMD" = x"none"
1131 then
1132   AC_MSG_CHECKING([for lynx])
1133   AC_PATH_PROG([HTML2TXT_CMD], [lynx], [none])
1134 fi
1135 if test x"$HTML2TXT_CMD" = x"none"
1136 then
1137   AC_MSG_CHECKING([for w3m])
1138   AC_PATH_PROG([HTML2TXT_CMD], [w3m], [none])
1139 fi
1140 case "$HTML2TXT_CMD" in
1141   *elinks*)
1142     HTML2TXT_CMD="$HTML2TXT_CMD -dump -no-numbering -no-references \$^ > \$@"
1143     ;;
1144   *lynx*)
1145     HTML2TXT_CMD="$HTML2TXT_CMD -dump -nolist -with_backspaces \$^ > \$@"
1146     ;;
1147   *w3m*)
1148     HTML2TXT_CMD="$HTML2TXT_CMD -dump \$^ > \$@"
1149     ;;
1150   *)
1151     HTML2TXT_CMD="true"
1152     ;;
1153 esac
1154 AC_SUBST(HTML2TXT_CMD)
1155
1156 AC_MSG_CHECKING([for tidy])
1157 AC_PATH_PROG([HTMLCLEAN_CMD], [tidy], [none])
1158
1159 if test x"$HTMLCLEAN_CMD" != x"none"
1160 then
1161   HTMLCLEAN_CMD="$HTMLCLEAN_CMD -q -i -m -asxml -utf8 "
1162 else
1163   HTMLCLEAN_CMD="echo "
1164 fi
1165 AC_SUBST(HTMLCLEAN_CMD)
1166
1167 AC_OUTPUT(Makefile intl/Makefile m4/Makefile
1168         po/Makefile.in doc/Makefile contrib/Makefile
1169         muttbug.sh
1170         lib/Makefile
1171         imap/Makefile
1172         pop/Makefile
1173         nntp/Makefile
1174         Muttngrc.head
1175         doc/instdoc.sh)