configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl !!! WHEN ADDING NEW CONFIGURE TESTS, PLEASE ADD CODE TO MAIN.C !!!
   4 dnl !!! TO DUMP THEIR RESULTS WHEN MUTT -V IS CALLED            !!!
   5
   6 AC_PREREQ([2.50])
   7 AC_INIT([mutt.h])
   8 AM_CONFIG_HEADER(config.h)
   9
  10 if test -f "$srcdir./.svn/entries" ; then
  11   echo "`cat $srcdir/VERSION.in`-r`grep revision $srcdir/.svn/entries | sort -r | uniq | head -n 1 | cut -d '"' -f 2`" > "$srcdir/VERSION"
  12 else
  13   cp "$srcdir/VERSION.in" "$srcdir/VERSION"
  14 fi
  15
  16 mutt_cv_version=`cat "$srcdir/VERSION"`
  17
  18 AM_INIT_AUTOMAKE(muttng, $mutt_cv_version)
  19 dnl AC_GNU_SOURCE
  20
  21 ifdef([AC_LIBOBJ], , [define([AC_LIBOBJ], [LIB[]OBJS="$LIBOBJS $1.o"])])
  22
  23 ALL_LINGUAS="de ru it es uk fr pl nl cs id sk ko el zh_TW zh_CN pt_BR eo gl sv da lt tr ja hu et ca bg"
  24
  25 AC_CANONICAL_HOST
  26
  27 AC_MSG_CHECKING([for prefix])
  28 if test x$prefix = xNONE; then
  29         mutt_cv_prefix=$ac_default_prefix
  30 else
  31         mutt_cv_prefix=$prefix
  32 fi
  33 AC_MSG_RESULT($mutt_cv_prefix)
  34
  35 AC_PROG_CC
  36 AC_ISC_POSIX
  37 AM_C_PROTOTYPES
  38 if test "x$U" != "x"; then
  39   AC_MSG_ERROR(Compiler not ANSI compliant)
  40 fi
  41 AC_PROG_CPP
  42 AC_PROG_MAKE_SET
  43 AC_PROG_INSTALL
  44 AC_PROG_RANLIB
  45 AC_CHECK_TOOL(AR, ar, ar)
  46
  47 AC_C_INLINE
  48 AC_C_CONST
  49
  50 AC_SYS_LARGEFILE
  51
  52 AC_PATH_PROG(DBX, dbx, no)
  53 AC_PATH_PROG(GDB, gdb, no)
  54 AC_PATH_PROG(SDB, sdb, no)
  55
  56 if test $GDB != no ; then
  57         DEBUGGER=$GDB
  58 elif test $DBX != no ; then
  59         DEBUGGER=$DBX
  60 elif test $SDB != no ; then
  61         DEBUGGER=$SDB
  62 else
  63         DEBUGGER=no
  64 fi
  65
  66 AC_SUBST([DEBUGGER])
  67
  68 AH_TEMPLATE([sig_atomic_t],
  69             [/* Define to `int' if <signal.h> doesn't define.])
  70 AH_TEMPLATE([HAVE_START_COLOR],
  71             [Define if you have start_color, as a function or macro.])
  72 AH_TEMPLATE([HAVE_TYPEAHEAD],
  73             [Define if you have typeahead, as a function or macro.])
  74 AH_TEMPLATE([HAVE_BKGDSET],
  75             [Define if you have bkgdset, as a function or macro.])
  76 AH_TEMPLATE([HAVE_CURS_SET],
  77             [Define if you have curs_set, as a function or macro.])
  78 AH_TEMPLATE([HAVE_META],
  79             [Define if you have meta, as a function or macro.])
  80 AH_TEMPLATE([HAVE_USE_DEFAULT_COLORS],
  81             [Define if you have use_default_colors, as a function or macro.])
  82 AH_TEMPLATE([HAVE_RESIZETERM],
  83             [Define if you have resizeterm, as a function or macro.])
  84 AH_TEMPLATE([SIG_ATOMIC_VOLATILE_T],
  85             [Some systems declare sig_atomic_t as volatile, some others -- no.
  86              This define will have value `sig_atomic_t' or
  87              `volatile sig_atomic_t' accordingly.])
  88 AH_TEMPLATE([ICONV_NONTRANS],
  89             [Define as 1 if iconv() only converts exactly and we should treat
  90              all return values other than (size_t)(-1) as equivalent.])
  91
  92 MUTT_C99_INTTYPES
  93
  94 ac_aux_path_sendmail=/usr/sbin:/usr/lib
  95 AC_PATH_PROG(SENDMAIL, sendmail, /usr/sbin/sendmail, $PATH:$ac_aux_path_sendmail)
  96 AC_DEFINE_UNQUOTED(SENDMAIL,"$ac_cv_path_SENDMAIL",[ Where to find sendmail on your system. ])
  97
  98 OPS='$(srcdir)/OPS'
  99
 100         AC_ARG_ENABLE(gpgme, AC_HELP_STRING([--enable-gpgme], [Enable GPGME support]),
 101         [       if test x$enableval = xyes; then
 102                         have_gpgme=yes
 103                 fi
 104         ])
 105         AC_ARG_WITH(gpgme-prefix, AC_HELP_STRING([--with-gpgme-prefix=PFX], [prefix where GPGME is installed (optional)]),
 106         gpgme_config_prefix="$withval", gpgme_config_prefix="")
 107
 108         if test x$have_gpgme = xyes; then
 109                 if test x$gpgme_config_prefix != x; then
 110                         GPGME_CONFIG="$gpgme_config_prefix/bin/gpgme-config"
 111                 else
 112                         AC_PATH_PROG(GPGME_CONFIG, gpgme-config, no)
 113                 fi
 114                 if test "x$GPGME_CONFIG" = "xno"; then
 115                         AC_MSG_ERROR([GPGME not found])
 116                 else
 117                         LIBGPGME_CFLAGS=`$GPGME_CONFIG --cflags`
 118                         LIBGPGME_LIBS=`$GPGME_CONFIG --libs`
 119       MUTTLIBS="$MUTTLIBS $LIBGPGME_LIBS"
 120                         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS crypt-gpgme.o crypt-mod-pgp-gpgme.o crypt-mod-smime-gpgme.o"
 121                         AC_DEFINE(CRYPT_BACKEND_GPGME, 1,
 122                                   [Defined, if GPGME support is enabled])
 123                 fi
 124         fi
 125         AC_SUBST(LIBGPGME_CFLAGS)
 126         AC_SUBST(LIBGPGME_LIBS)
 127
 128         AC_ARG_ENABLE(pgp, AC_HELP_STRING([--disable-pgp], [Disable PGP support]),
 129         [       if test x$enableval = xno ; then
 130                         have_pgp=no
 131                 fi
 132         ])
 133
 134         if test x$have_pgp != xno ; then
 135                 AC_DEFINE(CRYPT_BACKEND_CLASSIC_PGP,1,
 136                     [ Define if you want classic PGP support. ])
 137                 PGPAUX_TARGET="pgpringng\$(EXEEXT) pgpewrapng\$(EXEEXT)"
 138                 MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS pgp.o pgpinvoke.o pgpkey.o pgplib.o gnupgparse.o pgpmicalg.o pgppacket.o crypt-mod-pgp-classic.o"
 139         fi
 140
 141         AC_ARG_ENABLE(smime, AC_HELP_STRING([--disable-smime], [Disable SMIME support]),
 142         [       if test x$enableval = xno ; then
 143                         have_smime=no
 144                 fi
 145         ])
 146
 147         if test x$have_smime != xno ; then
 148                 AC_DEFINE(CRYPT_BACKEND_CLASSIC_SMIME,1,
 149                   [ Define if you want clasic S/MIME support. ])
 150                 MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS smime.o crypt-mod-smime-classic.o"
 151                 SMIMEAUX_TARGET="smime_keysng"
 152         fi
 153
 154         AC_ARG_WITH(mixmaster, AC_HELP_STRING([--with-mixmaster[=PATH]], [Include Mixmaster support]),
 155                 [if test -x "$withval" ; then
 156                         MIXMASTER="$withval"
 157                  else
 158                         MIXMASTER="mixmaster"
 159                  fi
 160                  OPS="$OPS \$(srcdir)/OPS.MIX"
 161                  MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS remailer.o"
 162                  AC_DEFINE_UNQUOTED(MIXMASTER,"$MIXMASTER",
 163                          [ Where to find mixmaster on your system. ])
 164                 ])
 165
 166 # We now require all OPS
 167 OPS="$OPS \$(srcdir)/OPS.PGP \$(srcdir)/OPS.SMIME \$(srcdir)/OPS.CRYPT "
 168 AC_SUBST([OPS])
 169
 170
 171 AC_SUBST(PGPAUX_TARGET)
 172 AC_SUBST(SMIMEAUX_TARGET)
 173
 174 AC_PATH_PROG(ISPELL, ispell, no)
 175 if test $ISPELL != no; then
 176         AC_DEFINE_UNQUOTED(ISPELL,"$ISPELL",[ Where to find ispell on your system. ])
 177 fi
 178
 179 AC_ARG_WITH(slang, AC_HELP_STRING([--with-slang[=DIR]], [Use S-Lang instead of ncurses]),
 180         [AC_CACHE_CHECK([if this is a BSD system], mutt_cv_bsdish,
 181                 [AC_TRY_RUN([#include <sys/param.h>
 182
 183 main ()
 184 {
 185 #ifdef BSD
 186         exit (0);
 187 #else
 188         exit (1);
 189 #endif
 190 }],
 191                         mutt_cv_bsdish=yes,
 192                         mutt_cv_bsdish=no,
 193                         mutt_cv_bsdish=no)])
 194
 195         AC_MSG_CHECKING(for S-Lang)
 196         if test $withval = yes; then
 197                 if test -d $srcdir/../slang; then
 198                         mutt_cv_slang=$srcdir/../slang/src
 199                         CFLAGS="$CFLAGS -I${mutt_cv_slang}"
 200                         LDFLAGS="$LDFLAGS -L${mutt_cv_slang}/objs"
 201                 else
 202                         if test -d $mutt_cv_prefix/include/slang; then
 203                                 CFLAGS="$CFLAGS -I$mutt_cv_prefix/include/slang"
 204                         elif test -d /usr/include/slang; then
 205                                 CFLAGS="$CFLAGS -I/usr/include/slang"
 206                         fi
 207                         mutt_cv_slang=yes
 208                 fi
 209         else
 210                 dnl ---Check to see if $withval is a source directory
 211                 if test -f $withval/src/slang.h; then
 212                         mutt_cv_slang=$withval/src
 213                         CFLAGS="$CFLAGS -I${mutt_cv_slang}"
 214                         LDFLAGS="$LDFLAGS -L${mutt_cv_slang}/objs"
 215                 else
 216                         dnl ---Must be installed somewhere
 217                         mutt_cv_slang=$withval
 218                         if test -d $withval/include/slang; then
 219                                 CFLAGS="$CFLAGS -I${withval}/include/slang"
 220                         elif test -d $withval/include; then
 221                                 CFLAGS="$CFLAGS -I${withval}/include"
 222                         fi
 223                         LDFLAGS="$LDFLAGS -L${withval}/lib"
 224                 fi
 225         fi
 226         AC_MSG_RESULT($mutt_cv_slang)
 227         if test $mutt_cv_bsdish = yes; then
 228                 AC_CHECK_LIB(termlib, main)
 229         fi
 230         AC_DEFINE(USE_SLANG_CURSES,1,
 231                 [ Define if you compile with SLang instead of curses/ncurses. ])
 232         AC_DEFINE(HAVE_COLOR,1,[ Define if your curses library supports color. ])
 233         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS resize.o"
 234
 235         dnl --- now that we've found it, check the link
 236
 237         AC_CHECK_LIB(slang, SLtt_get_terminfo,
 238                 [MUTTLIBS="$MUTTLIBS -lslang -lm"],
 239                 [AC_MSG_ERROR(unable to compile.  check config.log)], -lm)
 240
 241         ],
 242
 243         [mutt_cv_curses=/usr
 244         AC_ARG_WITH(curses, AC_HELP_STRING([--with-curses=DIR], [Where ncurses is installed]),
 245                 [if test $withval != yes; then
 246                         mutt_cv_curses=$withval
 247                 fi
 248                 if test x$mutt_cv_curses != x/usr; then
 249                         LDFLAGS="-L${mutt_cv_curses}/lib $LDFLAGS"
 250                         CPPFLAGS="$CPPFLAGS -I${mutt_cv_curses}/include"
 251                 fi])
 252
 253         AC_CHECK_FUNC(initscr,,[
 254         cf_ncurses="ncurses"
 255         for lib in ncursesw ncurses
 256         do
 257                 AC_CHECK_LIB($lib, waddnwstr, [cf_ncurses="$lib"; break])
 258         done
 259         AC_CHECK_LIB($cf_ncurses, initscr,
 260                 [MUTTLIBS="$MUTTLIBS -l$cf_ncurses"
 261                 if test x$mutt_cv_curses = x/usr -a -d /usr/include/ncurses; then
 262                         CPPFLAGS="$CPPFLAGS -I/usr/include/ncurses"
 263                 fi
 264
 265                 if test "$cf_ncurses" = ncursesw; then
 266                         AC_CHECK_HEADERS(ncursesw/ncurses.h,[cf_cv_ncurses_header="ncursesw/ncurses.h"])
 267                 else
 268                         AC_CHECK_HEADERS(ncurses.h,[cf_cv_ncurses_header="ncurses.h"])
 269                 fi],
 270
 271                 [CF_CURSES_LIBS])
 272                 ])
 273
 274         old_LIBS="$LIBS"
 275         LIBS="$LIBS $MUTTLIBS"
 276         CF_CHECK_FUNCDECLS([#include <${cf_cv_ncurses_header-curses.h}>],
 277                            [start_color typeahead bkgdset curs_set meta use_default_colors resizeterm])
 278         if test "$ac_cv_func_decl_start_color" = yes; then
 279                 AC_DEFINE(HAVE_COLOR,1,[ Define if your curses library supports color. ])
 280         fi
 281         if test "$ac_cv_func_decl_resizeterm" = yes; then
 282                 MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS resize.o"
 283         fi
 284         LIBS="$old_LIBS"
 285         ])
 286
 287 AC_HEADER_STDC
 288
 289 AC_CHECK_HEADERS(stdarg.h sys/ioctl.h ioctl.h sysexits.h)
 290 AC_CHECK_HEADERS(sys/time.h sys/resource.h)
 291 AC_CHECK_HEADERS(unix.h)
 292
 293 AC_CHECK_FUNCS(setrlimit getsid isctype)
 294
 295 AC_TYPE_SIGNAL
 296
 297 AC_MSG_CHECKING(for sig_atomic_t in signal.h)
 298 AC_EGREP_HEADER(sig_atomic_t,signal.h,
 299   [
 300     ac_cv_type_sig_atomic_t=yes;
 301     AC_EGREP_HEADER(volatile.*sig_atomic_t,
 302                     signal.h,
 303                     [
 304                         is_sig_atomic_t_volatile=yes;
 305                         AC_MSG_RESULT([yes, volatile])
 306                     ],
 307                     [
 308                         is_sig_atomic_t_volatile=no;
 309                         AC_MSG_RESULT([yes, non volatile])
 310                     ])
 311   ],
 312   [
 313     AC_MSG_RESULT(no)
 314     AC_CHECK_TYPE(sig_atomic_t, int)
 315     is_sig_atomic_t_volatile=no
 316   ])
 317 if test $is_sig_atomic_t_volatile = 'yes'
 318 then
 319     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, sig_atomic_t)
 320 else
 321     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, [volatile sig_atomic_t])
 322 fi
 323
 324 AC_DECL_SYS_SIGLIST
 325
 326 AC_TYPE_PID_T
 327 dnl AC_CHECK_TYPE(ssize_t, int)
 328
 329 AC_CHECK_FUNCS(fgetpos memmove setegid srand48 strerror)
 330
 331 AC_REPLACE_FUNCS(strcasecmp strdup)
 332
 333 AC_CHECK_FUNC(getopt)
 334 if test $ac_cv_func_getopt = yes; then
 335         AC_CHECK_HEADERS(getopt.h)
 336 fi
 337
 338 mutt_cv_snprintf=no
 339 SNPRINTFOBJS=""
 340 AC_CHECK_FUNCS(snprintf, , [mutt_cv_snprintf=yes])
 341 AC_CHECK_FUNCS(vsnprintf, , [mutt_cv_snprintf=yes])
 342 if test $mutt_cv_snprintf = yes; then
 343         AC_LIBOBJ(snprintf)
 344 fi
 345
 346 dnl SCO uses chsize() instead of ftruncate()
 347 AC_CHECK_FUNCS(ftruncate, , [AC_CHECK_LIB(x, chsize)])
 348
 349 dnl SCO has strftime() in libintl
 350 AC_CHECK_FUNCS(strftime, , [AC_CHECK_LIB(intl, strftime)])
 351
 352 dnl AIX may not have fchdir()
 353 AC_CHECK_FUNCS(fchdir, , [mutt_cv_fchdir=no])
 354
 355 AC_ARG_WITH(regex, AC_HELP_STRING([--with-regex], [Use the GNU regex library]),
 356         [mutt_cv_regex=yes],
 357         [AC_CHECK_FUNCS(regcomp, mutt_cv_regex=no, mutt_cv_regex=yes)])
 358
 359 if test $mutt_cv_regex = no ; then
 360 AC_CACHE_CHECK([whether your system's regexp library is completely broken],
 361         [mutt_cv_regex_broken],
 362         AC_TRY_RUN([
 363 #include <unistd.h>
 364 #include <regex.h>
 365 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
 366         mutt_cv_regex_broken=no, mutt_cv_regex_broken=yes, mutt_cv_regex_broken=yes))
 367         if test $mutt_cv_regex_broken = yes ; then
 368                 echo "Using the included GNU regex instead." >&AC_FD_MSG
 369                 mutt_cv_regex=yes
 370         fi
 371 fi
 372
 373 if test $mutt_cv_regex = yes; then
 374         AC_DEFINE(USE_GNU_REGEX,1,[ Define if you want to use the included regex.c. ])
 375         AC_LIBOBJ(regex)
 376 fi
 377
 378
 379 AC_ARG_WITH(homespool,
 380   AC_HELP_STRING([--with-homespool[=FILE]], [File in user's directory where new mail is spooled]), with_homespool=${withval})
 381 if test x$with_homespool != x; then
 382         if test $with_homespool = yes; then
 383                 with_homespool=mailbox
 384         fi
 385         AC_DEFINE_UNQUOTED(MAILPATH,"$with_homespool",[ Where new mail is spooled. ])
 386         AC_DEFINE(HOMESPOOL,1,
 387           [Is mail spooled to the user's home directory?  If defined,
 388            MAILPATH should be set to the filename of the spool mailbox
 389            relative the the home directory.
 390            use: configure --with-homespool=FILE])
 391         AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 392         mutt_cv_setgid=no
 393 else
 394         AC_ARG_WITH(mailpath, AC_HELP_STRING([--with-mailpath=DIR], [Directory where spool mailboxes are located]),
 395                 [mutt_cv_mailpath=$withval],
 396                 [ AC_CACHE_CHECK(where new mail is stored, mutt_cv_mailpath,
 397                         [mutt_cv_mailpath=no
 398                         if test -d /var/mail; then
 399                                 mutt_cv_mailpath=/var/mail
 400                         elif test -d /var/spool/mail; then
 401                                 mutt_cv_mailpath=/var/spool/mail
 402                         elif test -d /usr/spool/mail; then
 403                                 mutt_cv_mailpath=/usr/spool/mail
 404                         elif test -d /usr/mail; then
 405                                 mutt_cv_mailpath=/usr/mail
 406                         fi])
 407                 ])
 408         if test "$mutt_cv_mailpath" = no; then
 409                 AC_MSG_ERROR("Could not determine where new mail is stored.")
 410         fi
 411         AC_DEFINE_UNQUOTED(MAILPATH,"$mutt_cv_mailpath",[ Where new mail is spooled. ])
 412
 413         AC_CACHE_CHECK(if $mutt_cv_mailpath is world writable, mutt_cv_worldwrite, [AC_TRY_RUN([#include <sys/types.h>
 414 #include <sys/stat.h>
 415
 416 int main (int argc, char **argv)
 417 {
 418         struct stat s;
 419
 420         stat ("$mutt_cv_mailpath", &s);
 421         if (s.st_mode & S_IWOTH) exit (0);
 422         exit (1);
 423 }], mutt_cv_worldwrite=yes, mutt_cv_worldwrite=no, mutt_cv_worldwrite=no)])
 424
 425         mutt_cv_setgid=no
 426         if test $mutt_cv_worldwrite = yes; then
 427                 AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 428         else
 429
 430                 AC_CACHE_CHECK(if $mutt_cv_mailpath is group writable, mutt_cv_groupwrite, [AC_TRY_RUN([#include <sys/types.h>
 431 #include <sys/stat.h>
 432
 433 int main (int argc, char **argv)
 434 {
 435         struct stat s;
 436
 437         stat ("$mutt_cv_mailpath", &s);
 438         if (s.st_mode & S_IWGRP) exit (0);
 439         exit (1);
 440 }], mutt_cv_groupwrite=yes, mutt_cv_groupwrite=no, mutt_cv_groupwrite=no)])
 441
 442                 if test $mutt_cv_groupwrite = yes; then
 443                         AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 444                         AC_DEFINE(USE_SETGID,1,[ Define if mutt should run setgid "mail". ])
 445                         mutt_cv_setgid=yes
 446                 fi
 447         fi
 448 fi
 449
 450 AC_ARG_ENABLE(external_dotlock, AC_HELP_STRING([--enable-external-dotlock], [Force use of an external dotlock program]),
 451         [mutt_cv_external_dotlock="$enableval"])
 452
 453 if test "x$mutt_cv_setgid" = "xyes" || test "x$mutt_cv_fchdir" = "xno" \
 454         || test "x$mutt_cv_external_dotlock" = "xyes"
 455 then
 456         AC_DEFINE(DL_STANDALONE,1,[ Define if you want to use an external dotlocking program. ])
 457         DOTLOCK_TARGET="muttng_dotlock"
 458 else
 459         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS dotlock.o"
 460 fi
 461
 462 AC_SUBST(DOTLOCK_TARGET)
 463
 464
 465 AC_MSG_CHECKING(where to put the documentation)
 466 AC_ARG_WITH(docdir, AC_HELP_STRING([--with-docdir=PATH], [Specify where to put the documentation]),
 467         [mutt_cv_docdir=$withval],
 468         [mutt_cv_docdir="$mutt_cv_prefix/doc/muttng"])
 469 AC_MSG_RESULT($mutt_cv_docdir)
 470
 471 docdir=$mutt_cv_docdir
 472 AC_SUBST(docdir)
 473
 474 if test x$mutt_cv_setgid = xyes; then
 475         DOTLOCK_GROUP='mail'
 476         DOTLOCK_PERMISSION=2755
 477 else
 478         DOTLOCK_GROUP=''
 479         DOTLOCK_PERMISSION=755
 480 fi
 481 AC_SUBST(DOTLOCK_GROUP)
 482 AC_SUBST(DOTLOCK_PERMISSION)
 483
 484 AC_ARG_WITH(domain, AC_HELP_STRING([--with-domain=DOMAIN], [Specify your DNS domain name]),
 485         [if test $withval != yes; then
 486                 AC_DEFINE_UNQUOTED(DOMAIN,"$withval",[ Define your domain name. ])
 487         fi])
 488
 489 need_socket="no"
 490
 491 dnl -- socket dependencies --
 492
 493 AC_ARG_ENABLE(pop,  AC_HELP_STRING([--enable-pop], [Enable POP3 support]),
 494 [       if test x$enableval = xyes ; then
 495                 AC_DEFINE(USE_POP,1,[ Define if you want support for the POP3 protocol. ])
 496                 LIBPOP="-Lpop -lpop"
 497                 LIBPOPDEPS="\$(top_srcdir)/pop/pop.h pop/libpop.a"
 498                 need_socket="yes"
 499                 need_pop="yes"
 500                 need_md5="yes"
 501         fi
 502 ])
 503 AM_CONDITIONAL(BUILD_POP, test x$need_pop = xyes)
 504
 505 AC_ARG_ENABLE(imap, AC_HELP_STRING([--enable-imap], [Enable IMAP support]),
 506 [       if test x$enableval = xyes ; then
 507                 AC_DEFINE(USE_IMAP,1,[ Define if you want support for the IMAP protocol. ])
 508                 LIBIMAP="-Limap -limap"
 509                 LIBIMAPDEPS="\$(top_srcdir)/imap/imap.h imap/libimap.a"
 510                 need_imap="yes"
 511                 need_socket="yes"
 512                 need_md5="yes"
 513         fi
 514 ])
 515 AM_CONDITIONAL(BUILD_IMAP, test x$need_imap = xyes)
 516
 517 AC_ARG_ENABLE(nntp, [  --enable-nntp              Enable NNTP support],
 518 [       if test x$enableval = xyes ; then
 519                 AC_DEFINE(USE_NNTP)
 520                 LIBNNTP="-Lnntp -lnntp"
 521                 LIBNNTPDEPS="\$(top_srcdir)/nntp/nntp.h nntp/libnntp.a"
 522                 need_nntp="yes"
 523                 need_socket="yes"
 524         fi
 525 ])
 526 AM_CONDITIONAL(BUILD_NNTP, test x$need_nntp = xyes)
 527
 528 dnl -- end socket dependencies --
 529
 530 if test "$need_socket" = "yes"
 531 then
 532         AC_MSG_CHECKING([for socklen_t])
 533         AC_EGREP_HEADER(socklen_t, sys/socket.h, AC_MSG_RESULT([yes]),
 534                 AC_MSG_RESULT([no])
 535                 AC_DEFINE(socklen_t,int,
 536                         [ Define to 'int' if <sys/socket.h> doesn't have it. ]))
 537         AC_CHECK_FUNC(gethostent, , AC_CHECK_LIB(nsl, gethostent))
 538         AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt))
 539         AC_CHECK_FUNCS(getaddrinfo)
 540         AC_DEFINE(USE_SOCKET,1,
 541                 [ Include code for socket support. Set automatically if you enable POP3 or IMAP ])
 542         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS account.o mutt_socket.o mutt_tunnel.o"
 543 fi
 544
 545 dnl -- imap dependencies --
 546
 547 AC_ARG_WITH(gss, AC_HELP_STRING([--with-gss[=PFX]], [Compile in GSSAPI authentication for IMAP]),
 548     gss_prefix="$withval", gss_prefix="no")
 549 if test "$gss_prefix" != "no"
 550 then
 551   if test "$need_imap" = "yes"
 552   then
 553     MUTT_AM_PATH_GSSAPI(gss_prefix)
 554     AC_MSG_CHECKING(GSSAPI implementation)
 555     AC_MSG_RESULT($GSSAPI_IMPL)
 556     if test "$GSSAPI_IMPL" = "none"
 557     then
 558       AC_CACHE_SAVE
 559       AC_MSG_RESULT([GSSAPI libraries not found])
 560     fi
 561     if test "$GSSAPI_IMPL" = "Heimdal"
 562     then
 563       AC_DEFINE(HAVE_HEIMDAL,1,[ Define if your GSSAPI implementation is Heimdal ])
 564     fi
 565     CPPFLAGS="$CPPFLAGS $GSSAPI_CFLAGS"
 566     MUTTLIBS="$MUTTLIBS $GSSAPI_LIBS"
 567     AC_DEFINE(USE_GSS,1,[ Define if you have GSSAPI libraries available ])
 568     need_gss="yes"
 569   else
 570     AC_MSG_WARN([GSS was requested but IMAP is not enabled])
 571   fi
 572 fi
 573 AM_CONDITIONAL(USE_GSS, test x$need_gss = xyes)
 574
 575 dnl -- end imap dependencies --
 576
 577 AC_ARG_WITH(ssl, AC_HELP_STRING([--with-ssl[=PFX]], [Compile in SSL support for POP/IMAP]),
 578 [       if test "$with_ssl" != "no"
 579         then
 580           if test "$need_socket" != "yes"; then
 581            AC_MSG_ERROR([SSL support is only useful with POP or IMAP support])
 582           fi
 583
 584           if test "$with_ssl" != "yes"
 585           then
 586            LDFLAGS="$LDFLAGS -L$withval/lib"
 587            CPPFLAGS="$CPPFLAGS -I$withval/include"
 588           fi
 589           saved_LIBS="$LIBS"
 590
 591           AC_CHECK_LIB(crypto, X509_new,, AC_MSG_ERROR([Unable to find SSL library]))
 592           AC_CHECK_LIB(ssl, SSL_new,, AC_MSG_ERROR([Unable to find SSL library]), -lcrypto)
 593
 594           AC_CHECK_FUNCS(RAND_status RAND_egd)
 595
 596           AC_DEFINE(USE_SSL,1,[ Define if you want support for SSL. ])
 597           LIBS="$saved_LIBS"
 598           MUTTLIBS="$MUTTLIBS -lssl -lcrypto"
 599           MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_ssl.o"
 600           need_ssl=yes
 601
 602         fi
 603 ])
 604 AM_CONDITIONAL(USE_SSL, test x$need_ssl = xyes)
 605
 606 dnl SSL support via NSS
 607 AC_ARG_WITH(nss, AC_HELP_STRING([--with-nss[=PFX]], [Compile in SSL support for POP/IMAP via NSS]),
 608 [       if test "$with_nss" != no
 609         then
 610           if test "$need_socket" != "yes"; then
 611            AC_MSG_ERROR([SSL support is only useful with POP or IMAP support])
 612           fi
 613
 614           if test "$with_nss" != "yes"
 615           then
 616            LDFLAGS="$LDFLAGS -L$withval/lib"
 617            CPPFLAGS="$CPPFLAGS -I$withval/include -I$withval/public/security"
 618           fi
 619
 620           AC_DEFINE(USE_NSS,1,[ Define if you want support for SSL via the NSS library. ])
 621           MUTTLIBS="$MUTTLIBS -lssl -lnss -lcertdb -lcerthi -lcryptohi"
 622           MUTTLIBS="$MUTTLIBS -lpk11wrap -lsoftoken -lsecutil -ldbm -lplds4 -lplc4 -lfreebl"
 623           MUTTLIBS="$MUTTLIBS -lnspr4"
 624
 625           MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_ssl_nss.o"
 626           need_ssl=yes
 627         fi
 628 ])
 629
 630 AC_ARG_WITH([gnutls], AC_HELP_STRING([--with-gnutls[=PFX]], [Enable SSL support using gnutls]),
 631     [gnutls_prefix="$withval"], [gnutls_prefix="no"])
 632 if test "$gnutls_prefix" != "no"
 633 then
 634   if test "$need_socket" != "yes"
 635   then
 636     AC_MSG_ERROR([SSL support is only useful with POP or IMAP support])
 637   fi
 638   MUTT_AM_PATH_GNUTLS([$gnutls_prefix],
 639     [dnl GNUTLS found
 640     CPPFLAGS="$CPPFLAGS $LIBGNUTLS_CFLAGS"
 641     MUTTLIBS="$MUTTLIBS $LIBGNUTLS_LIBS"
 642     AC_DEFINE(USE_GNUTLS, 1, [Define if you want support for SSL via the gnutls library.])
 643
 644     MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_ssl_gnutls.o"
 645     need_ssl=yes],
 646     [dnl GNUTLS not found
 647       AC_MSG_ERROR([could not find libgnutls])
 648     ])
 649 fi
 650
 651 AC_ARG_WITH(sasl, AC_HELP_STRING([--with-sasl[=PFX]], [Use Cyrus SASL library for POP/IMAP authentication]),
 652         [
 653         if test "$with_sasl" != "no" -a "$need_imap" != "yes" -a "$need_pop" != "yes"
 654         then
 655           AC_MSG_ERROR([SASL support is only useful with POP or IMAP support])
 656         fi
 657
 658         if test "$with_sasl" != "no"
 659         then
 660           if test "$with_sasl" != "yes"
 661           then
 662             CPPFLAGS="$CPPFLAGS -I$with_sasl/include"
 663             LDFLAGS="$LDFLAGS -L$with_sasl/lib"
 664           fi
 665
 666           saved_LIBS="$LIBS"
 667
 668           AC_CHECK_LIB(sasl, sasl_client_init,,
 669             AC_MSG_ERROR([could not find libsasl]),)
 670
 671           MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_sasl.o"
 672           MUTTLIBS="$MUTTLIBS -lsasl"
 673           LIBS="$saved_LIBS"
 674           AC_DEFINE(USE_SASL,1,
 675                   [ Define if want to use the Cyrus SASL library for POP/IMAP authentication. ])
 676           need_sasl=yes
 677         fi
 678         ])
 679 AM_CONDITIONAL(USE_SASL, test x$need_sasl = xyes)
 680
 681 AC_ARG_WITH(sasl2, AC_HELP_STRING([--with-sasl2[=PFX]], [Use Cyrus SASL library version 2 for POP/IMAP authentication]),
 682         [
 683         if test "$with_sasl2" != "no" -a "$need_imap" != "yes" -a "$need_pop" != "yes"
 684         then
 685           AC_MSG_ERROR([SASL2 support is only useful with POP or IMAP support])
 686         fi
 687
 688         if test "$with_sasl2" != "no"
 689         then
 690           if test "$with_sasl2" != "yes"
 691           then
 692             CPPFLAGS="$CPPFLAGS -I$with_sasl2/include"
 693             LDFLAGS="$LDFLAGS -L$with_sasl2/lib"
 694           fi
 695
 696           saved_LIBS="$LIBS"
 697
 698           AC_CHECK_LIB(sasl2, sasl_client_init,,
 699             AC_MSG_ERROR([could not find libsasl2]),)
 700
 701           MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_sasl.o"
 702           MUTTLIBS="$MUTTLIBS -lsasl2"
 703           LIBS="$saved_LIBS"
 704           AC_DEFINE(USE_SASL,1,
 705                   [ Define if want to use the Cyrus SASL library for POP/IMAP authentication. ])
 706           AC_DEFINE(USE_SASL2,1,
 707                   [ Define if want to use version 2 of the Cyrus SASL library. ])
 708           need_sasl=yes
 709         fi
 710         ])
 711 AM_CONDITIONAL(USE_SASL, test x$need_sasl = xyes)
 712
 713 AC_ARG_WITH(idn, AC_HELP_STRING([--with-idn=[PFX]], [Use GNU libidn for domain names]),
 714                  [
 715                   if test "$with_idn" != "no" ; then
 716                         if test "$with_idn" != "yes" ; then
 717                            CPPFLAGS="$CPPFLAGS -I$with_idn/include"
 718                            LDFLAGS="$LDFLAGS -L$with_idn/lib"
 719                         fi
 720                   fi
 721                  ]
 722 )
 723
 724 if test "x$with_idn" != "xno"; then
 725    AC_CHECK_LIB(idn, stringprep_check_version)
 726    AC_CHECK_FUNCS(idna_to_unicode_utf8_from_utf8 idna_to_unicode_8z8z)
 727    AC_CHECK_FUNCS(idna_to_ascii_from_utf8 idna_to_ascii_8z)
 728    AC_CHECK_FUNCS(idna_to_ascii_lz idna_to_ascii_from_locale)
 729 fi
 730
 731 dnl -- end socket --
 732
 733 AC_ARG_ENABLE(debug, AC_HELP_STRING([--enable-debug], [Enable debugging support]),
 734         [ if test x$enableval = xyes ; then
 735                 AC_DEFINE(DEBUG,1,[ Define to enable debugging info. ])
 736           fi
 737          ])
 738
 739 AC_ARG_ENABLE(flock, AC_HELP_STRING([--enable-flock], [Use flock() to lock files]),
 740         [if test $enableval = yes; then
 741                 AC_DEFINE(USE_FLOCK,1, [ Define to use flock() to lock mailboxes. ])
 742         fi])
 743
 744 mutt_cv_fcntl=yes
 745 AC_ARG_ENABLE(fcntl, AC_HELP_STRING([--disable-fcntl], [Do NOT use fcntl() to lock files]),
 746         [if test $enableval = no; then mutt_cv_fcntl=no; fi])
 747
 748 if test $mutt_cv_fcntl = yes; then
 749         AC_DEFINE(USE_FCNTL,1, [ Define to use fcntl() to lock folders. ])
 750 fi
 751
 752 dnl This may look cumbersome -- please keep it that way, so we can
 753 dnl quickly change the default to "yes" again.
 754 mutt_cv_inodesort=no
 755 AC_ARG_ENABLE(inodesort,  AC_HELP_STRING([--enable-inodesort], [Read files in maildir folders sorted by inode.]),
 756        [if test x$enableval = xyes ; then mutt_cv_inodesort=yes; fi])
 757
 758 if test $mutt_cv_inodesort = yes; then
 759         AC_DEFINE(USE_INODESORT, 1, [ Define to sort files in a maildir by inode number. ])
 760 fi
 761
 762 mutt_cv_warnings=yes
 763 AC_ARG_ENABLE(warnings, AC_HELP_STRING([--disable-warnings], [Turn off compiler warnings (not recommended)]),
 764 [if test $enableval = no; then
 765         mutt_cv_warnings=no
 766 fi])
 767
 768 if test x$GCC = xyes -a $mutt_cv_warnings = yes; then
 769         CFLAGS="-Wall -pedantic $CFLAGS"
 770 fi
 771
 772 AC_ARG_ENABLE(nfs-fix, AC_HELP_STRING([--enable-nfs-fix], [Work around an NFS with broken attributes caching]),
 773         [if test x$enableval = xyes; then
 774                 AC_DEFINE(NFS_ATTRIBUTE_HACK,1,
 775                   [Define if you have problems with mutt not detecting
 776                    new/old mailboxes over NFS.  Some NFS implementations
 777                    incorrectly cache the attributes of small files.])
 778         fi])
 779
 780 AC_ARG_ENABLE(buffy-size, AC_HELP_STRING([--enable-buffy-size], [Use file size attribute instead of access time]),
 781         [if test x$enableval = xyes; then
 782                 AC_DEFINE(BUFFY_SIZE,1,[ Define to enable the "buffy_size" feature. ])
 783         fi])
 784
 785 AC_ARG_ENABLE(mailtool, AC_HELP_STRING([--enable-mailtool], [Enable Sun mailtool attachments support ]),
 786         [if test x$enableval = xyes; then
 787                 AC_DEFINE(SUN_ATTACHMENT,1,[ Define to enable Sun mailtool attachments support. ])
 788         fi])
 789
 790 AC_ARG_ENABLE(compressed, [  --enable-compressed        Enable compressed folders support ],
 791         [if test x$enableval = xyes; then
 792                 AC_DEFINE(USE_COMPRESSED)
 793         fi])
 794
 795 AC_ARG_ENABLE(locales-fix, AC_HELP_STRING([--enable-locales-fix], [The result of isprint() is unreliable ]),
 796         [if test x$enableval = xyes; then
 797                 AC_DEFINE(LOCALES_HACK,1,[ Define if the result of isprint() is unreliable. ])
 798         fi])
 799
 800 AC_ARG_WITH(exec-shell, AC_HELP_STRING([--with-exec-shell=SHELL], [Specify alternate shell (ONLY if /bin/sh is broken)]),
 801         [if test $withval != yes; then
 802                 AC_DEFINE_UNQUOTED(EXECSHELL, "$withval",
 803                  [program to use for shell commands])
 804          else
 805                 AC_DEFINE_UNQUOTED(EXECSHELL, "/bin/sh")
 806         fi],
 807         [AC_DEFINE_UNQUOTED(EXECSHELL, "/bin/sh")])
 808
 809 dnl -- start cache --
 810 AC_ARG_ENABLE(hcache, AC_HELP_STRING([--enable-hcache], [Enable header caching]),
 811 [if test x$enableval = xyes; then
 812     AC_DEFINE(USE_HCACHE, 1, [Enable header caching])
 813
 814     OLDCPPFLAGS="$CPPFLAGS"
 815     OLDLIBS="$LIBS"
 816
 817     need_md5="yes"
 818
 819     ac_prefer_qdbm=yes
 820     AC_ARG_WITH(qdbm, AC_HELP_STRING([--without-qdbm], [Don't use qdbm even if it is available]),
 821         ac_prefer_qdbm=$withval)
 822     if test x$ac_prefer_qdbm != xno; then
 823         ac_cv_vlopen=no
 824         QDBM_DIRS="$mutt_cv_prefix /usr/local /usr"
 825         AC_MSG_CHECKING([for vlopen])
 826         for d in $QDBM_DIRS; do
 827           if test x$ac_cv_vlopen = xno && test -d "$d/include" && test -d "$d/lib"; then
 828             QDBM_INC="-I$d/include"
 829             QDBM_LIB="-L$d/lib"
 830             CPPFLAGS="$OLDCPPFLAGS $QDBM_INC"
 831             LIBS="$OLDLIBS $QDBM_LIB -lqdbm"
 832             AC_TRY_LINK([#include <villa.h>],[vlopen(0,0,0);],[ac_cv_vlopen=yes])
 833           fi
 834         done
 835         if test x$ac_cv_vlopen = xyes; then
 836           AC_MSG_RESULT(yes)
 837         else
 838           AC_MSG_RESULT(no)
 839         fi
 840     fi
 841
 842     ac_prefer_gdbm=yes
 843     AC_ARG_WITH(gdbm, AC_HELP_STRING([--without-gdbm], [Don't use gdbm even if it is available]),
 844         ac_prefer_gdbm=$withval)
 845     if test x$ac_prefer_gdbm != xno -a x$ac_cv_vlopen != xyes; then
 846         ac_cv_gdbmopen=no
 847         GDBM_DIRS="$mutt_cv_prefix /usr/local /usr"
 848         AC_MSG_CHECKING([for gdbm_open])
 849         for d in $GDBM_DIRS; do
 850           if test x$ac_cv_gdbmopen = xno && test -d "$d/include" && test -d "$d/lib"; then
 851             GDBM_INC="-I$d/include"
 852             GDBM_LIB="-L$d/lib"
 853             CPPFLAGS="$OLDCPPFLAGS $GDBM_INC"
 854             LIBS="$OLDLIBS $GDBM_LIB -lgdbm"
 855             AC_TRY_LINK([#include <gdbm.h>],[gdbm_open(0,0,0,0,0);],[ac_cv_gdbmopen=yes])
 856           fi
 857         done
 858         if test x$ac_cv_gdbmopen = xyes; then
 859           AC_MSG_RESULT(yes)
 860         else
 861           AC_MSG_RESULT(no)
 862         fi
 863     fi
 864
 865     ac_bdb_prefix=yes
 866     AC_ARG_WITH(bdb, AC_HELP_STRING([--with-bdb[=DIR]], [Use BerkeleyDB4 if gdbm is not available ]),
 867         ac_bdb_prefix=$withval)
 868     if test x$ac_bdb_prefix != xno -a x$ac_cv_gdbmopen != xyes -a x$ac_cv_vlopen != xyes; then
 869         test x$ac_bdb_prefix = xyes && ac_bdb_prefix="$mutt_cv_prefix /opt/csw/bdb4 /opt /usr/local /usr"
 870         for d in $ac_bdb_prefix; do
 871             bdbpfx="$bdbpfx $d"
 872             for v in BerkeleyDB.4.3 BerkeleyDB.4.2 BerkeleyDB.4.1; do
 873                 bdbpfx="$bdbpfx $d/$v"
 874             done
 875         done
 876         BDB_VERSIONS="db-4 db4 db-4.3 db4.3 db43 db-4.2 db4.2 db42 db-4.1 db4.1 db41 db ''"
 877         AC_MSG_CHECKING([for BerkeleyDB > 4.0])
 878         for d in $bdbpfx; do
 879             BDB_INCLUDE_DIR=""
 880             BDB_LIB_DIR=""
 881             for v in / $BDB_VERSIONS; do
 882                 if test -r "$d/include/$v/db.h"; then
 883                     BDB_INCLUDE_DIR="$d/include/$v"
 884                     if test -d "$d/lib/$v"; then
 885                         BDB_LIB_DIR="$d/lib/$v"
 886                         for l in `echo $BDB_VERSIONS`; do
 887                             CPPFLAGS="-I$BDB_INCLUDE_DIR $OLDCPPFLAGS"
 888                             LIBS="$OLDLIBS -L$BDB_LIB_DIR -l$l"
 889                             AC_TRY_LINK([
 890                                 #include <stdlib.h>
 891                                 #include <db.h>
 892                             ],[
 893                                 DB *db = NULL;
 894                                 db->open(db,NULL,NULL,NULL,0,0,0);
 895                             ],[
 896                                 ac_cv_dbcreate=yes
 897                                 BDB_LIB="$l"
 898                                 break
 899                             ])
 900                         done
 901                         test x$ac_cv_dbcreate = xyes && break
 902                     fi
 903                 fi
 904             done
 905             test x$BDB_LIB != x && break
 906         done
 907         if test x$ac_cv_dbcreate = xyes; then
 908             AC_MSG_RESULT(yes)
 909         else
 910             AC_MSG_RESULT(no)
 911         fi
 912     fi
 913
 914     if test x$ac_cv_vlopen = xyes; then
 915         CPPFLAGS="$OLDCPPFLAGS $QDBM_INC"
 916         LIBS="$OLDLIBS $QDBM_LIB -lqdbm"
 917         AC_DEFINE(HAVE_QDBM, 1, [QDBM Support])
 918     elif test x$ac_cv_gdbmopen = xyes; then
 919         CPPFLAGS="$OLDCPPFLAGS $GDBM_INC"
 920         LIBS="$OLDLIBS $GDBM_LIB -lgdbm";
 921         AC_DEFINE(HAVE_GDBM, 1, [GDBM Support])
 922     elif test x$ac_cv_dbcreate = xyes; then
 923         CPPFLAGS="-I$BDB_INCLUDE_DIR $OLDCPPFLAGS"
 924         LIBS="$OLDLIBS -L$BDB_LIB_DIR -l$BDB_LIB"
 925         AC_DEFINE(HAVE_DB4, 1, [Sleepycat DB4 Support])
 926     else
 927         AC_MSG_ERROR([You need one of: QDBM, GDBM or Sleepycat DB4 for --enable-hcache])
 928     fi
 929 fi])
 930 dnl -- end cache --
 931
 932 AC_SUBST(MUTTLIBS)
 933 AC_SUBST(MUTT_LIB_OBJECTS)
 934 AC_SUBST(LIBIMAP)
 935 AC_SUBST(LIBIMAPDEPS)
 936 AC_SUBST(LIBPOP)
 937 AC_SUBST(LIBPOPDEPS)
 938 AC_SUBST(LIBNNTP)
 939 AC_SUBST(LIBNNTPDEPS)
 940
 941 dnl -- iconv/gettext --
 942
 943 AC_ARG_ENABLE(iconv, AC_HELP_STRING([--disable-iconv], [Disable iconv support]),
 944         [if test x$enableval = xno ; then
 945                 am_cv_func_iconv=no
 946         fi
 947 ])
 948
 949 MUTT_AM_GNU_GETTEXT
 950
 951 if test "$am_cv_func_iconv" != "yes"
 952 then
 953   AC_MSG_WARN([Configuring without iconv support. See INSTALL for details])
 954 else
 955
 956 AC_CHECK_HEADERS(iconv.h,
 957         [AC_MSG_CHECKING(whether iconv.h defines iconv_t)
 958          AC_EGREP_HEADER([typedef.*iconv_t],iconv.h,
 959                 [AC_MSG_RESULT(yes)
 960                  AC_DEFINE(HAVE_ICONV_T_DEF, 1,
 961                         [Define if <iconv.h> defines iconv_t.])],
 962                  AC_MSG_RESULT(no))])
 963
 964 dnl (1) Some implementations of iconv won't convert from UTF-8 to UTF-8.
 965 dnl (2) In glibc-2.1.2 and earlier there is a bug that messes up ob and
 966 dnl     obl when args 2 and 3 are 0 (fixed in glibc-2.1.3).
 967 AC_CACHE_CHECK([whether this iconv is good enough], mutt_cv_iconv_good,
 968         mutt_save_LIBS="$LIBS"
 969         LIBS="$LIBS $LIBICONV"
 970         AC_TRY_RUN([
 971 #include <iconv.h>
 972 int main()
 973 {
 974   iconv_t cd;
 975 changequote(, )dnl
 976   char buf[4];
 977 changequote([, ])dnl
 978   char *ob;
 979   size_t obl;
 980   ob = buf, obl = sizeof(buf);
 981   return ((cd = iconv_open("UTF-8", "UTF-8")) != (iconv_t)(-1) &&
 982           (iconv(cd, 0, 0, &ob, &obl) ||
 983            !(ob == buf && obl == sizeof(buf)) ||
 984            iconv_close(cd)));
 985 }
 986                 ],
 987                 mutt_cv_iconv_good=yes,
 988                 mutt_cv_iconv_good=no,
 989                 mutt_cv_iconv_good=yes)
 990         LIBS="$mutt_save_LIBS")
 991 if test "$mutt_cv_iconv_good" = no; then
 992   AC_MSG_ERROR(Try using libiconv instead)
 993 fi
 994
 995 dnl This is to detect implementations such as the one in glibc-2.1,
 996 dnl which always convert exactly but return the number of characters
 997 dnl converted instead of the number converted inexactly.
 998 AC_CACHE_CHECK([whether iconv is non-transcribing], mutt_cv_iconv_nontrans,
 999         mutt_save_LIBS="$LIBS"
1000         LIBS="$LIBS $LIBICONV"
1001         AC_TRY_RUN([
1002 #include <iconv.h>
1003 #include <string.h>
1004 int main()
1005 {
1006   iconv_t cd;
1007   const char *ib;
1008   char *ob;
1009   size_t ibl, obl;
1010   const char *s = "\304\211";
1011 changequote(, )dnl
1012   char t[3];
1013 changequote([, ])dnl
1014   ib = s, ibl = 2, ob = t, obl = 3;
1015   return ((cd = iconv_open("UTF-8", "UTF-8")) == (iconv_t)(-1) ||
1016           iconv(cd, &ib, &ibl, &ob, &obl));
1017 }
1018                 ],
1019                 mutt_cv_iconv_nontrans=no,
1020                 mutt_cv_iconv_nontrans=yes,
1021                 mutt_cv_iconv_nontrans=no)
1022         LIBS="$mutt_save_LIBS")
1023 if test "$mutt_cv_iconv_nontrans" = yes; then
1024   AC_DEFINE(ICONV_NONTRANS, 1)
1025 else
1026   AC_DEFINE(ICONV_NONTRANS, 0)
1027 fi
1028
1029 CPPFLAGS="$CPPFLAGS -I\$(top_srcdir)/intl"
1030
1031 if test "$BUILD_INCLUDED_LIBINTL" = "yes"; then
1032   AC_DEFINE(HAVE_BIND_TEXTDOMAIN_CODESET,1,
1033           [ Define if your gettext has bind_textdomain_codeset. ])
1034 else
1035   AC_CHECK_FUNCS(bind_textdomain_codeset)
1036 fi
1037
1038 fi # libiconv
1039
1040 dnl -- locales --
1041
1042 AC_CHECK_HEADERS(wchar.h)
1043
1044 AC_CACHE_CHECK([for wchar_t], mutt_cv_wchar_t,
1045         AC_TRY_COMPILE([
1046 #include <stddef.h>
1047 #include <stdlib.h>
1048 #ifdef HAVE_WCHAR_H
1049 #include <wchar.h>
1050 #endif
1051                 ],
1052                 [ wchar_t wc; return 0; ],
1053                 mutt_cv_wchar_t=yes,
1054                 mutt_cv_wchar_t=no))
1055
1056 if test "$mutt_cv_wchar_t" = no; then
1057         AC_DEFINE(wchar_t,int,[ Define to 'int' if system headers don't define. ])
1058 fi
1059
1060 AC_CACHE_CHECK([for wint_t], mutt_cv_wint_t,
1061         AC_TRY_COMPILE([
1062 #include <stddef.h>
1063 #include <stdlib.h>
1064 #ifdef HAVE_WCHAR_H
1065 #include <wchar.h>
1066 #endif
1067                 ],
1068                 [ wint_t wc; return 0; ],
1069                 mutt_cv_wint_t=yes,
1070                 mutt_cv_wint_t=no))
1071
1072 if test "$mutt_cv_wint_t" = no; then
1073         AC_DEFINE(wint_t,int,[ Define to 'int' if system headers don't define. ])
1074 fi
1075
1076 AC_CHECK_HEADERS(wctype.h)
1077 AC_CHECK_FUNCS(iswalnum iswalpha  iswcntrl iswdigit)
1078 AC_CHECK_FUNCS(iswgraph iswlower iswprint iswpunct iswspace iswupper)
1079 AC_CHECK_FUNCS(iswxdigit towupper towlower)
1080
1081 AC_CACHE_CHECK([for mbstate_t], mutt_cv_mbstate_t,
1082         AC_TRY_COMPILE([
1083 #include <stddef.h>
1084 #include <stdlib.h>
1085 #ifdef HAVE_WCHAR_H
1086 #include <wchar.h>
1087 #endif
1088                 ],
1089                 [ mbstate_t s; return 0; ],
1090                 mutt_cv_mbstate_t=yes,
1091                 mutt_cv_mbstate_t=no))
1092
1093 if test "$mutt_cv_mbstate_t" = no; then
1094         AC_DEFINE(mbstate_t,int,[ Define to 'int' if system headers don't define. ])
1095 fi
1096
1097 wc_funcs=maybe
1098 AC_ARG_WITH(wc-funcs, AC_HELP_STRING([--without-wc-funcs], [Do not use the system's wchar_t functions]),
1099         wc_funcs=$withval)
1100
1101 if test "$wc_funcs" != yes -a "$wc_funcs" != no; then
1102         AC_CACHE_CHECK([for wchar_t functions], mutt_cv_wc_funcs,
1103                 mutt_cv_wc_funcs=no
1104                 AC_TRY_LINK([
1105 #define _XOPEN_SOURCE 1
1106 #include <stddef.h>
1107 #include <stdlib.h>
1108 #ifdef HAVE_WCTYPE_H
1109 #include <wctype.h>
1110 #endif
1111 #ifdef HAVE_WCHAR_H
1112 #include <wchar.h>
1113 #endif],
1114                         [mbrtowc(0, 0, 0, 0); wctomb(0, 0); wcwidth(0);
1115         iswprint(0); iswspace(0); towlower(0); towupper(0); iswalnum(0)],
1116                         mutt_cv_wc_funcs=yes))
1117         wc_funcs=$mutt_cv_wc_funcs
1118 fi
1119
1120 if test $wc_funcs = yes; then
1121         AC_DEFINE(HAVE_WC_FUNCS,1,[ Define if you are using the system's wchar_t functions. ])
1122 fi
1123
1124 AC_CACHE_CHECK([for nl_langinfo and CODESET], mutt_cv_langinfo_codeset,
1125   [AC_TRY_LINK([#include <langinfo.h>],
1126     [char* cs = nl_langinfo(CODESET);],
1127     mutt_cv_langinfo_codeset=yes,
1128     mutt_cv_langinfo_codeset=no)])
1129 if test $mutt_cv_langinfo_codeset = yes; then
1130   AC_DEFINE(HAVE_LANGINFO_CODESET,1,[ Define if you have <langinfo.h> and nl_langinfo(CODESET). ])
1131 fi
1132
1133 AC_CACHE_CHECK([for nl_langinfo and YESEXPR], mutt_cv_langinfo_yesexpr,
1134   [AC_TRY_LINK([#include <langinfo.h>],
1135     [char* cs = nl_langinfo(YESEXPR);],
1136     mutt_cv_langinfo_yesexpr=yes,
1137     mutt_cv_langinfo_yesexpr=no)])
1138 if test $mutt_cv_langinfo_yesexpr = yes; then
1139   AC_DEFINE(HAVE_LANGINFO_YESEXPR,1,[ Define if you have <langinfo.h> and nl_langinfo(YESEXPR). ])
1140 fi
1141
1142 dnl -- libesmtp --
1143 MUTT_AM_LIBESMTP
1144 if test x$use_libesmtp = xyes; then
1145     CFLAGS="$CFLAGS $mutt_libesmtp_cflags"
1146     MUTTLIBS="$MUTTLIBS $mutt_libesmtp_libs"
1147     MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_libesmtp.o"
1148
1149     AC_DEFINE(USE_LIBESMTP,
1150               1,
1151               [Define to enable the use of libesmtp])
1152 fi
1153 dnl -- end libesmtp --
1154
1155 dnl -- sgml tools --
1156 AC_MSG_CHECKING([for SGML Tools style])
1157 SGML2TXT_CMD="true"
1158 SGML2PS_CMD="true"
1159 SGML2HTML_CMD="true"
1160 case "`uname -s`" in
1161   FreeBSD)
1162     SGML2TXT_CMD="sgmlfmt -f ascii manual.sgml && uniq < manual.ascii | expand > manual.txt && rm -rf manual.ascii || true"
1163     SGML2PS_CMD="sgmlfmt -f ps manual.sgml || true"
1164     SGML2HTML_CMD="sgmlfmt -f html manual.sgml || true"
1165     AC_MSG_RESULT(FreeBSD)
1166     ;;
1167   SunOS)
1168     SGML2TXT_CMD="sgml2txt manual || true"
1169     SGML2PS_CMD="sgml2latex -p manual || true"
1170     SGML2HTML_CMD="sgml2html manual || true"
1171     AC_MSG_RESULT(Solaris)
1172     ;;
1173   *)
1174     SGML2TXT_CMD="if linuxdoc -B txt --pass='-P -c' manual ; then uniq < manual.txt | expand > _manual.txt ; rm manual.txt ; col -b < _manual.txt > manual.txt ; rm -rf _manual.txt ; fi || true"
1175     SGML2PS_CMD="sgml2latex --output=ps manual || true"
1176     SGML2HTML_CMD="sgml2html manual || true"
1177     AC_MSG_RESULT(Linux (default))
1178     ;;
1179 esac
1180 AC_SUBST(SGML2TXT_CMD)
1181 AC_SUBST(SGML2PS_CMD)
1182 AC_SUBST(SGML2HTML_CMD)
1183
1184 AC_OUTPUT(Makefile intl/Makefile m4/Makefile
1185         po/Makefile.in doc/Makefile contrib/Makefile
1186         muttbug.sh
1187         lib/Makefile
1188         imap/Makefile
1189         pop/Makefile
1190         nntp/Makefile
1191         Muttngrc.head
1192         doc/instdoc.sh)