configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl !!! WHEN ADDING NEW CONFIGURE TESTS, PLEASE ADD CODE TO MAIN.C !!!
   4 dnl !!! TO DUMP THEIR RESULTS WHEN MUTT -V IS CALLED            !!!
   5
   6 AC_PREREQ([2.50])
   7 AC_INIT([mutt.h])
   8 AM_CONFIG_HEADER(config.h)
   9
  10 mutt_cv_version=`cat "$srcdir/VERSION.in"`
  11
  12 AM_INIT_AUTOMAKE(muttng, $mutt_cv_version)
  13 AC_SUBST([CONFIGURE_DEPENDENCIES], ['$(top_srcdir)/VERSION.in'])
  14
  15 dnl AC_GNU_SOURCE
  16
  17 ifdef([AC_LIBOBJ], , [define([AC_LIBOBJ], [LIB[]OBJS="$LIBOBJS $1.o"])])
  18
  19 ALL_LINGUAS="de ru it es uk fr pl nl cs id sk ko el zh_TW zh_CN pt_BR eo gl sv da lt tr ja hu et ca bg"
  20
  21 AC_CANONICAL_HOST
  22
  23 AC_MSG_CHECKING([for prefix])
  24 if test x$prefix = xNONE; then
  25         mutt_cv_prefix=$ac_default_prefix
  26 else
  27         mutt_cv_prefix=$prefix
  28 fi
  29 AC_MSG_RESULT($mutt_cv_prefix)
  30
  31 AC_PROG_CC
  32 AC_ISC_POSIX
  33 AM_C_PROTOTYPES
  34 if test "x$U" != "x"; then
  35   AC_MSG_ERROR(Compiler not ANSI compliant)
  36 fi
  37 AC_PROG_CPP
  38 AC_PROG_MAKE_SET
  39 AC_PROG_INSTALL
  40 AC_PROG_RANLIB
  41 AC_CHECK_TOOL(AR, ar, ar)
  42
  43 AC_C_INLINE
  44 AC_C_CONST
  45
  46 AC_SYS_LARGEFILE
  47 AC_FUNC_FSEEKO
  48 AC_CHECK_SIZEOF(off_t)
  49
  50 AC_PATH_PROG(DBX, dbx, no)
  51 AC_PATH_PROG(GDB, gdb, no)
  52 AC_PATH_PROG(SDB, sdb, no)
  53
  54 if test $GDB != no ; then
  55         DEBUGGER=$GDB
  56 elif test $DBX != no ; then
  57         DEBUGGER=$DBX
  58 elif test $SDB != no ; then
  59         DEBUGGER=$SDB
  60 else
  61         DEBUGGER=no
  62 fi
  63
  64 AC_SUBST([DEBUGGER])
  65
  66 AH_TEMPLATE([sig_atomic_t],
  67             [/* Define to `int' if <signal.h> doesn't define.])
  68 AH_TEMPLATE([HAVE_START_COLOR],
  69             [Define if you have start_color, as a function or macro.])
  70 AH_TEMPLATE([HAVE_TYPEAHEAD],
  71             [Define if you have typeahead, as a function or macro.])
  72 AH_TEMPLATE([HAVE_BKGDSET],
  73             [Define if you have bkgdset, as a function or macro.])
  74 AH_TEMPLATE([HAVE_CURS_SET],
  75             [Define if you have curs_set, as a function or macro.])
  76 AH_TEMPLATE([HAVE_META],
  77             [Define if you have meta, as a function or macro.])
  78 AH_TEMPLATE([HAVE_USE_DEFAULT_COLORS],
  79             [Define if you have use_default_colors, as a function or macro.])
  80 AH_TEMPLATE([HAVE_RESIZETERM],
  81             [Define if you have resizeterm, as a function or macro.])
  82 AH_TEMPLATE([SIG_ATOMIC_VOLATILE_T],
  83             [Some systems declare sig_atomic_t as volatile, some others -- no.
  84              This define will have value `sig_atomic_t' or
  85              `volatile sig_atomic_t' accordingly.])
  86 AH_TEMPLATE([ICONV_NONTRANS],
  87             [Define as 1 if iconv() only converts exactly and we should treat
  88              all return values other than (size_t)(-1) as equivalent.])
  89
  90 MUTT_C99_INTTYPES
  91
  92 ac_aux_path_sendmail=/usr/sbin:/usr/lib
  93 AC_PATH_PROG(SENDMAIL, sendmail, /usr/sbin/sendmail, $PATH:$ac_aux_path_sendmail)
  94 AC_DEFINE_UNQUOTED(SENDMAIL,"$ac_cv_path_SENDMAIL",[ Where to find sendmail on your system. ])
  95
  96 OPS='$(srcdir)/OPS'
  97
  98         AC_ARG_ENABLE(gpgme, AC_HELP_STRING([--enable-gpgme], [Enable GPGME support]),
  99         [       if test x$enableval = xyes; then
 100                         have_gpgme=yes
 101                 fi
 102         ])
 103         AC_ARG_WITH(gpgme-prefix, AC_HELP_STRING([--with-gpgme-prefix=PFX], [prefix where GPGME is installed (optional)]),
 104         gpgme_config_prefix="$withval", gpgme_config_prefix="")
 105
 106         if test x$have_gpgme = xyes; then
 107                 if test x$gpgme_config_prefix != x; then
 108                         GPGME_CONFIG="$gpgme_config_prefix/bin/gpgme-config"
 109                 else
 110                         AC_PATH_PROG(GPGME_CONFIG, gpgme-config, no)
 111                 fi
 112                 if test "x$GPGME_CONFIG" = "xno"; then
 113                         AC_MSG_ERROR([GPGME not found])
 114                 else
 115                         LIBGPGME_CFLAGS=`$GPGME_CONFIG --cflags`
 116                         LIBGPGME_LIBS=`$GPGME_CONFIG --libs`
 117       MUTTLIBS="$MUTTLIBS $LIBGPGME_LIBS"
 118                         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS crypt-gpgme.o crypt-mod-pgp-gpgme.o crypt-mod-smime-gpgme.o"
 119                         AC_DEFINE(CRYPT_BACKEND_GPGME, 1,
 120                                   [Defined, if GPGME support is enabled])
 121                 fi
 122         fi
 123         AC_SUBST(LIBGPGME_CFLAGS)
 124         AC_SUBST(LIBGPGME_LIBS)
 125
 126         AC_ARG_ENABLE(pgp, AC_HELP_STRING([--disable-pgp], [Disable PGP support]),
 127         [       if test x$enableval = xno ; then
 128                         have_pgp=no
 129                 fi
 130         ])
 131
 132         if test x$have_pgp != xno ; then
 133                 AC_DEFINE(CRYPT_BACKEND_CLASSIC_PGP,1,
 134                     [ Define if you want classic PGP support. ])
 135                 PGPAUX_TARGET="pgpringng\$(EXEEXT) pgpewrapng\$(EXEEXT)"
 136                 MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS pgp.o pgpinvoke.o pgpkey.o pgplib.o gnupgparse.o pgpmicalg.o pgppacket.o crypt-mod-pgp-classic.o"
 137         fi
 138
 139         AC_ARG_ENABLE(smime, AC_HELP_STRING([--disable-smime], [Disable SMIME support]),
 140         [       if test x$enableval = xno ; then
 141                         have_smime=no
 142                 fi
 143         ])
 144
 145         if test x$have_smime != xno ; then
 146                 AC_DEFINE(CRYPT_BACKEND_CLASSIC_SMIME,1,
 147                   [ Define if you want clasic S/MIME support. ])
 148                 MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS smime.o crypt-mod-smime-classic.o"
 149                 SMIMEAUX_TARGET="smime_keysng"
 150         fi
 151
 152         AC_ARG_WITH(mixmaster, AC_HELP_STRING([--with-mixmaster[=PATH]], [Include Mixmaster support]),
 153                 [if test -x "$withval" ; then
 154                         MIXMASTER="$withval"
 155                  else
 156                         MIXMASTER="mixmaster"
 157                  fi
 158                  OPS="$OPS \$(srcdir)/OPS.MIX"
 159                  MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS remailer.o"
 160                  AC_DEFINE_UNQUOTED(MIXMASTER,"$MIXMASTER",
 161                          [ Where to find mixmaster on your system. ])
 162                 ])
 163
 164 # We now require all OPS
 165 OPS="$OPS \$(srcdir)/OPS.PGP \$(srcdir)/OPS.SMIME \$(srcdir)/OPS.CRYPT "
 166 AC_SUBST([OPS])
 167
 168
 169 AC_SUBST(PGPAUX_TARGET)
 170 AC_SUBST(SMIMEAUX_TARGET)
 171
 172 AC_PATH_PROG(ISPELL, ispell, no)
 173 if test $ISPELL != no; then
 174         AC_DEFINE_UNQUOTED(ISPELL,"$ISPELL",[ Where to find ispell on your system. ])
 175 fi
 176
 177 AC_ARG_WITH(slang, AC_HELP_STRING([--with-slang[=DIR]], [Use S-Lang instead of ncurses]),
 178         [AC_CACHE_CHECK([if this is a BSD system], mutt_cv_bsdish,
 179                 [AC_TRY_RUN([#include <sys/param.h>
 180
 181 main ()
 182 {
 183 #ifdef BSD
 184         exit (0);
 185 #else
 186         exit (1);
 187 #endif
 188 }],
 189                         mutt_cv_bsdish=yes,
 190                         mutt_cv_bsdish=no,
 191                         mutt_cv_bsdish=no)])
 192
 193         AC_MSG_CHECKING(for S-Lang)
 194         if test $withval = yes; then
 195                 if test -d $srcdir/../slang; then
 196                         mutt_cv_slang=$srcdir/../slang/src
 197                         CFLAGS="$CFLAGS -I${mutt_cv_slang}"
 198                         LDFLAGS="$LDFLAGS -L${mutt_cv_slang}/objs"
 199                 else
 200                         if test -d $mutt_cv_prefix/include/slang; then
 201                                 CFLAGS="$CFLAGS -I$mutt_cv_prefix/include/slang"
 202                         elif test -d /usr/include/slang; then
 203                                 CFLAGS="$CFLAGS -I/usr/include/slang"
 204                         fi
 205                         mutt_cv_slang=yes
 206                 fi
 207         else
 208                 dnl ---Check to see if $withval is a source directory
 209                 if test -f $withval/src/slang.h; then
 210                         mutt_cv_slang=$withval/src
 211                         CFLAGS="$CFLAGS -I${mutt_cv_slang}"
 212                         LDFLAGS="$LDFLAGS -L${mutt_cv_slang}/objs"
 213                 else
 214                         dnl ---Must be installed somewhere
 215                         mutt_cv_slang=$withval
 216                         if test -d $withval/include/slang; then
 217                                 CFLAGS="$CFLAGS -I${withval}/include/slang"
 218                         elif test -d $withval/include; then
 219                                 CFLAGS="$CFLAGS -I${withval}/include"
 220                         fi
 221                         LDFLAGS="$LDFLAGS -L${withval}/lib"
 222                 fi
 223         fi
 224         AC_MSG_RESULT($mutt_cv_slang)
 225         if test $mutt_cv_bsdish = yes; then
 226                 AC_CHECK_LIB(termlib, main)
 227         fi
 228         AC_DEFINE(USE_SLANG_CURSES,1,
 229                 [ Define if you compile with SLang instead of curses/ncurses. ])
 230         AC_DEFINE(HAVE_COLOR,1,[ Define if your curses library supports color. ])
 231         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS resize.o"
 232
 233         dnl --- now that we've found it, check the link
 234
 235         AC_CHECK_LIB(slang, SLtt_get_terminfo,
 236                 [MUTTLIBS="$MUTTLIBS -lslang -lm"],
 237                 [AC_MSG_ERROR(unable to compile.  check config.log)], -lm)
 238
 239         ],
 240
 241         [mutt_cv_curses=/usr
 242         AC_ARG_WITH(curses, AC_HELP_STRING([--with-curses=DIR], [Where ncurses is installed]),
 243                 [if test $withval != yes; then
 244                         mutt_cv_curses=$withval
 245                 fi
 246                 if test x$mutt_cv_curses != x/usr; then
 247                         LDFLAGS="-L${mutt_cv_curses}/lib $LDFLAGS"
 248                         CPPFLAGS="$CPPFLAGS -I${mutt_cv_curses}/include"
 249                 fi])
 250
 251         AC_CHECK_FUNC(initscr,,[
 252         cf_ncurses="ncurses"
 253         for lib in ncursesw ncurses
 254         do
 255                 AC_CHECK_LIB($lib, waddnwstr, [cf_ncurses="$lib"; break])
 256         done
 257         AC_CHECK_LIB($cf_ncurses, initscr,
 258                 [MUTTLIBS="$MUTTLIBS -l$cf_ncurses"
 259                 if test x$mutt_cv_curses = x/usr -a -d /usr/include/ncurses; then
 260                         CPPFLAGS="$CPPFLAGS -I/usr/include/ncurses"
 261                 fi
 262
 263                 if test "$cf_ncurses" = ncursesw; then
 264                         AC_CHECK_HEADERS(ncurses/ncurses.h,[cf_cv_ncurses_header="ncurses/ncurses.h"])
 265                         AC_CHECK_HEADERS(ncursesw/ncurses.h,[cf_cv_ncurses_header="ncursesw/ncurses.h"])
 266                 else
 267                         AC_CHECK_HEADERS(ncurses.h,[cf_cv_ncurses_header="ncurses.h"])
 268                 fi],
 269
 270                 [CF_CURSES_LIBS])
 271                 ])
 272
 273         old_LIBS="$LIBS"
 274         LIBS="$LIBS $MUTTLIBS"
 275         CF_CHECK_FUNCDECLS([#include <${cf_cv_ncurses_header-curses.h}>],
 276                            [start_color typeahead bkgdset curs_set meta use_default_colors resizeterm])
 277         if test "$ac_cv_func_decl_start_color" = yes; then
 278                 AC_DEFINE(HAVE_COLOR,1,[ Define if your curses library supports color. ])
 279         fi
 280         if test "$ac_cv_func_decl_resizeterm" = yes; then
 281                 MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS resize.o"
 282         fi
 283         LIBS="$old_LIBS"
 284         ])
 285
 286 AC_HEADER_STDC
 287
 288 AC_CHECK_HEADERS(stdarg.h sys/ioctl.h ioctl.h sysexits.h)
 289 AC_CHECK_HEADERS(sys/time.h sys/resource.h)
 290 AC_CHECK_HEADERS(unix.h)
 291
 292 AC_CHECK_FUNCS(setrlimit getsid isctype)
 293
 294 AC_TYPE_SIGNAL
 295
 296 AC_MSG_CHECKING(for sig_atomic_t in signal.h)
 297 AC_EGREP_HEADER(sig_atomic_t,signal.h,
 298   [
 299     ac_cv_type_sig_atomic_t=yes;
 300     AC_EGREP_HEADER(volatile.*sig_atomic_t,
 301                     signal.h,
 302                     [
 303                         is_sig_atomic_t_volatile=yes;
 304                         AC_MSG_RESULT([yes, volatile])
 305                     ],
 306                     [
 307                         is_sig_atomic_t_volatile=no;
 308                         AC_MSG_RESULT([yes, non volatile])
 309                     ])
 310   ],
 311   [
 312     AC_MSG_RESULT(no)
 313     AC_CHECK_TYPE(sig_atomic_t, int)
 314     is_sig_atomic_t_volatile=no
 315   ])
 316 if test $is_sig_atomic_t_volatile = 'yes'
 317 then
 318     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, sig_atomic_t)
 319 else
 320     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, [volatile sig_atomic_t])
 321 fi
 322
 323 AC_DECL_SYS_SIGLIST
 324
 325 AC_TYPE_PID_T
 326 dnl AC_CHECK_TYPE(ssize_t, int)
 327
 328 AC_CHECK_FUNCS(fgetpos memmove setegid srand48 strerror)
 329
 330 AC_REPLACE_FUNCS(strcasecmp strdup setenv)
 331
 332 AC_CHECK_FUNC(getopt)
 333 if test $ac_cv_func_getopt = yes; then
 334         AC_CHECK_HEADERS(getopt.h)
 335 fi
 336
 337 mutt_cv_snprintf=no
 338 SNPRINTFOBJS=""
 339 AC_CHECK_FUNCS(snprintf, , [mutt_cv_snprintf=yes])
 340 AC_CHECK_FUNCS(vsnprintf, , [mutt_cv_snprintf=yes])
 341 if test $mutt_cv_snprintf = yes; then
 342         AC_LIBOBJ(snprintf)
 343 fi
 344
 345 dnl SCO uses chsize() instead of ftruncate()
 346 AC_CHECK_FUNCS(ftruncate, , [AC_CHECK_LIB(x, chsize)])
 347
 348 dnl SCO has strftime() in libintl
 349 AC_CHECK_FUNCS(strftime, , [AC_CHECK_LIB(intl, strftime)])
 350
 351 dnl AIX may not have fchdir()
 352 AC_CHECK_FUNCS(fchdir, , [mutt_cv_fchdir=no])
 353
 354 AC_ARG_WITH(regex, AC_HELP_STRING([--with-regex], [Use the GNU regex library]),
 355         [mutt_cv_regex=yes],
 356         [AC_CHECK_FUNCS(regcomp, mutt_cv_regex=no, mutt_cv_regex=yes)])
 357
 358 if test $mutt_cv_regex = no ; then
 359 AC_CACHE_CHECK([whether your system's regexp library is completely broken],
 360         [mutt_cv_regex_broken],
 361         AC_TRY_RUN([
 362 #include <unistd.h>
 363 #include <regex.h>
 364 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
 365         mutt_cv_regex_broken=no, mutt_cv_regex_broken=yes, mutt_cv_regex_broken=yes))
 366         if test $mutt_cv_regex_broken = yes ; then
 367                 echo "Using the included GNU regex instead." >&AC_FD_MSG
 368                 mutt_cv_regex=yes
 369         fi
 370 fi
 371
 372 if test $mutt_cv_regex = yes; then
 373         AC_DEFINE(USE_GNU_REGEX,1,[ Define if you want to use the included regex.c. ])
 374         AC_LIBOBJ(regex)
 375 fi
 376
 377
 378 AC_ARG_WITH(homespool,
 379   AC_HELP_STRING([--with-homespool[=FILE]], [File in user's directory where new mail is spooled]), with_homespool=${withval})
 380 if test x$with_homespool != x; then
 381         if test $with_homespool = yes; then
 382                 with_homespool=mailbox
 383         fi
 384         AC_DEFINE_UNQUOTED(MAILPATH,"$with_homespool",[ Where new mail is spooled. ])
 385         AC_DEFINE(HOMESPOOL,1,
 386           [Is mail spooled to the user's home directory?  If defined,
 387            MAILPATH should be set to the filename of the spool mailbox
 388            relative the the home directory.
 389            use: configure --with-homespool=FILE])
 390         AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 391         mutt_cv_setgid=no
 392 else
 393         AC_ARG_WITH(mailpath, AC_HELP_STRING([--with-mailpath=DIR], [Directory where spool mailboxes are located]),
 394                 [mutt_cv_mailpath=$withval],
 395                 [ AC_CACHE_CHECK(where new mail is stored, mutt_cv_mailpath,
 396                         [mutt_cv_mailpath=no
 397                         if test -d /var/mail; then
 398                                 mutt_cv_mailpath=/var/mail
 399                         elif test -d /var/spool/mail; then
 400                                 mutt_cv_mailpath=/var/spool/mail
 401                         elif test -d /usr/spool/mail; then
 402                                 mutt_cv_mailpath=/usr/spool/mail
 403                         elif test -d /usr/mail; then
 404                                 mutt_cv_mailpath=/usr/mail
 405                         fi])
 406                 ])
 407         if test "$mutt_cv_mailpath" = no; then
 408                 AC_MSG_ERROR("Could not determine where new mail is stored.")
 409         fi
 410         AC_DEFINE_UNQUOTED(MAILPATH,"$mutt_cv_mailpath",[ Where new mail is spooled. ])
 411
 412         AC_CACHE_CHECK(if $mutt_cv_mailpath is world writable, mutt_cv_worldwrite, [AC_TRY_RUN([#include <sys/types.h>
 413 #include <sys/stat.h>
 414
 415 int main (int argc, char **argv)
 416 {
 417         struct stat s;
 418
 419         stat ("$mutt_cv_mailpath", &s);
 420         if (s.st_mode & S_IWOTH) exit (0);
 421         exit (1);
 422 }], mutt_cv_worldwrite=yes, mutt_cv_worldwrite=no, mutt_cv_worldwrite=no)])
 423
 424         mutt_cv_setgid=no
 425         if test $mutt_cv_worldwrite = yes; then
 426                 AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 427         else
 428
 429                 AC_CACHE_CHECK(if $mutt_cv_mailpath is group writable, mutt_cv_groupwrite, [AC_TRY_RUN([#include <sys/types.h>
 430 #include <sys/stat.h>
 431
 432 int main (int argc, char **argv)
 433 {
 434         struct stat s;
 435
 436         stat ("$mutt_cv_mailpath", &s);
 437         if (s.st_mode & S_IWGRP) exit (0);
 438         exit (1);
 439 }], mutt_cv_groupwrite=yes, mutt_cv_groupwrite=no, mutt_cv_groupwrite=no)])
 440
 441                 if test $mutt_cv_groupwrite = yes; then
 442                         AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 443                         AC_DEFINE(USE_SETGID,1,[ Define if mutt should run setgid "mail". ])
 444                         mutt_cv_setgid=yes
 445                 fi
 446         fi
 447 fi
 448
 449 AC_ARG_ENABLE(external_dotlock, AC_HELP_STRING([--enable-external-dotlock], [Force use of an external dotlock program]),
 450         [mutt_cv_external_dotlock="$enableval"])
 451
 452 if test "x$mutt_cv_setgid" = "xyes" || test "x$mutt_cv_fchdir" = "xno" \
 453         || test "x$mutt_cv_external_dotlock" = "xyes"
 454 then
 455         AC_DEFINE(DL_STANDALONE,1,[ Define if you want to use an external dotlocking program. ])
 456         DOTLOCK_TARGET="muttng_dotlock"
 457 else
 458         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS dotlock.o"
 459 fi
 460
 461 AC_SUBST(DOTLOCK_TARGET)
 462
 463
 464 AC_MSG_CHECKING(where to put the documentation)
 465 AC_ARG_WITH(docdir, AC_HELP_STRING([--with-docdir=PATH], [Specify where to put the documentation]),
 466         [mutt_cv_docdir=$withval],
 467         [mutt_cv_docdir="${prefix}/doc/muttng"])
 468 AC_MSG_RESULT($mutt_cv_docdir)
 469
 470 docdir=$mutt_cv_docdir
 471 AC_SUBST(docdir)
 472
 473 if test x$mutt_cv_setgid = xyes; then
 474         DOTLOCK_GROUP='mail'
 475         DOTLOCK_PERMISSION=2755
 476 else
 477         DOTLOCK_GROUP=''
 478         DOTLOCK_PERMISSION=755
 479 fi
 480 AC_SUBST(DOTLOCK_GROUP)
 481 AC_SUBST(DOTLOCK_PERMISSION)
 482
 483 AC_ARG_WITH(domain, AC_HELP_STRING([--with-domain=DOMAIN], [Specify your DNS domain name]),
 484         [if test $withval != yes; then
 485          if test $withval != no; then
 486            AC_DEFINE_UNQUOTED(DOMAIN,"$withval",[ Define your domain name. ])
 487          fi
 488         fi])
 489
 490 need_socket="no"
 491
 492 dnl -- socket dependencies --
 493
 494 AC_ARG_ENABLE(pop,  AC_HELP_STRING([--enable-pop], [Enable POP3 support]),
 495 [       if test x$enableval = xyes ; then
 496                 AC_DEFINE(USE_POP,1,[ Define if you want support for the POP3 protocol. ])
 497                 LIBPOP="-Lpop -lpop"
 498                 LIBPOPDEPS="\$(top_srcdir)/pop/pop.h pop/libpop.a"
 499                 need_socket="yes"
 500                 need_pop="yes"
 501                 need_md5="yes"
 502         fi
 503 ])
 504 AM_CONDITIONAL(BUILD_POP, test x$need_pop = xyes)
 505
 506 AC_ARG_ENABLE(imap, AC_HELP_STRING([--enable-imap], [Enable IMAP support]),
 507 [       if test x$enableval = xyes ; then
 508                 AC_DEFINE(USE_IMAP,1,[ Define if you want support for the IMAP protocol. ])
 509                 LIBIMAP="-Limap -limap"
 510                 LIBIMAPDEPS="\$(top_srcdir)/imap/imap.h imap/libimap.a"
 511                 need_imap="yes"
 512                 need_socket="yes"
 513                 need_md5="yes"
 514         fi
 515 ])
 516 AM_CONDITIONAL(BUILD_IMAP, test x$need_imap = xyes)
 517
 518 AC_ARG_ENABLE(nntp, [  --enable-nntp              Enable NNTP support],
 519 [       if test x$enableval = xyes ; then
 520                 AC_DEFINE(USE_NNTP,1,[ Compiling with newsreading support with NNTP ])
 521                 LIBNNTP="-Lnntp -lnntp"
 522                 LIBNNTPDEPS="\$(top_srcdir)/nntp/nntp.h nntp/libnntp.a"
 523                 need_nntp="yes"
 524                 need_socket="yes"
 525         fi
 526 ])
 527 AM_CONDITIONAL(BUILD_NNTP, test x$need_nntp = xyes)
 528
 529 dnl -- end socket dependencies --
 530
 531 if test "$need_socket" = "yes"
 532 then
 533         AC_MSG_CHECKING([for socklen_t])
 534         AC_EGREP_HEADER(socklen_t, sys/socket.h, AC_MSG_RESULT([yes]),
 535                 AC_MSG_RESULT([no])
 536                 AC_DEFINE(socklen_t,int,
 537                         [ Define to 'int' if <sys/socket.h> doesn't have it. ]))
 538         AC_CHECK_FUNC(gethostent, , AC_CHECK_LIB(nsl, gethostent))
 539         AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt))
 540         AC_CHECK_FUNCS(getaddrinfo)
 541         AC_DEFINE(USE_SOCKET,1,
 542                 [ Include code for socket support. Set automatically if you enable POP3 or IMAP ])
 543         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS account.o mutt_socket.o mutt_tunnel.o"
 544 fi
 545
 546 dnl -- imap dependencies --
 547
 548 AC_ARG_WITH(gss, AC_HELP_STRING([--with-gss[=PFX]], [Compile in GSSAPI authentication for IMAP]),
 549     gss_prefix="$withval", gss_prefix="no")
 550 if test "$gss_prefix" != "no"
 551 then
 552   if test "$need_imap" = "yes"
 553   then
 554     MUTT_AM_PATH_GSSAPI(gss_prefix)
 555     AC_MSG_CHECKING(GSSAPI implementation)
 556     AC_MSG_RESULT($GSSAPI_IMPL)
 557     if test "$GSSAPI_IMPL" = "none"
 558     then
 559       AC_CACHE_SAVE
 560       AC_MSG_RESULT([GSSAPI libraries not found])
 561     fi
 562     if test "$GSSAPI_IMPL" = "Heimdal"
 563     then
 564       AC_DEFINE(HAVE_HEIMDAL,1,[ Define if your GSSAPI implementation is Heimdal ])
 565     fi
 566     CPPFLAGS="$CPPFLAGS $GSSAPI_CFLAGS"
 567     MUTTLIBS="$MUTTLIBS $GSSAPI_LIBS"
 568     AC_DEFINE(USE_GSS,1,[ Define if you have GSSAPI libraries available ])
 569     need_gss="yes"
 570   else
 571     AC_MSG_WARN([GSS was requested but IMAP is not enabled])
 572   fi
 573 fi
 574 AM_CONDITIONAL(USE_GSS, test x$need_gss = xyes)
 575
 576 dnl -- end imap dependencies --
 577
 578 AC_ARG_WITH(ssl, AC_HELP_STRING([--with-ssl[=PFX]], [Compile in SSL support for POP/IMAP]),
 579 [       if test "$with_ssl" != "no"
 580         then
 581           if test "$need_socket" != "yes"; then
 582            AC_MSG_ERROR([SSL support is only useful with POP or IMAP support])
 583           fi
 584
 585           if test "$with_ssl" != "yes"
 586           then
 587            LDFLAGS="$LDFLAGS -L$withval/lib"
 588            CPPFLAGS="$CPPFLAGS -I$withval/include"
 589           fi
 590           saved_LIBS="$LIBS"
 591
 592           AC_CHECK_LIB(crypto, X509_new,, AC_MSG_ERROR([Unable to find SSL library]))
 593           AC_CHECK_LIB(ssl, SSL_new,, AC_MSG_ERROR([Unable to find SSL library]), -lcrypto)
 594
 595           AC_CHECK_FUNCS(RAND_status RAND_egd)
 596
 597           AC_DEFINE(USE_SSL,1,[ Define if you want support for SSL. ])
 598           LIBS="$saved_LIBS"
 599           MUTTLIBS="$MUTTLIBS -lssl -lcrypto"
 600           MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_ssl.o"
 601           need_ssl=yes
 602
 603         fi
 604 ])
 605
 606 AC_ARG_WITH([gnutls], AC_HELP_STRING([--with-gnutls[=PFX]], [Enable SSL support using gnutls]),
 607     [gnutls_prefix="$withval"], [gnutls_prefix="no"])
 608 if test "$gnutls_prefix" != "no"
 609 then
 610   if test "$need_socket" != "yes"
 611   then
 612     AC_MSG_ERROR([SSL support is only useful with POP or IMAP support])
 613   fi
 614   if test x"$need_ssl" = x"yes"
 615   then
 616     AC_MSG_ERROR([Only either OpenSSL or GNUTLS may be used])
 617   fi
 618   MUTT_AM_PATH_GNUTLS([$gnutls_prefix],
 619     [dnl GNUTLS found
 620     CPPFLAGS="$CPPFLAGS $LIBGNUTLS_CFLAGS"
 621     MUTTLIBS="$MUTTLIBS $LIBGNUTLS_LIBS"
 622     AC_DEFINE(USE_GNUTLS, 1, [Define if you want support for SSL via the gnutls library.])
 623
 624     MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_ssl_gnutls.o"
 625     need_ssl=yes],
 626     [dnl GNUTLS not found
 627       AC_MSG_ERROR([could not find libgnutls])
 628     ])
 629 fi
 630
 631 AM_CONDITIONAL(USE_SSL, test x$need_ssl = xyes)
 632
 633 AC_ARG_WITH(sasl2, AC_HELP_STRING([--with-sasl2[=PFX]], [Use Cyrus SASL library version 2 for POP/IMAP authentication]),
 634         [
 635         if test "$with_sasl2" != "no" -a "$need_imap" != "yes" -a "$need_pop" != "yes"
 636         then
 637           AC_MSG_ERROR([SASL2 support is only useful with POP or IMAP support])
 638         fi
 639
 640         if test "$with_sasl2" != "no"
 641         then
 642           if test "$with_sasl2" != "yes"
 643           then
 644             CPPFLAGS="$CPPFLAGS -I$with_sasl2/include"
 645             LDFLAGS="$LDFLAGS -L$with_sasl2/lib"
 646           fi
 647
 648           saved_LIBS="$LIBS"
 649
 650           AC_CHECK_LIB(sasl2, sasl_client_init,,
 651             AC_MSG_ERROR([could not find libsasl2]),)
 652
 653           MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_sasl.o"
 654           MUTTLIBS="$MUTTLIBS -lsasl2"
 655           LIBS="$saved_LIBS"
 656           AC_DEFINE(USE_SASL,1,
 657                   [ Define if want to use version 2 of the Cyrus SASL library. ])
 658           need_sasl=yes
 659         fi
 660         ])
 661 AM_CONDITIONAL(USE_SASL, test x$need_sasl = xyes)
 662
 663 AC_ARG_WITH(idn, AC_HELP_STRING([--with-idn=[PFX]], [Use GNU libidn for domain names]),
 664                  [
 665                   if test "$with_idn" != "no" ; then
 666                         if test "$with_idn" != "yes" ; then
 667                            CPPFLAGS="$CPPFLAGS -I$with_idn/include"
 668                            LDFLAGS="$LDFLAGS -L$with_idn/lib"
 669                         fi
 670                   fi
 671                  ]
 672 )
 673
 674 if test "x$with_idn" != "xno"; then
 675    AC_CHECK_LIB(idn, stringprep_check_version)
 676    AC_CHECK_FUNCS(idna_to_unicode_utf8_from_utf8 idna_to_unicode_8z8z)
 677    AC_CHECK_FUNCS(idna_to_ascii_from_utf8 idna_to_ascii_8z)
 678    AC_CHECK_FUNCS(idna_to_ascii_lz idna_to_ascii_from_locale)
 679 fi
 680
 681 dnl -- end socket --
 682
 683 AC_ARG_ENABLE(debug, AC_HELP_STRING([--enable-debug], [Enable debugging support]),
 684         [ if test x$enableval = xyes ; then
 685                 AC_DEFINE(DEBUG,1,[ Define to enable debugging info. ])
 686           fi
 687          ])
 688
 689 AC_ARG_ENABLE(flock, AC_HELP_STRING([--enable-flock], [Use flock() to lock files]),
 690         [if test $enableval = yes; then
 691                 AC_DEFINE(USE_FLOCK,1, [ Define to use flock() to lock mailboxes. ])
 692         fi])
 693
 694 mutt_cv_fcntl=yes
 695 AC_ARG_ENABLE(fcntl, AC_HELP_STRING([--disable-fcntl], [Do NOT use fcntl() to lock files]),
 696         [if test $enableval = no; then mutt_cv_fcntl=no; fi])
 697
 698 if test $mutt_cv_fcntl = yes; then
 699         AC_DEFINE(USE_FCNTL,1, [ Define to use fcntl() to lock folders. ])
 700 fi
 701
 702 AC_MSG_CHECKING(whether struct dirent defines d_ino)
 703 ac_cv_dirent_d_ino=no
 704 AC_TRY_LINK([#include <dirent.h>],[struct dirent dp; (void)dp.d_ino],[ac_cv_dirent_d_ino=yes])
 705 if test x$ac_cv_dirent_d_ino = xyes ; then
 706   AC_DEFINE(HAVE_DIRENT_D_INO,1,
 707             [Define to 1 if your system has the dirent::d_ino member])
 708 fi
 709 AC_MSG_RESULT($ac_cv_dirent_d_ino)
 710
 711 dnl This may look cumbersome -- please keep it that way, so we can
 712 dnl quickly change the default to "yes" again.
 713 mutt_cv_inodesort=no
 714 AC_ARG_ENABLE(inodesort,  AC_HELP_STRING([--enable-inodesort], [Read files in maildir folders sorted by inode.]),
 715        [if test x$enableval = xyes -a x$ac_cv_dirent_d_ino = xyes ; then mutt_cv_inodesort=yes; fi])
 716
 717 if test $mutt_cv_inodesort = yes; then
 718         AC_DEFINE(USE_INODESORT, 1, [ Define to sort files in a maildir by inode number. ])
 719 fi
 720
 721 mutt_cv_warnings=yes
 722 AC_ARG_ENABLE(warnings, AC_HELP_STRING([--disable-warnings], [Turn off compiler warnings (not recommended)]),
 723 [if test $enableval = no; then
 724         mutt_cv_warnings=no
 725 fi])
 726
 727 if test x$GCC = xyes -a $mutt_cv_warnings = yes; then
 728         CFLAGS="-Wall -pedantic $CFLAGS"
 729 fi
 730
 731 AC_ARG_ENABLE(nfs-fix, AC_HELP_STRING([--enable-nfs-fix], [Work around an NFS with broken attributes caching]),
 732         [if test x$enableval = xyes; then
 733                 AC_DEFINE(NFS_ATTRIBUTE_HACK,1,
 734                   [Define if you have problems with mutt not detecting
 735                    new/old mailboxes over NFS.  Some NFS implementations
 736                    incorrectly cache the attributes of small files.])
 737         fi])
 738
 739 AC_ARG_ENABLE(buffy-size, AC_HELP_STRING([--enable-buffy-size], [Use file size attribute instead of access time]),
 740         [if test x$enableval = xyes; then
 741                 AC_DEFINE(BUFFY_SIZE,1,[ Define to enable the "buffy_size" feature. ])
 742         fi])
 743
 744 AC_ARG_ENABLE(mailtool, AC_HELP_STRING([--enable-mailtool], [Enable Sun mailtool attachments support ]),
 745         [if test x$enableval = xyes; then
 746                 AC_DEFINE(SUN_ATTACHMENT,1,[ Define to enable Sun mailtool attachments support. ])
 747         fi])
 748
 749 AC_ARG_ENABLE(compressed, [  --enable-compressed        Enable compressed folders support ],
 750         [if test x$enableval = xyes; then
 751                 AC_DEFINE(USE_COMPRESSED,1,[ The compressed mailboxes support ])
 752         fi])
 753
 754 AC_ARG_ENABLE(locales-fix, AC_HELP_STRING([--enable-locales-fix], [The result of isprint() is unreliable ]),
 755         [if test x$enableval = xyes; then
 756                 AC_DEFINE(LOCALES_HACK,1,[ Define if the result of isprint() is unreliable. ])
 757         fi])
 758
 759 AC_ARG_WITH(exec-shell, AC_HELP_STRING([--with-exec-shell=SHELL], [Specify alternate shell (ONLY if /bin/sh is broken)]),
 760         [if test $withval != yes; then
 761                 AC_DEFINE_UNQUOTED(EXECSHELL, "$withval",
 762                  [program to use for shell commands])
 763          else
 764                 AC_DEFINE_UNQUOTED(EXECSHELL, "/bin/sh")
 765         fi],
 766         [AC_DEFINE_UNQUOTED(EXECSHELL, "/bin/sh")])
 767
 768 dnl -- start cache --
 769 AC_ARG_ENABLE(hcache, AC_HELP_STRING([--enable-hcache], [Enable header caching]),
 770 [if test x$enableval = xyes; then
 771     AC_DEFINE(USE_HCACHE, 1, [Enable header caching])
 772
 773     OLDCPPFLAGS="$CPPFLAGS"
 774     OLDLIBS="$LIBS"
 775
 776     need_md5="yes"
 777
 778     ac_prefer_qdbm=yes
 779     AC_ARG_WITH(qdbm, AC_HELP_STRING([--without-qdbm], [Don't use qdbm even if it is available]),
 780         ac_prefer_qdbm=$withval)
 781     if test x$ac_prefer_qdbm != xno; then
 782         ac_cv_vlopen=no
 783         QDBM_DIRS="$mutt_cv_prefix /usr/local /usr"
 784         AC_MSG_CHECKING([for vlopen])
 785         for d in $QDBM_DIRS; do
 786           if test x$ac_cv_vlopen = xno && test -d "$d/include" && test -d "$d/lib"; then
 787             QDBM_INC="-I$d/include"
 788             QDBM_LIB="-L$d/lib"
 789             CPPFLAGS="$OLDCPPFLAGS $QDBM_INC"
 790             LIBS="$OLDLIBS $QDBM_LIB -lqdbm"
 791             AC_TRY_LINK([#include <villa.h>],[vlopen(0,0,0);],[ac_cv_vlopen=yes])
 792           fi
 793         done
 794         if test x$ac_cv_vlopen = xyes; then
 795           AC_MSG_RESULT(yes)
 796         else
 797           AC_MSG_RESULT(no)
 798         fi
 799     fi
 800
 801     ac_prefer_gdbm=yes
 802     AC_ARG_WITH(gdbm, AC_HELP_STRING([--without-gdbm], [Don't use gdbm even if it is available]),
 803         ac_prefer_gdbm=$withval)
 804     if test x$ac_prefer_gdbm != xno -a x$ac_cv_vlopen != xyes; then
 805         ac_cv_gdbmopen=no
 806         GDBM_DIRS="$mutt_cv_prefix /usr/local /usr"
 807         AC_MSG_CHECKING([for gdbm_open])
 808         for d in $GDBM_DIRS; do
 809           if test x$ac_cv_gdbmopen = xno && test -d "$d/include" && test -d "$d/lib"; then
 810             GDBM_INC="-I$d/include"
 811             GDBM_LIB="-L$d/lib"
 812             CPPFLAGS="$OLDCPPFLAGS $GDBM_INC"
 813             LIBS="$OLDLIBS $GDBM_LIB -lgdbm"
 814             AC_TRY_LINK([#include <gdbm.h>],[gdbm_open(0,0,0,0,0);],[ac_cv_gdbmopen=yes])
 815           fi
 816         done
 817         if test x$ac_cv_gdbmopen = xyes; then
 818           AC_MSG_RESULT(yes)
 819         else
 820           AC_MSG_RESULT(no)
 821         fi
 822     fi
 823
 824     ac_bdb_prefix=yes
 825     AC_ARG_WITH(bdb, AC_HELP_STRING([--with-bdb[=DIR]], [Use BerkeleyDB4 if gdbm is not available ]),
 826         ac_bdb_prefix=$withval)
 827     if test x$ac_bdb_prefix != xno -a x$ac_cv_gdbmopen != xyes -a x$ac_cv_vlopen != xyes; then
 828         test x$ac_bdb_prefix = xyes && ac_bdb_prefix="$mutt_cv_prefix /opt/csw/bdb4 /opt /usr/local /usr"
 829         for d in $ac_bdb_prefix; do
 830             bdbpfx="$bdbpfx $d"
 831             for v in BerkeleyDB.4.3 BerkeleyDB.4.2 BerkeleyDB.4.1; do
 832                 bdbpfx="$bdbpfx $d/$v"
 833             done
 834         done
 835         BDB_VERSIONS="db-4 db4 db-4.3 db4.3 db43 db-4.2 db4.2 db42 db-4.1 db4.1 db41 db ''"
 836         AC_MSG_CHECKING([for BerkeleyDB > 4.0])
 837         for d in $bdbpfx; do
 838             BDB_INCLUDE_DIR=""
 839             BDB_LIB_DIR=""
 840             for v in / $BDB_VERSIONS; do
 841                 if test -r "$d/include/$v/db.h"; then
 842                     BDB_INCLUDE_DIR="$d/include/$v"
 843                     if test -d "$d/lib/$v"; then
 844                         BDB_LIB_DIR="$d/lib/$v"
 845                         for l in `echo $BDB_VERSIONS`; do
 846                             CPPFLAGS="-I$BDB_INCLUDE_DIR $OLDCPPFLAGS"
 847                             LIBS="$OLDLIBS -L$BDB_LIB_DIR -l$l"
 848                             AC_TRY_LINK([
 849                                 #include <stdlib.h>
 850                                 #include <db.h>
 851                             ],[
 852                                 DB *db = NULL;
 853                                 db->open(db,NULL,NULL,NULL,0,0,0);
 854                             ],[
 855                                 ac_cv_dbcreate=yes
 856                                 BDB_LIB="$l"
 857                                 break
 858                             ])
 859                         done
 860                         test x$ac_cv_dbcreate = xyes && break
 861                     fi
 862                 fi
 863             done
 864             test x$BDB_LIB != x && break
 865         done
 866         if test x$ac_cv_dbcreate = xyes; then
 867             AC_MSG_RESULT(yes)
 868         else
 869             AC_MSG_RESULT(no)
 870         fi
 871     fi
 872
 873     if test x$ac_cv_vlopen = xyes; then
 874         CPPFLAGS="$OLDCPPFLAGS $QDBM_INC"
 875         LIBS="$OLDLIBS $QDBM_LIB -lqdbm"
 876         AC_DEFINE(HAVE_QDBM, 1, [QDBM Support])
 877     elif test x$ac_cv_gdbmopen = xyes; then
 878         CPPFLAGS="$OLDCPPFLAGS $GDBM_INC"
 879         LIBS="$OLDLIBS $GDBM_LIB -lgdbm";
 880         AC_DEFINE(HAVE_GDBM, 1, [GDBM Support])
 881     elif test x$ac_cv_dbcreate = xyes; then
 882         CPPFLAGS="-I$BDB_INCLUDE_DIR $OLDCPPFLAGS"
 883         LIBS="$OLDLIBS -L$BDB_LIB_DIR -l$BDB_LIB"
 884         AC_DEFINE(HAVE_DB4, 1, [Sleepycat DB4 Support])
 885     else
 886         AC_MSG_ERROR([You need one of: QDBM, GDBM or Sleepycat DB4 for --enable-hcache])
 887     fi
 888 fi])
 889 dnl -- end cache --
 890
 891 AC_SUBST(MUTTLIBS)
 892 AC_SUBST(MUTT_LIB_OBJECTS)
 893 AC_SUBST(LIBIMAP)
 894 AC_SUBST(LIBIMAPDEPS)
 895 AC_SUBST(LIBPOP)
 896 AC_SUBST(LIBPOPDEPS)
 897 AC_SUBST(LIBNNTP)
 898 AC_SUBST(LIBNNTPDEPS)
 899
 900 dnl -- iconv/gettext --
 901
 902 AC_ARG_ENABLE(iconv, AC_HELP_STRING([--disable-iconv], [Disable iconv support]),
 903         [if test x$enableval = xno ; then
 904                 am_cv_func_iconv=no
 905         fi
 906 ])
 907
 908 MUTT_AM_GNU_GETTEXT
 909
 910 if test "$am_cv_func_iconv" != "yes"
 911 then
 912   AC_MSG_WARN([Configuring without iconv support. See INSTALL for details])
 913 else
 914
 915 AC_CHECK_HEADERS(iconv.h,
 916         [AC_MSG_CHECKING(whether iconv.h defines iconv_t)
 917          AC_EGREP_HEADER([typedef.*iconv_t],iconv.h,
 918                 [AC_MSG_RESULT(yes)
 919                  AC_DEFINE(HAVE_ICONV_T_DEF, 1,
 920                         [Define if <iconv.h> defines iconv_t.])],
 921                  AC_MSG_RESULT(no))])
 922
 923 dnl (1) Some implementations of iconv won't convert from UTF-8 to UTF-8.
 924 dnl (2) In glibc-2.1.2 and earlier there is a bug that messes up ob and
 925 dnl     obl when args 2 and 3 are 0 (fixed in glibc-2.1.3).
 926 AC_CACHE_CHECK([whether this iconv is good enough], mutt_cv_iconv_good,
 927         mutt_save_LIBS="$LIBS"
 928         LIBS="$LIBS $LIBICONV"
 929         AC_TRY_RUN([
 930 #include <iconv.h>
 931 int main()
 932 {
 933   iconv_t cd;
 934 changequote(, )dnl
 935   char buf[4];
 936 changequote([, ])dnl
 937   char *ob;
 938   size_t obl;
 939   ob = buf, obl = sizeof(buf);
 940   return ((cd = iconv_open("UTF-8", "UTF-8")) != (iconv_t)(-1) &&
 941           (iconv(cd, 0, 0, &ob, &obl) ||
 942            !(ob == buf && obl == sizeof(buf)) ||
 943            iconv_close(cd)));
 944 }
 945                 ],
 946                 mutt_cv_iconv_good=yes,
 947                 mutt_cv_iconv_good=no,
 948                 mutt_cv_iconv_good=yes)
 949         LIBS="$mutt_save_LIBS")
 950 if test "$mutt_cv_iconv_good" = no; then
 951   AC_MSG_ERROR(Try using libiconv instead)
 952 fi
 953
 954 dnl This is to detect implementations such as the one in glibc-2.1,
 955 dnl which always convert exactly but return the number of characters
 956 dnl converted instead of the number converted inexactly.
 957 AC_CACHE_CHECK([whether iconv is non-transcribing], mutt_cv_iconv_nontrans,
 958         mutt_save_LIBS="$LIBS"
 959         LIBS="$LIBS $LIBICONV"
 960         AC_TRY_RUN([
 961 #include <iconv.h>
 962 #include <string.h>
 963 int main()
 964 {
 965   iconv_t cd;
 966   const char *ib;
 967   char *ob;
 968   size_t ibl, obl;
 969   const char *s = "\304\211";
 970 changequote(, )dnl
 971   char t[3];
 972 changequote([, ])dnl
 973   ib = s, ibl = 2, ob = t, obl = 3;
 974   return ((cd = iconv_open("UTF-8", "UTF-8")) == (iconv_t)(-1) ||
 975           iconv(cd, &ib, &ibl, &ob, &obl));
 976 }
 977                 ],
 978                 mutt_cv_iconv_nontrans=no,
 979                 mutt_cv_iconv_nontrans=yes,
 980                 mutt_cv_iconv_nontrans=no)
 981         LIBS="$mutt_save_LIBS")
 982 if test "$mutt_cv_iconv_nontrans" = yes; then
 983   AC_DEFINE(ICONV_NONTRANS, 1)
 984 else
 985   AC_DEFINE(ICONV_NONTRANS, 0)
 986 fi
 987
 988 CPPFLAGS="$CPPFLAGS -I\$(top_srcdir)/intl"
 989
 990 if test "$BUILD_INCLUDED_LIBINTL" = "yes"; then
 991   AC_DEFINE(HAVE_BIND_TEXTDOMAIN_CODESET,1,
 992           [ Define if your gettext has bind_textdomain_codeset. ])
 993 else
 994   AC_CHECK_FUNCS(bind_textdomain_codeset)
 995 fi
 996
 997 fi # libiconv
 998
 999 dnl -- locales --
1000
1001 AC_CHECK_HEADERS(wchar.h)
1002
1003 AC_CACHE_CHECK([for wchar_t], mutt_cv_wchar_t,
1004         AC_TRY_COMPILE([
1005 #include <stddef.h>
1006 #include <stdlib.h>
1007 #ifdef HAVE_WCHAR_H
1008 #include <wchar.h>
1009 #endif
1010                 ],
1011                 [ wchar_t wc; return 0; ],
1012                 mutt_cv_wchar_t=yes,
1013                 mutt_cv_wchar_t=no))
1014
1015 if test "$mutt_cv_wchar_t" = no; then
1016         AC_DEFINE(wchar_t,int,[ Define to 'int' if system headers don't define. ])
1017 fi
1018
1019 AC_CACHE_CHECK([for wint_t], mutt_cv_wint_t,
1020         AC_TRY_COMPILE([
1021 #include <stddef.h>
1022 #include <stdlib.h>
1023 #ifdef HAVE_WCHAR_H
1024 #include <wchar.h>
1025 #endif
1026                 ],
1027                 [ wint_t wc; return 0; ],
1028                 mutt_cv_wint_t=yes,
1029                 mutt_cv_wint_t=no))
1030
1031 if test "$mutt_cv_wint_t" = no; then
1032         AC_DEFINE(wint_t,int,[ Define to 'int' if system headers don't define. ])
1033 fi
1034
1035 AC_CHECK_HEADERS(wctype.h)
1036 AC_CHECK_FUNCS(iswalnum iswalpha  iswcntrl iswdigit)
1037 AC_CHECK_FUNCS(iswgraph iswlower iswprint iswpunct iswspace iswupper)
1038 AC_CHECK_FUNCS(iswxdigit towupper towlower)
1039
1040 AC_CACHE_CHECK([for mbstate_t], mutt_cv_mbstate_t,
1041         AC_TRY_COMPILE([
1042 #include <stddef.h>
1043 #include <stdlib.h>
1044 #ifdef HAVE_WCHAR_H
1045 #include <wchar.h>
1046 #endif
1047                 ],
1048                 [ mbstate_t s; return 0; ],
1049                 mutt_cv_mbstate_t=yes,
1050                 mutt_cv_mbstate_t=no))
1051
1052 if test "$mutt_cv_mbstate_t" = no; then
1053         AC_DEFINE(mbstate_t,int,[ Define to 'int' if system headers don't define. ])
1054 fi
1055
1056 wc_funcs=maybe
1057 AC_ARG_WITH(wc-funcs, AC_HELP_STRING([--without-wc-funcs], [Do not use the system's wchar_t functions]),
1058         wc_funcs=$withval)
1059
1060 if test "$wc_funcs" != yes -a "$wc_funcs" != no; then
1061         AC_CACHE_CHECK([for wchar_t functions], mutt_cv_wc_funcs,
1062                 mutt_cv_wc_funcs=no
1063                 AC_TRY_LINK([
1064 #define _XOPEN_SOURCE 1
1065 #include <stddef.h>
1066 #include <stdlib.h>
1067 #ifdef HAVE_WCTYPE_H
1068 #include <wctype.h>
1069 #endif
1070 #ifdef HAVE_WCHAR_H
1071 #include <wchar.h>
1072 #endif],
1073                         [mbrtowc(0, 0, 0, 0); wctomb(0, 0); wcwidth(0);
1074         iswprint(0); iswspace(0); towlower(0); towupper(0); iswalnum(0)],
1075                         mutt_cv_wc_funcs=yes))
1076         wc_funcs=$mutt_cv_wc_funcs
1077 fi
1078
1079 if test $wc_funcs = yes; then
1080         AC_DEFINE(HAVE_WC_FUNCS,1,[ Define if you are using the system's wchar_t functions. ])
1081 fi
1082
1083 AC_CACHE_CHECK([for nl_langinfo and CODESET], mutt_cv_langinfo_codeset,
1084   [AC_TRY_LINK([#include <langinfo.h>],
1085     [char* cs = nl_langinfo(CODESET);],
1086     mutt_cv_langinfo_codeset=yes,
1087     mutt_cv_langinfo_codeset=no)])
1088 if test $mutt_cv_langinfo_codeset = yes; then
1089   AC_DEFINE(HAVE_LANGINFO_CODESET,1,[ Define if you have <langinfo.h> and nl_langinfo(CODESET). ])
1090 fi
1091
1092 AC_CACHE_CHECK([for nl_langinfo and YESEXPR], mutt_cv_langinfo_yesexpr,
1093   [AC_TRY_LINK([#include <langinfo.h>],
1094     [char* cs = nl_langinfo(YESEXPR);],
1095     mutt_cv_langinfo_yesexpr=yes,
1096     mutt_cv_langinfo_yesexpr=no)])
1097 if test $mutt_cv_langinfo_yesexpr = yes; then
1098   AC_DEFINE(HAVE_LANGINFO_YESEXPR,1,[ Define if you have <langinfo.h> and nl_langinfo(YESEXPR). ])
1099 fi
1100
1101 dnl -- libesmtp --
1102 MUTT_AM_LIBESMTP
1103 if test x$use_libesmtp = xyes; then
1104     CFLAGS="$CFLAGS $mutt_libesmtp_cflags"
1105     MUTTLIBS="$MUTTLIBS $mutt_libesmtp_libs"
1106     MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_libesmtp.o"
1107
1108     AC_DEFINE(USE_LIBESMTP,
1109               1,
1110               [Define to enable the use of libesmtp])
1111 fi
1112 dnl -- end libesmtp --
1113
1114 dnl -- sgml tools --
1115
1116 dnl Documentation tools
1117 have_openjade="no"
1118 AC_PATH_PROG([OSPCAT], [ospcat], [none])
1119 if test "$OSPCAT" != "none"
1120 then
1121   AC_MSG_CHECKING([for openjade docbook stylesheets])
1122   dslosfile=`ospcat --public-id="-//Norman Walsh//DOCUMENT DocBook Print Stylesheet//EN"`
1123   DSLROOT=`echo $dslosfile | sed -n -e "s/.*SOIBASE='\(@<:@^'@:>@*\)\/catalog'.*/\1/p"`
1124   # ospcat may spit out an absolute path without an SOIBASE
1125   if test -z "$DSLROOT"
1126   then
1127     DSLROOT=`echo $dslosfile | sed -e 's|<OSFILE>\(.*\)/print/docbook.dsl|\1|'`
1128   fi
1129   if test -f $DSLROOT/print/docbook.dsl
1130   then
1131     AC_MSG_RESULT([in $DSLROOT])
1132     have_openjade="yes"
1133   else
1134     AC_MSG_RESULT([not found: PDF documentation will not be built.])
1135   fi
1136 fi
1137 AC_SUBST(DSLROOT)
1138
1139 AC_MSG_CHECKING([for lynx])
1140 AC_PATH_PROG([HTML2TXT_CMD], [lynx], [none])
1141 if test x"$HTML2TXT_CMD" = x"none"
1142 then
1143   AC_MSG_CHECKING([for w3m])
1144   AC_PATH_PROG([HTML2TXT_CMD], [w3m], [none])
1145 fi
1146 if test x"$HTML2TXT_CMD" = x"none"
1147 then
1148   AC_MSG_CHECKING([for elinks])
1149   AC_PATH_PROG([HTML2TXT_CMD], [elinks], [none])
1150 fi
1151 case "$HTML2TXT_CMD" in
1152   *elinks*)
1153     HTML2TXT_CMD="$HTML2TXT_CMD -dump -no-numbering -no-references \$^ > \$@"
1154     ;;
1155   *lynx*)
1156     HTML2TXT_CMD="$HTML2TXT_CMD -dump -nolist -with_backspaces \$^ > \$@"
1157     ;;
1158   *w3m*)
1159     HTML2TXT_CMD="$HTML2TXT_CMD -dump \$^ > \$@"
1160     ;;
1161   *)
1162     HTML2TXT_CMD="true"
1163     ;;
1164 esac
1165 AC_SUBST(HTML2TXT_CMD)
1166
1167 AC_MSG_CHECKING([for tidy])
1168 AC_PATH_PROG([HTMLCLEAN_CMD], [tidy], [none])
1169
1170 if test x"$HTMLCLEAN_CMD" != x"none"
1171 then
1172   HTMLCLEAN_CMD="$HTMLCLEAN_CMD -q -i -m -asxml -utf8 "
1173 else
1174   HTMLCLEAN_CMD="echo "
1175 fi
1176 AC_SUBST(HTMLCLEAN_CMD)
1177
1178 AC_OUTPUT(Makefile intl/Makefile m4/Makefile
1179         po/Makefile.in doc/Makefile contrib/Makefile
1180         muttbug.sh
1181         lib/Makefile
1182         imap/Makefile
1183         pop/Makefile
1184         nntp/Makefile
1185         Muttngrc.head
1186         doc/instdoc.sh)