configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl !!! WHEN ADDING NEW CONFIGURE TESTS, PLEASE ADD CODE TO MAIN.C !!!
   4 dnl !!! TO DUMP THEIR RESULTS WHEN MUTT -V IS CALLED            !!!
   5
   6 AC_PREREQ([2.50])
   7 AC_INIT([mutt.h])
   8 AM_CONFIG_HEADER(config.h)
   9
  10 mutt_cv_version=`cat $srcdir/VERSION`
  11
  12 AM_INIT_AUTOMAKE(muttng, $mutt_cv_version)
  13 dnl AC_GNU_SOURCE
  14
  15 ifdef([AC_LIBOBJ], , [define([AC_LIBOBJ], [LIB[]OBJS="$LIBOBJS $1.o"])])
  16
  17 ALL_LINGUAS="de ru it es uk fr pl nl cs id sk ko el zh_TW zh_CN pt_BR eo gl sv da lt tr ja hu et ca bg"
  18
  19 AC_CANONICAL_HOST
  20
  21 AC_MSG_CHECKING([for prefix])
  22 if test x$prefix = xNONE; then
  23         mutt_cv_prefix=$ac_default_prefix
  24 else
  25         mutt_cv_prefix=$prefix
  26 fi
  27 AC_MSG_RESULT($mutt_cv_prefix)
  28
  29 AC_PROG_CC
  30 AC_ISC_POSIX
  31 AM_C_PROTOTYPES
  32 if test "x$U" != "x"; then
  33   AC_MSG_ERROR(Compiler not ANSI compliant)
  34 fi
  35 AC_PROG_CPP
  36 AC_PROG_MAKE_SET
  37 AC_PROG_INSTALL
  38 AC_PROG_RANLIB
  39 AC_CHECK_TOOL(AR, ar, ar)
  40
  41 AC_C_INLINE
  42 AC_C_CONST
  43
  44 AC_SYS_LARGEFILE
  45
  46 AC_PATH_PROG(DBX, dbx, no)
  47 AC_PATH_PROG(GDB, gdb, no)
  48 AC_PATH_PROG(SDB, sdb, no)
  49
  50 if test $GDB != no ; then
  51         DEBUGGER=$GDB
  52 elif test $DBX != no ; then
  53         DEBUGGER=$DBX
  54 elif test $SDB != no ; then
  55         DEBUGGER=$SDB
  56 else
  57         DEBUGGER=no
  58 fi
  59
  60 AC_SUBST([DEBUGGER])
  61
  62 AH_TEMPLATE([sig_atomic_t],
  63             [/* Define to `int' if <signal.h> doesn't define.])
  64 AH_TEMPLATE([HAVE_START_COLOR],
  65             [Define if you have start_color, as a function or macro.])
  66 AH_TEMPLATE([HAVE_TYPEAHEAD],
  67             [Define if you have typeahead, as a function or macro.])
  68 AH_TEMPLATE([HAVE_BKGDSET],
  69             [Define if you have bkgdset, as a function or macro.])
  70 AH_TEMPLATE([HAVE_CURS_SET],
  71             [Define if you have curs_set, as a function or macro.])
  72 AH_TEMPLATE([HAVE_META],
  73             [Define if you have meta, as a function or macro.])
  74 AH_TEMPLATE([HAVE_USE_DEFAULT_COLORS],
  75             [Define if you have use_default_colors, as a function or macro.])
  76 AH_TEMPLATE([HAVE_RESIZETERM],
  77             [Define if you have resizeterm, as a function or macro.])
  78 AH_TEMPLATE([SIG_ATOMIC_VOLATILE_T],
  79             [Some systems declare sig_atomic_t as volatile, some others -- no.
  80              This define will have value `sig_atomic_t' or
  81              `volatile sig_atomic_t' accordingly.])
  82 AH_TEMPLATE([ICONV_NONTRANS],
  83             [Define as 1 if iconv() only converts exactly and we should treat
  84              all return values other than (size_t)(-1) as equivalent.])
  85
  86 MUTT_C99_INTTYPES
  87
  88 ac_aux_path_sendmail=/usr/sbin:/usr/lib
  89 AC_PATH_PROG(SENDMAIL, sendmail, /usr/sbin/sendmail, $PATH:$ac_aux_path_sendmail)
  90 AC_DEFINE_UNQUOTED(SENDMAIL,"$ac_cv_path_SENDMAIL",[ Where to find sendmail on your system. ])
  91
  92 OPS='$(srcdir)/OPS'
  93 if test -f $srcdir/EXPORTABLE ; then
  94         SUBVERSION="us"
  95 else
  96         SUBVERSION="i"
  97
  98         AC_ARG_ENABLE(gpgme, AC_HELP_STRING([--enable-gpgme], [Enable GPGME support]),
  99         [       if test x$enableval = xyes; then
 100                         have_gpgme=yes
 101                 fi
 102         ])
 103         AC_ARG_WITH(gpgme-prefix, AC_HELP_STRING([--with-gpgme-prefix=PFX], [prefix where GPGME is installed (optional)]),
 104         gpgme_config_prefix="$withval", gpgme_config_prefix="")
 105
 106         if test x$have_gpgme = xyes; then
 107                 if test x$gpgme_config_prefix != x; then
 108                         GPGME_CONFIG="$gpgme_config_prefix/bin/gpgme-config"
 109                 else
 110                         AC_PATH_PROG(GPGME_CONFIG, gpgme-config, no)
 111                 fi
 112                 if test "x$GPGME_CONFIG" = "xno"; then
 113                         AC_MSG_ERROR([GPGME not found])
 114                 else
 115                         LIBGPGME_CFLAGS=`$GPGME_CONFIG --cflags`
 116                         LIBGPGME_LIBS=`$GPGME_CONFIG --libs`
 117                         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS crypt-gpgme.o crypt-mod-pgp-gpgme.o crypt-mod-smime-gpgme.o"
 118                         AC_DEFINE(CRYPT_BACKEND_GPGME, 1,
 119                                   [Defined, if GPGME support is enabled])
 120                 fi
 121         fi
 122         AC_SUBST(LIBGPGME_CFLAGS)
 123         AC_SUBST(LIBGPGME_LIBS)
 124
 125         AC_ARG_ENABLE(pgp, AC_HELP_STRING([--disable-pgp], [Disable PGP support]),
 126         [       if test x$enableval = xno ; then
 127                         have_pgp=no
 128                 fi
 129         ])
 130
 131         if test x$have_pgp != xno ; then
 132                 AC_DEFINE(CRYPT_BACKEND_CLASSIC_PGP,1,
 133                     [ Define if you want classic PGP support. ])
 134                 PGPAUX_TARGET="pgpring pgpewrap"
 135                 MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS pgp.o pgpinvoke.o pgpkey.o pgplib.o gnupgparse.o pgpmicalg.o pgppacket.o crypt-mod-pgp-classic.o"
 136         fi
 137
 138         AC_ARG_ENABLE(smime, AC_HELP_STRING([--disable-smime], [Disable SMIME support]),
 139         [       if test x$enableval = xno ; then
 140                         have_smime=no
 141                 fi
 142         ])
 143
 144         if test x$have_smime != xno ; then
 145                 AC_DEFINE(CRYPT_BACKEND_CLASSIC_SMIME,1,
 146                   [ Define if you want clasic S/MIME support. ])
 147                 MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS smime.o crypt-mod-smime-classic.o"
 148                 SMIMEAUX_TARGET="smime_keys"
 149         fi
 150
 151         AC_ARG_WITH(mixmaster, AC_HELP_STRING([--with-mixmaster[=PATH]], [Include Mixmaster support]),
 152                 [if test -x "$withval" ; then
 153                         MIXMASTER="$withval"
 154                  else
 155                         MIXMASTER="mixmaster"
 156                  fi
 157                  OPS="$OPS \$(srcdir)/OPS.MIX"
 158                  MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS remailer.o"
 159                  AC_DEFINE_UNQUOTED(MIXMASTER,"$MIXMASTER",
 160                          [ Where to find mixmaster on your system. ])
 161                 ])
 162
 163 fi
 164 # We now require all OPS
 165 OPS="$OPS \$(srcdir)/OPS.PGP \$(srcdir)/OPS.SMIME \$(srcdir)/OPS.CRYPT "
 166 AC_SUBST([OPS])
 167
 168
 169 AC_SUBST(PGPAUX_TARGET)
 170 AC_SUBST(SMIMEAUX_TARGET)
 171
 172 AC_DEFINE_UNQUOTED(SUBVERSION,"$SUBVERSION",[ Is this the international version? ])
 173 AC_SUBST([SUBVERSION])
 174
 175 AC_PATH_PROG(ISPELL, ispell, no)
 176 if test $ISPELL != no; then
 177         AC_DEFINE_UNQUOTED(ISPELL,"$ISPELL",[ Where to find ispell on your system. ])
 178 fi
 179
 180 AC_ARG_WITH(slang, AC_HELP_STRING([--with-slang[=DIR]], [Use S-Lang instead of ncurses]),
 181         [AC_CACHE_CHECK([if this is a BSD system], mutt_cv_bsdish,
 182                 [AC_TRY_RUN([#include <sys/param.h>
 183
 184 main ()
 185 {
 186 #ifdef BSD
 187         exit (0);
 188 #else
 189         exit (1);
 190 #endif
 191 }],
 192                         mutt_cv_bsdish=yes,
 193                         mutt_cv_bsdish=no,
 194                         mutt_cv_bsdish=no)])
 195
 196         AC_MSG_CHECKING(for S-Lang)
 197         if test $withval = yes; then
 198                 if test -d $srcdir/../slang; then
 199                         mutt_cv_slang=$srcdir/../slang/src
 200                         CPPFLAGS="$CPPFLAGS -I${mutt_cv_slang}"
 201                         LDFLAGS="$LDFLAGS -L${mutt_cv_slang}/objs"
 202                 else
 203                         if test -d $mutt_cv_prefix/include/slang; then
 204                                 CPPFLAGS="$CPPFLAGS -I$mutt_cv_prefix/include/slang"
 205                         elif test -d /usr/include/slang; then
 206                                 CPPFLAGS="$CPPFLAGS -I/usr/include/slang"
 207                         fi
 208                         mutt_cv_slang=yes
 209                 fi
 210         else
 211                 dnl ---Check to see if $withval is a source directory
 212                 if test -f $withval/src/slang.h; then
 213                         mutt_cv_slang=$withval/src
 214                         CPPFLAGS="$CPPFLAGS -I${mutt_cv_slang}"
 215                         LDFLAGS="$LDFLAGS -L${mutt_cv_slang}/objs"
 216                 else
 217                         dnl ---Must be installed somewhere
 218                         mutt_cv_slang=$withval
 219                         if test -d $withval/include/slang; then
 220                                 CPPFLAGS="$CPPFLAGS -I${withval}/include/slang"
 221                         elif test -d $withval/include; then
 222                                 CPPFLAGS="$CPPFLAGS -I${withval}/include"
 223                         fi
 224                         LDFLAGS="$LDFLAGS -L${withval}/lib"
 225                 fi
 226         fi
 227         AC_MSG_RESULT($mutt_cv_slang)
 228         if test $mutt_cv_bsdish = yes; then
 229                 AC_CHECK_LIB(termlib, main)
 230         fi
 231         AC_DEFINE(USE_SLANG_CURSES,1,
 232                 [ Define if you compile with SLang instead of curses/ncurses. ])
 233         AC_DEFINE(HAVE_COLOR,1,[ Define if your curses library supports color. ])
 234         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS resize.o"
 235
 236         dnl --- now that we've found it, check the link
 237
 238         AC_CHECK_LIB(slang, SLtt_get_terminfo,
 239                 [MUTTLIBS="$MUTTLIBS -lslang -lm"],
 240                 [AC_MSG_ERROR(unable to compile.  check config.log)], -lm)
 241
 242         ],
 243
 244         [mutt_cv_curses=/usr
 245         AC_ARG_WITH(curses, AC_HELP_STRING([--with-curses=DIR], [Where ncurses is installed]),
 246                 [if test $withval != yes; then
 247                         mutt_cv_curses=$withval
 248                 fi
 249                 if test x$mutt_cv_curses != x/usr; then
 250                         LDFLAGS="-L${mutt_cv_curses}/lib $LDFLAGS"
 251                         CPPFLAGS="$CPPFLAGS -I${mutt_cv_curses}/include"
 252                 fi])
 253
 254         AC_CHECK_FUNC(initscr,,[
 255         cf_ncurses="ncurses"
 256         for lib in ncurses ncursesw
 257         do
 258                 AC_CHECK_LIB($lib, waddnwstr, [cf_ncurses="$lib"; break])
 259         done
 260         AC_CHECK_LIB($cf_ncurses, initscr,
 261                 [MUTTLIBS="$MUTTLIBS -l$cf_ncurses"
 262                 if test x$mutt_cv_curses = x/usr -a -d /usr/include/ncurses; then
 263                         CPPFLAGS="$CPPFLAGS -I/usr/include/ncurses"
 264                 fi
 265
 266                 if test "$cf_ncurses" = ncursesw; then
 267                         AC_CHECK_HEADERS(ncursesw/ncurses.h,[cf_cv_ncurses_header="ncursesw/ncurses.h"])
 268                 else
 269                         AC_CHECK_HEADERS(ncurses.h,[cf_cv_ncurses_header="ncurses.h"])
 270                 fi],
 271
 272                 [CF_CURSES_LIBS])
 273                 ])
 274
 275         old_LIBS="$LIBS"
 276         LIBS="$LIBS $MUTTLIBS"
 277         CF_CHECK_FUNCDECLS([#include <${cf_cv_ncurses_header-curses.h}>],
 278                            [start_color typeahead bkgdset curs_set meta use_default_colors resizeterm])
 279         if test "$ac_cv_func_decl_start_color" = yes; then
 280                 AC_DEFINE(HAVE_COLOR,1,[ Define if your curses library supports color. ])
 281         fi
 282         if test "$ac_cv_func_decl_resizeterm" = yes; then
 283                 MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS resize.o"
 284         fi
 285         LIBS="$old_LIBS"
 286         ])
 287
 288 AC_HEADER_STDC
 289
 290 AC_CHECK_HEADERS(stdarg.h sys/ioctl.h ioctl.h sysexits.h)
 291 AC_CHECK_HEADERS(sys/time.h sys/resource.h)
 292 AC_CHECK_HEADERS(unix.h)
 293
 294 AC_CHECK_FUNCS(setrlimit getsid isctype)
 295
 296 AC_TYPE_SIGNAL
 297
 298 AC_MSG_CHECKING(for sig_atomic_t in signal.h)
 299 AC_EGREP_HEADER(sig_atomic_t,signal.h,
 300   [
 301     ac_cv_type_sig_atomic_t=yes;
 302     AC_EGREP_HEADER(volatile.*sig_atomic_t,
 303                     signal.h,
 304                     [
 305                         is_sig_atomic_t_volatile=yes;
 306                         AC_MSG_RESULT([yes, volatile])
 307                     ],
 308                     [
 309                         is_sig_atomic_t_volatile=no;
 310                         AC_MSG_RESULT([yes, non volatile])
 311                     ])
 312   ],
 313   [
 314     AC_MSG_RESULT(no)
 315     AC_CHECK_TYPE(sig_atomic_t, int)
 316     is_sig_atomic_t_volatile=no
 317   ])
 318 if test $is_sig_atomic_t_volatile = 'yes'
 319 then
 320     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, sig_atomic_t)
 321 else
 322     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, [volatile sig_atomic_t])
 323 fi
 324
 325 AC_DECL_SYS_SIGLIST
 326
 327 AC_TYPE_PID_T
 328 dnl AC_CHECK_TYPE(ssize_t, int)
 329
 330 AC_CHECK_FUNCS(fgetpos memmove setegid srand48 strerror)
 331
 332 AC_REPLACE_FUNCS(strcasecmp strdup)
 333
 334 AC_CHECK_FUNC(getopt)
 335 if test $ac_cv_func_getopt = yes; then
 336         AC_CHECK_HEADERS(getopt.h)
 337 fi
 338
 339 mutt_cv_snprintf=no
 340 SNPRINTFOBJS=""
 341 AC_CHECK_FUNCS(snprintf, , [mutt_cv_snprintf=yes])
 342 AC_CHECK_FUNCS(vsnprintf, , [mutt_cv_snprintf=yes])
 343 if test $mutt_cv_snprintf = yes; then
 344         AC_LIBOBJ(snprintf)
 345 fi
 346
 347 dnl SCO uses chsize() instead of ftruncate()
 348 AC_CHECK_FUNCS(ftruncate, , [AC_CHECK_LIB(x, chsize)])
 349
 350 dnl SCO has strftime() in libintl
 351 AC_CHECK_FUNCS(strftime, , [AC_CHECK_LIB(intl, strftime)])
 352
 353 dnl AIX may not have fchdir()
 354 AC_CHECK_FUNCS(fchdir, , [mutt_cv_fchdir=no])
 355
 356 AC_ARG_WITH(regex, AC_HELP_STRING([--with-regex], [Use the GNU regex library]),
 357         [mutt_cv_regex=yes],
 358         [AC_CHECK_FUNCS(regcomp, mutt_cv_regex=no, mutt_cv_regex=yes)])
 359
 360 if test $mutt_cv_regex = no ; then
 361 AC_CACHE_CHECK([whether your system's regexp library is completely broken],
 362         [mutt_cv_regex_broken],
 363         AC_TRY_RUN([
 364 #include <unistd.h>
 365 #include <regex.h>
 366 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
 367         mutt_cv_regex_broken=no, mutt_cv_regex_broken=yes, mutt_cv_regex_broken=yes))
 368         if test $mutt_cv_regex_broken = yes ; then
 369                 echo "Using the included GNU regex instead." >&AC_FD_MSG
 370                 mutt_cv_regex=yes
 371         fi
 372 fi
 373
 374 if test $mutt_cv_regex = yes; then
 375         AC_DEFINE(USE_GNU_REGEX,1,[ Define if you want to use the included regex.c. ])
 376         AC_LIBOBJ(regex)
 377 fi
 378
 379
 380 AC_ARG_WITH(homespool,
 381   AC_HELP_STRING([--with-homespool[=FILE]], [File in user's directory where new mail is spooled]), with_homespool=${withval})
 382 if test x$with_homespool != x; then
 383         if test $with_homespool = yes; then
 384                 with_homespool=mailbox
 385         fi
 386         AC_DEFINE_UNQUOTED(MAILPATH,"$with_homespool",[ Where new mail is spooled. ])
 387         AC_DEFINE(HOMESPOOL,1,
 388           [Is mail spooled to the user's home directory?  If defined,
 389            MAILPATH should be set to the filename of the spool mailbox
 390            relative the the home directory.
 391            use: configure --with-homespool=FILE])
 392         AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 393         mutt_cv_setgid=no
 394 else
 395         AC_ARG_WITH(mailpath, AC_HELP_STRING([--with-mailpath=DIR], [Directory where spool mailboxes are located]),
 396                 [mutt_cv_mailpath=$withval],
 397                 [ AC_CACHE_CHECK(where new mail is stored, mutt_cv_mailpath,
 398                         [mutt_cv_mailpath=no
 399                         if test -d /var/mail; then
 400                                 mutt_cv_mailpath=/var/mail
 401                         elif test -d /var/spool/mail; then
 402                                 mutt_cv_mailpath=/var/spool/mail
 403                         elif test -d /usr/spool/mail; then
 404                                 mutt_cv_mailpath=/usr/spool/mail
 405                         elif test -d /usr/mail; then
 406                                 mutt_cv_mailpath=/usr/mail
 407                         fi])
 408                 ])
 409         if test "$mutt_cv_mailpath" = no; then
 410                 AC_MSG_ERROR("Could not determine where new mail is stored.")
 411         fi
 412         AC_DEFINE_UNQUOTED(MAILPATH,"$mutt_cv_mailpath",[ Where new mail is spooled. ])
 413
 414         AC_CACHE_CHECK(if $mutt_cv_mailpath is world writable, mutt_cv_worldwrite, [AC_TRY_RUN([#include <sys/types.h>
 415 #include <sys/stat.h>
 416
 417 int main (int argc, char **argv)
 418 {
 419         struct stat s;
 420
 421         stat ("$mutt_cv_mailpath", &s);
 422         if (s.st_mode & S_IWOTH) exit (0);
 423         exit (1);
 424 }], mutt_cv_worldwrite=yes, mutt_cv_worldwrite=no, mutt_cv_worldwrite=no)])
 425
 426         mutt_cv_setgid=no
 427         if test $mutt_cv_worldwrite = yes; then
 428                 AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 429         else
 430
 431                 AC_CACHE_CHECK(if $mutt_cv_mailpath is group writable, mutt_cv_groupwrite, [AC_TRY_RUN([#include <sys/types.h>
 432 #include <sys/stat.h>
 433
 434 int main (int argc, char **argv)
 435 {
 436         struct stat s;
 437
 438         stat ("$mutt_cv_mailpath", &s);
 439         if (s.st_mode & S_IWGRP) exit (0);
 440         exit (1);
 441 }], mutt_cv_groupwrite=yes, mutt_cv_groupwrite=no, mutt_cv_groupwrite=no)])
 442
 443                 if test $mutt_cv_groupwrite = yes; then
 444                         AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 445                         AC_DEFINE(USE_SETGID,1,[ Define if mutt should run setgid "mail". ])
 446                         mutt_cv_setgid=yes
 447                 fi
 448         fi
 449 fi
 450
 451 AC_ARG_ENABLE(external_dotlock, AC_HELP_STRING([--enable-external-dotlock], [Force use of an external dotlock program]),
 452         [mutt_cv_external_dotlock="$enableval"])
 453
 454 if test "x$mutt_cv_setgid" = "xyes" || test "x$mutt_cv_fchdir" = "xno" \
 455         || test "x$mutt_cv_external_dotlock" = "xyes"
 456 then
 457         AC_DEFINE(DL_STANDALONE,1,[ Define if you want to use an external dotlocking program. ])
 458         DOTLOCK_TARGET="muttng_dotlock"
 459 else
 460         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS dotlock.o"
 461 fi
 462
 463 AC_SUBST(DOTLOCK_TARGET)
 464
 465
 466 AC_MSG_CHECKING(where to put the documentation)
 467 AC_ARG_WITH(docdir, AC_HELP_STRING([--with-docdir=PATH], [Specify where to put the documentation]),
 468         [mutt_cv_docdir=$withval],
 469         [mutt_cv_docdir="$mutt_cv_prefix/doc/muttng"])
 470 AC_MSG_RESULT($mutt_cv_docdir)
 471
 472 docdir=$mutt_cv_docdir
 473 AC_SUBST(docdir)
 474
 475 if test x$mutt_cv_setgid = xyes; then
 476         DOTLOCK_GROUP='mail'
 477         DOTLOCK_PERMISSION=2755
 478 else
 479         DOTLOCK_GROUP=''
 480         DOTLOCK_PERMISSION=755
 481 fi
 482 AC_SUBST(DOTLOCK_GROUP)
 483 AC_SUBST(DOTLOCK_PERMISSION)
 484
 485 AC_ARG_WITH(domain, AC_HELP_STRING([--with-domain=DOMAIN], [Specify your DNS domain name]),
 486         [if test $withval != yes; then
 487                 AC_DEFINE_UNQUOTED(DOMAIN,"$withval",[ Define your domain name. ])
 488         fi])
 489
 490 need_socket="no"
 491
 492 dnl -- socket dependencies --
 493
 494 AC_ARG_ENABLE(pop,  AC_HELP_STRING([--enable-pop], [Enable POP3 support]),
 495 [       if test x$enableval = xyes ; then
 496                 AC_DEFINE(USE_POP,1,[ Define if you want support for the POP3 protocol. ])
 497                 MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS pop.o pop_lib.o pop_auth.o"
 498                 need_socket="yes"
 499                 need_pop="yes"
 500                 need_md5="yes"
 501         fi
 502 ])
 503
 504 AC_ARG_ENABLE(imap, AC_HELP_STRING([--enable-imap], [Enable IMAP support]),
 505 [       if test x$enableval = xyes ; then
 506                 AC_DEFINE(USE_IMAP,1,[ Define if you want support for the IMAP protocol. ])
 507                 LIBIMAP="-Limap -limap"
 508                 LIBIMAPDEPS="\$(top_srcdir)/imap/imap.h imap/libimap.a"
 509                 need_imap="yes"
 510                 need_socket="yes"
 511                 need_md5="yes"
 512         fi
 513 ])
 514 AM_CONDITIONAL(BUILD_IMAP, test x$need_imap = xyes)
 515
 516 AC_ARG_ENABLE(nntp, [  --enable-nntp              Enable NNTP support],
 517 [       if test x$enableval = xyes ; then
 518                 AC_DEFINE(USE_NNTP)
 519                 MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS nntp.o newsrc.o"
 520                 need_socket="yes"
 521         fi
 522 ])
 523
 524 dnl -- end socket dependencies --
 525
 526 if test "$need_socket" = "yes"
 527 then
 528         AC_MSG_CHECKING([for socklen_t])
 529         AC_EGREP_HEADER(socklen_t, sys/socket.h, AC_MSG_RESULT([yes]),
 530                 AC_MSG_RESULT([no])
 531                 AC_DEFINE(socklen_t,int,
 532                         [ Define to 'int' if <sys/socket.h> doesn't have it. ]))
 533         AC_CHECK_FUNC(gethostent, , AC_CHECK_LIB(nsl, gethostent))
 534         AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt))
 535         AC_CHECK_FUNCS(getaddrinfo)
 536         AC_DEFINE(USE_SOCKET,1,
 537                 [ Include code for socket support. Set automatically if you enable POP3 or IMAP ])
 538         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS account.o mutt_socket.o mutt_tunnel.o"
 539 fi
 540
 541 dnl -- imap dependencies --
 542
 543 AC_ARG_WITH(gss, AC_HELP_STRING([--with-gss[=PFX]], [Compile in GSSAPI authentication for IMAP]),
 544     gss_prefix="$withval", gss_prefix="no")
 545 if test "$gss_prefix" != "no"
 546 then
 547   if test "$need_imap" = "yes"
 548   then
 549     MUTT_AM_PATH_GSSAPI(gss_prefix)
 550     AC_MSG_CHECKING(GSSAPI implementation)
 551     AC_MSG_RESULT($GSSAPI_IMPL)
 552     if test "$GSSAPI_IMPL" = "none"
 553     then
 554       AC_CACHE_SAVE
 555       AC_MSG_RESULT([GSSAPI libraries not found])
 556     fi
 557     if test "$GSSAPI_IMPL" = "Heimdal"
 558     then
 559       AC_DEFINE(HAVE_HEIMDAL,1,[ Define if your GSSAPI implementation is Heimdal ])
 560     fi
 561     CPPFLAGS="$CPPFLAGS $GSSAPI_CFLAGS"
 562     MUTTLIBS="$MUTTLIBS $GSSAPI_LIBS"
 563     AC_DEFINE(USE_GSS,1,[ Define if you have GSSAPI libraries available ])
 564     need_gss="yes"
 565   else
 566     AC_MSG_WARN([GSS was requested but IMAP is not enabled])
 567   fi
 568 fi
 569 AM_CONDITIONAL(USE_GSS, test x$need_gss = xyes)
 570
 571 dnl -- end imap dependencies --
 572
 573 AC_ARG_WITH(ssl, AC_HELP_STRING([--with-ssl[=PFX]], [Compile in SSL support for POP/IMAP]),
 574 [       if test "$with_ssl" != "no"
 575         then
 576           if test "$need_socket" != "yes"; then
 577            AC_MSG_ERROR([SSL support is only useful with POP or IMAP support])
 578           fi
 579
 580           if test "$with_ssl" != "yes"
 581           then
 582            LDFLAGS="$LDFLAGS -L$withval/lib"
 583            CPPFLAGS="$CPPFLAGS -I$withval/include"
 584           fi
 585           saved_LIBS="$LIBS"
 586
 587           AC_CHECK_LIB(crypto, X509_new,, AC_MSG_ERROR([Unable to find SSL library]))
 588           AC_CHECK_LIB(ssl, SSL_new,, AC_MSG_ERROR([Unable to find SSL library]), -lcrypto)
 589
 590           AC_CHECK_FUNCS(RAND_status RAND_egd)
 591
 592           AC_DEFINE(USE_SSL,1,[ Define if you want support for SSL. ])
 593           LIBS="$saved_LIBS"
 594           MUTTLIBS="$MUTTLIBS -lssl -lcrypto"
 595           MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_ssl.o"
 596           need_ssl=yes
 597
 598         fi
 599 ])
 600 AM_CONDITIONAL(USE_SSL, test x$need_ssl = xyes)
 601
 602 AC_ARG_WITH(gnutls, [  --with-gnutls[=PFX]        Compile in GNU TLS support for POP/IMAP],
 603 [   if test "$need_ssl" = "yes"
 604     then
 605       AC_MSG_ERROR([In order to compile in GNU TLS support, you must first disable SSL support])
 606     fi
 607     if test "$with_gnutls" != "no"
 608     then
 609       if test "$need_socket" != "yes"; then
 610         AC_MSG_ERROR([GNU TLS support is only useful with POP or IMAP support])
 611       fi
 612       if test "$with_gnutls" != "yes"
 613       then
 614         LDFLAGS="$LDFLAGS -L$withval/lib"
 615         CPPFLAGS="$CPPFLAGS -I$withval/include"
 616       fi
 617 #saved_LIBS="$LIBS"
 618
 619       AC_CHECK_LIB([gnutls], [gnutls_init],, AC_MSG_ERROR(Unable to find GNU TLS library))
 620
 621       AC_DEFINE(USE_GNUTLS,1,[ Define if you want support for GNU TLS. ])
 622 #LIBS="$saved_LIBS"
 623 #MUTTLIBS="$MUTTLIBS -lgnutls"
 624       MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_ssl_gnutls.o"
 625       need_gnutls=yes
 626     fi
 627 ])
 628 AM_CONDITIONAL(USE_GNUTLS, test x$need_gnutls = xyes)
 629
 630 dnl SSL support via NSS
 631 AC_ARG_WITH(nss, AC_HELP_STRING([--with-nss[=PFX]], [Compile in SSL support for POP/IMAP via NSS]),
 632 [       if test "$with_nss" != no
 633         then
 634           if test "$need_socket" != "yes"; then
 635            AC_MSG_ERROR([SSL support is only useful with POP or IMAP support])
 636           fi
 637
 638           if test "$with_nss" != "yes"
 639           then
 640            LDFLAGS="$LDFLAGS -L$withval/lib"
 641            CPPFLAGS="$CPPFLAGS -I$withval/include -I$withval/public/security"
 642           fi
 643
 644           AC_DEFINE(USE_NSS,1,[ Define if you want support for SSL via the NSS library. ])
 645           MUTTLIBS="$MUTTLIBS -lssl -lnss -lcertdb -lcerthi -lcryptohi"
 646           MUTTLIBS="$MUTTLIBS -lpk11wrap -lsoftoken -lsecutil -ldbm -lplds4 -lplc4 -lfreebl"
 647           MUTTLIBS="$MUTTLIBS -lnspr4"
 648
 649           MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_ssl_nss.o"
 650           need_ssl=yes
 651         fi
 652 ])
 653
 654 AC_ARG_WITH([gnutls], AC_HELP_STRING([--with-gnutls[=PFX]], [Enable SSL support using gnutls]),
 655     [gnutls_prefix="$withval"], [gnutls_prefix="no"])
 656 if test "$gnutls_prefix" != "no"
 657 then
 658   if test "$need_socket" != "yes"
 659   then
 660     AC_MSG_ERROR([SSL support is only useful with POP or IMAP support])
 661   fi
 662   MUTT_AM_PATH_GNUTLS([$gnutls_prefix],
 663     [dnl GNUTLS found
 664     CPPFLAGS="$CPPFLAGS $LIBGNUTLS_CFLAGS"
 665     MUTTLIBS="$MUTTLIBS $LIBGNUTLS_LIBS"
 666     AC_DEFINE(USE_GNUTLS, 1, [Define if you want support for SSL via the gnutls library.])
 667
 668     MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_ssl_gnutls.o"
 669     need_ssl=yes],
 670     [dnl GNUTLS not found
 671       AC_MSG_ERROR([could not find libgnutls])
 672     ])
 673 fi
 674
 675 AC_ARG_WITH(sasl, AC_HELP_STRING([--with-sasl[=PFX]], [Use Cyrus SASL library for POP/IMAP authentication]),
 676         [
 677         if test "$with_sasl" != "no" -a "$need_imap" != "yes" -a "$need_pop" != "yes"
 678         then
 679           AC_MSG_ERROR([SASL support is only useful with POP or IMAP support])
 680         fi
 681
 682         if test "$with_sasl" != "no"
 683         then
 684           if test "$with_sasl" != "yes"
 685           then
 686             CPPFLAGS="$CPPFLAGS -I$with_sasl/include"
 687             LDFLAGS="$LDFLAGS -L$with_sasl/lib"
 688           fi
 689
 690           saved_LIBS="$LIBS"
 691
 692           AC_CHECK_LIB(sasl, sasl_client_init,,
 693             AC_MSG_ERROR([could not find libsasl]),)
 694
 695           MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_sasl.o"
 696           MUTTLIBS="$MUTTLIBS -lsasl"
 697           LIBS="$saved_LIBS"
 698           AC_DEFINE(USE_SASL,1,
 699                   [ Define if want to use the Cyrus SASL library for POP/IMAP authentication. ])
 700           need_sasl=yes
 701         fi
 702         ])
 703 AM_CONDITIONAL(USE_SASL, test x$need_sasl = xyes)
 704
 705 AC_ARG_WITH(sasl2, AC_HELP_STRING([--with-sasl2[=PFX]], [Use Cyrus SASL library version 2 for POP/IMAP authentication]),
 706         [
 707         if test "$with_sasl2" != "no" -a "$need_imap" != "yes" -a "$need_pop" != "yes"
 708         then
 709           AC_MSG_ERROR([SASL2 support is only useful with POP or IMAP support])
 710         fi
 711
 712         if test "$with_sasl2" != "no"
 713         then
 714           if test "$with_sasl2" != "yes"
 715           then
 716             CPPFLAGS="$CPPFLAGS -I$with_sasl2/include"
 717             LDFLAGS="$LDFLAGS -L$with_sasl2/lib"
 718           fi
 719
 720           saved_LIBS="$LIBS"
 721
 722           AC_CHECK_LIB(sasl2, sasl_client_init,,
 723             AC_MSG_ERROR([could not find libsasl2]),)
 724
 725           MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_sasl.o"
 726           MUTTLIBS="$MUTTLIBS -lsasl2"
 727           LIBS="$saved_LIBS"
 728           AC_DEFINE(USE_SASL,1,
 729                   [ Define if want to use the Cyrus SASL library for POP/IMAP authentication. ])
 730           AC_DEFINE(USE_SASL2,1,
 731                   [ Define if want to use version 2 of the Cyrus SASL library. ])
 732           need_sasl=yes
 733         fi
 734         ])
 735 AM_CONDITIONAL(USE_SASL, test x$need_sasl = xyes)
 736
 737 AC_ARG_WITH(idn, AC_HELP_STRING([--with-idn=[PFX]], [Use GNU libidn for domain names]),
 738                  [
 739                   if test "$with_idn" != "no" ; then
 740                         if test "$with_idn" != "yes" ; then
 741                            CPPFLAGS="$CPPFLAGS -I$with_idn/include"
 742                            LDFLAGS="$LDFLAGS -L$with_idn/lib"
 743                         fi
 744                   fi
 745                  ]
 746 )
 747
 748 if test "x$with_idn" != "xno"; then
 749    AC_CHECK_LIB(idn, stringprep_check_version)
 750    AC_CHECK_FUNCS(idna_to_unicode_utf8_from_utf8 idna_to_unicode_8z8z)
 751    AC_CHECK_FUNCS(idna_to_ascii_from_utf8 idna_to_ascii_8z)
 752    AC_CHECK_FUNCS(idna_to_ascii_lz idna_to_ascii_from_locale)
 753 fi
 754
 755 dnl -- end socket --
 756
 757 AC_ARG_ENABLE(debug, AC_HELP_STRING([--enable-debug], [Enable debugging support]),
 758         [ if test x$enableval = xyes ; then
 759                 AC_DEFINE(DEBUG,1,[ Define to enable debugging info. ])
 760           fi
 761          ])
 762
 763 AC_ARG_ENABLE(flock, AC_HELP_STRING([--enable-flock], [Use flock() to lock files]),
 764         [if test $enableval = yes; then
 765                 AC_DEFINE(USE_FLOCK,1, [ Define to use flock() to lock mailboxes. ])
 766         fi])
 767
 768 mutt_cv_fcntl=yes
 769 AC_ARG_ENABLE(fcntl, AC_HELP_STRING([--disable-fcntl], [Do NOT use fcntl() to lock files]),
 770         [if test $enableval = no; then mutt_cv_fcntl=no; fi])
 771
 772 if test $mutt_cv_fcntl = yes; then
 773         AC_DEFINE(USE_FCNTL,1, [ Define to use fcntl() to lock folders. ])
 774 fi
 775
 776 dnl This may look cumbersome -- please keep it that way, so we can
 777 dnl quickly change the default to "yes" again.
 778 mutt_cv_inodesort=no
 779 AC_ARG_ENABLE(inodesort,  AC_HELP_STRING([--enable-inodesort], [Read files in maildir folders sorted by inode.]),
 780        [if test x$enableval = xyes ; then mutt_cv_inodesort=yes; fi])
 781
 782 if test $mutt_cv_inodesort = yes; then
 783         AC_DEFINE(USE_INODESORT, 1, [ Define to sort files in a maildir by inode number. ])
 784 fi
 785
 786 mutt_cv_warnings=yes
 787 AC_ARG_ENABLE(warnings, AC_HELP_STRING([--disable-warnings], [Turn off compiler warnings (not recommended)]),
 788 [if test $enableval = no; then
 789         mutt_cv_warnings=no
 790 fi])
 791
 792 if test x$GCC = xyes -a $mutt_cv_warnings = yes; then
 793         CFLAGS="-Wall -pedantic $CFLAGS"
 794 fi
 795
 796 AC_ARG_ENABLE(nfs-fix, AC_HELP_STRING([--enable-nfs-fix], [Work around an NFS with broken attributes caching]),
 797         [if test x$enableval = xyes; then
 798                 AC_DEFINE(NFS_ATTRIBUTE_HACK,1,
 799                   [Define if you have problems with mutt not detecting
 800                    new/old mailboxes over NFS.  Some NFS implementations
 801                    incorrectly cache the attributes of small files.])
 802         fi])
 803
 804 AC_ARG_ENABLE(buffy-size, AC_HELP_STRING([--enable-buffy-size], [Use file size attribute instead of access time]),
 805         [if test x$enableval = xyes; then
 806                 AC_DEFINE(BUFFY_SIZE,1,[ Define to enable the "buffy_size" feature. ])
 807         fi])
 808
 809 AC_ARG_ENABLE(mailtool, AC_HELP_STRING([--enable-mailtool], [Enable Sun mailtool attachments support ]),
 810         [if test x$enableval = xyes; then
 811                 AC_DEFINE(SUN_ATTACHMENT,1,[ Define to enable Sun mailtool attachments support. ])
 812         fi])
 813
 814 AC_ARG_ENABLE(compressed, [  --enable-compressed        Enable compressed folders support ],
 815         [if test x$enableval = xyes; then
 816                 AC_DEFINE(USE_COMPRESSED)
 817         fi])
 818
 819 AC_ARG_ENABLE(locales-fix, AC_HELP_STRING([--enable-locales-fix], [The result of isprint() is unreliable ]),
 820         [if test x$enableval = xyes; then
 821                 AC_DEFINE(LOCALES_HACK,1,[ Define if the result of isprint() is unreliable. ])
 822         fi])
 823
 824 AC_ARG_WITH(exec-shell, AC_HELP_STRING([--with-exec-shell=SHELL], [Specify alternate shell (ONLY if /bin/sh is broken)]),
 825         [if test $withval != yes; then
 826                 AC_DEFINE_UNQUOTED(EXECSHELL, "$withval",
 827                  [program to use for shell commands])
 828          else
 829                 AC_DEFINE_UNQUOTED(EXECSHELL, "/bin/sh")
 830         fi],
 831         [AC_DEFINE_UNQUOTED(EXECSHELL, "/bin/sh")])
 832
 833 AC_ARG_ENABLE(exact-address, AC_HELP_STRING([--enable-exact-address], [Enable regeneration of email addresses]),
 834         [if test $enableval = yes; then
 835                 AC_DEFINE(EXACT_ADDRESS,1,
 836                   [Enable exact regeneration of email addresses as parsed?
 837                    NOTE: this requires significant more memory when defined.])
 838
 839         fi])
 840
 841 dnl -- start cache --
 842 AC_ARG_ENABLE(hcache, AC_HELP_STRING([--enable-hcache], [Enable header caching]),
 843 [if test x$enableval = xyes; then
 844     AC_DEFINE(USE_HCACHE, 1, [Enable header caching])
 845
 846     OLDCPPFLAGS="$CPPFLAGS"
 847     OLDLIBS="$LIBS"
 848
 849     need_md5="yes"
 850     ac_prefer_gdbm=yes
 851     AC_ARG_WITH(gdbm, AC_HELP_STRING([--without-gdbm], [Don't use gdbm even if it is available]),
 852         ac_prefer_gdbm=$withval)
 853     if test x$ac_prefer_gdbm != xno; then
 854         CPPFLAGS="$OLDCPPFLAGS"
 855         LIBS="$OLDLIBS -lgdbm";
 856         AC_CACHE_CHECK(for gdbm_open, ac_cv_gdbmopen,[
 857             ac_cv_gdbmopen=no
 858             AC_TRY_LINK([#include <gdbm.h>],[gdbm_open(0,0,0,0,0);],[ac_cv_gdbmopen=yes])
 859         ])
 860     fi
 861
 862     ac_bdb_prefix=yes
 863     AC_ARG_WITH(bdb, AC_HELP_STRING([--with-bdb[=DIR]], [Use BerkeleyDB4 if gdbm is not available ]),
 864         ac_bdb_prefix=$withval)
 865     if test x$ac_bdb_prefix != xno -a x$ac_cv_gdbmopen != xyes; then
 866         test x$ac_bdb_prefix = xyes && ac_bdb_prefix="$mutt_cv_prefix /opt/csw/bdb4 /opt /usr/local /usr"
 867         for d in $ac_bdb_prefix; do
 868             bdbpfx="$bdbpfx $d"
 869             for v in BerkeleyDB.4.3 BerkeleyDB.4.2 BerkeleyDB.4.1; do
 870                 bdbpfx="$bdbpfx $d/$v"
 871             done
 872         done
 873         BDB_VERSIONS="db-4 db4 db-4.3 db4.3 db43 db-4.2 db4.2 db42 db-4.1 db4.1 db41 db ''"
 874         AC_MSG_CHECKING([for BerkeleyDB > 4.0])
 875         for d in $bdbpfx; do
 876             BDB_INCLUDE_DIR=""
 877             BDB_LIB_DIR=""
 878             for v in / $BDB_VERSIONS; do
 879                 if test -r "$d/include/$v/db.h"; then
 880                     BDB_INCLUDE_DIR="$d/include/$v"
 881                     if test -d "$d/lib/$v"; then
 882                         BDB_LIB_DIR="$d/lib/$v"
 883                         for l in `echo $BDB_VERSIONS`; do
 884                             CPPFLAGS="-I$BDB_INCLUDE_DIR $OLDCPPFLAGS"
 885                             LIBS="$OLDLIBS -L$BDB_LIB_DIR -l$l"
 886                             AC_TRY_LINK([
 887                                 #include <stdlib.h>
 888                                 #include <db.h>
 889                             ],[
 890                                 DB *db = NULL;
 891                                 db->open(db,NULL,NULL,NULL,0,0,0);
 892                             ],[
 893                                 ac_cv_dbcreate=yes
 894                                 BDB_LIB="$l"
 895                                 break
 896                             ])
 897                         done
 898                         test x$ac_dbcreate = xyes && break
 899                     fi
 900                 fi
 901             done
 902             test x$BDB_LIB != x && break
 903         done
 904         if test x$ac_cv_dbcreate = xyes; then
 905             AC_MSG_RESULT(yes)
 906         else
 907             AC_MSG_RESULT(no)
 908         fi
 909     fi
 910
 911     if test x$ac_cv_gdbmopen = xyes; then
 912         CPPFLAGS="$OLDCPPFLAGS"
 913         LIBS="$OLDLIBS -lgdbm";
 914         AC_DEFINE(HAVE_GDBM, 1, [GDBM Support])
 915     elif test x$ac_cv_dbcreate = xyes; then
 916         CPPFLAGS="-I$BDB_INCLUDE_DIR $OLDCPPFLAGS"
 917         LIBS="$OLDLIBS -L$BDB_LIB_DIR -l$BDB_LIB"
 918         AC_DEFINE(HAVE_DB4, 1, [Sleepycat DB4 Support])
 919     else
 920         AC_MSG_ERROR(You need Sleepycat DB4 or GDBM for --enable-hcache)
 921     fi
 922 fi])
 923 dnl -- end cache --
 924
 925 AC_SUBST(MUTTLIBS)
 926 AC_SUBST(MUTT_LIB_OBJECTS)
 927 AC_SUBST(LIBIMAP)
 928 AC_SUBST(LIBIMAPDEPS)
 929
 930 dnl -- iconv/gettext --
 931
 932 AC_ARG_ENABLE(iconv, AC_HELP_STRING([--disable-iconv], [Disable iconv support]),
 933         [if test x$enableval = xno ; then
 934                 am_cv_func_iconv=no
 935         fi
 936 ])
 937
 938 MUTT_AM_GNU_GETTEXT
 939
 940 if test "$am_cv_func_iconv" != "yes"
 941 then
 942   AC_MSG_WARN([Configuring without iconv support. See INSTALL for details])
 943 else
 944
 945 AC_CHECK_HEADERS(iconv.h,
 946         [AC_MSG_CHECKING(whether iconv.h defines iconv_t)
 947          AC_EGREP_HEADER([typedef.*iconv_t],iconv.h,
 948                 [AC_MSG_RESULT(yes)
 949                  AC_DEFINE(HAVE_ICONV_T_DEF, 1,
 950                         [Define if <iconv.h> defines iconv_t.])],
 951                  AC_MSG_RESULT(no))])
 952
 953 dnl (1) Some implementations of iconv won't convert from UTF-8 to UTF-8.
 954 dnl (2) In glibc-2.1.2 and earlier there is a bug that messes up ob and
 955 dnl     obl when args 2 and 3 are 0 (fixed in glibc-2.1.3).
 956 AC_CACHE_CHECK([whether this iconv is good enough], mutt_cv_iconv_good,
 957         mutt_save_LIBS="$LIBS"
 958         LIBS="$LIBS $LIBICONV"
 959         AC_TRY_RUN([
 960 #include <iconv.h>
 961 int main()
 962 {
 963   iconv_t cd;
 964 changequote(, )dnl
 965   char buf[4];
 966 changequote([, ])dnl
 967   char *ob;
 968   size_t obl;
 969   ob = buf, obl = sizeof(buf);
 970   return ((cd = iconv_open("UTF-8", "UTF-8")) != (iconv_t)(-1) &&
 971           (iconv(cd, 0, 0, &ob, &obl) ||
 972            !(ob == buf && obl == sizeof(buf)) ||
 973            iconv_close(cd)));
 974 }
 975                 ],
 976                 mutt_cv_iconv_good=yes,
 977                 mutt_cv_iconv_good=no,
 978                 mutt_cv_iconv_good=yes)
 979         LIBS="$mutt_save_LIBS")
 980 if test "$mutt_cv_iconv_good" = no; then
 981   AC_MSG_ERROR(Try using libiconv instead)
 982 fi
 983
 984 dnl This is to detect implementations such as the one in glibc-2.1,
 985 dnl which always convert exactly but return the number of characters
 986 dnl converted instead of the number converted inexactly.
 987 AC_CACHE_CHECK([whether iconv is non-transcribing], mutt_cv_iconv_nontrans,
 988         mutt_save_LIBS="$LIBS"
 989         LIBS="$LIBS $LIBICONV"
 990         AC_TRY_RUN([
 991 #include <iconv.h>
 992 #include <string.h>
 993 int main()
 994 {
 995   iconv_t cd;
 996   const char *ib;
 997   char *ob;
 998   size_t ibl, obl;
 999   const char *s = "\304\211";
1000 changequote(, )dnl
1001   char t[3];
1002 changequote([, ])dnl
1003   ib = s, ibl = 2, ob = t, obl = 3;
1004   return ((cd = iconv_open("UTF-8", "UTF-8")) == (iconv_t)(-1) ||
1005           iconv(cd, &ib, &ibl, &ob, &obl));
1006 }
1007                 ],
1008                 mutt_cv_iconv_nontrans=no,
1009                 mutt_cv_iconv_nontrans=yes,
1010                 mutt_cv_iconv_nontrans=no)
1011         LIBS="$mutt_save_LIBS")
1012 if test "$mutt_cv_iconv_nontrans" = yes; then
1013   AC_DEFINE(ICONV_NONTRANS, 1)
1014 else
1015   AC_DEFINE(ICONV_NONTRANS, 0)
1016 fi
1017
1018 CPPFLAGS="$CPPFLAGS -I\$(top_srcdir)/intl"
1019
1020 if test "$BUILD_INCLUDED_LIBINTL" = "yes"; then
1021   AC_DEFINE(HAVE_BIND_TEXTDOMAIN_CODESET,1,
1022           [ Define if your gettext has bind_textdomain_codeset. ])
1023 else
1024   AC_CHECK_FUNCS(bind_textdomain_codeset)
1025 fi
1026
1027 fi # libiconv
1028
1029 dnl -- locales --
1030
1031 AC_CHECK_HEADERS(wchar.h)
1032
1033 AC_CACHE_CHECK([for wchar_t], mutt_cv_wchar_t,
1034         AC_TRY_COMPILE([
1035 #include <stddef.h>
1036 #include <stdlib.h>
1037 #ifdef HAVE_WCHAR_H
1038 #include <wchar.h>
1039 #endif
1040                 ],
1041                 [ wchar_t wc; return 0; ],
1042                 mutt_cv_wchar_t=yes,
1043                 mutt_cv_wchar_t=no))
1044
1045 if test "$mutt_cv_wchar_t" = no; then
1046         AC_DEFINE(wchar_t,int,[ Define to 'int' if system headers don't define. ])
1047 fi
1048
1049 AC_CACHE_CHECK([for wint_t], mutt_cv_wint_t,
1050         AC_TRY_COMPILE([
1051 #include <stddef.h>
1052 #include <stdlib.h>
1053 #ifdef HAVE_WCHAR_H
1054 #include <wchar.h>
1055 #endif
1056                 ],
1057                 [ wint_t wc; return 0; ],
1058                 mutt_cv_wint_t=yes,
1059                 mutt_cv_wint_t=no))
1060
1061 if test "$mutt_cv_wint_t" = no; then
1062         AC_DEFINE(wint_t,int,[ Define to 'int' if system headers don't define. ])
1063 fi
1064
1065 AC_CHECK_HEADERS(wctype.h)
1066 AC_CHECK_FUNCS(iswalnum iswalpha  iswcntrl iswdigit)
1067 AC_CHECK_FUNCS(iswgraph iswlower iswprint iswpunct iswspace iswupper)
1068 AC_CHECK_FUNCS(iswxdigit towupper towlower)
1069
1070 AC_CACHE_CHECK([for mbstate_t], mutt_cv_mbstate_t,
1071         AC_TRY_COMPILE([
1072 #include <stddef.h>
1073 #include <stdlib.h>
1074 #ifdef HAVE_WCHAR_H
1075 #include <wchar.h>
1076 #endif
1077                 ],
1078                 [ mbstate_t s; return 0; ],
1079                 mutt_cv_mbstate_t=yes,
1080                 mutt_cv_mbstate_t=no))
1081
1082 if test "$mutt_cv_mbstate_t" = no; then
1083         AC_DEFINE(mbstate_t,int,[ Define to 'int' if system headers don't define. ])
1084 fi
1085
1086 wc_funcs=maybe
1087 AC_ARG_WITH(wc-funcs, AC_HELP_STRING([--without-wc-funcs], [Do not use the system's wchar_t functions]),
1088         wc_funcs=$withval)
1089
1090 if test "$wc_funcs" != yes -a "$wc_funcs" != no; then
1091         AC_CACHE_CHECK([for wchar_t functions], mutt_cv_wc_funcs,
1092                 mutt_cv_wc_funcs=no
1093                 AC_TRY_LINK([
1094 #define _XOPEN_SOURCE 1
1095 #include <stddef.h>
1096 #include <stdlib.h>
1097 #ifdef HAVE_WCTYPE_H
1098 #include <wctype.h>
1099 #endif
1100 #ifdef HAVE_WCHAR_H
1101 #include <wchar.h>
1102 #endif],
1103                         [mbrtowc(0, 0, 0, 0); wctomb(0, 0); wcwidth(0);
1104         iswprint(0); iswspace(0); towlower(0); towupper(0); iswalnum(0)],
1105                         mutt_cv_wc_funcs=yes))
1106         wc_funcs=$mutt_cv_wc_funcs
1107 fi
1108
1109 if test $wc_funcs = yes; then
1110         AC_DEFINE(HAVE_WC_FUNCS,1,[ Define if you are using the system's wchar_t functions. ])
1111 fi
1112
1113 AC_CACHE_CHECK([for nl_langinfo and CODESET], mutt_cv_langinfo_codeset,
1114   [AC_TRY_LINK([#include <langinfo.h>],
1115     [char* cs = nl_langinfo(CODESET);],
1116     mutt_cv_langinfo_codeset=yes,
1117     mutt_cv_langinfo_codeset=no)])
1118 if test $mutt_cv_langinfo_codeset = yes; then
1119   AC_DEFINE(HAVE_LANGINFO_CODESET,1,[ Define if you have <langinfo.h> and nl_langinfo(CODESET). ])
1120 fi
1121
1122 AC_CACHE_CHECK([for nl_langinfo and YESEXPR], mutt_cv_langinfo_yesexpr,
1123   [AC_TRY_LINK([#include <langinfo.h>],
1124     [char* cs = nl_langinfo(YESEXPR);],
1125     mutt_cv_langinfo_yesexpr=yes,
1126     mutt_cv_langinfo_yesexpr=no)])
1127 if test $mutt_cv_langinfo_yesexpr = yes; then
1128   AC_DEFINE(HAVE_LANGINFO_YESEXPR,1,[ Define if you have <langinfo.h> and nl_langinfo(YESEXPR). ])
1129 fi
1130
1131 dnl -- libesmtp --
1132 MUTT_AM_LIBESMTP
1133 if test x$use_libesmtp = xyes; then
1134     CFLAGS="$CFLAGS $mutt_libesmtp_cflags"
1135     MUTTLIBS="$MUTTLIBS $mutt_libesmtp_libs"
1136     MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_libesmtp.o"
1137
1138     AC_DEFINE(USE_LIBESMTP,
1139               1,
1140               [Define to enable the use of libesmtp])
1141 fi
1142 dnl -- end libesmtp --
1143
1144 AC_OUTPUT(Makefile intl/Makefile m4/Makefile
1145         po/Makefile.in doc/Makefile contrib/Makefile
1146         muttbug.sh
1147         imap/Makefile
1148         Muttngrc.head
1149         doc/instdoc.sh)