configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl !!! WHEN ADDING NEW CONFIGURE TESTS, PLEASE ADD CODE TO MAIN.C !!!
   4 dnl !!! TO DUMP THEIR RESULTS WHEN MUTT -V IS CALLED            !!!
   5
   6 AC_PREREQ([2.50])
   7 AC_INIT([mutt.h])
   8 AM_CONFIG_HEADER(config.h)
   9
  10 mutt_cv_version=`cat $srcdir/VERSION`
  11
  12 AM_INIT_AUTOMAKE(muttng, $mutt_cv_version)
  13 dnl AC_GNU_SOURCE
  14
  15 ifdef([AC_LIBOBJ], , [define([AC_LIBOBJ], [LIB[]OBJS="$LIBOBJS $1.o"])])
  16
  17 ALL_LINGUAS="de ru it es uk fr pl nl cs id sk ko el zh_TW zh_CN pt_BR eo gl sv da lt tr ja hu et ca bg"
  18
  19 AC_CANONICAL_HOST
  20
  21 AC_MSG_CHECKING([for prefix])
  22 if test x$prefix = xNONE; then
  23         mutt_cv_prefix=$ac_default_prefix
  24 else
  25         mutt_cv_prefix=$prefix
  26 fi
  27 AC_MSG_RESULT($mutt_cv_prefix)
  28
  29 AC_PROG_CC
  30 AC_ISC_POSIX
  31 AM_C_PROTOTYPES
  32 if test "x$U" != "x"; then
  33   AC_MSG_ERROR(Compiler not ANSI compliant)
  34 fi
  35 AC_PROG_CPP
  36 AC_PROG_MAKE_SET
  37 AC_PROG_INSTALL
  38 AC_PROG_RANLIB
  39 AC_CHECK_TOOL(AR, ar, ar)
  40
  41 AC_C_INLINE
  42 AC_C_CONST
  43
  44 AC_SYS_LARGEFILE
  45
  46 AC_PATH_PROG(DBX, dbx, no)
  47 AC_PATH_PROG(GDB, gdb, no)
  48 AC_PATH_PROG(SDB, sdb, no)
  49
  50 if test $GDB != no ; then
  51         DEBUGGER=$GDB
  52 elif test $DBX != no ; then
  53         DEBUGGER=$DBX
  54 elif test $SDB != no ; then
  55         DEBUGGER=$SDB
  56 else
  57         DEBUGGER=no
  58 fi
  59
  60 AC_SUBST([DEBUGGER])
  61
  62 AH_TEMPLATE([sig_atomic_t],
  63             [/* Define to `int' if <signal.h> doesn't define.])
  64 AH_TEMPLATE([HAVE_START_COLOR],
  65             [Define if you have start_color, as a function or macro.])
  66 AH_TEMPLATE([HAVE_TYPEAHEAD],
  67             [Define if you have typeahead, as a function or macro.])
  68 AH_TEMPLATE([HAVE_BKGDSET],
  69             [Define if you have bkgdset, as a function or macro.])
  70 AH_TEMPLATE([HAVE_CURS_SET],
  71             [Define if you have curs_set, as a function or macro.])
  72 AH_TEMPLATE([HAVE_META],
  73             [Define if you have meta, as a function or macro.])
  74 AH_TEMPLATE([HAVE_USE_DEFAULT_COLORS],
  75             [Define if you have use_default_colors, as a function or macro.])
  76 AH_TEMPLATE([HAVE_RESIZETERM],
  77             [Define if you have resizeterm, as a function or macro.])
  78 AH_TEMPLATE([SIG_ATOMIC_VOLATILE_T],
  79             [Some systems declare sig_atomic_t as volatile, some others -- no.
  80              This define will have value `sig_atomic_t' or
  81              `volatile sig_atomic_t' accordingly.])
  82 AH_TEMPLATE([ICONV_NONTRANS],
  83             [Define as 1 if iconv() only converts exactly and we should treat
  84              all return values other than (size_t)(-1) as equivalent.])
  85
  86 MUTT_C99_INTTYPES
  87
  88 ac_aux_path_sendmail=/usr/sbin:/usr/lib
  89 AC_PATH_PROG(SENDMAIL, sendmail, /usr/sbin/sendmail, $PATH:$ac_aux_path_sendmail)
  90 AC_DEFINE_UNQUOTED(SENDMAIL,"$ac_cv_path_SENDMAIL",[ Where to find sendmail on your system. ])
  91
  92 OPS='$(srcdir)/OPS'
  93
  94         AC_ARG_ENABLE(gpgme, AC_HELP_STRING([--enable-gpgme], [Enable GPGME support]),
  95         [       if test x$enableval = xyes; then
  96                         have_gpgme=yes
  97                 fi
  98         ])
  99         AC_ARG_WITH(gpgme-prefix, AC_HELP_STRING([--with-gpgme-prefix=PFX], [prefix where GPGME is installed (optional)]),
 100         gpgme_config_prefix="$withval", gpgme_config_prefix="")
 101
 102         if test x$have_gpgme = xyes; then
 103                 if test x$gpgme_config_prefix != x; then
 104                         GPGME_CONFIG="$gpgme_config_prefix/bin/gpgme-config"
 105                 else
 106                         AC_PATH_PROG(GPGME_CONFIG, gpgme-config, no)
 107                 fi
 108                 if test "x$GPGME_CONFIG" = "xno"; then
 109                         AC_MSG_ERROR([GPGME not found])
 110                 else
 111                         LIBGPGME_CFLAGS=`$GPGME_CONFIG --cflags`
 112                         LIBGPGME_LIBS=`$GPGME_CONFIG --libs`
 113       MUTTLIBS="$MUTTLIBS $LIBGPGME_LIBS"
 114                         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS crypt-gpgme.o crypt-mod-pgp-gpgme.o crypt-mod-smime-gpgme.o"
 115                         AC_DEFINE(CRYPT_BACKEND_GPGME, 1,
 116                                   [Defined, if GPGME support is enabled])
 117                 fi
 118         fi
 119         AC_SUBST(LIBGPGME_CFLAGS)
 120         AC_SUBST(LIBGPGME_LIBS)
 121
 122         AC_ARG_ENABLE(pgp, AC_HELP_STRING([--disable-pgp], [Disable PGP support]),
 123         [       if test x$enableval = xno ; then
 124                         have_pgp=no
 125                 fi
 126         ])
 127
 128         if test x$have_pgp != xno ; then
 129                 AC_DEFINE(CRYPT_BACKEND_CLASSIC_PGP,1,
 130                     [ Define if you want classic PGP support. ])
 131                 PGPAUX_TARGET="pgpringng\$(EXEEXT) pgpewrapng\$(EXEEXT)"
 132                 MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS pgp.o pgpinvoke.o pgpkey.o pgplib.o gnupgparse.o pgpmicalg.o pgppacket.o crypt-mod-pgp-classic.o"
 133         fi
 134
 135         AC_ARG_ENABLE(smime, AC_HELP_STRING([--disable-smime], [Disable SMIME support]),
 136         [       if test x$enableval = xno ; then
 137                         have_smime=no
 138                 fi
 139         ])
 140
 141         if test x$have_smime != xno ; then
 142                 AC_DEFINE(CRYPT_BACKEND_CLASSIC_SMIME,1,
 143                   [ Define if you want clasic S/MIME support. ])
 144                 MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS smime.o crypt-mod-smime-classic.o"
 145                 SMIMEAUX_TARGET="smime_keysng"
 146         fi
 147
 148         AC_ARG_WITH(mixmaster, AC_HELP_STRING([--with-mixmaster[=PATH]], [Include Mixmaster support]),
 149                 [if test -x "$withval" ; then
 150                         MIXMASTER="$withval"
 151                  else
 152                         MIXMASTER="mixmaster"
 153                  fi
 154                  OPS="$OPS \$(srcdir)/OPS.MIX"
 155                  MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS remailer.o"
 156                  AC_DEFINE_UNQUOTED(MIXMASTER,"$MIXMASTER",
 157                          [ Where to find mixmaster on your system. ])
 158                 ])
 159
 160 # We now require all OPS
 161 OPS="$OPS \$(srcdir)/OPS.PGP \$(srcdir)/OPS.SMIME \$(srcdir)/OPS.CRYPT "
 162 AC_SUBST([OPS])
 163
 164
 165 AC_SUBST(PGPAUX_TARGET)
 166 AC_SUBST(SMIMEAUX_TARGET)
 167
 168 AC_PATH_PROG(ISPELL, ispell, no)
 169 if test $ISPELL != no; then
 170         AC_DEFINE_UNQUOTED(ISPELL,"$ISPELL",[ Where to find ispell on your system. ])
 171 fi
 172
 173 AC_ARG_WITH(slang, AC_HELP_STRING([--with-slang[=DIR]], [Use S-Lang instead of ncurses]),
 174         [AC_CACHE_CHECK([if this is a BSD system], mutt_cv_bsdish,
 175                 [AC_TRY_RUN([#include <sys/param.h>
 176
 177 main ()
 178 {
 179 #ifdef BSD
 180         exit (0);
 181 #else
 182         exit (1);
 183 #endif
 184 }],
 185                         mutt_cv_bsdish=yes,
 186                         mutt_cv_bsdish=no,
 187                         mutt_cv_bsdish=no)])
 188
 189         AC_MSG_CHECKING(for S-Lang)
 190         if test $withval = yes; then
 191                 if test -d $srcdir/../slang; then
 192                         mutt_cv_slang=$srcdir/../slang/src
 193                         CFLAGS="$CFLAGS -I${mutt_cv_slang}"
 194                         LDFLAGS="$LDFLAGS -L${mutt_cv_slang}/objs"
 195                 else
 196                         if test -d $mutt_cv_prefix/include/slang; then
 197                                 CFLAGS="$CFLAGS -I$mutt_cv_prefix/include/slang"
 198                         elif test -d /usr/include/slang; then
 199                                 CFLAGS="$CFLAGS -I/usr/include/slang"
 200                         fi
 201                         mutt_cv_slang=yes
 202                 fi
 203         else
 204                 dnl ---Check to see if $withval is a source directory
 205                 if test -f $withval/src/slang.h; then
 206                         mutt_cv_slang=$withval/src
 207                         CFLAGS="$CFLAGS -I${mutt_cv_slang}"
 208                         LDFLAGS="$LDFLAGS -L${mutt_cv_slang}/objs"
 209                 else
 210                         dnl ---Must be installed somewhere
 211                         mutt_cv_slang=$withval
 212                         if test -d $withval/include/slang; then
 213                                 CFLAGS="$CFLAGS -I${withval}/include/slang"
 214                         elif test -d $withval/include; then
 215                                 CFLAGS="$CFLAGS -I${withval}/include"
 216                         fi
 217                         LDFLAGS="$LDFLAGS -L${withval}/lib"
 218                 fi
 219         fi
 220         AC_MSG_RESULT($mutt_cv_slang)
 221         if test $mutt_cv_bsdish = yes; then
 222                 AC_CHECK_LIB(termlib, main)
 223         fi
 224         AC_DEFINE(USE_SLANG_CURSES,1,
 225                 [ Define if you compile with SLang instead of curses/ncurses. ])
 226         AC_DEFINE(HAVE_COLOR,1,[ Define if your curses library supports color. ])
 227         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS resize.o"
 228
 229         dnl --- now that we've found it, check the link
 230
 231         AC_CHECK_LIB(slang, SLtt_get_terminfo,
 232                 [MUTTLIBS="$MUTTLIBS -lslang -lm"],
 233                 [AC_MSG_ERROR(unable to compile.  check config.log)], -lm)
 234
 235         ],
 236
 237         [mutt_cv_curses=/usr
 238         AC_ARG_WITH(curses, AC_HELP_STRING([--with-curses=DIR], [Where ncurses is installed]),
 239                 [if test $withval != yes; then
 240                         mutt_cv_curses=$withval
 241                 fi
 242                 if test x$mutt_cv_curses != x/usr; then
 243                         LDFLAGS="-L${mutt_cv_curses}/lib $LDFLAGS"
 244                         CPPFLAGS="$CPPFLAGS -I${mutt_cv_curses}/include"
 245                 fi])
 246
 247         AC_CHECK_FUNC(initscr,,[
 248         cf_ncurses="ncurses"
 249         for lib in ncursesw ncurses
 250         do
 251                 AC_CHECK_LIB($lib, waddnwstr, [cf_ncurses="$lib"; break])
 252         done
 253         AC_CHECK_LIB($cf_ncurses, initscr,
 254                 [MUTTLIBS="$MUTTLIBS -l$cf_ncurses"
 255                 if test x$mutt_cv_curses = x/usr -a -d /usr/include/ncurses; then
 256                         CPPFLAGS="$CPPFLAGS -I/usr/include/ncurses"
 257                 fi
 258
 259                 if test "$cf_ncurses" = ncursesw; then
 260                         AC_CHECK_HEADERS(ncursesw/ncurses.h,[cf_cv_ncurses_header="ncursesw/ncurses.h"])
 261                 else
 262                         AC_CHECK_HEADERS(ncurses.h,[cf_cv_ncurses_header="ncurses.h"])
 263                 fi],
 264
 265                 [CF_CURSES_LIBS])
 266                 ])
 267
 268         old_LIBS="$LIBS"
 269         LIBS="$LIBS $MUTTLIBS"
 270         CF_CHECK_FUNCDECLS([#include <${cf_cv_ncurses_header-curses.h}>],
 271                            [start_color typeahead bkgdset curs_set meta use_default_colors resizeterm])
 272         if test "$ac_cv_func_decl_start_color" = yes; then
 273                 AC_DEFINE(HAVE_COLOR,1,[ Define if your curses library supports color. ])
 274         fi
 275         if test "$ac_cv_func_decl_resizeterm" = yes; then
 276                 MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS resize.o"
 277         fi
 278         LIBS="$old_LIBS"
 279         ])
 280
 281 AC_HEADER_STDC
 282
 283 AC_CHECK_HEADERS(stdarg.h sys/ioctl.h ioctl.h sysexits.h)
 284 AC_CHECK_HEADERS(sys/time.h sys/resource.h)
 285 AC_CHECK_HEADERS(unix.h)
 286
 287 AC_CHECK_FUNCS(setrlimit getsid isctype)
 288
 289 AC_TYPE_SIGNAL
 290
 291 AC_MSG_CHECKING(for sig_atomic_t in signal.h)
 292 AC_EGREP_HEADER(sig_atomic_t,signal.h,
 293   [
 294     ac_cv_type_sig_atomic_t=yes;
 295     AC_EGREP_HEADER(volatile.*sig_atomic_t,
 296                     signal.h,
 297                     [
 298                         is_sig_atomic_t_volatile=yes;
 299                         AC_MSG_RESULT([yes, volatile])
 300                     ],
 301                     [
 302                         is_sig_atomic_t_volatile=no;
 303                         AC_MSG_RESULT([yes, non volatile])
 304                     ])
 305   ],
 306   [
 307     AC_MSG_RESULT(no)
 308     AC_CHECK_TYPE(sig_atomic_t, int)
 309     is_sig_atomic_t_volatile=no
 310   ])
 311 if test $is_sig_atomic_t_volatile = 'yes'
 312 then
 313     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, sig_atomic_t)
 314 else
 315     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, [volatile sig_atomic_t])
 316 fi
 317
 318 AC_DECL_SYS_SIGLIST
 319
 320 AC_TYPE_PID_T
 321 dnl AC_CHECK_TYPE(ssize_t, int)
 322
 323 AC_CHECK_FUNCS(fgetpos memmove setegid srand48 strerror)
 324
 325 AC_REPLACE_FUNCS(strcasecmp strdup)
 326
 327 AC_CHECK_FUNC(getopt)
 328 if test $ac_cv_func_getopt = yes; then
 329         AC_CHECK_HEADERS(getopt.h)
 330 fi
 331
 332 mutt_cv_snprintf=no
 333 SNPRINTFOBJS=""
 334 AC_CHECK_FUNCS(snprintf, , [mutt_cv_snprintf=yes])
 335 AC_CHECK_FUNCS(vsnprintf, , [mutt_cv_snprintf=yes])
 336 if test $mutt_cv_snprintf = yes; then
 337         AC_LIBOBJ(snprintf)
 338 fi
 339
 340 dnl SCO uses chsize() instead of ftruncate()
 341 AC_CHECK_FUNCS(ftruncate, , [AC_CHECK_LIB(x, chsize)])
 342
 343 dnl SCO has strftime() in libintl
 344 AC_CHECK_FUNCS(strftime, , [AC_CHECK_LIB(intl, strftime)])
 345
 346 dnl AIX may not have fchdir()
 347 AC_CHECK_FUNCS(fchdir, , [mutt_cv_fchdir=no])
 348
 349 AC_ARG_WITH(regex, AC_HELP_STRING([--with-regex], [Use the GNU regex library]),
 350         [mutt_cv_regex=yes],
 351         [AC_CHECK_FUNCS(regcomp, mutt_cv_regex=no, mutt_cv_regex=yes)])
 352
 353 if test $mutt_cv_regex = no ; then
 354 AC_CACHE_CHECK([whether your system's regexp library is completely broken],
 355         [mutt_cv_regex_broken],
 356         AC_TRY_RUN([
 357 #include <unistd.h>
 358 #include <regex.h>
 359 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
 360         mutt_cv_regex_broken=no, mutt_cv_regex_broken=yes, mutt_cv_regex_broken=yes))
 361         if test $mutt_cv_regex_broken = yes ; then
 362                 echo "Using the included GNU regex instead." >&AC_FD_MSG
 363                 mutt_cv_regex=yes
 364         fi
 365 fi
 366
 367 if test $mutt_cv_regex = yes; then
 368         AC_DEFINE(USE_GNU_REGEX,1,[ Define if you want to use the included regex.c. ])
 369         AC_LIBOBJ(regex)
 370 fi
 371
 372
 373 AC_ARG_WITH(homespool,
 374   AC_HELP_STRING([--with-homespool[=FILE]], [File in user's directory where new mail is spooled]), with_homespool=${withval})
 375 if test x$with_homespool != x; then
 376         if test $with_homespool = yes; then
 377                 with_homespool=mailbox
 378         fi
 379         AC_DEFINE_UNQUOTED(MAILPATH,"$with_homespool",[ Where new mail is spooled. ])
 380         AC_DEFINE(HOMESPOOL,1,
 381           [Is mail spooled to the user's home directory?  If defined,
 382            MAILPATH should be set to the filename of the spool mailbox
 383            relative the the home directory.
 384            use: configure --with-homespool=FILE])
 385         AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 386         mutt_cv_setgid=no
 387 else
 388         AC_ARG_WITH(mailpath, AC_HELP_STRING([--with-mailpath=DIR], [Directory where spool mailboxes are located]),
 389                 [mutt_cv_mailpath=$withval],
 390                 [ AC_CACHE_CHECK(where new mail is stored, mutt_cv_mailpath,
 391                         [mutt_cv_mailpath=no
 392                         if test -d /var/mail; then
 393                                 mutt_cv_mailpath=/var/mail
 394                         elif test -d /var/spool/mail; then
 395                                 mutt_cv_mailpath=/var/spool/mail
 396                         elif test -d /usr/spool/mail; then
 397                                 mutt_cv_mailpath=/usr/spool/mail
 398                         elif test -d /usr/mail; then
 399                                 mutt_cv_mailpath=/usr/mail
 400                         fi])
 401                 ])
 402         if test "$mutt_cv_mailpath" = no; then
 403                 AC_MSG_ERROR("Could not determine where new mail is stored.")
 404         fi
 405         AC_DEFINE_UNQUOTED(MAILPATH,"$mutt_cv_mailpath",[ Where new mail is spooled. ])
 406
 407         AC_CACHE_CHECK(if $mutt_cv_mailpath is world writable, mutt_cv_worldwrite, [AC_TRY_RUN([#include <sys/types.h>
 408 #include <sys/stat.h>
 409
 410 int main (int argc, char **argv)
 411 {
 412         struct stat s;
 413
 414         stat ("$mutt_cv_mailpath", &s);
 415         if (s.st_mode & S_IWOTH) exit (0);
 416         exit (1);
 417 }], mutt_cv_worldwrite=yes, mutt_cv_worldwrite=no, mutt_cv_worldwrite=no)])
 418
 419         mutt_cv_setgid=no
 420         if test $mutt_cv_worldwrite = yes; then
 421                 AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 422         else
 423
 424                 AC_CACHE_CHECK(if $mutt_cv_mailpath is group writable, mutt_cv_groupwrite, [AC_TRY_RUN([#include <sys/types.h>
 425 #include <sys/stat.h>
 426
 427 int main (int argc, char **argv)
 428 {
 429         struct stat s;
 430
 431         stat ("$mutt_cv_mailpath", &s);
 432         if (s.st_mode & S_IWGRP) exit (0);
 433         exit (1);
 434 }], mutt_cv_groupwrite=yes, mutt_cv_groupwrite=no, mutt_cv_groupwrite=no)])
 435
 436                 if test $mutt_cv_groupwrite = yes; then
 437                         AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 438                         AC_DEFINE(USE_SETGID,1,[ Define if mutt should run setgid "mail". ])
 439                         mutt_cv_setgid=yes
 440                 fi
 441         fi
 442 fi
 443
 444 AC_ARG_ENABLE(external_dotlock, AC_HELP_STRING([--enable-external-dotlock], [Force use of an external dotlock program]),
 445         [mutt_cv_external_dotlock="$enableval"])
 446
 447 if test "x$mutt_cv_setgid" = "xyes" || test "x$mutt_cv_fchdir" = "xno" \
 448         || test "x$mutt_cv_external_dotlock" = "xyes"
 449 then
 450         AC_DEFINE(DL_STANDALONE,1,[ Define if you want to use an external dotlocking program. ])
 451         DOTLOCK_TARGET="muttng_dotlock"
 452 else
 453         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS dotlock.o"
 454 fi
 455
 456 AC_SUBST(DOTLOCK_TARGET)
 457
 458
 459 AC_MSG_CHECKING(where to put the documentation)
 460 AC_ARG_WITH(docdir, AC_HELP_STRING([--with-docdir=PATH], [Specify where to put the documentation]),
 461         [mutt_cv_docdir=$withval],
 462         [mutt_cv_docdir="$mutt_cv_prefix/doc/muttng"])
 463 AC_MSG_RESULT($mutt_cv_docdir)
 464
 465 docdir=$mutt_cv_docdir
 466 AC_SUBST(docdir)
 467
 468 if test x$mutt_cv_setgid = xyes; then
 469         DOTLOCK_GROUP='mail'
 470         DOTLOCK_PERMISSION=2755
 471 else
 472         DOTLOCK_GROUP=''
 473         DOTLOCK_PERMISSION=755
 474 fi
 475 AC_SUBST(DOTLOCK_GROUP)
 476 AC_SUBST(DOTLOCK_PERMISSION)
 477
 478 AC_ARG_WITH(domain, AC_HELP_STRING([--with-domain=DOMAIN], [Specify your DNS domain name]),
 479         [if test $withval != yes; then
 480                 AC_DEFINE_UNQUOTED(DOMAIN,"$withval",[ Define your domain name. ])
 481         fi])
 482
 483 need_socket="no"
 484
 485 dnl -- socket dependencies --
 486
 487 AC_ARG_ENABLE(pop,  AC_HELP_STRING([--enable-pop], [Enable POP3 support]),
 488 [       if test x$enableval = xyes ; then
 489                 AC_DEFINE(USE_POP,1,[ Define if you want support for the POP3 protocol. ])
 490                 LIBPOP="-Lpop -lpop"
 491                 LIBPOPDEPS="\$(top_srcdir)/pop/pop.h pop/libpop.a"
 492                 need_socket="yes"
 493                 need_pop="yes"
 494                 need_md5="yes"
 495         fi
 496 ])
 497 AM_CONDITIONAL(BUILD_POP, test x$need_pop = xyes)
 498
 499 AC_ARG_ENABLE(imap, AC_HELP_STRING([--enable-imap], [Enable IMAP support]),
 500 [       if test x$enableval = xyes ; then
 501                 AC_DEFINE(USE_IMAP,1,[ Define if you want support for the IMAP protocol. ])
 502                 LIBIMAP="-Limap -limap"
 503                 LIBIMAPDEPS="\$(top_srcdir)/imap/imap.h imap/libimap.a"
 504                 need_imap="yes"
 505                 need_socket="yes"
 506                 need_md5="yes"
 507         fi
 508 ])
 509 AM_CONDITIONAL(BUILD_IMAP, test x$need_imap = xyes)
 510
 511 AC_ARG_ENABLE(nntp, [  --enable-nntp              Enable NNTP support],
 512 [       if test x$enableval = xyes ; then
 513                 AC_DEFINE(USE_NNTP)
 514                 LIBNNTP="-Lnntp -lnntp"
 515                 LIBNNTPDEPS="\$(top_srcdir)/nntp/nntp.h nntp/libnntp.a"
 516                 need_nntp="yes"
 517                 need_socket="yes"
 518         fi
 519 ])
 520 AM_CONDITIONAL(BUILD_NNTP, test x$need_nntp = xyes)
 521
 522 dnl -- end socket dependencies --
 523
 524 if test "$need_socket" = "yes"
 525 then
 526         AC_MSG_CHECKING([for socklen_t])
 527         AC_EGREP_HEADER(socklen_t, sys/socket.h, AC_MSG_RESULT([yes]),
 528                 AC_MSG_RESULT([no])
 529                 AC_DEFINE(socklen_t,int,
 530                         [ Define to 'int' if <sys/socket.h> doesn't have it. ]))
 531         AC_CHECK_FUNC(gethostent, , AC_CHECK_LIB(nsl, gethostent))
 532         AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt))
 533         AC_CHECK_FUNCS(getaddrinfo)
 534         AC_DEFINE(USE_SOCKET,1,
 535                 [ Include code for socket support. Set automatically if you enable POP3 or IMAP ])
 536         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS account.o mutt_socket.o mutt_tunnel.o"
 537 fi
 538
 539 dnl -- imap dependencies --
 540
 541 AC_ARG_WITH(gss, AC_HELP_STRING([--with-gss[=PFX]], [Compile in GSSAPI authentication for IMAP]),
 542     gss_prefix="$withval", gss_prefix="no")
 543 if test "$gss_prefix" != "no"
 544 then
 545   if test "$need_imap" = "yes"
 546   then
 547     MUTT_AM_PATH_GSSAPI(gss_prefix)
 548     AC_MSG_CHECKING(GSSAPI implementation)
 549     AC_MSG_RESULT($GSSAPI_IMPL)
 550     if test "$GSSAPI_IMPL" = "none"
 551     then
 552       AC_CACHE_SAVE
 553       AC_MSG_RESULT([GSSAPI libraries not found])
 554     fi
 555     if test "$GSSAPI_IMPL" = "Heimdal"
 556     then
 557       AC_DEFINE(HAVE_HEIMDAL,1,[ Define if your GSSAPI implementation is Heimdal ])
 558     fi
 559     CPPFLAGS="$CPPFLAGS $GSSAPI_CFLAGS"
 560     MUTTLIBS="$MUTTLIBS $GSSAPI_LIBS"
 561     AC_DEFINE(USE_GSS,1,[ Define if you have GSSAPI libraries available ])
 562     need_gss="yes"
 563   else
 564     AC_MSG_WARN([GSS was requested but IMAP is not enabled])
 565   fi
 566 fi
 567 AM_CONDITIONAL(USE_GSS, test x$need_gss = xyes)
 568
 569 dnl -- end imap dependencies --
 570
 571 AC_ARG_WITH(ssl, AC_HELP_STRING([--with-ssl[=PFX]], [Compile in SSL support for POP/IMAP]),
 572 [       if test "$with_ssl" != "no"
 573         then
 574           if test "$need_socket" != "yes"; then
 575            AC_MSG_ERROR([SSL support is only useful with POP or IMAP support])
 576           fi
 577
 578           if test "$with_ssl" != "yes"
 579           then
 580            LDFLAGS="$LDFLAGS -L$withval/lib"
 581            CPPFLAGS="$CPPFLAGS -I$withval/include"
 582           fi
 583           saved_LIBS="$LIBS"
 584
 585           AC_CHECK_LIB(crypto, X509_new,, AC_MSG_ERROR([Unable to find SSL library]))
 586           AC_CHECK_LIB(ssl, SSL_new,, AC_MSG_ERROR([Unable to find SSL library]), -lcrypto)
 587
 588           AC_CHECK_FUNCS(RAND_status RAND_egd)
 589
 590           AC_DEFINE(USE_SSL,1,[ Define if you want support for SSL. ])
 591           LIBS="$saved_LIBS"
 592           MUTTLIBS="$MUTTLIBS -lssl -lcrypto"
 593           MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_ssl.o"
 594           need_ssl=yes
 595
 596         fi
 597 ])
 598 AM_CONDITIONAL(USE_SSL, test x$need_ssl = xyes)
 599
 600 dnl SSL support via NSS
 601 AC_ARG_WITH(nss, AC_HELP_STRING([--with-nss[=PFX]], [Compile in SSL support for POP/IMAP via NSS]),
 602 [       if test "$with_nss" != no
 603         then
 604           if test "$need_socket" != "yes"; then
 605            AC_MSG_ERROR([SSL support is only useful with POP or IMAP support])
 606           fi
 607
 608           if test "$with_nss" != "yes"
 609           then
 610            LDFLAGS="$LDFLAGS -L$withval/lib"
 611            CPPFLAGS="$CPPFLAGS -I$withval/include -I$withval/public/security"
 612           fi
 613
 614           AC_DEFINE(USE_NSS,1,[ Define if you want support for SSL via the NSS library. ])
 615           MUTTLIBS="$MUTTLIBS -lssl -lnss -lcertdb -lcerthi -lcryptohi"
 616           MUTTLIBS="$MUTTLIBS -lpk11wrap -lsoftoken -lsecutil -ldbm -lplds4 -lplc4 -lfreebl"
 617           MUTTLIBS="$MUTTLIBS -lnspr4"
 618
 619           MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_ssl_nss.o"
 620           need_ssl=yes
 621         fi
 622 ])
 623
 624 AC_ARG_WITH([gnutls], AC_HELP_STRING([--with-gnutls[=PFX]], [Enable SSL support using gnutls]),
 625     [gnutls_prefix="$withval"], [gnutls_prefix="no"])
 626 if test "$gnutls_prefix" != "no"
 627 then
 628   if test "$need_socket" != "yes"
 629   then
 630     AC_MSG_ERROR([SSL support is only useful with POP or IMAP support])
 631   fi
 632   MUTT_AM_PATH_GNUTLS([$gnutls_prefix],
 633     [dnl GNUTLS found
 634     CPPFLAGS="$CPPFLAGS $LIBGNUTLS_CFLAGS"
 635     MUTTLIBS="$MUTTLIBS $LIBGNUTLS_LIBS"
 636     AC_DEFINE(USE_GNUTLS, 1, [Define if you want support for SSL via the gnutls library.])
 637
 638     MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_ssl_gnutls.o"
 639     need_ssl=yes],
 640     [dnl GNUTLS not found
 641       AC_MSG_ERROR([could not find libgnutls])
 642     ])
 643 fi
 644
 645 AC_ARG_WITH(sasl, AC_HELP_STRING([--with-sasl[=PFX]], [Use Cyrus SASL library for POP/IMAP authentication]),
 646         [
 647         if test "$with_sasl" != "no" -a "$need_imap" != "yes" -a "$need_pop" != "yes"
 648         then
 649           AC_MSG_ERROR([SASL support is only useful with POP or IMAP support])
 650         fi
 651
 652         if test "$with_sasl" != "no"
 653         then
 654           if test "$with_sasl" != "yes"
 655           then
 656             CPPFLAGS="$CPPFLAGS -I$with_sasl/include"
 657             LDFLAGS="$LDFLAGS -L$with_sasl/lib"
 658           fi
 659
 660           saved_LIBS="$LIBS"
 661
 662           AC_CHECK_LIB(sasl, sasl_client_init,,
 663             AC_MSG_ERROR([could not find libsasl]),)
 664
 665           MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_sasl.o"
 666           MUTTLIBS="$MUTTLIBS -lsasl"
 667           LIBS="$saved_LIBS"
 668           AC_DEFINE(USE_SASL,1,
 669                   [ Define if want to use the Cyrus SASL library for POP/IMAP authentication. ])
 670           need_sasl=yes
 671         fi
 672         ])
 673 AM_CONDITIONAL(USE_SASL, test x$need_sasl = xyes)
 674
 675 AC_ARG_WITH(sasl2, AC_HELP_STRING([--with-sasl2[=PFX]], [Use Cyrus SASL library version 2 for POP/IMAP authentication]),
 676         [
 677         if test "$with_sasl2" != "no" -a "$need_imap" != "yes" -a "$need_pop" != "yes"
 678         then
 679           AC_MSG_ERROR([SASL2 support is only useful with POP or IMAP support])
 680         fi
 681
 682         if test "$with_sasl2" != "no"
 683         then
 684           if test "$with_sasl2" != "yes"
 685           then
 686             CPPFLAGS="$CPPFLAGS -I$with_sasl2/include"
 687             LDFLAGS="$LDFLAGS -L$with_sasl2/lib"
 688           fi
 689
 690           saved_LIBS="$LIBS"
 691
 692           AC_CHECK_LIB(sasl2, sasl_client_init,,
 693             AC_MSG_ERROR([could not find libsasl2]),)
 694
 695           MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_sasl.o"
 696           MUTTLIBS="$MUTTLIBS -lsasl2"
 697           LIBS="$saved_LIBS"
 698           AC_DEFINE(USE_SASL,1,
 699                   [ Define if want to use the Cyrus SASL library for POP/IMAP authentication. ])
 700           AC_DEFINE(USE_SASL2,1,
 701                   [ Define if want to use version 2 of the Cyrus SASL library. ])
 702           need_sasl=yes
 703         fi
 704         ])
 705 AM_CONDITIONAL(USE_SASL, test x$need_sasl = xyes)
 706
 707 AC_ARG_WITH(idn, AC_HELP_STRING([--with-idn=[PFX]], [Use GNU libidn for domain names]),
 708                  [
 709                   if test "$with_idn" != "no" ; then
 710                         if test "$with_idn" != "yes" ; then
 711                            CPPFLAGS="$CPPFLAGS -I$with_idn/include"
 712                            LDFLAGS="$LDFLAGS -L$with_idn/lib"
 713                         fi
 714                   fi
 715                  ]
 716 )
 717
 718 if test "x$with_idn" != "xno"; then
 719    AC_CHECK_LIB(idn, stringprep_check_version)
 720    AC_CHECK_FUNCS(idna_to_unicode_utf8_from_utf8 idna_to_unicode_8z8z)
 721    AC_CHECK_FUNCS(idna_to_ascii_from_utf8 idna_to_ascii_8z)
 722    AC_CHECK_FUNCS(idna_to_ascii_lz idna_to_ascii_from_locale)
 723 fi
 724
 725 dnl -- end socket --
 726
 727 AC_ARG_ENABLE(debug, AC_HELP_STRING([--enable-debug], [Enable debugging support]),
 728         [ if test x$enableval = xyes ; then
 729                 AC_DEFINE(DEBUG,1,[ Define to enable debugging info. ])
 730           fi
 731          ])
 732
 733 AC_ARG_ENABLE(flock, AC_HELP_STRING([--enable-flock], [Use flock() to lock files]),
 734         [if test $enableval = yes; then
 735                 AC_DEFINE(USE_FLOCK,1, [ Define to use flock() to lock mailboxes. ])
 736         fi])
 737
 738 mutt_cv_fcntl=yes
 739 AC_ARG_ENABLE(fcntl, AC_HELP_STRING([--disable-fcntl], [Do NOT use fcntl() to lock files]),
 740         [if test $enableval = no; then mutt_cv_fcntl=no; fi])
 741
 742 if test $mutt_cv_fcntl = yes; then
 743         AC_DEFINE(USE_FCNTL,1, [ Define to use fcntl() to lock folders. ])
 744 fi
 745
 746 dnl This may look cumbersome -- please keep it that way, so we can
 747 dnl quickly change the default to "yes" again.
 748 mutt_cv_inodesort=no
 749 AC_ARG_ENABLE(inodesort,  AC_HELP_STRING([--enable-inodesort], [Read files in maildir folders sorted by inode.]),
 750        [if test x$enableval = xyes ; then mutt_cv_inodesort=yes; fi])
 751
 752 if test $mutt_cv_inodesort = yes; then
 753         AC_DEFINE(USE_INODESORT, 1, [ Define to sort files in a maildir by inode number. ])
 754 fi
 755
 756 mutt_cv_warnings=yes
 757 AC_ARG_ENABLE(warnings, AC_HELP_STRING([--disable-warnings], [Turn off compiler warnings (not recommended)]),
 758 [if test $enableval = no; then
 759         mutt_cv_warnings=no
 760 fi])
 761
 762 if test x$GCC = xyes -a $mutt_cv_warnings = yes; then
 763         CFLAGS="-Wall -pedantic $CFLAGS"
 764 fi
 765
 766 AC_ARG_ENABLE(nfs-fix, AC_HELP_STRING([--enable-nfs-fix], [Work around an NFS with broken attributes caching]),
 767         [if test x$enableval = xyes; then
 768                 AC_DEFINE(NFS_ATTRIBUTE_HACK,1,
 769                   [Define if you have problems with mutt not detecting
 770                    new/old mailboxes over NFS.  Some NFS implementations
 771                    incorrectly cache the attributes of small files.])
 772         fi])
 773
 774 AC_ARG_ENABLE(buffy-size, AC_HELP_STRING([--enable-buffy-size], [Use file size attribute instead of access time]),
 775         [if test x$enableval = xyes; then
 776                 AC_DEFINE(BUFFY_SIZE,1,[ Define to enable the "buffy_size" feature. ])
 777         fi])
 778
 779 AC_ARG_ENABLE(mailtool, AC_HELP_STRING([--enable-mailtool], [Enable Sun mailtool attachments support ]),
 780         [if test x$enableval = xyes; then
 781                 AC_DEFINE(SUN_ATTACHMENT,1,[ Define to enable Sun mailtool attachments support. ])
 782         fi])
 783
 784 AC_ARG_ENABLE(compressed, [  --enable-compressed        Enable compressed folders support ],
 785         [if test x$enableval = xyes; then
 786                 AC_DEFINE(USE_COMPRESSED)
 787         fi])
 788
 789 AC_ARG_ENABLE(locales-fix, AC_HELP_STRING([--enable-locales-fix], [The result of isprint() is unreliable ]),
 790         [if test x$enableval = xyes; then
 791                 AC_DEFINE(LOCALES_HACK,1,[ Define if the result of isprint() is unreliable. ])
 792         fi])
 793
 794 AC_ARG_WITH(exec-shell, AC_HELP_STRING([--with-exec-shell=SHELL], [Specify alternate shell (ONLY if /bin/sh is broken)]),
 795         [if test $withval != yes; then
 796                 AC_DEFINE_UNQUOTED(EXECSHELL, "$withval",
 797                  [program to use for shell commands])
 798          else
 799                 AC_DEFINE_UNQUOTED(EXECSHELL, "/bin/sh")
 800         fi],
 801         [AC_DEFINE_UNQUOTED(EXECSHELL, "/bin/sh")])
 802
 803 dnl -- start cache --
 804 AC_ARG_ENABLE(hcache, AC_HELP_STRING([--enable-hcache], [Enable header caching]),
 805 [if test x$enableval = xyes; then
 806     AC_DEFINE(USE_HCACHE, 1, [Enable header caching])
 807
 808     OLDCPPFLAGS="$CPPFLAGS"
 809     OLDLIBS="$LIBS"
 810
 811     need_md5="yes"
 812
 813     ac_prefer_qdbm=yes
 814     AC_ARG_WITH(qdbm, AC_HELP_STRING([--without-qdbm], [Don't use qdbm even if it is available]),
 815         ac_prefer_qdbm=$withval)
 816     if test x$ac_prefer_qdbm != xno; then
 817         ac_cv_vlopen=no
 818         QDBM_DIRS="$mutt_cv_prefix /usr/local /usr"
 819         AC_MSG_CHECKING([for vlopen])
 820         for d in $QDBM_DIRS; do
 821           if test x$ac_cv_vlopen = xno && test -d "$d/include" && test -d "$d/lib"; then
 822             QDBM_INC="-I$d/include"
 823             QDBM_LIB="-L$d/lib"
 824             CPPFLAGS="$OLDCPPFLAGS $QDBM_INC"
 825             LIBS="$OLDLIBS $QDBM_LIB -lqdbm"
 826             AC_TRY_LINK([#include <villa.h>],[vlopen(0,0,0);],[ac_cv_vlopen=yes])
 827           fi
 828         done
 829         if test x$ac_cv_vlopen = xyes; then
 830           AC_MSG_RESULT(yes)
 831         else
 832           AC_MSG_RESULT(no)
 833         fi
 834     fi
 835
 836     ac_prefer_gdbm=yes
 837     AC_ARG_WITH(gdbm, AC_HELP_STRING([--without-gdbm], [Don't use gdbm even if it is available]),
 838         ac_prefer_gdbm=$withval)
 839     if test x$ac_prefer_gdbm != xno -a x$ac_cv_vlopen != xyes; then
 840         ac_cv_gdbmopen=no
 841         GDBM_DIRS="$mutt_cv_prefix /usr/local /usr"
 842         AC_MSG_CHECKING([for gdbm_open])
 843         for d in $GDBM_DIRS; do
 844           if test x$ac_cv_gdbmopen = xno && test -d "$d/include" && test -d "$d/lib"; then
 845             GDBM_INC="-I$d/include"
 846             GDBM_LIB="-L$d/lib"
 847             CPPFLAGS="$OLDCPPFLAGS $GDBM_INC"
 848             LIBS="$OLDLIBS $GDBM_LIB -lgdbm"
 849             AC_TRY_LINK([#include <gdbm.h>],[gdbm_open(0,0,0,0,0);],[ac_cv_gdbmopen=yes])
 850           fi
 851         done
 852         if test x$ac_cv_gdbmopen = xyes; then
 853           AC_MSG_RESULT(yes)
 854         else
 855           AC_MSG_RESULT(no)
 856         fi
 857     fi
 858
 859     ac_bdb_prefix=yes
 860     AC_ARG_WITH(bdb, AC_HELP_STRING([--with-bdb[=DIR]], [Use BerkeleyDB4 if gdbm is not available ]),
 861         ac_bdb_prefix=$withval)
 862     if test x$ac_bdb_prefix != xno -a x$ac_cv_gdbmopen != xyes -a x$ac_cv_vlopen != xyes; then
 863         test x$ac_bdb_prefix = xyes && ac_bdb_prefix="$mutt_cv_prefix /opt/csw/bdb4 /opt /usr/local /usr"
 864         for d in $ac_bdb_prefix; do
 865             bdbpfx="$bdbpfx $d"
 866             for v in BerkeleyDB.4.3 BerkeleyDB.4.2 BerkeleyDB.4.1; do
 867                 bdbpfx="$bdbpfx $d/$v"
 868             done
 869         done
 870         BDB_VERSIONS="db-4 db4 db-4.3 db4.3 db43 db-4.2 db4.2 db42 db-4.1 db4.1 db41 db ''"
 871         AC_MSG_CHECKING([for BerkeleyDB > 4.0])
 872         for d in $bdbpfx; do
 873             BDB_INCLUDE_DIR=""
 874             BDB_LIB_DIR=""
 875             for v in / $BDB_VERSIONS; do
 876                 if test -r "$d/include/$v/db.h"; then
 877                     BDB_INCLUDE_DIR="$d/include/$v"
 878                     if test -d "$d/lib/$v"; then
 879                         BDB_LIB_DIR="$d/lib/$v"
 880                         for l in `echo $BDB_VERSIONS`; do
 881                             CPPFLAGS="-I$BDB_INCLUDE_DIR $OLDCPPFLAGS"
 882                             LIBS="$OLDLIBS -L$BDB_LIB_DIR -l$l"
 883                             AC_TRY_LINK([
 884                                 #include <stdlib.h>
 885                                 #include <db.h>
 886                             ],[
 887                                 DB *db = NULL;
 888                                 db->open(db,NULL,NULL,NULL,0,0,0);
 889                             ],[
 890                                 ac_cv_dbcreate=yes
 891                                 BDB_LIB="$l"
 892                                 break
 893                             ])
 894                         done
 895                         test x$ac_cv_dbcreate = xyes && break
 896                     fi
 897                 fi
 898             done
 899             test x$BDB_LIB != x && break
 900         done
 901         if test x$ac_cv_dbcreate = xyes; then
 902             AC_MSG_RESULT(yes)
 903         else
 904             AC_MSG_RESULT(no)
 905         fi
 906     fi
 907
 908     if test x$ac_cv_vlopen = xyes; then
 909         CPPFLAGS="$OLDCPPFLAGS $QDBM_INC"
 910         LIBS="$OLDLIBS $QDBM_LIB -lqdbm"
 911         AC_DEFINE(HAVE_QDBM, 1, [QDBM Support])
 912     elif test x$ac_cv_gdbmopen = xyes; then
 913         CPPFLAGS="$OLDCPPFLAGS $GDBM_INC"
 914         LIBS="$OLDLIBS $GDBM_LIB -lgdbm";
 915         AC_DEFINE(HAVE_GDBM, 1, [GDBM Support])
 916     elif test x$ac_cv_dbcreate = xyes; then
 917         CPPFLAGS="-I$BDB_INCLUDE_DIR $OLDCPPFLAGS"
 918         LIBS="$OLDLIBS -L$BDB_LIB_DIR -l$BDB_LIB"
 919         AC_DEFINE(HAVE_DB4, 1, [Sleepycat DB4 Support])
 920     else
 921         AC_MSG_ERROR(You need QDBM, GDBM or Sleepycat DB4 for --enable-hcache)
 922     fi
 923 fi])
 924 dnl -- end cache --
 925
 926 AC_SUBST(MUTTLIBS)
 927 AC_SUBST(MUTT_LIB_OBJECTS)
 928 AC_SUBST(LIBIMAP)
 929 AC_SUBST(LIBIMAPDEPS)
 930 AC_SUBST(LIBPOP)
 931 AC_SUBST(LIBPOPDEPS)
 932 AC_SUBST(LIBNNTP)
 933 AC_SUBST(LIBNNTPDEPS)
 934
 935 dnl -- iconv/gettext --
 936
 937 AC_ARG_ENABLE(iconv, AC_HELP_STRING([--disable-iconv], [Disable iconv support]),
 938         [if test x$enableval = xno ; then
 939                 am_cv_func_iconv=no
 940         fi
 941 ])
 942
 943 MUTT_AM_GNU_GETTEXT
 944
 945 if test "$am_cv_func_iconv" != "yes"
 946 then
 947   AC_MSG_WARN([Configuring without iconv support. See INSTALL for details])
 948 else
 949
 950 AC_CHECK_HEADERS(iconv.h,
 951         [AC_MSG_CHECKING(whether iconv.h defines iconv_t)
 952          AC_EGREP_HEADER([typedef.*iconv_t],iconv.h,
 953                 [AC_MSG_RESULT(yes)
 954                  AC_DEFINE(HAVE_ICONV_T_DEF, 1,
 955                         [Define if <iconv.h> defines iconv_t.])],
 956                  AC_MSG_RESULT(no))])
 957
 958 dnl (1) Some implementations of iconv won't convert from UTF-8 to UTF-8.
 959 dnl (2) In glibc-2.1.2 and earlier there is a bug that messes up ob and
 960 dnl     obl when args 2 and 3 are 0 (fixed in glibc-2.1.3).
 961 AC_CACHE_CHECK([whether this iconv is good enough], mutt_cv_iconv_good,
 962         mutt_save_LIBS="$LIBS"
 963         LIBS="$LIBS $LIBICONV"
 964         AC_TRY_RUN([
 965 #include <iconv.h>
 966 int main()
 967 {
 968   iconv_t cd;
 969 changequote(, )dnl
 970   char buf[4];
 971 changequote([, ])dnl
 972   char *ob;
 973   size_t obl;
 974   ob = buf, obl = sizeof(buf);
 975   return ((cd = iconv_open("UTF-8", "UTF-8")) != (iconv_t)(-1) &&
 976           (iconv(cd, 0, 0, &ob, &obl) ||
 977            !(ob == buf && obl == sizeof(buf)) ||
 978            iconv_close(cd)));
 979 }
 980                 ],
 981                 mutt_cv_iconv_good=yes,
 982                 mutt_cv_iconv_good=no,
 983                 mutt_cv_iconv_good=yes)
 984         LIBS="$mutt_save_LIBS")
 985 if test "$mutt_cv_iconv_good" = no; then
 986   AC_MSG_ERROR(Try using libiconv instead)
 987 fi
 988
 989 dnl This is to detect implementations such as the one in glibc-2.1,
 990 dnl which always convert exactly but return the number of characters
 991 dnl converted instead of the number converted inexactly.
 992 AC_CACHE_CHECK([whether iconv is non-transcribing], mutt_cv_iconv_nontrans,
 993         mutt_save_LIBS="$LIBS"
 994         LIBS="$LIBS $LIBICONV"
 995         AC_TRY_RUN([
 996 #include <iconv.h>
 997 #include <string.h>
 998 int main()
 999 {
1000   iconv_t cd;
1001   const char *ib;
1002   char *ob;
1003   size_t ibl, obl;
1004   const char *s = "\304\211";
1005 changequote(, )dnl
1006   char t[3];
1007 changequote([, ])dnl
1008   ib = s, ibl = 2, ob = t, obl = 3;
1009   return ((cd = iconv_open("UTF-8", "UTF-8")) == (iconv_t)(-1) ||
1010           iconv(cd, &ib, &ibl, &ob, &obl));
1011 }
1012                 ],
1013                 mutt_cv_iconv_nontrans=no,
1014                 mutt_cv_iconv_nontrans=yes,
1015                 mutt_cv_iconv_nontrans=no)
1016         LIBS="$mutt_save_LIBS")
1017 if test "$mutt_cv_iconv_nontrans" = yes; then
1018   AC_DEFINE(ICONV_NONTRANS, 1)
1019 else
1020   AC_DEFINE(ICONV_NONTRANS, 0)
1021 fi
1022
1023 CPPFLAGS="$CPPFLAGS -I\$(top_srcdir)/intl"
1024
1025 if test "$BUILD_INCLUDED_LIBINTL" = "yes"; then
1026   AC_DEFINE(HAVE_BIND_TEXTDOMAIN_CODESET,1,
1027           [ Define if your gettext has bind_textdomain_codeset. ])
1028 else
1029   AC_CHECK_FUNCS(bind_textdomain_codeset)
1030 fi
1031
1032 fi # libiconv
1033
1034 dnl -- locales --
1035
1036 AC_CHECK_HEADERS(wchar.h)
1037
1038 AC_CACHE_CHECK([for wchar_t], mutt_cv_wchar_t,
1039         AC_TRY_COMPILE([
1040 #include <stddef.h>
1041 #include <stdlib.h>
1042 #ifdef HAVE_WCHAR_H
1043 #include <wchar.h>
1044 #endif
1045                 ],
1046                 [ wchar_t wc; return 0; ],
1047                 mutt_cv_wchar_t=yes,
1048                 mutt_cv_wchar_t=no))
1049
1050 if test "$mutt_cv_wchar_t" = no; then
1051         AC_DEFINE(wchar_t,int,[ Define to 'int' if system headers don't define. ])
1052 fi
1053
1054 AC_CACHE_CHECK([for wint_t], mutt_cv_wint_t,
1055         AC_TRY_COMPILE([
1056 #include <stddef.h>
1057 #include <stdlib.h>
1058 #ifdef HAVE_WCHAR_H
1059 #include <wchar.h>
1060 #endif
1061                 ],
1062                 [ wint_t wc; return 0; ],
1063                 mutt_cv_wint_t=yes,
1064                 mutt_cv_wint_t=no))
1065
1066 if test "$mutt_cv_wint_t" = no; then
1067         AC_DEFINE(wint_t,int,[ Define to 'int' if system headers don't define. ])
1068 fi
1069
1070 AC_CHECK_HEADERS(wctype.h)
1071 AC_CHECK_FUNCS(iswalnum iswalpha  iswcntrl iswdigit)
1072 AC_CHECK_FUNCS(iswgraph iswlower iswprint iswpunct iswspace iswupper)
1073 AC_CHECK_FUNCS(iswxdigit towupper towlower)
1074
1075 AC_CACHE_CHECK([for mbstate_t], mutt_cv_mbstate_t,
1076         AC_TRY_COMPILE([
1077 #include <stddef.h>
1078 #include <stdlib.h>
1079 #ifdef HAVE_WCHAR_H
1080 #include <wchar.h>
1081 #endif
1082                 ],
1083                 [ mbstate_t s; return 0; ],
1084                 mutt_cv_mbstate_t=yes,
1085                 mutt_cv_mbstate_t=no))
1086
1087 if test "$mutt_cv_mbstate_t" = no; then
1088         AC_DEFINE(mbstate_t,int,[ Define to 'int' if system headers don't define. ])
1089 fi
1090
1091 wc_funcs=maybe
1092 AC_ARG_WITH(wc-funcs, AC_HELP_STRING([--without-wc-funcs], [Do not use the system's wchar_t functions]),
1093         wc_funcs=$withval)
1094
1095 if test "$wc_funcs" != yes -a "$wc_funcs" != no; then
1096         AC_CACHE_CHECK([for wchar_t functions], mutt_cv_wc_funcs,
1097                 mutt_cv_wc_funcs=no
1098                 AC_TRY_LINK([
1099 #define _XOPEN_SOURCE 1
1100 #include <stddef.h>
1101 #include <stdlib.h>
1102 #ifdef HAVE_WCTYPE_H
1103 #include <wctype.h>
1104 #endif
1105 #ifdef HAVE_WCHAR_H
1106 #include <wchar.h>
1107 #endif],
1108                         [mbrtowc(0, 0, 0, 0); wctomb(0, 0); wcwidth(0);
1109         iswprint(0); iswspace(0); towlower(0); towupper(0); iswalnum(0)],
1110                         mutt_cv_wc_funcs=yes))
1111         wc_funcs=$mutt_cv_wc_funcs
1112 fi
1113
1114 if test $wc_funcs = yes; then
1115         AC_DEFINE(HAVE_WC_FUNCS,1,[ Define if you are using the system's wchar_t functions. ])
1116 fi
1117
1118 AC_CACHE_CHECK([for nl_langinfo and CODESET], mutt_cv_langinfo_codeset,
1119   [AC_TRY_LINK([#include <langinfo.h>],
1120     [char* cs = nl_langinfo(CODESET);],
1121     mutt_cv_langinfo_codeset=yes,
1122     mutt_cv_langinfo_codeset=no)])
1123 if test $mutt_cv_langinfo_codeset = yes; then
1124   AC_DEFINE(HAVE_LANGINFO_CODESET,1,[ Define if you have <langinfo.h> and nl_langinfo(CODESET). ])
1125 fi
1126
1127 AC_CACHE_CHECK([for nl_langinfo and YESEXPR], mutt_cv_langinfo_yesexpr,
1128   [AC_TRY_LINK([#include <langinfo.h>],
1129     [char* cs = nl_langinfo(YESEXPR);],
1130     mutt_cv_langinfo_yesexpr=yes,
1131     mutt_cv_langinfo_yesexpr=no)])
1132 if test $mutt_cv_langinfo_yesexpr = yes; then
1133   AC_DEFINE(HAVE_LANGINFO_YESEXPR,1,[ Define if you have <langinfo.h> and nl_langinfo(YESEXPR). ])
1134 fi
1135
1136 dnl -- libesmtp --
1137 MUTT_AM_LIBESMTP
1138 if test x$use_libesmtp = xyes; then
1139     CFLAGS="$CFLAGS $mutt_libesmtp_cflags"
1140     MUTTLIBS="$MUTTLIBS $mutt_libesmtp_libs"
1141     MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_libesmtp.o"
1142
1143     AC_DEFINE(USE_LIBESMTP,
1144               1,
1145               [Define to enable the use of libesmtp])
1146 fi
1147 dnl -- end libesmtp --
1148
1149 dnl -- sgml tools --
1150 AC_MSG_CHECKING([for SGML Tools style])
1151 SGML2TXT_CMD="true"
1152 SGML2PS_CMD="true"
1153 SGML2HTML_CMD="true"
1154 case "`uname -s`" in
1155   FreeBSD)
1156     SGML2TXT_CMD="sgmlfmt -f ascii manual.sgml && uniq < manual.ascii | expand > manual.txt && rm -rf manual.ascii || true"
1157     SGML2PS_CMD="sgmlfmt -f ps manual.sgml || true"
1158     SGML2HTML_CMD="sgmlfmt -f html manual.sgml || true"
1159     AC_MSG_RESULT(FreeBSD)
1160     ;;
1161   SunOS)
1162     SGML2TXT_CMD="sgml2txt manual || true"
1163     SGML2PS_CMD="sgml2latex -p manual || true"
1164     SGML2HTML_CMD="sgml2html manual || true"
1165     AC_MSG_RESULT(Solaris)
1166     ;;
1167   *)
1168     SGML2TXT_CMD="if linuxdoc -B txt --pass='-P -c' manual ; then uniq < manual.txt | expand > _manual.txt ; rm manual.txt ; col -b < _manual.txt > manual.txt ; rm -rf _manual.txt ; fi || true"
1169     SGML2PS_CMD="sgml2latex --output=ps manual || true"
1170     SGML2HTML_CMD="sgml2html manual || true"
1171     AC_MSG_RESULT(Linux (default))
1172     ;;
1173 esac
1174 AC_SUBST(SGML2TXT_CMD)
1175 AC_SUBST(SGML2PS_CMD)
1176 AC_SUBST(SGML2HTML_CMD)
1177
1178 AC_OUTPUT(Makefile intl/Makefile m4/Makefile
1179         po/Makefile.in doc/Makefile contrib/Makefile
1180         muttbug.sh
1181         lib/Makefile
1182         imap/Makefile
1183         pop/Makefile
1184         nntp/Makefile
1185         Muttngrc.head
1186         doc/instdoc.sh)