configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl !!! WHEN ADDING NEW CONFIGURE TESTS, PLEASE ADD CODE TO MAIN.C !!!
   4 dnl !!! TO DUMP THEIR RESULTS WHEN MUTT -V IS CALLED            !!!
   5
   6 AC_PREREQ([2.50])
   7 AC_INIT([mutt.h])
   8 AM_CONFIG_HEADER(config.h)
   9
  10 mutt_cv_version=`cat $srcdir/VERSION`
  11
  12 AM_INIT_AUTOMAKE(muttng, $mutt_cv_version)
  13 dnl AC_GNU_SOURCE
  14
  15 ifdef([AC_LIBOBJ], , [define([AC_LIBOBJ], [LIB[]OBJS="$LIBOBJS $1.o"])])
  16
  17 ALL_LINGUAS="de ru it es uk fr pl nl cs id sk ko el zh_TW zh_CN pt_BR eo gl sv da lt tr ja hu et ca bg"
  18
  19 AC_CANONICAL_HOST
  20
  21 AC_MSG_CHECKING([for prefix])
  22 if test x$prefix = xNONE; then
  23         mutt_cv_prefix=$ac_default_prefix
  24 else
  25         mutt_cv_prefix=$prefix
  26 fi
  27 AC_MSG_RESULT($mutt_cv_prefix)
  28
  29 AC_PROG_CC
  30 AC_ISC_POSIX
  31 AM_C_PROTOTYPES
  32 if test "x$U" != "x"; then
  33   AC_MSG_ERROR(Compiler not ANSI compliant)
  34 fi
  35 AC_PROG_CPP
  36 AC_PROG_MAKE_SET
  37 AC_PROG_INSTALL
  38 AC_PROG_RANLIB
  39 AC_CHECK_TOOL(AR, ar, ar)
  40
  41 AC_C_INLINE
  42 AC_C_CONST
  43
  44 AC_SYS_LARGEFILE
  45
  46 AC_PATH_PROG(DBX, dbx, no)
  47 AC_PATH_PROG(GDB, gdb, no)
  48 AC_PATH_PROG(SDB, sdb, no)
  49
  50 if test $GDB != no ; then
  51         DEBUGGER=$GDB
  52 elif test $DBX != no ; then
  53         DEBUGGER=$DBX
  54 elif test $SDB != no ; then
  55         DEBUGGER=$SDB
  56 else
  57         DEBUGGER=no
  58 fi
  59
  60 AC_SUBST([DEBUGGER])
  61
  62 AH_TEMPLATE([sig_atomic_t],
  63             [/* Define to `int' if <signal.h> doesn't define.])
  64 AH_TEMPLATE([HAVE_START_COLOR],
  65             [Define if you have start_color, as a function or macro.])
  66 AH_TEMPLATE([HAVE_TYPEAHEAD],
  67             [Define if you have typeahead, as a function or macro.])
  68 AH_TEMPLATE([HAVE_BKGDSET],
  69             [Define if you have bkgdset, as a function or macro.])
  70 AH_TEMPLATE([HAVE_CURS_SET],
  71             [Define if you have curs_set, as a function or macro.])
  72 AH_TEMPLATE([HAVE_META],
  73             [Define if you have meta, as a function or macro.])
  74 AH_TEMPLATE([HAVE_USE_DEFAULT_COLORS],
  75             [Define if you have use_default_colors, as a function or macro.])
  76 AH_TEMPLATE([HAVE_RESIZETERM],
  77             [Define if you have resizeterm, as a function or macro.])
  78 AH_TEMPLATE([SIG_ATOMIC_VOLATILE_T],
  79             [Some systems declare sig_atomic_t as volatile, some others -- no.
  80              This define will have value `sig_atomic_t' or
  81              `volatile sig_atomic_t' accordingly.])
  82 AH_TEMPLATE([ICONV_NONTRANS],
  83             [Define as 1 if iconv() only converts exactly and we should treat
  84              all return values other than (size_t)(-1) as equivalent.])
  85
  86 MUTT_C99_INTTYPES
  87
  88 ac_aux_path_sendmail=/usr/sbin:/usr/lib
  89 AC_PATH_PROG(SENDMAIL, sendmail, /usr/sbin/sendmail, $PATH:$ac_aux_path_sendmail)
  90 AC_DEFINE_UNQUOTED(SENDMAIL,"$ac_cv_path_SENDMAIL",[ Where to find sendmail on your system. ])
  91
  92 OPS='$(srcdir)/OPS'
  93 if test -f $srcdir/EXPORTABLE ; then
  94         SUBVERSION="us"
  95 else
  96         SUBVERSION="i"
  97
  98         AC_ARG_ENABLE(gpgme, AC_HELP_STRING([--enable-gpgme], [Enable GPGME support]),
  99         [       if test x$enableval = xyes; then
 100                         have_gpgme=yes
 101                 fi
 102         ])
 103         AC_ARG_WITH(gpgme-prefix, AC_HELP_STRING([--with-gpgme-prefix=PFX], [prefix where GPGME is installed (optional)]),
 104         gpgme_config_prefix="$withval", gpgme_config_prefix="")
 105
 106         if test x$have_gpgme = xyes; then
 107                 if test x$gpgme_config_prefix != x; then
 108                         GPGME_CONFIG="$gpgme_config_prefix/bin/gpgme-config"
 109                 else
 110                         AC_PATH_PROG(GPGME_CONFIG, gpgme-config, no)
 111                 fi
 112                 if test "x$GPGME_CONFIG" = "xno"; then
 113                         AC_MSG_ERROR([GPGME not found])
 114                 else
 115                         LIBGPGME_CFLAGS=`$GPGME_CONFIG --cflags`
 116                         LIBGPGME_LIBS=`$GPGME_CONFIG --libs`
 117       MUTTLIBS="$MUTTLIBS $LIBGPGME_LIBS"
 118                         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS crypt-gpgme.o crypt-mod-pgp-gpgme.o crypt-mod-smime-gpgme.o"
 119                         AC_DEFINE(CRYPT_BACKEND_GPGME, 1,
 120                                   [Defined, if GPGME support is enabled])
 121                 fi
 122         fi
 123         AC_SUBST(LIBGPGME_CFLAGS)
 124         AC_SUBST(LIBGPGME_LIBS)
 125
 126         AC_ARG_ENABLE(pgp, AC_HELP_STRING([--disable-pgp], [Disable PGP support]),
 127         [       if test x$enableval = xno ; then
 128                         have_pgp=no
 129                 fi
 130         ])
 131
 132         if test x$have_pgp != xno ; then
 133                 AC_DEFINE(CRYPT_BACKEND_CLASSIC_PGP,1,
 134                     [ Define if you want classic PGP support. ])
 135                 PGPAUX_TARGET="pgpringng\$(EXEEXT) pgpewrapng\$(EXEEXT)"
 136                 MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS pgp.o pgpinvoke.o pgpkey.o pgplib.o gnupgparse.o pgpmicalg.o pgppacket.o crypt-mod-pgp-classic.o"
 137         fi
 138
 139         AC_ARG_ENABLE(smime, AC_HELP_STRING([--disable-smime], [Disable SMIME support]),
 140         [       if test x$enableval = xno ; then
 141                         have_smime=no
 142                 fi
 143         ])
 144
 145         if test x$have_smime != xno ; then
 146                 AC_DEFINE(CRYPT_BACKEND_CLASSIC_SMIME,1,
 147                   [ Define if you want clasic S/MIME support. ])
 148                 MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS smime.o crypt-mod-smime-classic.o"
 149                 SMIMEAUX_TARGET="smime_keysng"
 150         fi
 151
 152         AC_ARG_WITH(mixmaster, AC_HELP_STRING([--with-mixmaster[=PATH]], [Include Mixmaster support]),
 153                 [if test -x "$withval" ; then
 154                         MIXMASTER="$withval"
 155                  else
 156                         MIXMASTER="mixmaster"
 157                  fi
 158                  OPS="$OPS \$(srcdir)/OPS.MIX"
 159                  MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS remailer.o"
 160                  AC_DEFINE_UNQUOTED(MIXMASTER,"$MIXMASTER",
 161                          [ Where to find mixmaster on your system. ])
 162                 ])
 163
 164 fi
 165 # We now require all OPS
 166 OPS="$OPS \$(srcdir)/OPS.PGP \$(srcdir)/OPS.SMIME \$(srcdir)/OPS.CRYPT "
 167 AC_SUBST([OPS])
 168
 169
 170 AC_SUBST(PGPAUX_TARGET)
 171 AC_SUBST(SMIMEAUX_TARGET)
 172
 173 AC_DEFINE_UNQUOTED(SUBVERSION,"$SUBVERSION",[ Is this the international version? ])
 174 AC_SUBST([SUBVERSION])
 175
 176 AC_PATH_PROG(ISPELL, ispell, no)
 177 if test $ISPELL != no; then
 178         AC_DEFINE_UNQUOTED(ISPELL,"$ISPELL",[ Where to find ispell on your system. ])
 179 fi
 180
 181 AC_ARG_WITH(slang, AC_HELP_STRING([--with-slang[=DIR]], [Use S-Lang instead of ncurses]),
 182         [AC_CACHE_CHECK([if this is a BSD system], mutt_cv_bsdish,
 183                 [AC_TRY_RUN([#include <sys/param.h>
 184
 185 main ()
 186 {
 187 #ifdef BSD
 188         exit (0);
 189 #else
 190         exit (1);
 191 #endif
 192 }],
 193                         mutt_cv_bsdish=yes,
 194                         mutt_cv_bsdish=no,
 195                         mutt_cv_bsdish=no)])
 196
 197         AC_MSG_CHECKING(for S-Lang)
 198         if test $withval = yes; then
 199                 if test -d $srcdir/../slang; then
 200                         mutt_cv_slang=$srcdir/../slang/src
 201                         CFLAGS="$CFLAGS -I${mutt_cv_slang}"
 202                         LDFLAGS="$LDFLAGS -L${mutt_cv_slang}/objs"
 203                 else
 204                         if test -d $mutt_cv_prefix/include/slang; then
 205                                 CFLAGS="$CFLAGS -I$mutt_cv_prefix/include/slang"
 206                         elif test -d /usr/include/slang; then
 207                                 CFLAGS="$CFLAGS -I/usr/include/slang"
 208                         fi
 209                         mutt_cv_slang=yes
 210                 fi
 211         else
 212                 dnl ---Check to see if $withval is a source directory
 213                 if test -f $withval/src/slang.h; then
 214                         mutt_cv_slang=$withval/src
 215                         CFLAGS="$CFLAGS -I${mutt_cv_slang}"
 216                         LDFLAGS="$LDFLAGS -L${mutt_cv_slang}/objs"
 217                 else
 218                         dnl ---Must be installed somewhere
 219                         mutt_cv_slang=$withval
 220                         if test -d $withval/include/slang; then
 221                                 CFLAGS="$CFLAGS -I${withval}/include/slang"
 222                         elif test -d $withval/include; then
 223                                 CFLAGS="$CFLAGS -I${withval}/include"
 224                         fi
 225                         LDFLAGS="$LDFLAGS -L${withval}/lib"
 226                 fi
 227         fi
 228         AC_MSG_RESULT($mutt_cv_slang)
 229         if test $mutt_cv_bsdish = yes; then
 230                 AC_CHECK_LIB(termlib, main)
 231         fi
 232         AC_DEFINE(USE_SLANG_CURSES,1,
 233                 [ Define if you compile with SLang instead of curses/ncurses. ])
 234         AC_DEFINE(HAVE_COLOR,1,[ Define if your curses library supports color. ])
 235         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS resize.o"
 236
 237         dnl --- now that we've found it, check the link
 238
 239         AC_CHECK_LIB(slang, SLtt_get_terminfo,
 240                 [MUTTLIBS="$MUTTLIBS -lslang -lm"],
 241                 [AC_MSG_ERROR(unable to compile.  check config.log)], -lm)
 242
 243         ],
 244
 245         [mutt_cv_curses=/usr
 246         AC_ARG_WITH(curses, AC_HELP_STRING([--with-curses=DIR], [Where ncurses is installed]),
 247                 [if test $withval != yes; then
 248                         mutt_cv_curses=$withval
 249                 fi
 250                 if test x$mutt_cv_curses != x/usr; then
 251                         LDFLAGS="-L${mutt_cv_curses}/lib $LDFLAGS"
 252                         CPPFLAGS="$CPPFLAGS -I${mutt_cv_curses}/include"
 253                 fi])
 254
 255         AC_CHECK_FUNC(initscr,,[
 256         cf_ncurses="ncurses"
 257         for lib in ncurses ncursesw
 258         do
 259                 AC_CHECK_LIB($lib, waddnwstr, [cf_ncurses="$lib"; break])
 260         done
 261         AC_CHECK_LIB($cf_ncurses, initscr,
 262                 [MUTTLIBS="$MUTTLIBS -l$cf_ncurses"
 263                 if test x$mutt_cv_curses = x/usr -a -d /usr/include/ncurses; then
 264                         CPPFLAGS="$CPPFLAGS -I/usr/include/ncurses"
 265                 fi
 266
 267                 if test "$cf_ncurses" = ncursesw; then
 268                         AC_CHECK_HEADERS(ncursesw/ncurses.h,[cf_cv_ncurses_header="ncursesw/ncurses.h"])
 269                 else
 270                         AC_CHECK_HEADERS(ncurses.h,[cf_cv_ncurses_header="ncurses.h"])
 271                 fi],
 272
 273                 [CF_CURSES_LIBS])
 274                 ])
 275
 276         old_LIBS="$LIBS"
 277         LIBS="$LIBS $MUTTLIBS"
 278         CF_CHECK_FUNCDECLS([#include <${cf_cv_ncurses_header-curses.h}>],
 279                            [start_color typeahead bkgdset curs_set meta use_default_colors resizeterm])
 280         if test "$ac_cv_func_decl_start_color" = yes; then
 281                 AC_DEFINE(HAVE_COLOR,1,[ Define if your curses library supports color. ])
 282         fi
 283         if test "$ac_cv_func_decl_resizeterm" = yes; then
 284                 MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS resize.o"
 285         fi
 286         LIBS="$old_LIBS"
 287         ])
 288
 289 AC_HEADER_STDC
 290
 291 AC_CHECK_HEADERS(stdarg.h sys/ioctl.h ioctl.h sysexits.h)
 292 AC_CHECK_HEADERS(sys/time.h sys/resource.h)
 293 AC_CHECK_HEADERS(unix.h)
 294
 295 AC_CHECK_FUNCS(setrlimit getsid isctype)
 296
 297 AC_TYPE_SIGNAL
 298
 299 AC_MSG_CHECKING(for sig_atomic_t in signal.h)
 300 AC_EGREP_HEADER(sig_atomic_t,signal.h,
 301   [
 302     ac_cv_type_sig_atomic_t=yes;
 303     AC_EGREP_HEADER(volatile.*sig_atomic_t,
 304                     signal.h,
 305                     [
 306                         is_sig_atomic_t_volatile=yes;
 307                         AC_MSG_RESULT([yes, volatile])
 308                     ],
 309                     [
 310                         is_sig_atomic_t_volatile=no;
 311                         AC_MSG_RESULT([yes, non volatile])
 312                     ])
 313   ],
 314   [
 315     AC_MSG_RESULT(no)
 316     AC_CHECK_TYPE(sig_atomic_t, int)
 317     is_sig_atomic_t_volatile=no
 318   ])
 319 if test $is_sig_atomic_t_volatile = 'yes'
 320 then
 321     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, sig_atomic_t)
 322 else
 323     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, [volatile sig_atomic_t])
 324 fi
 325
 326 AC_DECL_SYS_SIGLIST
 327
 328 AC_TYPE_PID_T
 329 dnl AC_CHECK_TYPE(ssize_t, int)
 330
 331 AC_CHECK_FUNCS(fgetpos memmove setegid srand48 strerror)
 332
 333 AC_REPLACE_FUNCS(strcasecmp strdup)
 334
 335 AC_CHECK_FUNC(getopt)
 336 if test $ac_cv_func_getopt = yes; then
 337         AC_CHECK_HEADERS(getopt.h)
 338 fi
 339
 340 mutt_cv_snprintf=no
 341 SNPRINTFOBJS=""
 342 AC_CHECK_FUNCS(snprintf, , [mutt_cv_snprintf=yes])
 343 AC_CHECK_FUNCS(vsnprintf, , [mutt_cv_snprintf=yes])
 344 if test $mutt_cv_snprintf = yes; then
 345         AC_LIBOBJ(snprintf)
 346 fi
 347
 348 dnl SCO uses chsize() instead of ftruncate()
 349 AC_CHECK_FUNCS(ftruncate, , [AC_CHECK_LIB(x, chsize)])
 350
 351 dnl SCO has strftime() in libintl
 352 AC_CHECK_FUNCS(strftime, , [AC_CHECK_LIB(intl, strftime)])
 353
 354 dnl AIX may not have fchdir()
 355 AC_CHECK_FUNCS(fchdir, , [mutt_cv_fchdir=no])
 356
 357 AC_ARG_WITH(regex, AC_HELP_STRING([--with-regex], [Use the GNU regex library]),
 358         [mutt_cv_regex=yes],
 359         [AC_CHECK_FUNCS(regcomp, mutt_cv_regex=no, mutt_cv_regex=yes)])
 360
 361 if test $mutt_cv_regex = no ; then
 362 AC_CACHE_CHECK([whether your system's regexp library is completely broken],
 363         [mutt_cv_regex_broken],
 364         AC_TRY_RUN([
 365 #include <unistd.h>
 366 #include <regex.h>
 367 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
 368         mutt_cv_regex_broken=no, mutt_cv_regex_broken=yes, mutt_cv_regex_broken=yes))
 369         if test $mutt_cv_regex_broken = yes ; then
 370                 echo "Using the included GNU regex instead." >&AC_FD_MSG
 371                 mutt_cv_regex=yes
 372         fi
 373 fi
 374
 375 if test $mutt_cv_regex = yes; then
 376         AC_DEFINE(USE_GNU_REGEX,1,[ Define if you want to use the included regex.c. ])
 377         AC_LIBOBJ(regex)
 378 fi
 379
 380
 381 AC_ARG_WITH(homespool,
 382   AC_HELP_STRING([--with-homespool[=FILE]], [File in user's directory where new mail is spooled]), with_homespool=${withval})
 383 if test x$with_homespool != x; then
 384         if test $with_homespool = yes; then
 385                 with_homespool=mailbox
 386         fi
 387         AC_DEFINE_UNQUOTED(MAILPATH,"$with_homespool",[ Where new mail is spooled. ])
 388         AC_DEFINE(HOMESPOOL,1,
 389           [Is mail spooled to the user's home directory?  If defined,
 390            MAILPATH should be set to the filename of the spool mailbox
 391            relative the the home directory.
 392            use: configure --with-homespool=FILE])
 393         AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 394         mutt_cv_setgid=no
 395 else
 396         AC_ARG_WITH(mailpath, AC_HELP_STRING([--with-mailpath=DIR], [Directory where spool mailboxes are located]),
 397                 [mutt_cv_mailpath=$withval],
 398                 [ AC_CACHE_CHECK(where new mail is stored, mutt_cv_mailpath,
 399                         [mutt_cv_mailpath=no
 400                         if test -d /var/mail; then
 401                                 mutt_cv_mailpath=/var/mail
 402                         elif test -d /var/spool/mail; then
 403                                 mutt_cv_mailpath=/var/spool/mail
 404                         elif test -d /usr/spool/mail; then
 405                                 mutt_cv_mailpath=/usr/spool/mail
 406                         elif test -d /usr/mail; then
 407                                 mutt_cv_mailpath=/usr/mail
 408                         fi])
 409                 ])
 410         if test "$mutt_cv_mailpath" = no; then
 411                 AC_MSG_ERROR("Could not determine where new mail is stored.")
 412         fi
 413         AC_DEFINE_UNQUOTED(MAILPATH,"$mutt_cv_mailpath",[ Where new mail is spooled. ])
 414
 415         AC_CACHE_CHECK(if $mutt_cv_mailpath is world writable, mutt_cv_worldwrite, [AC_TRY_RUN([#include <sys/types.h>
 416 #include <sys/stat.h>
 417
 418 int main (int argc, char **argv)
 419 {
 420         struct stat s;
 421
 422         stat ("$mutt_cv_mailpath", &s);
 423         if (s.st_mode & S_IWOTH) exit (0);
 424         exit (1);
 425 }], mutt_cv_worldwrite=yes, mutt_cv_worldwrite=no, mutt_cv_worldwrite=no)])
 426
 427         mutt_cv_setgid=no
 428         if test $mutt_cv_worldwrite = yes; then
 429                 AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 430         else
 431
 432                 AC_CACHE_CHECK(if $mutt_cv_mailpath is group writable, mutt_cv_groupwrite, [AC_TRY_RUN([#include <sys/types.h>
 433 #include <sys/stat.h>
 434
 435 int main (int argc, char **argv)
 436 {
 437         struct stat s;
 438
 439         stat ("$mutt_cv_mailpath", &s);
 440         if (s.st_mode & S_IWGRP) exit (0);
 441         exit (1);
 442 }], mutt_cv_groupwrite=yes, mutt_cv_groupwrite=no, mutt_cv_groupwrite=no)])
 443
 444                 if test $mutt_cv_groupwrite = yes; then
 445                         AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 446                         AC_DEFINE(USE_SETGID,1,[ Define if mutt should run setgid "mail". ])
 447                         mutt_cv_setgid=yes
 448                 fi
 449         fi
 450 fi
 451
 452 AC_ARG_ENABLE(external_dotlock, AC_HELP_STRING([--enable-external-dotlock], [Force use of an external dotlock program]),
 453         [mutt_cv_external_dotlock="$enableval"])
 454
 455 if test "x$mutt_cv_setgid" = "xyes" || test "x$mutt_cv_fchdir" = "xno" \
 456         || test "x$mutt_cv_external_dotlock" = "xyes"
 457 then
 458         AC_DEFINE(DL_STANDALONE,1,[ Define if you want to use an external dotlocking program. ])
 459         DOTLOCK_TARGET="muttng_dotlock"
 460 else
 461         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS dotlock.o"
 462 fi
 463
 464 AC_SUBST(DOTLOCK_TARGET)
 465
 466
 467 AC_MSG_CHECKING(where to put the documentation)
 468 AC_ARG_WITH(docdir, AC_HELP_STRING([--with-docdir=PATH], [Specify where to put the documentation]),
 469         [mutt_cv_docdir=$withval],
 470         [mutt_cv_docdir="$mutt_cv_prefix/doc/muttng"])
 471 AC_MSG_RESULT($mutt_cv_docdir)
 472
 473 docdir=$mutt_cv_docdir
 474 AC_SUBST(docdir)
 475
 476 if test x$mutt_cv_setgid = xyes; then
 477         DOTLOCK_GROUP='mail'
 478         DOTLOCK_PERMISSION=2755
 479 else
 480         DOTLOCK_GROUP=''
 481         DOTLOCK_PERMISSION=755
 482 fi
 483 AC_SUBST(DOTLOCK_GROUP)
 484 AC_SUBST(DOTLOCK_PERMISSION)
 485
 486 AC_ARG_WITH(domain, AC_HELP_STRING([--with-domain=DOMAIN], [Specify your DNS domain name]),
 487         [if test $withval != yes; then
 488                 AC_DEFINE_UNQUOTED(DOMAIN,"$withval",[ Define your domain name. ])
 489         fi])
 490
 491 need_socket="no"
 492
 493 dnl -- socket dependencies --
 494
 495 AC_ARG_ENABLE(pop,  AC_HELP_STRING([--enable-pop], [Enable POP3 support]),
 496 [       if test x$enableval = xyes ; then
 497                 AC_DEFINE(USE_POP,1,[ Define if you want support for the POP3 protocol. ])
 498                 LIBPOP="-Lpop -lpop"
 499                 LIBPOPDEPS="\$(top_srcdir)/pop/pop.h pop/libpop.a"
 500                 need_socket="yes"
 501                 need_pop="yes"
 502                 need_md5="yes"
 503         fi
 504 ])
 505 AM_CONDITIONAL(BUILD_POP, test x$need_pop = xyes)
 506
 507 AC_ARG_ENABLE(imap, AC_HELP_STRING([--enable-imap], [Enable IMAP support]),
 508 [       if test x$enableval = xyes ; then
 509                 AC_DEFINE(USE_IMAP,1,[ Define if you want support for the IMAP protocol. ])
 510                 LIBIMAP="-Limap -limap"
 511                 LIBIMAPDEPS="\$(top_srcdir)/imap/imap.h imap/libimap.a"
 512                 need_imap="yes"
 513                 need_socket="yes"
 514                 need_md5="yes"
 515         fi
 516 ])
 517 AM_CONDITIONAL(BUILD_IMAP, test x$need_imap = xyes)
 518
 519 AC_ARG_ENABLE(nntp, [  --enable-nntp              Enable NNTP support],
 520 [       if test x$enableval = xyes ; then
 521                 AC_DEFINE(USE_NNTP)
 522                 LIBNNTP="-Lnntp -lnntp"
 523                 LIBNNTPDEPS="\$(top_srcdir)/nntp/nntp.h nntp/libnntp.a"
 524                 need_nntp="yes"
 525                 need_socket="yes"
 526         fi
 527 ])
 528 AM_CONDITIONAL(BUILD_NNTP, test x$need_nntp = xyes)
 529
 530 dnl -- end socket dependencies --
 531
 532 if test "$need_socket" = "yes"
 533 then
 534         AC_MSG_CHECKING([for socklen_t])
 535         AC_EGREP_HEADER(socklen_t, sys/socket.h, AC_MSG_RESULT([yes]),
 536                 AC_MSG_RESULT([no])
 537                 AC_DEFINE(socklen_t,int,
 538                         [ Define to 'int' if <sys/socket.h> doesn't have it. ]))
 539         AC_CHECK_FUNC(gethostent, , AC_CHECK_LIB(nsl, gethostent))
 540         AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt))
 541         AC_CHECK_FUNCS(getaddrinfo)
 542         AC_DEFINE(USE_SOCKET,1,
 543                 [ Include code for socket support. Set automatically if you enable POP3 or IMAP ])
 544         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS account.o mutt_socket.o mutt_tunnel.o"
 545 fi
 546
 547 dnl -- imap dependencies --
 548
 549 AC_ARG_WITH(gss, AC_HELP_STRING([--with-gss[=PFX]], [Compile in GSSAPI authentication for IMAP]),
 550     gss_prefix="$withval", gss_prefix="no")
 551 if test "$gss_prefix" != "no"
 552 then
 553   if test "$need_imap" = "yes"
 554   then
 555     MUTT_AM_PATH_GSSAPI(gss_prefix)
 556     AC_MSG_CHECKING(GSSAPI implementation)
 557     AC_MSG_RESULT($GSSAPI_IMPL)
 558     if test "$GSSAPI_IMPL" = "none"
 559     then
 560       AC_CACHE_SAVE
 561       AC_MSG_RESULT([GSSAPI libraries not found])
 562     fi
 563     if test "$GSSAPI_IMPL" = "Heimdal"
 564     then
 565       AC_DEFINE(HAVE_HEIMDAL,1,[ Define if your GSSAPI implementation is Heimdal ])
 566     fi
 567     CPPFLAGS="$CPPFLAGS $GSSAPI_CFLAGS"
 568     MUTTLIBS="$MUTTLIBS $GSSAPI_LIBS"
 569     AC_DEFINE(USE_GSS,1,[ Define if you have GSSAPI libraries available ])
 570     need_gss="yes"
 571   else
 572     AC_MSG_WARN([GSS was requested but IMAP is not enabled])
 573   fi
 574 fi
 575 AM_CONDITIONAL(USE_GSS, test x$need_gss = xyes)
 576
 577 dnl -- end imap dependencies --
 578
 579 AC_ARG_WITH(ssl, AC_HELP_STRING([--with-ssl[=PFX]], [Compile in SSL support for POP/IMAP]),
 580 [       if test "$with_ssl" != "no"
 581         then
 582           if test "$need_socket" != "yes"; then
 583            AC_MSG_ERROR([SSL support is only useful with POP or IMAP support])
 584           fi
 585
 586           if test "$with_ssl" != "yes"
 587           then
 588            LDFLAGS="$LDFLAGS -L$withval/lib"
 589            CPPFLAGS="$CPPFLAGS -I$withval/include"
 590           fi
 591           saved_LIBS="$LIBS"
 592
 593           AC_CHECK_LIB(crypto, X509_new,, AC_MSG_ERROR([Unable to find SSL library]))
 594           AC_CHECK_LIB(ssl, SSL_new,, AC_MSG_ERROR([Unable to find SSL library]), -lcrypto)
 595
 596           AC_CHECK_FUNCS(RAND_status RAND_egd)
 597
 598           AC_DEFINE(USE_SSL,1,[ Define if you want support for SSL. ])
 599           LIBS="$saved_LIBS"
 600           MUTTLIBS="$MUTTLIBS -lssl -lcrypto"
 601           MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_ssl.o"
 602           need_ssl=yes
 603
 604         fi
 605 ])
 606 AM_CONDITIONAL(USE_SSL, test x$need_ssl = xyes)
 607
 608 dnl SSL support via NSS
 609 AC_ARG_WITH(nss, AC_HELP_STRING([--with-nss[=PFX]], [Compile in SSL support for POP/IMAP via NSS]),
 610 [       if test "$with_nss" != no
 611         then
 612           if test "$need_socket" != "yes"; then
 613            AC_MSG_ERROR([SSL support is only useful with POP or IMAP support])
 614           fi
 615
 616           if test "$with_nss" != "yes"
 617           then
 618            LDFLAGS="$LDFLAGS -L$withval/lib"
 619            CPPFLAGS="$CPPFLAGS -I$withval/include -I$withval/public/security"
 620           fi
 621
 622           AC_DEFINE(USE_NSS,1,[ Define if you want support for SSL via the NSS library. ])
 623           MUTTLIBS="$MUTTLIBS -lssl -lnss -lcertdb -lcerthi -lcryptohi"
 624           MUTTLIBS="$MUTTLIBS -lpk11wrap -lsoftoken -lsecutil -ldbm -lplds4 -lplc4 -lfreebl"
 625           MUTTLIBS="$MUTTLIBS -lnspr4"
 626
 627           MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_ssl_nss.o"
 628           need_ssl=yes
 629         fi
 630 ])
 631
 632 AC_ARG_WITH([gnutls], AC_HELP_STRING([--with-gnutls[=PFX]], [Enable SSL support using gnutls]),
 633     [gnutls_prefix="$withval"], [gnutls_prefix="no"])
 634 if test "$gnutls_prefix" != "no"
 635 then
 636   if test "$need_socket" != "yes"
 637   then
 638     AC_MSG_ERROR([SSL support is only useful with POP or IMAP support])
 639   fi
 640   MUTT_AM_PATH_GNUTLS([$gnutls_prefix],
 641     [dnl GNUTLS found
 642     CPPFLAGS="$CPPFLAGS $LIBGNUTLS_CFLAGS"
 643     MUTTLIBS="$MUTTLIBS $LIBGNUTLS_LIBS"
 644     AC_DEFINE(USE_GNUTLS, 1, [Define if you want support for SSL via the gnutls library.])
 645
 646     MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_ssl_gnutls.o"
 647     need_ssl=yes],
 648     [dnl GNUTLS not found
 649       AC_MSG_ERROR([could not find libgnutls])
 650     ])
 651 fi
 652
 653 AC_ARG_WITH(sasl, AC_HELP_STRING([--with-sasl[=PFX]], [Use Cyrus SASL library for POP/IMAP authentication]),
 654         [
 655         if test "$with_sasl" != "no" -a "$need_imap" != "yes" -a "$need_pop" != "yes"
 656         then
 657           AC_MSG_ERROR([SASL support is only useful with POP or IMAP support])
 658         fi
 659
 660         if test "$with_sasl" != "no"
 661         then
 662           if test "$with_sasl" != "yes"
 663           then
 664             CPPFLAGS="$CPPFLAGS -I$with_sasl/include"
 665             LDFLAGS="$LDFLAGS -L$with_sasl/lib"
 666           fi
 667
 668           saved_LIBS="$LIBS"
 669
 670           AC_CHECK_LIB(sasl, sasl_client_init,,
 671             AC_MSG_ERROR([could not find libsasl]),)
 672
 673           MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_sasl.o"
 674           MUTTLIBS="$MUTTLIBS -lsasl"
 675           LIBS="$saved_LIBS"
 676           AC_DEFINE(USE_SASL,1,
 677                   [ Define if want to use the Cyrus SASL library for POP/IMAP authentication. ])
 678           need_sasl=yes
 679         fi
 680         ])
 681 AM_CONDITIONAL(USE_SASL, test x$need_sasl = xyes)
 682
 683 AC_ARG_WITH(sasl2, AC_HELP_STRING([--with-sasl2[=PFX]], [Use Cyrus SASL library version 2 for POP/IMAP authentication]),
 684         [
 685         if test "$with_sasl2" != "no" -a "$need_imap" != "yes" -a "$need_pop" != "yes"
 686         then
 687           AC_MSG_ERROR([SASL2 support is only useful with POP or IMAP support])
 688         fi
 689
 690         if test "$with_sasl2" != "no"
 691         then
 692           if test "$with_sasl2" != "yes"
 693           then
 694             CPPFLAGS="$CPPFLAGS -I$with_sasl2/include"
 695             LDFLAGS="$LDFLAGS -L$with_sasl2/lib"
 696           fi
 697
 698           saved_LIBS="$LIBS"
 699
 700           AC_CHECK_LIB(sasl2, sasl_client_init,,
 701             AC_MSG_ERROR([could not find libsasl2]),)
 702
 703           MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_sasl.o"
 704           MUTTLIBS="$MUTTLIBS -lsasl2"
 705           LIBS="$saved_LIBS"
 706           AC_DEFINE(USE_SASL,1,
 707                   [ Define if want to use the Cyrus SASL library for POP/IMAP authentication. ])
 708           AC_DEFINE(USE_SASL2,1,
 709                   [ Define if want to use version 2 of the Cyrus SASL library. ])
 710           need_sasl=yes
 711         fi
 712         ])
 713 AM_CONDITIONAL(USE_SASL, test x$need_sasl = xyes)
 714
 715 AC_ARG_WITH(idn, AC_HELP_STRING([--with-idn=[PFX]], [Use GNU libidn for domain names]),
 716                  [
 717                   if test "$with_idn" != "no" ; then
 718                         if test "$with_idn" != "yes" ; then
 719                            CPPFLAGS="$CPPFLAGS -I$with_idn/include"
 720                            LDFLAGS="$LDFLAGS -L$with_idn/lib"
 721                         fi
 722                   fi
 723                  ]
 724 )
 725
 726 if test "x$with_idn" != "xno"; then
 727    AC_CHECK_LIB(idn, stringprep_check_version)
 728    AC_CHECK_FUNCS(idna_to_unicode_utf8_from_utf8 idna_to_unicode_8z8z)
 729    AC_CHECK_FUNCS(idna_to_ascii_from_utf8 idna_to_ascii_8z)
 730    AC_CHECK_FUNCS(idna_to_ascii_lz idna_to_ascii_from_locale)
 731 fi
 732
 733 dnl -- end socket --
 734
 735 AC_ARG_ENABLE(debug, AC_HELP_STRING([--enable-debug], [Enable debugging support]),
 736         [ if test x$enableval = xyes ; then
 737                 AC_DEFINE(DEBUG,1,[ Define to enable debugging info. ])
 738           fi
 739          ])
 740
 741 AC_ARG_ENABLE(flock, AC_HELP_STRING([--enable-flock], [Use flock() to lock files]),
 742         [if test $enableval = yes; then
 743                 AC_DEFINE(USE_FLOCK,1, [ Define to use flock() to lock mailboxes. ])
 744         fi])
 745
 746 mutt_cv_fcntl=yes
 747 AC_ARG_ENABLE(fcntl, AC_HELP_STRING([--disable-fcntl], [Do NOT use fcntl() to lock files]),
 748         [if test $enableval = no; then mutt_cv_fcntl=no; fi])
 749
 750 if test $mutt_cv_fcntl = yes; then
 751         AC_DEFINE(USE_FCNTL,1, [ Define to use fcntl() to lock folders. ])
 752 fi
 753
 754 dnl This may look cumbersome -- please keep it that way, so we can
 755 dnl quickly change the default to "yes" again.
 756 mutt_cv_inodesort=no
 757 AC_ARG_ENABLE(inodesort,  AC_HELP_STRING([--enable-inodesort], [Read files in maildir folders sorted by inode.]),
 758        [if test x$enableval = xyes ; then mutt_cv_inodesort=yes; fi])
 759
 760 if test $mutt_cv_inodesort = yes; then
 761         AC_DEFINE(USE_INODESORT, 1, [ Define to sort files in a maildir by inode number. ])
 762 fi
 763
 764 mutt_cv_warnings=yes
 765 AC_ARG_ENABLE(warnings, AC_HELP_STRING([--disable-warnings], [Turn off compiler warnings (not recommended)]),
 766 [if test $enableval = no; then
 767         mutt_cv_warnings=no
 768 fi])
 769
 770 if test x$GCC = xyes -a $mutt_cv_warnings = yes; then
 771         CFLAGS="-Wall -pedantic $CFLAGS"
 772 fi
 773
 774 AC_ARG_ENABLE(nfs-fix, AC_HELP_STRING([--enable-nfs-fix], [Work around an NFS with broken attributes caching]),
 775         [if test x$enableval = xyes; then
 776                 AC_DEFINE(NFS_ATTRIBUTE_HACK,1,
 777                   [Define if you have problems with mutt not detecting
 778                    new/old mailboxes over NFS.  Some NFS implementations
 779                    incorrectly cache the attributes of small files.])
 780         fi])
 781
 782 AC_ARG_ENABLE(buffy-size, AC_HELP_STRING([--enable-buffy-size], [Use file size attribute instead of access time]),
 783         [if test x$enableval = xyes; then
 784                 AC_DEFINE(BUFFY_SIZE,1,[ Define to enable the "buffy_size" feature. ])
 785         fi])
 786
 787 AC_ARG_ENABLE(mailtool, AC_HELP_STRING([--enable-mailtool], [Enable Sun mailtool attachments support ]),
 788         [if test x$enableval = xyes; then
 789                 AC_DEFINE(SUN_ATTACHMENT,1,[ Define to enable Sun mailtool attachments support. ])
 790         fi])
 791
 792 AC_ARG_ENABLE(compressed, [  --enable-compressed        Enable compressed folders support ],
 793         [if test x$enableval = xyes; then
 794                 AC_DEFINE(USE_COMPRESSED)
 795         fi])
 796
 797 AC_ARG_ENABLE(locales-fix, AC_HELP_STRING([--enable-locales-fix], [The result of isprint() is unreliable ]),
 798         [if test x$enableval = xyes; then
 799                 AC_DEFINE(LOCALES_HACK,1,[ Define if the result of isprint() is unreliable. ])
 800         fi])
 801
 802 AC_ARG_WITH(exec-shell, AC_HELP_STRING([--with-exec-shell=SHELL], [Specify alternate shell (ONLY if /bin/sh is broken)]),
 803         [if test $withval != yes; then
 804                 AC_DEFINE_UNQUOTED(EXECSHELL, "$withval",
 805                  [program to use for shell commands])
 806          else
 807                 AC_DEFINE_UNQUOTED(EXECSHELL, "/bin/sh")
 808         fi],
 809         [AC_DEFINE_UNQUOTED(EXECSHELL, "/bin/sh")])
 810
 811 dnl -- start cache --
 812 AC_ARG_ENABLE(hcache, AC_HELP_STRING([--enable-hcache], [Enable header caching]),
 813 [if test x$enableval = xyes; then
 814     AC_DEFINE(USE_HCACHE, 1, [Enable header caching])
 815
 816     OLDCPPFLAGS="$CPPFLAGS"
 817     OLDLIBS="$LIBS"
 818
 819     need_md5="yes"
 820
 821     ac_prefer_qdbm=yes
 822     AC_ARG_WITH(qdbm, AC_HELP_STRING([--without-qdbm], [Don't use qdbm even if it is available]),
 823         ac_prefer_qdbm=$withval)
 824     if test x$ac_prefer_qdbm != xno; then
 825         ac_cv_vlopen=no
 826         QDBM_DIRS="$mutt_cv_prefix /usr/local /usr"
 827         AC_MSG_CHECKING([for vlopen])
 828         for d in $QDBM_DIRS; do
 829           if test x$ac_cv_vlopen = xno && test -d "$d/include" && test -d "$d/lib"; then
 830             QDBM_INC="-I$d/include"
 831             QDBM_LIB="-L$d/lib"
 832             CPPFLAGS="$OLDCPPFLAGS $QDBM_INC"
 833             LIBS="$OLDLIBS $QDBM_LIB -lqdbm"
 834             AC_TRY_LINK([#include <villa.h>],[vlopen(0,0,0);],[ac_cv_vlopen=yes])
 835           fi
 836         done
 837         if test x$ac_cv_vlopen = xyes; then
 838           AC_MSG_RESULT(yes)
 839         else
 840           AC_MSG_RESULT(no)
 841         fi
 842     fi
 843
 844     ac_prefer_gdbm=yes
 845     AC_ARG_WITH(gdbm, AC_HELP_STRING([--without-gdbm], [Don't use gdbm even if it is available]),
 846         ac_prefer_gdbm=$withval)
 847     if test x$ac_prefer_gdbm != xno -a x$ac_cv_vlopen != xyes; then
 848         ac_cv_gdbmopen=no
 849         GDBM_DIRS="$mutt_cv_prefix /usr/local /usr"
 850         AC_MSG_CHECKING([for gdbm_open])
 851         for d in $GDBM_DIRS; do
 852           if test x$ac_cv_gdbmopen = xno && test -d "$d/include" && test -d "$d/lib"; then
 853             GDBM_INC="-I$d/include"
 854             GDBM_LIB="-L$d/lib"
 855             CPPFLAGS="$OLDCPPFLAGS $GDBM_INC"
 856             LIBS="$OLDLIBS $GDBM_LIB -lgdbm"
 857             AC_TRY_LINK([#include <gdbm.h>],[gdbm_open(0,0,0,0,0);],[ac_cv_gdbmopen=yes])
 858           fi
 859         done
 860         if test x$ac_cv_gdbmopen = xyes; then
 861           AC_MSG_RESULT(yes)
 862         else
 863           AC_MSG_RESULT(no)
 864         fi
 865     fi
 866
 867     ac_bdb_prefix=yes
 868     AC_ARG_WITH(bdb, AC_HELP_STRING([--with-bdb[=DIR]], [Use BerkeleyDB4 if gdbm is not available ]),
 869         ac_bdb_prefix=$withval)
 870     if test x$ac_bdb_prefix != xno -a x$ac_cv_gdbmopen != xyes -a x$ac_cv_vlopen != xyes; then
 871         test x$ac_bdb_prefix = xyes && ac_bdb_prefix="$mutt_cv_prefix /opt/csw/bdb4 /opt /usr/local /usr"
 872         for d in $ac_bdb_prefix; do
 873             bdbpfx="$bdbpfx $d"
 874             for v in BerkeleyDB.4.3 BerkeleyDB.4.2 BerkeleyDB.4.1; do
 875                 bdbpfx="$bdbpfx $d/$v"
 876             done
 877         done
 878         BDB_VERSIONS="db-4 db4 db-4.3 db4.3 db43 db-4.2 db4.2 db42 db-4.1 db4.1 db41 db ''"
 879         AC_MSG_CHECKING([for BerkeleyDB > 4.0])
 880         for d in $bdbpfx; do
 881             BDB_INCLUDE_DIR=""
 882             BDB_LIB_DIR=""
 883             for v in / $BDB_VERSIONS; do
 884                 if test -r "$d/include/$v/db.h"; then
 885                     BDB_INCLUDE_DIR="$d/include/$v"
 886                     if test -d "$d/lib/$v"; then
 887                         BDB_LIB_DIR="$d/lib/$v"
 888                         for l in `echo $BDB_VERSIONS`; do
 889                             CPPFLAGS="-I$BDB_INCLUDE_DIR $OLDCPPFLAGS"
 890                             LIBS="$OLDLIBS -L$BDB_LIB_DIR -l$l"
 891                             AC_TRY_LINK([
 892                                 #include <stdlib.h>
 893                                 #include <db.h>
 894                             ],[
 895                                 DB *db = NULL;
 896                                 db->open(db,NULL,NULL,NULL,0,0,0);
 897                             ],[
 898                                 ac_cv_dbcreate=yes
 899                                 BDB_LIB="$l"
 900                                 break
 901                             ])
 902                         done
 903                         test x$ac_dbcreate = xyes && break
 904                     fi
 905                 fi
 906             done
 907             test x$BDB_LIB != x && break
 908         done
 909         if test x$ac_cv_dbcreate = xyes; then
 910             AC_MSG_RESULT(yes)
 911         else
 912             AC_MSG_RESULT(no)
 913         fi
 914     fi
 915
 916     if test x$ac_cv_vlopen = xyes; then
 917         CPPFLAGS="$OLDCPPFLAGS $QDBM_INC"
 918         LIBS="$OLDLIBS $QDBM_LIB -lqdbm"
 919         AC_DEFINE(HAVE_QDBM, 1, [QDBM Support])
 920     elif test x$ac_cv_gdbmopen = xyes; then
 921         CPPFLAGS="$OLDCPPFLAGS $GDBM_INC"
 922         LIBS="$OLDLIBS $GDBM_LIB -lgdbm";
 923         AC_DEFINE(HAVE_GDBM, 1, [GDBM Support])
 924     elif test x$ac_cv_dbcreate = xyes; then
 925         CPPFLAGS="-I$BDB_INCLUDE_DIR $OLDCPPFLAGS"
 926         LIBS="$OLDLIBS -L$BDB_LIB_DIR -l$BDB_LIB"
 927         AC_DEFINE(HAVE_DB4, 1, [Sleepycat DB4 Support])
 928     else
 929         AC_MSG_ERROR(You need QDBM, GDBM or Sleepycat DB4 for --enable-hcache)
 930     fi
 931 fi])
 932 dnl -- end cache --
 933
 934 AC_SUBST(MUTTLIBS)
 935 AC_SUBST(MUTT_LIB_OBJECTS)
 936 AC_SUBST(LIBIMAP)
 937 AC_SUBST(LIBIMAPDEPS)
 938 AC_SUBST(LIBPOP)
 939 AC_SUBST(LIBPOPDEPS)
 940 AC_SUBST(LIBNNTP)
 941 AC_SUBST(LIBNNTPDEPS)
 942
 943 dnl -- iconv/gettext --
 944
 945 AC_ARG_ENABLE(iconv, AC_HELP_STRING([--disable-iconv], [Disable iconv support]),
 946         [if test x$enableval = xno ; then
 947                 am_cv_func_iconv=no
 948         fi
 949 ])
 950
 951 MUTT_AM_GNU_GETTEXT
 952
 953 if test "$am_cv_func_iconv" != "yes"
 954 then
 955   AC_MSG_WARN([Configuring without iconv support. See INSTALL for details])
 956 else
 957
 958 AC_CHECK_HEADERS(iconv.h,
 959         [AC_MSG_CHECKING(whether iconv.h defines iconv_t)
 960          AC_EGREP_HEADER([typedef.*iconv_t],iconv.h,
 961                 [AC_MSG_RESULT(yes)
 962                  AC_DEFINE(HAVE_ICONV_T_DEF, 1,
 963                         [Define if <iconv.h> defines iconv_t.])],
 964                  AC_MSG_RESULT(no))])
 965
 966 dnl (1) Some implementations of iconv won't convert from UTF-8 to UTF-8.
 967 dnl (2) In glibc-2.1.2 and earlier there is a bug that messes up ob and
 968 dnl     obl when args 2 and 3 are 0 (fixed in glibc-2.1.3).
 969 AC_CACHE_CHECK([whether this iconv is good enough], mutt_cv_iconv_good,
 970         mutt_save_LIBS="$LIBS"
 971         LIBS="$LIBS $LIBICONV"
 972         AC_TRY_RUN([
 973 #include <iconv.h>
 974 int main()
 975 {
 976   iconv_t cd;
 977 changequote(, )dnl
 978   char buf[4];
 979 changequote([, ])dnl
 980   char *ob;
 981   size_t obl;
 982   ob = buf, obl = sizeof(buf);
 983   return ((cd = iconv_open("UTF-8", "UTF-8")) != (iconv_t)(-1) &&
 984           (iconv(cd, 0, 0, &ob, &obl) ||
 985            !(ob == buf && obl == sizeof(buf)) ||
 986            iconv_close(cd)));
 987 }
 988                 ],
 989                 mutt_cv_iconv_good=yes,
 990                 mutt_cv_iconv_good=no,
 991                 mutt_cv_iconv_good=yes)
 992         LIBS="$mutt_save_LIBS")
 993 if test "$mutt_cv_iconv_good" = no; then
 994   AC_MSG_ERROR(Try using libiconv instead)
 995 fi
 996
 997 dnl This is to detect implementations such as the one in glibc-2.1,
 998 dnl which always convert exactly but return the number of characters
 999 dnl converted instead of the number converted inexactly.
1000 AC_CACHE_CHECK([whether iconv is non-transcribing], mutt_cv_iconv_nontrans,
1001         mutt_save_LIBS="$LIBS"
1002         LIBS="$LIBS $LIBICONV"
1003         AC_TRY_RUN([
1004 #include <iconv.h>
1005 #include <string.h>
1006 int main()
1007 {
1008   iconv_t cd;
1009   const char *ib;
1010   char *ob;
1011   size_t ibl, obl;
1012   const char *s = "\304\211";
1013 changequote(, )dnl
1014   char t[3];
1015 changequote([, ])dnl
1016   ib = s, ibl = 2, ob = t, obl = 3;
1017   return ((cd = iconv_open("UTF-8", "UTF-8")) == (iconv_t)(-1) ||
1018           iconv(cd, &ib, &ibl, &ob, &obl));
1019 }
1020                 ],
1021                 mutt_cv_iconv_nontrans=no,
1022                 mutt_cv_iconv_nontrans=yes,
1023                 mutt_cv_iconv_nontrans=no)
1024         LIBS="$mutt_save_LIBS")
1025 if test "$mutt_cv_iconv_nontrans" = yes; then
1026   AC_DEFINE(ICONV_NONTRANS, 1)
1027 else
1028   AC_DEFINE(ICONV_NONTRANS, 0)
1029 fi
1030
1031 CPPFLAGS="$CPPFLAGS -I\$(top_srcdir)/intl"
1032
1033 if test "$BUILD_INCLUDED_LIBINTL" = "yes"; then
1034   AC_DEFINE(HAVE_BIND_TEXTDOMAIN_CODESET,1,
1035           [ Define if your gettext has bind_textdomain_codeset. ])
1036 else
1037   AC_CHECK_FUNCS(bind_textdomain_codeset)
1038 fi
1039
1040 fi # libiconv
1041
1042 dnl -- locales --
1043
1044 AC_CHECK_HEADERS(wchar.h)
1045
1046 AC_CACHE_CHECK([for wchar_t], mutt_cv_wchar_t,
1047         AC_TRY_COMPILE([
1048 #include <stddef.h>
1049 #include <stdlib.h>
1050 #ifdef HAVE_WCHAR_H
1051 #include <wchar.h>
1052 #endif
1053                 ],
1054                 [ wchar_t wc; return 0; ],
1055                 mutt_cv_wchar_t=yes,
1056                 mutt_cv_wchar_t=no))
1057
1058 if test "$mutt_cv_wchar_t" = no; then
1059         AC_DEFINE(wchar_t,int,[ Define to 'int' if system headers don't define. ])
1060 fi
1061
1062 AC_CACHE_CHECK([for wint_t], mutt_cv_wint_t,
1063         AC_TRY_COMPILE([
1064 #include <stddef.h>
1065 #include <stdlib.h>
1066 #ifdef HAVE_WCHAR_H
1067 #include <wchar.h>
1068 #endif
1069                 ],
1070                 [ wint_t wc; return 0; ],
1071                 mutt_cv_wint_t=yes,
1072                 mutt_cv_wint_t=no))
1073
1074 if test "$mutt_cv_wint_t" = no; then
1075         AC_DEFINE(wint_t,int,[ Define to 'int' if system headers don't define. ])
1076 fi
1077
1078 AC_CHECK_HEADERS(wctype.h)
1079 AC_CHECK_FUNCS(iswalnum iswalpha  iswcntrl iswdigit)
1080 AC_CHECK_FUNCS(iswgraph iswlower iswprint iswpunct iswspace iswupper)
1081 AC_CHECK_FUNCS(iswxdigit towupper towlower)
1082
1083 AC_CACHE_CHECK([for mbstate_t], mutt_cv_mbstate_t,
1084         AC_TRY_COMPILE([
1085 #include <stddef.h>
1086 #include <stdlib.h>
1087 #ifdef HAVE_WCHAR_H
1088 #include <wchar.h>
1089 #endif
1090                 ],
1091                 [ mbstate_t s; return 0; ],
1092                 mutt_cv_mbstate_t=yes,
1093                 mutt_cv_mbstate_t=no))
1094
1095 if test "$mutt_cv_mbstate_t" = no; then
1096         AC_DEFINE(mbstate_t,int,[ Define to 'int' if system headers don't define. ])
1097 fi
1098
1099 wc_funcs=maybe
1100 AC_ARG_WITH(wc-funcs, AC_HELP_STRING([--without-wc-funcs], [Do not use the system's wchar_t functions]),
1101         wc_funcs=$withval)
1102
1103 if test "$wc_funcs" != yes -a "$wc_funcs" != no; then
1104         AC_CACHE_CHECK([for wchar_t functions], mutt_cv_wc_funcs,
1105                 mutt_cv_wc_funcs=no
1106                 AC_TRY_LINK([
1107 #define _XOPEN_SOURCE 1
1108 #include <stddef.h>
1109 #include <stdlib.h>
1110 #ifdef HAVE_WCTYPE_H
1111 #include <wctype.h>
1112 #endif
1113 #ifdef HAVE_WCHAR_H
1114 #include <wchar.h>
1115 #endif],
1116                         [mbrtowc(0, 0, 0, 0); wctomb(0, 0); wcwidth(0);
1117         iswprint(0); iswspace(0); towlower(0); towupper(0); iswalnum(0)],
1118                         mutt_cv_wc_funcs=yes))
1119         wc_funcs=$mutt_cv_wc_funcs
1120 fi
1121
1122 if test $wc_funcs = yes; then
1123         AC_DEFINE(HAVE_WC_FUNCS,1,[ Define if you are using the system's wchar_t functions. ])
1124 fi
1125
1126 AC_CACHE_CHECK([for nl_langinfo and CODESET], mutt_cv_langinfo_codeset,
1127   [AC_TRY_LINK([#include <langinfo.h>],
1128     [char* cs = nl_langinfo(CODESET);],
1129     mutt_cv_langinfo_codeset=yes,
1130     mutt_cv_langinfo_codeset=no)])
1131 if test $mutt_cv_langinfo_codeset = yes; then
1132   AC_DEFINE(HAVE_LANGINFO_CODESET,1,[ Define if you have <langinfo.h> and nl_langinfo(CODESET). ])
1133 fi
1134
1135 AC_CACHE_CHECK([for nl_langinfo and YESEXPR], mutt_cv_langinfo_yesexpr,
1136   [AC_TRY_LINK([#include <langinfo.h>],
1137     [char* cs = nl_langinfo(YESEXPR);],
1138     mutt_cv_langinfo_yesexpr=yes,
1139     mutt_cv_langinfo_yesexpr=no)])
1140 if test $mutt_cv_langinfo_yesexpr = yes; then
1141   AC_DEFINE(HAVE_LANGINFO_YESEXPR,1,[ Define if you have <langinfo.h> and nl_langinfo(YESEXPR). ])
1142 fi
1143
1144 dnl -- libesmtp --
1145 MUTT_AM_LIBESMTP
1146 if test x$use_libesmtp = xyes; then
1147     CFLAGS="$CFLAGS $mutt_libesmtp_cflags"
1148     MUTTLIBS="$MUTTLIBS $mutt_libesmtp_libs"
1149     MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_libesmtp.o"
1150
1151     AC_DEFINE(USE_LIBESMTP,
1152               1,
1153               [Define to enable the use of libesmtp])
1154 fi
1155 dnl -- end libesmtp --
1156
1157 dnl -- sgml tools --
1158 AC_MSG_CHECKING([for SGML Tools style])
1159 SGML2TXT_CMD="true"
1160 SGML2PS_CMD="true"
1161 SGML2HTML_CMD="true"
1162 case "`uname -s`" in
1163   FreeBSD)
1164     SGML2TXT_CMD="sgmlfmt -f ascii manual.sgml && uniq < manual.ascii | expand > manual.txt && rm -rf manual.ascii || true"
1165     SGML2PS_CMD="sgmlfmt -f ps manual.sgml || true"
1166     SGML2HTML_CMD="sgmlfmt -f html manual.sgml || true"
1167     AC_MSG_RESULT(FreeBSD)
1168     ;;
1169   SunOS)
1170     SGML2TXT_CMD="sgml2txt manual || true"
1171     SGML2PS_CMD="sgml2latex -p manual || true"
1172     SGML2HTML_CMD="sgml2html manual || true"
1173     AC_MSG_RESULT(Solaris)
1174     ;;
1175   *)
1176     SGML2TXT_CMD="if linuxdoc -B txt --pass='-P -c' manual ; then uniq < manual.txt | expand > _manual.txt ; rm manual.txt ; col -b < _manual.txt > manual.txt ; rm -rf _manual.txt ; fi || true"
1177     SGML2PS_CMD="sgml2latex --output=ps manual || true"
1178     SGML2HTML_CMD="sgml2html manual || true"
1179     AC_MSG_RESULT(Linux (default))
1180     ;;
1181 esac
1182 AC_SUBST(SGML2TXT_CMD)
1183 AC_SUBST(SGML2PS_CMD)
1184 AC_SUBST(SGML2HTML_CMD)
1185
1186 AC_OUTPUT(Makefile intl/Makefile m4/Makefile
1187         po/Makefile.in doc/Makefile contrib/Makefile
1188         muttbug.sh
1189         lib/Makefile
1190         imap/Makefile
1191         pop/Makefile
1192         nntp/Makefile
1193         Muttngrc.head
1194         doc/instdoc.sh)